-
Notifications
You must be signed in to change notification settings - Fork 150
/
SearchWidget.mxml
1211 lines (1065 loc) · 53.8 KB
/
SearchWidget.mxml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0" encoding="utf-8"?>
<!--
///////////////////////////////////////////////////////////////////////////
// Copyright (c) 2010-2011 Esri. All Rights Reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
///////////////////////////////////////////////////////////////////////////
-->
<viewer:BaseWidget xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
xmlns:Search="widgets.Search.*"
xmlns:viewer="com.esri.viewer.*"
xmlns:esri="http://www.esri.com/2008/ags"
xmlns:components="com.esri.viewer.components.*"
x="600" y="300"
initialize="basewidget_initializeHandler()"
widgetConfigLoaded="basewidget_widgetConfigLoaded()">
<viewer:states>
<s:State name="graphicalInput"/>
<s:State name="textInput"/>
<s:State name="resultsList"/>
</viewer:states>
<viewer:transitions>
<s:Transition autoReverse="true" toState="*">
<s:Fade id="fade"/>
</s:Transition>
</viewer:transitions>
<fx:Script>
<![CDATA[
import com.esri.ags.FeatureSet;
import com.esri.ags.Graphic;
import com.esri.ags.Map;
import com.esri.ags.clusterers.IClusterer;
import com.esri.ags.events.DrawEvent;
import com.esri.ags.events.GeometryServiceEvent;
import com.esri.ags.events.LayerEvent;
import com.esri.ags.geometry.Extent;
import com.esri.ags.geometry.Geometry;
import com.esri.ags.geometry.MapPoint;
import com.esri.ags.geometry.Polygon;
import com.esri.ags.layers.FeatureLayer;
import com.esri.ags.layers.supportClasses.FeatureCollection;
import com.esri.ags.layers.supportClasses.LayerDetails;
import com.esri.ags.portal.PopUpRenderer;
import com.esri.ags.portal.supportClasses.PopUpInfo;
import com.esri.ags.portal.supportClasses.PopUpMediaInfo;
import com.esri.ags.renderers.SimpleRenderer;
import com.esri.ags.symbols.PictureMarkerSymbol;
import com.esri.ags.symbols.SimpleFillSymbol;
import com.esri.ags.symbols.SimpleLineSymbol;
import com.esri.ags.symbols.SimpleMarkerSymbol;
import com.esri.ags.symbols.Symbol;
import com.esri.ags.tasks.GeometryServiceSingleton;
import com.esri.ags.tasks.supportClasses.Query;
import com.esri.ags.tools.DrawTool;
import com.esri.ags.utils.GeometryUtil;
import com.esri.viewer.AppEvent;
import com.esri.viewer.utils.ClustererParser;
import com.esri.viewer.utils.ErrorMessageUtil;
import com.esri.viewer.utils.LabelUtil;
import com.esri.viewer.utils.SymbolParser;
import mx.collections.ArrayCollection;
import mx.collections.ArrayList;
import mx.core.LayoutDirection;
import mx.events.FlexEvent;
import mx.rpc.AsyncResponder;
import mx.rpc.events.FaultEvent;
import mx.utils.StringUtil;
import spark.components.supportClasses.ItemRenderer;
import widgets.supportClasses.FeatureSetUtil;
import widgets.supportClasses.ResultAttributes;
import widgets.supportClasses.ResultItem;
private const ICON_URL:String = "assets/images/";
private var configSearchGraphical:Array;
private var configSearchText:Array;
private var finishDrawing:Boolean;
private var graphicalsearchLabel:String;
private var loadingLabel:String;
private var nolayerLabel:String;
private var queryLayer:FeatureLayer;
private var queryGeom:Geometry;
private var queryExpr:String;
private var queryFields:XMLList;
private var queryTitleField:String;
private var queryLinkField:String;
private var queryLinkAlias:String;
private var querySymbol:Symbol;
private var resultsLabel:String;
private var selectionLabel:String;
private var selectedDrawingIcon:FocusableImage;
private var textsearchLabel:String;
private var zoomScale:Number = 50000;
[Bindable]
private var clearLabel:String;
[Bindable]
private var layerLabel:String;
[Bindable]
private var lineLabel:String;
[Bindable]
private var freehandLineLabel:String;
[Bindable]
private var noResultLabel:String;
[Bindable]
private var pointLabel:String;
[Bindable]
private var polygonLabel:String;
[Bindable]
private var freehandPolygonLabel:String;
[Bindable]
private var rectangleLabel:String;
[Bindable]
private var circleLabel:String;
[Bindable]
private var searchResultAC:ArrayCollection;
[Bindable]
private var submitLabel:String;
[Bindable]
private var msgVisible:Boolean = false;
private var drawSymbol:Symbol;
private var resultMarkerSymbol:Symbol;
private var resultLineSymbol:Symbol;
private var resultFillSymbol:Symbol;
private var shareResults:Boolean;
private var pointSearchTolerance:Number = 6;
private var popUpRenderer:PopUpRenderer = new PopUpRenderer();
private var resultFeatureLayer:FeatureLayer;
private function basewidget_initializeHandler():void
{
if (isPartOfPanel) // if widget is part of "left", "right" or "bottom" panel
{
this.percentWidth = this.percentHeight = 100;
wTemplate.percentWidth = wTemplate.percentHeight = 100;
}
else
{
wTemplate.width = Math.max(width, 430);
wTemplate.height = Math.max(height, 240);
}
}
private function basewidget_widgetConfigLoaded():void
{
if (configXML)
{
geometryService.url = GeometryServiceSingleton.instance.url;
geometryService.token = GeometryServiceSingleton.instance.token;
geometryService.proxyURL = GeometryServiceSingleton.instance.proxyURL;
graphicalsearchLabel = configXML.labels.graphicalsearchlabel || getDefaultString("graphicalTitleBarTooltip");
textsearchLabel = configXML.labels.textsearchlabel || getDefaultString("textTitleBarTooltip");
resultsLabel = configXML.labels.resultslabel || getDefaultString("resultsLabel");
layerLabel = configXML.labels.layerlabel || getDefaultString("layerLabel");
nolayerLabel = configXML.labels.nolayerlabel || getDefaultString("nolayerLabel");
submitLabel = configXML.labels.submitlabel || getDefaultString("searchSubmitLabel");
pointLabel = configXML.labels.pointlabel || getDefaultString("drawPointLabel");
lineLabel = configXML.labels.linelabel || getDefaultString("drawLineLabel");
freehandLineLabel = configXML.labels.freehandlinelabel || getDefaultString("drawFreehandLineLabel");
rectangleLabel = configXML.labels.rectanglelabel || getDefaultString("drawRectangleLabel");
circleLabel = configXML.labels.circlelabel || getDefaultString("drawCircleLabel");
polygonLabel = configXML.labels.polygonlabel || getDefaultString("drawPolygonLabel");
freehandPolygonLabel = configXML.labels.freehandpolygonlabel || getDefaultString("drawFreehandPolygonLabel");
clearLabel = configXML.labels.clearlabel || getDefaultString("clearLabel");
loadingLabel = configXML.labels.loadinglabel || getDefaultString("loadingLabel");
selectionLabel = configXML.labels.selectionlabel || getDefaultString("selectionLabel");
noResultLabel = configXML.labels.noresultlabel || getDefaultString("noFeatures");
shareResults = configXML.shareresults[0] && configXML.shareresults == "true";
var symbolParser:SymbolParser = new SymbolParser();
configSearchGraphical = [];
configSearchText = [];
var lyrList:XMLList = configXML..layer;
for (var i:int = 0; i < lyrList.length(); i++)
{
var lyrURL:String = lyrList[i].url;
var lyrLabel:String = lyrList[i].name;
var lyrGraphicalLabel:String = lyrList[i].graphicalsearchlabel || getDefaultString("graphicalsearchLabel");
var lyrTextLabel:String = lyrList[i].textsearchlabel || getDefaultString("textsearchLabel");
var lyrExpr:String = lyrList[i].expression;
var lyrFields:XMLList = lyrList[i].fields;
var lyrTitleField:String = lyrList[i].titlefield;
var lyrLinkField:String = lyrList[i].linkfield;
var lyrSymbol:Symbol = symbolParser.parseSymbol(lyrList[i].symbol[0]);
var linkAlias:String = lyrList[i].linkfield.@alias[0];
var useAMF:String = lyrList[i].useamf;
var useProxy:Boolean = lyrList[i].useproxy[0] && lyrList[i].useproxy == "true";
const orderByFieldsText:String = lyrList[i].orderbyfields[0];
var lyrOrderByFields:Array;
if (orderByFieldsText)
{
lyrOrderByFields = orderByFieldsText.split(',');
}
var layer:FeatureLayer = new FeatureLayer();
layer.addEventListener(LayerEvent.LOAD, searchLayer_loadHandler);
layer.addEventListener(LayerEvent.LOAD_ERROR, searchLayer_faultHandler);
layer.url = lyrURL;
layer.name = buildLayerName(lyrLabel);
if (useProxy && configData.proxyUrl)
{
layer.proxyURL = configData.proxyUrl;
}
if (useAMF)
{
layer.useAMF = useAMF == "true";
}
if (lyrFields && lyrFields[0].@all[0] == "true")
{
layer.outFields = [ "*" ];
}
else if (lyrFields)
{
var fields:XMLList = lyrFields.field;
layer.outFields = [];
for each (var fieldXML:XML in fields)
{
if (fieldXML.@name[0])
{
layer.outFields.push(fieldXML.@name[0]);
}
}
}
var searchLayer:Object =
{
layer: layer,
label: lyrLabel,
textlabel: lyrTextLabel,
graphicallabel: lyrGraphicalLabel,
expr: lyrExpr,
fields: lyrFields,
orderbyfields: lyrOrderByFields,
titlefield: lyrTitleField,
linkfield: lyrLinkField,
linkalias: linkAlias,
symbol: lyrSymbol
};
configSearchGraphical.push(searchLayer);
if (lyrExpr)
{
configSearchText.push(searchLayer);
}
}
const resultMarkerSymbolURL:String = configXML.symbols.picturemarkersymbol.@url || widgetIcon;
const parsedResultMarkerSymbolHeight:Number = parseFloat(configXML.symbols.picturemarkersymbol.@height[0]);
const resultMarkerSymbolHeight:Number = isNaN(parsedResultMarkerSymbolHeight) ? 0 : parsedResultMarkerSymbolHeight;
const parsedResultMarkerSymbolWidth:Number = parseFloat(configXML.symbols.picturemarkersymbol.@width[0]);
const resultMarkerSymbolWidth:Number = isNaN(parsedResultMarkerSymbolWidth) ? 0 : parsedResultMarkerSymbolWidth;
const resultMarkerSymbolXOffset:Number = (configXML.symbols.picturemarkersymbol.@xoffset != null) ? configXML.symbols.picturemarkersymbol.@xoffset : 0;
const resultMarkerSymbolYOffset:Number = (configXML.symbols.picturemarkersymbol.@yoffset != null) ? configXML.symbols.picturemarkersymbol.@yoffset : 0;
resultMarkerSymbol = new PictureMarkerSymbol(resultMarkerSymbolURL, resultMarkerSymbolWidth, resultMarkerSymbolHeight, resultMarkerSymbolXOffset, resultMarkerSymbolYOffset);
const resultLineSymbolColor:uint = (configXML.symbols.simplelinesymbol.@color[0] != null) ? configXML.symbols.simplelinesymbol.@color : 0xFF0000;
const resultLineSymbolAlpha:Number = (configXML.symbols.simplelinesymbol.@alpha[0] != null) ? configXML.symbols.simplelinesymbol.@alpha : 0.8;
const resultLineSymbolWidth:Number = (configXML.symbols.simplelinesymbol.@width[0] != null) ? configXML.symbols.simplelinesymbol.@width : 2;
resultLineSymbol = new SimpleLineSymbol(SimpleLineSymbol.STYLE_SOLID, resultLineSymbolColor, resultLineSymbolAlpha, resultLineSymbolWidth);
const resultFillSymbolColor:uint = (configXML.symbols.simplefillsymbol.@color[0] != null) ? configXML.symbols.simplefillsymbol.@color : 0xFF0000;
const resultFillSymbolAlpha:Number = (configXML.symbols.simplefillsymbol.@alpha[0] != null) ? configXML.symbols.simplefillsymbol.@alpha : 0.5;
const resultFillSymbolOutlineColor:uint = (configXML.symbols.simplefillsymbol.outline.@color[0] != null) ? configXML.symbols.simplefillsymbol.outline.@color : 0xFF0000;
const resultFillSymbolOutlineAlpha:Number = (configXML.symbols.simplefillsymbol.outline.@alpha[0] != null) ? configXML.symbols.simplefillsymbol.outline.@alpha : 0.8;
const resultFillSymbolOutlineWidth:Number = (configXML.symbols.simplefillsymbol.outline.@width[0] != null) ? configXML.symbols.simplefillsymbol.outline.@width : 2;
resultFillSymbol = new SimpleFillSymbol(SimpleFillSymbol.STYLE_SOLID, resultFillSymbolColor, resultFillSymbolAlpha, new SimpleLineSymbol(SimpleLineSymbol.STYLE_SOLID, resultFillSymbolOutlineColor, resultFillSymbolOutlineAlpha, resultFillSymbolOutlineWidth));
resultFeatureLayer = new FeatureLayer();
resultFeatureLayer.visible = false;
resultFeatureLayer.isEditable = false;
var clustererParser:ClustererParser = new ClustererParser();
var clusterer:IClusterer = clustererParser.parseClusterer(configXML.clustering[0]);
if (clusterer)
{
resultFeatureLayer.clusterer = clusterer;
}
resultFeatureLayer.addEventListener(FlexEvent.HIDE, resultFeatureLayer_hideHandler);
var userTolerance:Number = configXML.tolerance;
if (userTolerance > 0)
{
pointSearchTolerance = userTolerance;
}
if (Number(configXML.zoomscale) > 0)
{
zoomScale = Number(configXML.zoomscale);
}
}
wTemplate.addTitlebarButton(ICON_URL + "i_searchgraphical.png", graphicalsearchLabel, showStateGraphicalSearch);
if (configSearchText.length)
{
wTemplate.addTitlebarButton(ICON_URL + "i_searchtext.png", textsearchLabel, showStateTextSearch);
}
wTemplate.addTitlebarButton(ICON_URL + "i_table.png", resultsLabel, showStateResults);
setInitialView(configXML.initialview[0]);
fade.targets = [ graphicalInput, textInput, resultsList ];
wTemplate.visible = true;
setupTextSearch();
setupGraphicalSearch();
AppEvent.addListener(AppEvent.DATA_PUBLISH, sharedDataUpdated);
}
private function buildLayerName(name:String):String
{
var widgetName:String = configXML.layername || widgetTitle;
name = name ? name : widgetName;
if (widgetName == name)
{
return shareResults ? widgetName : "hiddenLayer_" + widgetName;
}
var layerNameTemplate:String =
(layoutDirection == LayoutDirection.LTR) ? "{0} - {1}" : "{1} - {0}";
layerNameTemplate =
shareResults ? layerNameTemplate : "hiddenLayer_" + layerNameTemplate;
return StringUtil.substitute(layerNameTemplate, widgetName, name);
}
private function searchLayer_loadHandler(event:LayerEvent):void
{
var layer:FeatureLayer = event.layer as FeatureLayer;
layer.removeEventListener(LayerEvent.LOAD, searchLayer_loadHandler);
layer.removeEventListener(LayerEvent.LOAD_ERROR, searchLayer_faultHandler);
layer.layerDetails.minScale = 0; // removing scale dependency
layer.layerDetails.maxScale = 0;
}
private function searchLayer_faultHandler(event:LayerEvent):void
{
var layer:FeatureLayer = event.currentTarget as FeatureLayer;
layer.removeEventListener(LayerEvent.LOAD, searchLayer_loadHandler);
layer.removeEventListener(LayerEvent.LOAD_ERROR, searchLayer_faultHandler);
showLoadErrorMessage(event);
}
private function showLoadErrorMessage(event:LayerEvent):void
{
var errorMessage:String = getDefaultString("layerFailedToLoad",
event.layer.name,
ErrorMessageUtil.makeHTMLSafe(ErrorMessageUtil.buildFaultMessage(event.fault)));
showError(errorMessage);
}
private function setInitialView(view:String):void
{
if (view == "graphical")
{
showStateGraphicalSearch();
}
else if (view == "text")
{
showStateTextSearch();
}
}
private function setupTextSearch():void
{
if (configSearchText.length)
{
cboLayerText.dataProvider = new ArrayList(configSearchText);
txtLabelText.text = configSearchText[0].textlabel;
if (configSearchText.length == 1)
{
boxText.visible = false;
boxText.includeInLayout = false;
}
else
{
cboLayerText.typicalItem = LabelUtil.findLongestLabelItem(configSearchText, "label");
}
}
else
{
boxText.visible = false;
txtLabelText.text = nolayerLabel;
}
}
private function setupGraphicalSearch():void
{
if (configSearchGraphical.length)
{
cboLayerGraphical.dataProvider = new ArrayList(configSearchGraphical);
txtLabelGraphical.text = configSearchGraphical[0].graphicallabel;
if (configSearchGraphical.length == 1)
{
boxGraphical.visible = false;
boxGraphical.includeInLayout = false;
}
else
{
cboLayerGraphical.typicalItem = LabelUtil.findLongestLabelItem(configSearchGraphical, "label");
}
}
else
{
boxGraphical.visible = false;
imageGroup.visible = false;
clearGroup.visible = false;
txtLabelGraphical.text = nolayerLabel;
}
}
private function resultFeatureLayer_hideHandler(event:FlexEvent):void
{
hideInfoWindow();
}
private function searchLayerChangedText():void
{
txtLabelText.text = cboLayerText.selectedItem.textlabel;
}
private function searchLayerChangedGraphical():void
{
txtLabelGraphical.text = cboLayerGraphical.selectedItem.graphicallabel;
}
private function activateDrawTool(event:MouseEvent):void
{
addSharedData("Deactivate_DrawTool", null); // to be able to deactivate drawTool on other widgets
// apply glow
selectedDrawingIcon = FocusableImage(event.currentTarget);
clearSelectionFilter();
selectedDrawingIcon.filters = [ glowFilter ];
finishDrawing = false;
var status:String;
var value:String = selectedDrawingIcon.name;
switch (value)
{
case DrawTool.MAPPOINT:
{
status = pointLabel;
drawSymbol = new SimpleMarkerSymbol(SimpleMarkerSymbol.STYLE_CIRCLE, 15, 0x3FAFDC, 1);
break;
}
case DrawTool.POLYLINE:
{
status = lineLabel;
drawSymbol = new SimpleLineSymbol(SimpleLineSymbol.STYLE_SOLID, 0x3FAFDC, 1, 1);
break;
}
case DrawTool.EXTENT:
{
status = rectangleLabel;
drawSymbol = new SimpleFillSymbol(SimpleFillSymbol.STYLE_SOLID, 0x3FAFDC, 0.5, new SimpleLineSymbol(SimpleLineSymbol.STYLE_SOLID, 0x3FAFDC, 1, 1));
break;
}
case DrawTool.POLYGON:
{
status = polygonLabel;
drawSymbol = new SimpleFillSymbol(SimpleFillSymbol.STYLE_SOLID, 0x3FAFDC, 0.5, new SimpleLineSymbol(SimpleLineSymbol.STYLE_SOLID, 0x3FAFDC, 1, 1));
break;
}
}
setMapAction(value, status, drawSymbol, searchDrawEnd);
}
private function searchDrawEnd(event:DrawEvent):void
{
// deactivate the draw tool
finishDrawing = true;
selectedDrawingIcon = null;
clearSelectionFilter();
event.target.deactivate();
var geom:Geometry = event.graphic.geometry;
if (geom is Polygon && GeometryUtil.polygonSelfIntersecting(geom as Polygon))
{
geometryService.simplify([ geom ]);
}
else
{
//to improve search results
if (geom.type == Geometry.MAPPOINT)
{
geom = createExtentAroundMapPoint(geom as MapPoint, pointSearchTolerance);
}
queryFeaturesGraphical(geom);
}
}
private function createExtentAroundMapPoint(centerPoint:MapPoint, tolerance:Number):Extent
{
var screenPoint:Point = map.toScreen(centerPoint as MapPoint);
var upperLeftScreenPoint:Point = new Point(screenPoint.x - tolerance, screenPoint.y - tolerance);
var lowerRightScreenPoint:Point = new Point(screenPoint.x + tolerance, screenPoint.y + tolerance);
var upperLeftMapPoint:MapPoint = map.toMap(upperLeftScreenPoint);
var lowerRightMapPoint:MapPoint = map.toMap(lowerRightScreenPoint);
return new Extent(upperLeftMapPoint.x, upperLeftMapPoint.y, lowerRightMapPoint.x, lowerRightMapPoint.y, map.spatialReference);
}
private function queryFeaturesText():void
{
hideInfoWindow();
var searchLayer:Object = cboLayerText.selectedItem;
queryLayer = searchLayer.layer;
if (queryLayer && !queryLayer.loaded)
{
queryLayer.addEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.addEventListener(LayerEvent.LOAD_ERROR, queryLayer_loadErrorHandler);
function queryLayer_loadHandler(event:LayerEvent):void
{
queryLayer.removeEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.removeEventListener(LayerEvent.LOAD_ERROR, queryLayer_loadErrorHandler);
queryFeaturesText();
}
function queryLayer_loadErrorHandler(event:LayerEvent):void
{
queryLayer.removeEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.removeEventListener(LayerEvent.LOAD_ERROR, queryLayer_loadErrorHandler);
showLoadErrorMessage(event);
}
return;
}
queryExpr = searchLayer.expr;
queryFields = searchLayer.fields;
queryTitleField = searchLayer.titlefield;
queryLinkField = searchLayer.linkfield;
queryLinkAlias = searchLayer.linkalias;
querySymbol = searchLayer.symbol;
if (queryLayer && txtSearch.text)
{
var query:Query = new Query();
var expr:String = queryExpr.replace(/\[value\]/g, txtSearch.text);
query.where = expr;
query.outSpatialReference = map.spatialReference;
const supportsServerSideSorting:Boolean = queryLayer.layerDetails
&& queryLayer.layerDetails.version >= 10.1
&& queryLayer.layerDetails.supportsAdvancedQueries;
const orderByFields:Array = searchLayer.orderbyfields;
if (supportsServerSideSorting && orderByFields)
{
query.orderByFields = orderByFields;
}
var queryOptions:Object =
{
supportsServerSideSorting: supportsServerSideSorting,
orderByFields: orderByFields,
queryFields: queryFields
};
queryLayer.queryFeatures(
query, new AsyncResponder(queryFeatures_resultHandler,
queryFeatures_faultHandler,
queryOptions));
showMessage(loadingLabel, true);
showStateResults();
}
}
private function queryFeatures_resultHandler(featureSet:FeatureSet, queryOptions:Object):void
{
try
{
if (!queryOptions.supportsServerSideSorting && queryOptions.orderByFields)
{
FeatureSetUtil.sortFeaturesByFieldName(featureSet, queryOptions.orderByFields);
}
if (searchResultAC)
{
searchResultAC.removeAll();
}
searchResultAC = createSearchResults(featureSet, queryOptions.queryFields);
addSharedData(widgetTitle, searchResultAC);
if (featureSet.features.length < 1)
{
showMessage(noResultLabel, false);
}
else
{
showMessage(selectionLabel + " " + featureSet.features.length, false);
}
}
catch (error:Error)
{
showMessage(error.message, false);
}
if (!resultFeatureLayer.map)
{
map.addLayer(resultFeatureLayer);
}
}
private function queryFeatures_faultHandler(info:Object, queryOptions:Object):void
{
showMessage(info.toString(), false);
}
private function queryFeaturesGraphical(geom:Geometry):void
{
hideInfoWindow();
var searchLayer:Object = cboLayerGraphical.selectedItem;
queryLayer = searchLayer.layer;
if (queryLayer && !queryLayer.loaded)
{
queryLayer.addEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.addEventListener(LayerEvent.LOAD_ERROR, queryLayer_faultHandler);
function queryLayer_loadHandler(event:LayerEvent):void
{
queryLayer.removeEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.removeEventListener(LayerEvent.LOAD_ERROR, queryLayer_faultHandler);
queryFeaturesGraphical(geom);
}
function queryLayer_faultHandler(event:LayerEvent):void
{
queryLayer.removeEventListener(LayerEvent.LOAD, queryLayer_loadHandler);
queryLayer.removeEventListener(LayerEvent.LOAD_ERROR, queryLayer_faultHandler);
showLoadErrorMessage(event);
}
return;
}
queryGeom = geom;
queryFields = searchLayer.fields;
queryTitleField = searchLayer.titlefield;
queryLinkField = searchLayer.linkfield;
queryLinkAlias = searchLayer.linkalias;
querySymbol = searchLayer.symbol;
if (queryLayer)
{
var query:Query = new Query();
query.geometry = queryGeom;
query.spatialRelationship = Query.SPATIAL_REL_INTERSECTS;
query.outSpatialReference = map.spatialReference;
const supportsServerSideSorting:Boolean = queryLayer.layerDetails
&& queryLayer.layerDetails.version >= 10.1
&& queryLayer.layerDetails.supportsAdvancedQueries;
const orderByFields:Array = searchLayer.orderbyfields;
if (supportsServerSideSorting && orderByFields)
{
query.orderByFields = orderByFields;
}
var queryOptions:Object =
{
supportsServerSideSorting: supportsServerSideSorting,
orderByFields: orderByFields,
queryFields: queryFields
};
queryLayer.queryFeatures(
query, new AsyncResponder(queryFeatures_resultHandler,
queryFeatures_faultHandler,
queryOptions));
showMessage(loadingLabel, true);
showStateResults();
}
}
private function createSearchResults(featureSet:FeatureSet, queryFields:XMLList):ArrayCollection
{
var result:ArrayCollection = new ArrayCollection();
var layerDetails:LayerDetails = queryLayer.layerDetails;
if (!queryTitleField)
{
queryTitleField = featureSet.displayFieldName;
}
var defaultSymbol:Symbol = querySymbol ? querySymbol : getMatchingDefaultSymbol(featureSet.geometryType);
var resultAttributes:ResultAttributes;
var infoWindowRenderer:ClassFactory;
for each (var graphic:Graphic in featureSet.features)
{
graphic.symbol = defaultSymbol;
resultAttributes =
ResultAttributes.toResultAttributes(queryFields, graphic, featureSet,
queryLayer, layerDetails, widgetTitle,
queryTitleField, queryLinkField, queryLinkAlias);
result.addItem(new ResultItem(graphic, resultAttributes));
infoWindowRenderer = new ClassFactory(PopUpRenderer);
infoWindowRenderer.properties = { popUpInfo: configurePopUpInfo(resultAttributes)};
graphic.infoWindowRenderer = infoWindowRenderer;
}
resultFeatureLayer.outFields = queryLayer.outFields;
resultFeatureLayer.visible = true;
resultFeatureLayer.featureCollection = new FeatureCollection(featureSet, layerDetails);
resultFeatureLayer.name = queryLayer.name;
resultFeatureLayer.renderer = new SimpleRenderer(defaultSymbol);
return result;
}
private function getMatchingDefaultSymbol(geometryType:String):Symbol
{
var defaultSymbol:Symbol;
switch (geometryType)
{
case Geometry.MAPPOINT:
{
defaultSymbol = resultMarkerSymbol;
break;
}
case Geometry.POLYLINE:
{
defaultSymbol = resultLineSymbol;
break;
}
case Geometry.POLYGON:
{
defaultSymbol = resultFillSymbol;
break;
}
}
return defaultSymbol;
}
private function configurePopUpInfo(resultAttributes:ResultAttributes):PopUpInfo
{
var popUpInfo:PopUpInfo = new PopUpInfo;
popUpInfo.title = resultAttributes.title;
popUpInfo.description = resultAttributes.content;
var link:String = resultAttributes.link;
var linkAlias:String = resultAttributes.linkAlias
if (link)
{
var pos:Number = link.length - 4;
var sfx:String = link.substr(pos, 4).toLowerCase();
var isImageLink:Boolean = (sfx == ".jpg") || (sfx == ".png") || (sfx == ".gif");
if (isImageLink)
{
var popUpMediaInfo:PopUpMediaInfo = new PopUpMediaInfo;
popUpMediaInfo.type = PopUpMediaInfo.IMAGE;
popUpMediaInfo.imageLinkURL = link;
popUpMediaInfo.imageSourceURL = link;
popUpInfo.popUpMediaInfos = [ popUpMediaInfo ];
}
else
{
var linkText:String = linkAlias ? linkAlias : link;
popUpInfo.description += "<br/><a href='" + link + "'>" + linkText + "</a>";
}
}
return popUpInfo;
}
private function clear():void
{
hideInfoWindow();
if (resultFeatureLayer)
{
resultFeatureLayer.featureCollection = new FeatureCollection(new FeatureSet(), resultFeatureLayer.layerDetails); // empty featureset to clear
}
clearMessage();
txtSearch.text = "";
if (searchResultAC)
{
searchResultAC.removeAll();
}
}
private var hitimer:uint;
private function mouseOverSearchResult(event:Event):void
{
if (resultFeatureLayer.visible)
{
clearTimeout(hitimer);
var searchResult:ResultItem = ItemRenderer(event.target).data as ResultItem;
var mapExtentContainsSearchResult:Boolean = map.extent.containsXY(searchResult.center.x, searchResult.center.y);
if (mapExtentContainsSearchResult)
{
hitimer = setTimeout(showHighlight, 300, [ searchResult ]);
}
else
{
hideInfoWindow();
}
}
}
private function mouseOutSearchResult(event:Event):void
{
clearTimeout(hitimer);
}
private function clickSearchResult(event:Event):void
{
if (resultFeatureLayer.visible)
{
var searchResult:ResultItem = ItemRenderer(event.target).data as ResultItem;
if (searchResult.geometry)
{
if (searchResult.geometry.type == Geometry.MAPPOINT)
{
if (map.scale > zoomScale)
{
map.scale = zoomScale;
}
}
map.zoomTo(searchResult.geometry);
}
clearTimeout(hitimer);
hitimer = setTimeout(showHighlight, 300, [ searchResult ]);
}
}
private function showHighlight(params:Array):void
{
var searchResult:ResultItem = params[0];
var showHighlightPoint:MapPoint = searchResult.center as MapPoint;
var linkAlias:String = searchResult.attributes.linkAlias;
popUpRenderer.popUpInfo = configurePopUpInfo(searchResult.attributes);
popUpRenderer.graphic = searchResult.graphic;
map.infoWindow.content = popUpRenderer;
map.infoWindow.contentOwner = popUpRenderer.graphic;
map.infoWindow.show(showHighlightPoint);
}
private function showMessage(msg:String, swfVisible:Boolean):void
{
txtMessage.text = msg;
swfMessage.visible = swfVisible;
msgVisible = true;
}
private function clearMessage():void
{
msgVisible = false;
}
private function widgetClosedHandler(event:Event):void
{
if (shareResults)
{
map.removeLayer(resultFeatureLayer);
}
else
{
resultFeatureLayer.visible = false;
}
hideInfoWindow();
setMapNavigation(null, null);
finishDrawing = true;
if (selectedDrawingIcon)
{
selectedDrawingIcon.filters = [];
selectedDrawingIcon = null;
}
}
private function widgetOpenedHandler(event:Event):void
{
if (resultFeatureLayer)
{
if (shareResults)
{
map.addLayer(resultFeatureLayer);
}
else
{
resultFeatureLayer.visible = true;
}
}
}
private function showStateGraphicalSearch():void
{
this.currentState = "graphicalInput";
wTemplate.selectedTitlebarButtonIndex = 0;
}
private function showStateTextSearch():void
{
this.currentState = "textInput";
wTemplate.selectedTitlebarButtonIndex = 1;
}
private function showStateResults():void
{
this.currentState = "resultsList";
wTemplate.selectedTitlebarButtonIndex = 2;
}
private function iconRollOverHandler(event:MouseEvent):void
{
clearSelectionFilter();
event.target.filters = [ glowFilter ];
}
private function iconRollOutHandler(event:MouseEvent):void
{
clearSelectionFilter();
}
private function clearSelectionFilter():void
{
for (var i:int = 0; i < imageGroup.numChildren; i++)
{
if (imageGroup.getChildAt(i).filters && imageGroup.getChildAt(i).filters.length > 0)
{
if (!(selectedDrawingIcon && imageGroup.getChildAt(i) === selectedDrawingIcon))
{
imageGroup.getChildAt(i).filters = [];
}
}
}
}
private function sharedDataUpdated(event:AppEvent):void
{
var data:Object = event.data;
if (data.key == "Deactivate_DrawTool")
{
setMapAction(null, null, null, null);
if (selectedDrawingIcon)