-
Notifications
You must be signed in to change notification settings - Fork 7
/
ErriezDS3231SetBuildDateTime.ino
176 lines (148 loc) · 4.13 KB
/
ErriezDS3231SetBuildDateTime.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
/*
* MIT License
*
* Copyright (c) 2020 Erriez
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in all
* copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
*/
/*!
* \brief DS3231 RTC set build date/time example for Arduino
* \details
* Source: https://github.com/Erriez/ErriezDS3231
* Documentation: https://erriez.github.io/ErriezDS3231
*/
#include <Wire.h>
#include <ErriezDS3231.h>
// Create DS3231 RTC object
ErriezDS3231 rtc;
// Global date/time object
struct tm dt;
void rtcInit()
{
// Initialize RTC
while (!rtc.begin()) {
Serial.println(F("RTC not found"));
delay(3000);
}
// Enable RTC clock
rtc.clockEnable(true);
// Set square wave out pin
// SquareWaveDisable, SquareWave1Hz, SquareWave4096Hz, SquareWave8192Hz, SquareWave32768Hz
rtc.setSquareWave(SquareWaveDisable);
}
bool getBuildTime(const char *str)
{
int hour;
int minute;
int second;
// Convert build time macro to time
if (sscanf(str, "%d:%d:%d", &hour, &minute, &second) != 3) {
return false;
}
dt.tm_hour = hour;
dt.tm_min = minute;
dt.tm_sec = second;
return true;
}
bool getBuildDate(const char *str)
{
const char *monthName[] = {
"Jan", "Feb", "Mar", "Apr", "May", "Jun",
"Jul", "Aug", "Sep", "Oct", "Nov", "Dec"
};
uint8_t monthIndex;
char month[12];
int dayMonth;
int year;
time_t t;
// Convert build time macro to date
if (sscanf(str, "%s %d %d", month, &dayMonth, &year) != 3) {
return false;
}
// Convert month string to month number
for (monthIndex = 0; monthIndex < 12; monthIndex++) {
if (strcmp(month, monthName[monthIndex]) == 0) {
break;
}
}
if (monthIndex >= 12) {
// Not found
return false;
}
// Set date
dt.tm_mday = dayMonth;
dt.tm_mon = monthIndex;
dt.tm_year = year - 1900;
// Calculate day of the week
t = mktime(&dt);
dt.tm_wday = localtime(&t)->tm_wday;
return true;
}
bool rtcSetDateTime()
{
// Convert compile date/time to date/time string
if (!getBuildDate(__DATE__) || !getBuildTime(__TIME__)) {
Serial.print(F("Build date/time error"));
return false;
}
// Print build date/time
Serial.print(F("Build date time: "));
Serial.println(asctime(&dt));
// Set new date time
Serial.print(F("Set RTC date time..."));
if (!rtc.write(&dt)) {
Serial.println(F("FAILED"));
} else {
Serial.println(F("OK"));
}
return true;
}
void setup()
{
// Initialize serial port
delay(500);
Serial.begin(115200);
while (!Serial) {
;
}
Serial.println(F("\nErriez DS3231 RTC Set Time example\n"));
// Initialize TWI
Wire.begin();
Wire.setClock(100000);
// Initialize RTC
rtcInit();
// Set date/time
if (!rtcSetDateTime()) {
// Could not parse build date/time to program RTC
while (1) {
delay(1000);
}
}
}
void loop()
{
// Get date/time
if (!rtc.read(&dt)) {
Serial.println(F("RTC read failed"));
} else {
Serial.println(asctime(&dt));
}
// Wait some time
delay(1000);
}