/
MapManager.mxml
1657 lines (1470 loc) · 72.4 KB
/
MapManager.mxml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0" encoding="utf-8"?>
<!--
///////////////////////////////////////////////////////////////////////////
// Copyright (c) 2010-2011 Esri. All Rights Reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
///////////////////////////////////////////////////////////////////////////
-->
<!---
Class used to configure the viewer map component (including layers) and handle map navigation modes.
-->
<s:SkinnableContainer xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
width="100%" height="100%"
creationComplete="this_creationCompleteHandler()"
skinClass="com.esri.viewer.skins.MapManagerSkin">
<fx:Metadata>
[SkinState("decorated")]
[SkinState("resized")]
[SkinState("normal")]
</fx:Metadata>
<fx:Script>
<![CDATA[
import com.esri.ags.Graphic;
import com.esri.ags.Map;
import com.esri.ags.SpatialReference;
import com.esri.ags.events.DrawEvent;
import com.esri.ags.events.LayerEvent;
import com.esri.ags.events.MapEvent;
import com.esri.ags.geometry.Extent;
import com.esri.ags.geometry.Geometry;
import com.esri.ags.geometry.MapPoint;
import com.esri.ags.layers.ArcGISDynamicMapServiceLayer;
import com.esri.ags.layers.ArcGISTiledMapServiceLayer;
import com.esri.ags.layers.FeatureLayer;
import com.esri.ags.layers.KMLLayer;
import com.esri.ags.layers.Layer;
import com.esri.ags.layers.supportClasses.Field;
import com.esri.ags.layers.supportClasses.LayerDetails;
import com.esri.ags.layers.supportClasses.LayerInfoWindowRenderer;
import com.esri.ags.layers.supportClasses.StaticLayer_m_esriLogo;
import com.esri.ags.layers.supportClasses.TableDetails;
import com.esri.ags.portal.PopUpRenderer;
import com.esri.ags.portal.supportClasses.PopUpFieldFormat;
import com.esri.ags.portal.supportClasses.PopUpFieldInfo;
import com.esri.ags.portal.supportClasses.PopUpInfo;
import com.esri.ags.portal.supportClasses.PopUpMediaInfo;
import com.esri.ags.skins.ScaleBarMetricSkin;
import com.esri.ags.skins.ScaleBarSkin;
import com.esri.ags.skins.ScaleBarUSSkin;
import com.esri.ags.symbols.PictureMarkerSymbol;
import com.esri.ags.symbols.SimpleFillSymbol;
import com.esri.ags.symbols.SimpleLineSymbol;
import com.esri.ags.symbols.SimpleMarkerSymbol;
import com.esri.ags.symbols.Symbol;
import com.esri.ags.symbols.TextSymbol;
import com.esri.ags.tasks.GeometryServiceSingleton;
import com.esri.ags.tasks.supportClasses.ProjectParameters;
import com.esri.ags.tools.DrawTool;
import com.esri.ags.tools.NavigationTool;
import com.esri.ags.utils.WebMercatorUtil;
import com.esri.viewer.AppEvent;
import com.esri.viewer.ConfigData;
import com.esri.viewer.DrawTooltips;
import com.esri.viewer.IBaseWidget;
import com.esri.viewer.IInfowindowTemplate;
import com.esri.viewer.ViewerContainer;
import com.esri.viewer.components.InfoPopup;
import com.esri.viewer.components.toc.utils.MapUtil;
import com.esri.viewer.utils.ErrorMessageUtil;
import com.esri.viewer.utils.LocalizationUtil;
import com.esri.viewer.utils.MapServiceUtil;
import mx.collections.ArrayCollection;
import mx.collections.ArrayList;
import mx.containers.Canvas;
import mx.controls.Alert;
import mx.events.CloseEvent;
import mx.events.FlexEvent;
import mx.managers.CursorManagerPriority;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.Fault;
import mx.rpc.IResponder;
import mx.rpc.Responder;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.http.HTTPService;
import spark.components.Group;
import spark.globalization.SortingCollator;
private const MAP_MANAGER:String = "MapManager";
[Embed(source="/assets/images/cross_cursor.png")]
private var _crossCursor:Class;
private var _cursorID:int = -1;
/* skin section */
[SkinPart(required="false")]
public var managerView:Group;
[SkinPart(required="false")]
public var map:Map;
[Bindable]
public var mapLeft:Number = 0;
[Bindable]
public var mapRight:Number = 0;
[Bindable]
public var mapTop:Number = 0;
[Bindable]
public var mapBottom:Number = 0;
private var m_configData:ConfigData;
private var m_defaultStatus:String;
private var m_infoPopup:InfoPopup;
private var m_navTool:NavigationTool;
private var m_navigationTool:String;
private var m_navigationStatus:String;
private var m_drawTool:DrawTool;
private var m_drawUpdateFunction:Function;
private var m_drawEndFunction:Function;
private var m_initialExtent:Extent;
private var m_fullExtent:Extent;
private var m_mapManagerState:String = "resized";
private var m_optLayerTable:Array = [];
private var m_basemapLayerIndex:int = 0;
private var m_operationalLayerIndex:int = 0;
private var m_basemapLayers:Array = [];
private var m_operationalLayers:Array = [];
private var m_sortingCollator:SortingCollator;
private function this_creationCompleteHandler():void
{
// for ordering popup fields
m_sortingCollator = new SortingCollator;
m_sortingCollator.setStyle("locale", resourceManager.localeChain[0]);
AppEvent.addListener(AppEvent.CONFIG_LOADED, configLoadedHandler);
AppEvent.addListener(AppEvent.SET_MAP_NAVIGATION, setMapNavigationHandler);
AppEvent.addListener(AppEvent.BASEMAP_SWITCH, basemapSwitchHandler);
AppEvent.addListener(AppEvent.SET_MAP_ACTION, setMapActionHandler);
AppEvent.addListener(AppEvent.SHOW_INFOWINDOW, showInfoWindowHandler);
AppEvent.addListener(AppEvent.MAP_RESIZE, mapResizeHandler);
AppEvent.addListener(AppEvent.DATA_OPT_LAYERS, dataOptLayersHandler);
AppEvent.addListener(AppEvent.MAP_LAYER_VISIBLE, mapLayerVisibleHandler);
}
protected override function partAdded(partName:String, instance:Object):void
{
super.partAdded(partName, instance);
if (instance === map)
{
var cssStyleDeclaration:CSSStyleDeclaration = styleManager.getStyleDeclaration("com.esri.ags.components.supportClasses.InfoWindow")
cssStyleDeclaration.setStyle("backgroundColor", getStyle('contentBackgroundColor'));
styleManager.setStyleDeclaration("com.esri.ags.components.supportClasses.InfoWindow", cssStyleDeclaration, true);
}
}
private function setViewerVersion():void
{
var contextMenuText:String = LocalizationUtil.getDefaultString("contextMenuText");
var aboutText:String = LocalizationUtil.getDefaultString("aboutText");
var menuItem:ContextMenuItem = new ContextMenuItem(contextMenuText, true, true);
menuItem.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, function(event:ContextMenuEvent):void
{
// save normal labels
var buttonWidth:Number = Alert.buttonWidth;
var yesLabel:String = Alert.yesLabel;
var noLabel:String = Alert.noLabel;
// change labels
Alert.buttonWidth = 100;
Alert.yesLabel = LocalizationUtil.getDefaultString("aboutLearnMoreBtn");
Alert.noLabel = LocalizationUtil.getDefaultString("aboutCloseBtn");
Alert.show(aboutText, contextMenuText, Alert.YES | Alert.NO, null, function(event:CloseEvent):void
{
if (event.detail == Alert.YES)
{
navigateToURL(new URLRequest("http://links.esri.com/flexviewer"));
}
}, StaticLayer_m_esriLogo, Alert.NO);
// restore labels to normal
Alert.buttonWidth = buttonWidth;
Alert.yesLabel = yesLabel;
Alert.noLabel = noLabel;
});
if (map.contextMenu)
{
// call contextMenu dynamically so this will compile in AIR
if (map.contextMenu["customItems"] is Array)
{
(map.contextMenu["customItems"] as Array).push(menuItem);
}
else if (map.contextMenu["addItem"])
{
map.contextMenu["addItem"](menuItem);
}
}
}
//config
//TODO: Factory or builder pattern need to be used for extendability
private function configLoadedHandler(event:AppEvent):void
{
m_configData = event.data as ConfigData;
AppEvent.dispatch(AppEvent.MAP_LOADED, map);
var infoContainer:Canvas = new Canvas(); // TODO - make this a Group instance.
infoContainer.setStyle("borderSkin", null);
/* Adding these two lines removes the container that displays below the header controller in graphical theme
but increases CPU usage.
TODO: Need to convert see if this is needed. if yes, then could be replaced by Group
infoContainer.x = -100
infoContainer.y = -100
*/
infoContainer.percentWidth = 100;
infoContainer.percentHeight = 100;
infoContainer.horizontalScrollPolicy = "off";
infoContainer.verticalScrollPolicy = "off";
managerView.addElement(infoContainer);
m_infoPopup = new InfoPopup();
m_infoPopup.map = map;
infoContainer.addChild(m_infoPopup);
m_navTool = new NavigationTool();
m_navTool.map = map;
m_drawTool = new DrawTool();
m_drawTool.map = map;
m_drawTool.addEventListener(DrawEvent.DRAW_END, drawEndHandler);
m_drawTool.addEventListener(DrawEvent.DRAW_UPDATE, drawUpdateHandler);
configMapAttributes();
configBasemaps();
setViewerVersion();
}
private function configMapAttributes():void
{
var mapSpatialReference:SpatialReference;
for (var i:int = 0; i < m_configData.mapAttrs.length; i++)
{
var id:String = m_configData.mapAttrs[i].id;
if (id == "full")
{
var fullExtentTextCoordinates:String = m_configData.mapAttrs[i].extent;
m_fullExtent = MapUtil.createExtent(fullExtentTextCoordinates.split(" "));
}
else if (id == "initial")
{
var initExtentTextCoordinates:String = m_configData.mapAttrs[i].extent;
m_initialExtent = MapUtil.createExtent(initExtentTextCoordinates.split(" "));
map.addEventListener(MapEvent.LOAD, map_loadHandler);
}
else if (id == "center")
{
map.addEventListener(MapEvent.LOAD, map_loadHandler);
}
else if (id == "map")
{
var mapAttr:Object = m_configData.mapAttrs[i];
if (mapAttr.left || mapAttr.right || mapAttr.top || mapAttr.bottom)
{
this.m_mapManagerState = "decorated";
dispatchEvent(new Event(m_mapManagerState));
invalidateSkinState();
if (mapAttr.left)
{
this.left = mapAttr.left;
}
if (mapAttr.right)
{
this.right = mapAttr.right;
}
if (mapAttr.top)
{
this.top = mapAttr.top;
}
if (mapAttr.bottom)
{
this.bottom = mapAttr.bottom;
}
this.m_mapManagerState = "decorated";
dispatchEvent(new Event(this.m_mapManagerState));
invalidateSkinState();
}
}
else if (id == "spatialref")
{
var wkid:Number = m_configData.mapAttrs[i].wkid;
var wkt:String = m_configData.mapAttrs[i].wkt;
if (wkid || wkt)
{
mapSpatialReference = new SpatialReference(wkid, wkt);
}
m_configData.mapAttrs[i].refObj = mapSpatialReference;
}
else if (id == "zoomSlider")
{
map.zoomSliderVisible = m_configData.mapAttrs[i].zoomSliderVisible;
}
else if (id == "scaleBar")
{
map.scaleBarVisible = m_configData.mapAttrs[i].scaleBarVisible;
var scaleBarStyleName:String = m_configData.mapAttrs[i].scaleBarStyleName;
if (scaleBarStyleName)
{
var scaleBarStyleDeclaration:CSSStyleDeclaration = styleManager.getStyleDeclaration('com.esri.ags.components.ScaleBar');
scaleBarStyleDeclaration.setStyle("skinClass", toScaleBarSkinClass(scaleBarStyleName));
}
}
else if (id == "esriLogo")
{
map.logoVisible = m_configData.mapAttrs[i].esriLogoVisible;
}
else if (id == "attributionVisible")
{
map.attributionVisible = m_configData.mapAttrs[i].attributionVisible;
}
else if (id == "openHandCursor")
{
map.openHandCursorVisible = m_configData.mapAttrs[i].openHandCursorVisible;
}
else if (id == "wrapAround180")
{
map.wrapAround180 = m_configData.mapAttrs[i].wrapAround180;
}
else if (id == "panEasingFactor")
{
map.panEasingFactor = m_configData.mapAttrs[i].panEasingFactor;
}
else if (id == "lods")
{
map.lods = m_configData.mapAttrs[i].lods;
}
else if (id == "mapRotation")
{
map.mapRotation = m_configData.mapAttrs[i].mapRotation;
}
}
// set size now so that only one extentChange event will be fired
map.percentHeight = 100;
map.percentWidth = 100;
if (m_fullExtent)
{
m_fullExtent.spatialReference = mapSpatialReference;
}
if (m_initialExtent)
{
//ensure map's SR, extent may be updated later if projection is needed
map.extent = new Extent(m_initialExtent.xmin,
m_initialExtent.ymin,
m_initialExtent.xmax,
m_initialExtent.ymax,
mapSpatialReference);
}
}
private function map_loadHandler(event:MapEvent):void
{
map.removeEventListener(MapEvent.LOAD, map_loadHandler);
if (m_initialExtent)
{
project(m_initialExtent, new mx.rpc.Responder(project_resultHandler,
project_faultHandler));
}
else
{
applyCenter();
}
function project_resultHandler(extent:Extent):void
{
map.extent = extent;
applyCenter();
}
function project_faultHandler(fault:Fault):void
{
applyCenter();
}
}
private function project(geometry:Geometry, responder:IResponder):void
{
var canApplyDirectlyToMap:Boolean = !geometry.spatialReference
|| map.spatialReference.equals(geometry.spatialReference)
|| (map.spatialReference.isWebMercator() && geometry.spatialReference.isWebMercator());
if (canApplyDirectlyToMap)
{
responder.result(geometry);
}
else if (map.spatialReference.isWebMercator()
&& geometry.spatialReference.wkid == 4326)
{
responder.result(WebMercatorUtil.geographicToWebMercator(geometry));
}
else if (map.spatialReference.wkid == 4326
&& geometry.spatialReference.isWebMercator())
{
responder.result(WebMercatorUtil.webMercatorToGeographic(geometry));
}
else
{
var projectParams:ProjectParameters = new ProjectParameters();
projectParams.geometries = [ geometry ];
projectParams.outSpatialReference = map.spatialReference;
GeometryServiceSingleton.instance.project(
projectParams, new mx.rpc.Responder(projectionSuccessHandler,
projectionFailureHandler));
function projectionSuccessHandler(geometries:Array):void
{
responder.result(geometries[0]);
}
function projectionFailureHandler(fault:Fault):void
{
responder.fault(fault);
}
}
}
private function applyCenter():void
{
var center:String;
var level:Number;
var scale:Number;
for (var i:int = 0; i < m_configData.mapAttrs.length; i++)
{
var id:String = m_configData.mapAttrs[i].id;
if (id == "center")
{
center = m_configData.mapAttrs[i].center;
}
else if (id == "level")
{
level = parseInt(m_configData.mapAttrs[i].level);
}
else if (id == "scale")
{
scale = parseFloat(m_configData.mapAttrs[i].scale);
}
}
if (!center)
{
return;
}
var centerPoint:MapPoint = createMapPoint(center.split(" "));
if (!centerPoint)
{
return;
}
project(centerPoint,
new mx.rpc.Responder(project_resultHandler,
project_faultHandler));
function project_resultHandler(center:MapPoint):void
{
map.centerAt(center);
if (scale > 0)
{
map.scale = scale;
}
else if (level >= 0)
{
map.level = level;
}
}
function project_faultHandler(fault:Fault):void {}
}
private function createMapPoint(textualMapPointAttributes:Array):MapPoint
{
var point:MapPoint;
if (textualMapPointAttributes.length >= 2)
{
var pointX:Number = parseFloat(textualMapPointAttributes[0]);
var pointY:Number = parseFloat(textualMapPointAttributes[1]);
if (textualMapPointAttributes.length == 3)
{
var wkid:Number = parseFloat(textualMapPointAttributes[2]);
}
if (!isNaN(pointX) && !isNaN(pointY))
{
point = new MapPoint(pointX, pointY);
if (!isNaN(wkid))
{
point.spatialReference = new SpatialReference(wkid);
}
}
}
return point;
}
private function configBasemaps():void
{
m_basemapLayers.forEach(removeLayer);
var layers:Array = m_configData.basemaps;
for (var i:uint = 0; i < layers.length; i++)
{
if (!layers[i].reference)
{
m_basemapLayers.push(layers[i]);
}
}
if (m_basemapLayers.length > 0)
{
loadNextBasemapLayer();
}
else
{
configOperationalLayers();
}
if (layers.length > 0)
{
map.addEventListener(MapEvent.LAYER_ADD, layerloadComplete);
}
}
private function loadNextBasemapLayer():void
{
var basemapLayerObject:Object = m_basemapLayers[m_basemapLayerIndex];
var layer:Layer = basemapLayerObject.layer ? basemapLayerObject.layer : LayerCreator.createLayerFromLayerObject(basemapLayerObject);
basemapLayerObject.layer = layer;
// configure popups, if any
configureLayerRenderer(basemapLayerObject, false);
}
private function configReferenceBasemaps():void
{
var layers:Array = m_configData.basemaps;
var layerObject:Object;
for (var i:uint = 0; i < layers.length; i++)
{
layerObject = layers[i];
if (layerObject.reference)
{
layerObject.layer = layerObject.layer ? layerObject.layer : LayerCreator.createLayerFromLayerObject(layerObject);
addLayerToMap(layerObject);
}
}
}
private function configOperationalLayers():void
{
m_operationalLayers.forEach(removeLayer);
var layers:Array = m_configData.opLayers;
if (layers && layers.length > 0)
{
for (var i:uint = 0; i < layers.length; i++)
{
m_operationalLayers.push(layers[i]);
}
}
if (m_operationalLayers.length > 0)
{
loadNextOperationalLayer();
}
else
{
configReferenceBasemaps();
}
}
private function loadNextOperationalLayer():void
{
var optLayerObject:Object = m_operationalLayers[m_operationalLayerIndex];
var layer:Layer = optLayerObject.layer ? optLayerObject.layer : LayerCreator.createLayerFromLayerObject(optLayerObject);
optLayerObject.layer = layer;
// configure pop-ups, if any
configureLayerRenderer(optLayerObject, true);
}
private function addLayerToMap(layerObject:Object):void
{
var layer:Layer = layerObject.layer;
if (layer)
{
layer.addEventListener(LayerEvent.LOAD_ERROR, layer_loadErrorEvent);
layer.addEventListener(LayerEvent.LOAD, layer_loadEvent);
if (layer is FeatureLayer)
{
layer.addEventListener(FlexEvent.HIDE, featureLayer_hideHandler);
}
if (layer is KMLLayer)
{
layer.addEventListener(FlexEvent.HIDE, kmlLayer_hideHandler);
}
map.addLayer(layer);
}
else
{
var errorMessage:String = LocalizationUtil.getDefaultString('incorrectLayerTypeText', "'" + layerObject.type + "'");
AppEvent.showError(errorMessage, MAP_MANAGER);
}
}
private function layer_loadErrorEvent(event:LayerEvent):void
{
event.layer.removeEventListener(LayerEvent.LOAD_ERROR, layer_loadErrorEvent);
event.layer.removeEventListener(LayerEvent.LOAD, layer_loadEvent);
if (event.fault.faultString != "Sign in aborted")
{
var errorMessage:String = LocalizationUtil.getDefaultString("layerFailedToLoad",
event.layer.name,
ErrorMessageUtil.makeHTMLSafe(ErrorMessageUtil.buildFaultMessage(event.fault)));
AppEvent.showError(errorMessage, MAP_MANAGER);
}
// remove layer from map and map switcher
removeLayerFromLayerObject(event.layer);
map.removeLayer(event.layer);
}
private function removeLayerFromLayerObject(layer:Layer):void
{
var layerFound:Boolean;
var i:int;
for (i = 0; i < m_configData.opLayers.length; )
{
if (m_configData.opLayers[i].layer == layer)
{
layerFound = true;
m_configData.opLayers.splice(i, 1);
break;
}
else
{
i++;
}
}
if (!layerFound)
{
for (i = 0; i < m_configData.basemaps.length; )
{
if (m_configData.basemaps[i].layer == layer)
{
layerFound = true;
m_configData.basemaps.splice(i, 1);
break;
}
else
{
i++;
}
}
}
}
private function layer_loadEvent(event:LayerEvent):void
{
event.layer.removeEventListener(LayerEvent.LOAD_ERROR, layer_loadErrorEvent);
event.layer.removeEventListener(LayerEvent.LOAD, layer_loadEvent);
// update visible layers on dynamic map service
if (event.layer is ArcGISDynamicMapServiceLayer)
{
var arcgisDynamicMapServiceLayer:ArcGISDynamicMapServiceLayer = event.layer as ArcGISDynamicMapServiceLayer;
var visibleLayers:Array = arcgisDynamicMapServiceLayer.visibleLayers ? arcgisDynamicMapServiceLayer.visibleLayers.toArray() : null;
var layerInfos:Array = arcgisDynamicMapServiceLayer.dynamicLayerInfos || arcgisDynamicMapServiceLayer.layerInfos;
var actualVisibleLayers:Array = MapServiceUtil.getVisibleSubLayers(layerInfos, visibleLayers);
arcgisDynamicMapServiceLayer.visibleLayers = new ArrayList(actualVisibleLayers);
}
}
private function featureLayer_hideHandler(event:FlexEvent):void
{
const featureLayer:FeatureLayer = event.target as FeatureLayer;
const graphic:Graphic = map.infoWindow.contentOwner as Graphic;
if (map.infoWindow.visible && graphic && graphic.graphicsLayer === featureLayer)
{
map.infoWindow.hide();
}
}
private function kmlLayer_hideHandler(event:FlexEvent):void
{
const kmlLayer:KMLLayer = event.target as KMLLayer;
const graphic:Graphic = map.infoWindow.contentOwner as Graphic;
if (map.infoWindow.visible && graphic)
{
for (var i:int = 0; i < kmlLayer.layers.length; )
{
if (graphic.graphicsLayer === kmlLayer.layers[i])
{
map.infoWindow.hide();
break;
}
else
{
i++;
}
}
}
}
private function configureLayerRenderer(layerObject:Object, isOperationalLayer:Boolean):void
{
if (layerObject.layer is ArcGISDynamicMapServiceLayer || layerObject.layer is ArcGISTiledMapServiceLayer)
{
// look at the sublayers
var subLayers:Array = layerObject.subLayers as Array;
if ((subLayers).length > 0)
{
var dynamicLayer:ArcGISDynamicMapServiceLayer = layerObject.layer as ArcGISDynamicMapServiceLayer;
if (dynamicLayer)
{
dynamicLayer.layerDefinitions = getLayerDefinitions(subLayers);
}
var arrLayerInfoWindowRenderer:Array = [];
var i:int;
var arrSubLayerPopUp:Array = [];
var arrSubLayerInfoWinWidget:Array = [];
var countPopUpOrInfoWinWidget:int = 0;
for (i = 0; i < subLayers.length; i++)
{
if (subLayers[i].popUpConfig[0])
{
countPopUpOrInfoWinWidget++;
arrSubLayerPopUp.push({ layer: layerObject.layer, sublayer: subLayers[i], popUpConfig: subLayers[i].popUpConfig });
}
else if (subLayers[i].infoConfig[0])
{
countPopUpOrInfoWinWidget++;
arrSubLayerInfoWinWidget.push({ layer: layerObject.layer, sublayer: subLayers[i], infoConfig: subLayers[i].infoConfig, info: subLayers[i].info });
}
}
if (countPopUpOrInfoWinWidget > 0)
{
// popups for sublayers
if (arrSubLayerPopUp.length > 0)
{
configurePopUps(isOperationalLayer, arrSubLayerPopUp, true, arrLayerInfoWindowRenderer);
}
// simple info win widget for sublayers
for (i = 0; i < arrSubLayerInfoWinWidget.length; i++)
{
var layerInfoWindowRenderer:LayerInfoWindowRenderer = new LayerInfoWindowRenderer;
layerInfoWindowRenderer.layerId = arrSubLayerInfoWinWidget[i].sublayer.id;
var sublayerData:Object = { id: arrSubLayerInfoWinWidget[i].id, url: arrSubLayerInfoWinWidget[i].info, config: arrSubLayerInfoWinWidget[i].infoConfig, layerInfoWindowRenderer: layerInfoWindowRenderer };
AppEvent.dispatch(AppEvent.DATA_CREATE_INFOWIDGET, sublayerData, subLayerInfoReady);
}
function subLayerInfoReady(event:AppEvent):void
{
var infoTemplate:IInfowindowTemplate = event.data.infoWidget;
var biWidget:IBaseWidget = infoTemplate as IBaseWidget;
var infoConfigXML:XML = biWidget.configXML;
var infoRender:ClassFactory = new ClassFactory(infoTemplate.infoClass);
infoRender.properties = { infoConfig: infoConfigXML, map: map };
event.data.layerInfoWindowRenderer.infoWindowRenderer = infoRender;
arrLayerInfoWindowRenderer.push(event.data.layerInfoWindowRenderer);
if (arrLayerInfoWindowRenderer.length == countPopUpOrInfoWinWidget)
{
layerObject.layer.layerInfoWindowRenderers = arrLayerInfoWindowRenderer;
loadNextOperationalOrBasemapLayer(isOperationalLayer);
}
}
}
else
{
loadNextOperationalOrBasemapLayer(isOperationalLayer);
}
}
else
{
loadNextOperationalOrBasemapLayer(isOperationalLayer);
}
}
else if (layerObject.popUpConfig)
{
configurePopUps(isOperationalLayer, [{ layer: layerObject.layer, popUpConfig: layerObject.popUpConfig }], false);
}
else if (layerObject.infoUrl)
{
var data:Object = {
id: layerObject.label,
url: layerObject.infoUrl,
config: layerObject.infoConfig,
isOptLayer: isOperationalLayer
};
AppEvent.dispatch(AppEvent.DATA_CREATE_INFOWIDGET, data, infoReady);
}
else
{
loadNextOperationalOrBasemapLayer(isOperationalLayer);
}
function configurePopUps(isOptLayer:Boolean, arrLayerPopUp:Array, isSublayer:Boolean, arrLayerInfoWindowRenderer:Array = null):void
{
var popUpCount:int = 0;
var popUpArray:Array = [];
for (i = 0; i < arrLayerPopUp.length; i++)
{
if (isSublayer)
{
var layerInfoWindowRenderer:LayerInfoWindowRenderer = new LayerInfoWindowRenderer();
layerInfoWindowRenderer.layerId = arrLayerPopUp[i].sublayer.id;
}
var popUpConfigURL:String = arrLayerPopUp[i].popUpConfig;
var responderToken:Object = {
popUpConfigURL: popUpConfigURL,
layer: arrLayerPopUp[i].layer,
isSublayer: isSublayer,
layerInfoWindowRenderer: isSublayer ? layerInfoWindowRenderer : null };
if (popUpConfigURL.charAt(0) === "#")
{
var popUpConfigXML:XML = m_configData.configXML.configuration.(@id == popUpConfigURL.substr(1))[0];
responderToken.popUpConfigXML = popUpConfigXML;
arrPopUpPush(responderToken);
}
else
{
var configService:HTTPService = new HTTPService();
configService.url = popUpConfigURL;
configService.resultFormat = HTTPService.RESULT_FORMAT_TEXT;
var asyncToken:AsyncToken = configService.send();
asyncToken.addResponder(new AsyncResponder(configResult, configFault, responderToken));
}
}
function arrPopUpPush(token:Object):void
{
popUpCount++;
// arrPopUp.push({ popUpConfigXML: XML(event.result), layer: token.layer, isSublayer: isSublayer, layerInfoWindowRenderer: token.layerInfoWindowRenderer });
popUpArray.push(token);
if (popUpCount === arrLayerPopUp.length)
{
createPopUpRenderer(isOptLayer, popUpArray, arrLayerInfoWindowRenderer);
}
}
//config result
function configResult(event:ResultEvent, token:Object = null):void
{
try
{
token.popUpConfigXML = XML(event.result);
arrPopUpPush(token);
}
catch (error:Error)
{
AppEvent.showError(LocalizationUtil.getDefaultString("parseConfigErrorText", token.popUpConfigURL + "\n" + error.message), MAP_MANAGER);
}
}
//config fault
function configFault(event:FaultEvent, token:Object = null):void
{
// happens if for example the popup config file missing or have crossdomain problem
var sInfo:String = "";
// Missing file
if (event.fault.rootCause is IOErrorEvent)
{
var ioe:IOErrorEvent = event.fault.rootCause as IOErrorEvent;
if (ioe.text.indexOf("2032: Stream Error. URL:") > -1)
{
sInfo += LocalizationUtil.getDefaultString('missingConfigFileText', ioe.text.substring(32)) + "\n\n";
}
else
{
// some other IOError
sInfo += event.fault.rootCause + "\n\n";
}
}
// config file with crossdomain issue
if (event.fault.rootCause is SecurityErrorEvent)
{
var sec:SecurityErrorEvent = event.fault.rootCause as SecurityErrorEvent;
if (sec.text.indexOf("Error #2048: ") > -1) // debug player
{
sInfo += LocalizationUtil.getDefaultString('configFileCrossDomain', "\n", sec.text) + "\n\n";
}
else if (sec.text.indexOf("Error #2048") > -1) // non-debug player
{
sInfo += LocalizationUtil.getDefaultString('configFileCrossDomain', "\n", sec.toString()) + "\n\n";
}
else
{
// some other Security error
sInfo += event.fault.rootCause + "\n\n";
}
}
if (event.statusCode) // e.g. 404 - Not Found - http://en.wikipedia.org/wiki/List_of_HTTP_status_codes
{
sInfo += LocalizationUtil.getDefaultString('httpResponseStatus', event.statusCode) + "\n\n";
}
sInfo += ErrorMessageUtil.buildFaultMessage(event.fault);
AppEvent.showError(sInfo, MAP_MANAGER);
popUpCount++;
if (popUpCount == arrLayerPopUp.length)
{
createPopUpRenderer(isOptLayer, popUpArray, arrLayerInfoWindowRenderer);
}
}
}
function createPopUpRenderer(isOptLayer:Boolean, arr:Array, arrLayerInfoWindowRenderer:Array = null):void
{
var index:int = 0;
parseArray(index, isOptLayer, arr, arrLayerInfoWindowRenderer);
}
function parseArray(index:int, isOptLayer:Boolean, arr:Array, arrLayerInfoWindowRenderer:Array):void
{
if (index < arr.length)
{
var popUpConfigXML:XML = arr[index].popUpConfigXML;
var popUpInfo:PopUpInfo = new PopUpInfo();
var i:int;
if (popUpConfigXML.fields[0])
{
var fields:XMLList = popUpConfigXML.fields[0].field;
var fieldsOrder:String = popUpConfigXML.fields[0].@order;
var pFieldInfos:Array = [];
var arrFields:Array = [];