-
Notifications
You must be signed in to change notification settings - Fork 231
/
FStar.ModifiesGen.fst
2232 lines (1980 loc) · 82.4 KB
/
FStar.ModifiesGen.fst
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Copyright 2008-2018 Microsoft Research
Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at
http://www.apache.org/licenses/LICENSE-2.0
Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*)
module FStar.ModifiesGen
#set-options "--split_queries no --ext 'context_pruning='"
#set-options "--using_facts_from '*,-FStar.Tactics,-FStar.Reflection,-FStar.List'"
module HS = FStar.HyperStack
module HST = FStar.HyperStack.ST
noeq
type aloc (#al: aloc_t) (c: cls al) = | ALoc:
(region: HS.rid) ->
(addr: nat) ->
(loc: option (al region addr)) ->
aloc c
let aloc_domain (#al: aloc_t) (c: cls al) (regions: Ghost.erased (Set.set HS.rid)) (addrs: ((r: HS.rid { Set.mem r (Ghost.reveal regions) } ) -> GTot (GSet.set nat))) : GTot (GSet.set (aloc c)) =
GSet.comprehend (fun a -> Set.mem a.region (Ghost.reveal regions) && GSet.mem a.addr (addrs a.region))
module F = FStar.FunctionalExtensionality
[@@(unifier_hint_injective)]
let i_restricted_g_t = F.restricted_g_t
let addrs_dom regions =
(r: HS.rid { Set.mem r (Ghost.reveal regions) } )
let non_live_addrs_codom
(regions: Ghost.erased (Set.set HS.rid))
(region_liveness_tags: Ghost.erased (Set.set HS.rid) { Ghost.reveal region_liveness_tags `Set.subset` Ghost.reveal regions } )
(r:addrs_dom regions) =
(y: GSet.set nat { r `Set.mem` (Ghost.reveal region_liveness_tags) ==> GSet.subset (GSet.complement GSet.empty) y })
let live_addrs_codom
(regions: Ghost.erased (Set.set HS.rid))
(region_liveness_tags: Ghost.erased (Set.set HS.rid) { Ghost.reveal region_liveness_tags `Set.subset` Ghost.reveal regions } )
(non_live_addrs:
i_restricted_g_t
(addrs_dom regions)
(non_live_addrs_codom regions region_liveness_tags))
(r:addrs_dom regions) = (y: GSet.set nat { GSet.subset (non_live_addrs r) y } )
[@@erasable]
noeq
type loc' (#al: aloc_t u#x) (c: cls al) : Type u#x =
| Loc:
(regions: Ghost.erased (Set.set HS.rid)) ->
(region_liveness_tags: Ghost.erased (Set.set HS.rid) { Ghost.reveal region_liveness_tags `Set.subset` Ghost.reveal regions } ) ->
(non_live_addrs:
i_restricted_g_t
(addrs_dom regions)
(non_live_addrs_codom regions region_liveness_tags)) ->
(live_addrs:
i_restricted_g_t
(addrs_dom regions)
(live_addrs_codom regions region_liveness_tags non_live_addrs)) ->
(aux: Ghost.erased (GSet.set (aloc c)) {
aloc_domain c regions live_addrs `GSet.subset` Ghost.reveal aux /\
Ghost.reveal aux `GSet.subset` (aloc_domain c regions (fun _ -> GSet.complement GSet.empty))
} ) ->
loc' c
let loc = loc'
let mk_non_live_addrs (#regions:_) (#region_liveness_tags:_)
(f: (x:addrs_dom regions -> GTot (non_live_addrs_codom regions region_liveness_tags x)))
: i_restricted_g_t
(addrs_dom regions)
(non_live_addrs_codom regions region_liveness_tags) =
F.on_dom_g _ f
let mk_live_addrs (#regions:_) (#region_liveness_tags:_)
(#non_live_addrs_codom: _)
(f: (x:addrs_dom regions -> GTot (live_addrs_codom regions region_liveness_tags non_live_addrs_codom x)))
: i_restricted_g_t
(addrs_dom regions)
(live_addrs_codom regions region_liveness_tags non_live_addrs_codom) =
F.on_dom_g _ f
let loc_none #a #c =
Loc
(Ghost.hide (Set.empty))
(Ghost.hide (Set.empty))
(mk_non_live_addrs (fun _ -> GSet.empty))
(mk_live_addrs (fun _ -> GSet.empty))
(Ghost.hide GSet.empty)
let regions_of_loc
(#al: aloc_t) (#c: cls al)
(s: loc c)
: GTot (Set.set HS.rid)
= Ghost.reveal (Loc?.regions s)
let addrs_of_loc_liveness_not_preserved
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
: GTot (GSet.set nat)
= if Set.mem r (regions_of_loc l)
then Loc?.non_live_addrs l r
else GSet.empty
let addrs_of_loc_weak
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
: GTot (GSet.set nat)
= if Set.mem r (regions_of_loc l)
then Loc?.live_addrs l r
else GSet.empty
let addrs_of_loc_aux_pred
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
(addr: nat)
: GTot bool
= StrongExcludedMiddle.strong_excluded_middle (exists a . GSet.mem a (Ghost.reveal (Loc?.aux l)) /\ a.region == r /\ a.addr == addr)
let addrs_of_loc_aux
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
: GTot (y: GSet.set nat { GSet.subset (GSet.intersect y (addrs_of_loc_weak l r)) GSet.empty } )
= GSet.comprehend (addrs_of_loc_aux_pred l r)
`GSet.intersect` (GSet.complement (addrs_of_loc_weak l r))
let addrs_of_loc
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
: GTot (GSet.set nat)
= GSet.union
(addrs_of_loc_weak l r)
(addrs_of_loc_aux l r)
let addrs_of_loc_aux_prop
(#al: aloc_t) (#c: cls al)
(l: loc c)
(r: HS.rid)
: Lemma
(GSet.subset (GSet.intersect (addrs_of_loc_aux l r) (addrs_of_loc_weak l r)) GSet.empty)
[SMTPatOr [
[SMTPat (addrs_of_loc_aux l r)];
[SMTPat (addrs_of_loc_weak l r)];
[SMTPat (addrs_of_loc l r)];
]]
= ()
let loc_union #al #c s1 s2 =
let regions1 = Ghost.reveal (Loc?.regions s1) in
let regions2 = Ghost.reveal (Loc?.regions s2) in
let regions = Set.union regions1 regions2 in
let region_liveness_tags : Ghost.erased (Set.set HS.rid) = (Ghost.hide (Set.union (Ghost.reveal (Loc?.region_liveness_tags s1)) (Ghost.reveal (Loc?.region_liveness_tags s2)))) in
let gregions = Ghost.hide regions in
let non_live_addrs =
F.on_dom_g (addrs_dom gregions) #(non_live_addrs_codom gregions region_liveness_tags)
(fun r ->
GSet.union
(if Set.mem r regions1 then Loc?.non_live_addrs s1 r else GSet.empty)
(if Set.mem r regions2 then Loc?.non_live_addrs s2 r else GSet.empty))
in
let live_addrs =
F.on_dom_g (addrs_dom gregions) #(live_addrs_codom gregions region_liveness_tags non_live_addrs)
(fun r ->
GSet.union
(if Set.mem r regions1 then addrs_of_loc_weak s1 r else GSet.empty)
(if Set.mem r regions2 then addrs_of_loc_weak s2 r else GSet.empty))
in
let aux = Ghost.hide
(Ghost.reveal (Loc?.aux s1) `GSet.union` Ghost.reveal (Loc?.aux s2))
in
Loc
(Ghost.hide regions)
region_liveness_tags
non_live_addrs
live_addrs
aux
let fun_set_equal (#t: Type) (#t': Type)
(#p:(t -> GSet.set t' -> Type))
(f1 f2: i_restricted_g_t t (fun x -> g:GSet.set t'{p x g})) :Tot Type0 =
forall (x: t) . {:pattern (f1 x) \/ (f2 x) } f1 x `GSet.equal` f2 x
let fun_set_equal_elim (#t: Type) (#t': Type)
(#p:(t -> GSet.set t' -> Type))
(f1 f2: i_restricted_g_t t (fun x -> g:GSet.set t'{p x g})) : Lemma
(requires (fun_set_equal f1 f2))
(ensures (f1 == f2))
// [SMTPat (fun_set_equal f1 f2)]
= assert (f1 `FunctionalExtensionality.feq_g` f2)
let loc_equal (#al: aloc_t) (#c: cls al) (s1 s2: loc c) : GTot Type0 =
let Loc regions1 region_liveness_tags1 _ _ aux1 = s1 in
let Loc regions2 region_liveness_tags2 _ _ aux2 = s2 in
Ghost.reveal regions1 `Set.equal` Ghost.reveal regions2 /\
Ghost.reveal region_liveness_tags1 `Set.equal` Ghost.reveal region_liveness_tags2 /\
fun_set_equal (Loc?.non_live_addrs s1) (Loc?.non_live_addrs s2) /\
fun_set_equal (Loc?.live_addrs s1) (Loc?.live_addrs s2) /\
Ghost.reveal (Loc?.aux s1) `GSet.equal` Ghost.reveal (Loc?.aux s2)
let loc_equal_elim (#al: aloc_t) (#c: cls al) (s1 s2: loc c) : Lemma
(requires (loc_equal s1 s2))
(ensures (s1 == s2))
[SMTPat (s1 `loc_equal` s2)]
= fun_set_equal_elim (Loc?.non_live_addrs s1) (Loc?.non_live_addrs s2);
fun_set_equal_elim (Loc?.live_addrs s1) (Loc?.live_addrs s2)
let loc_union_idem #al #c s =
assert (loc_union s s `loc_equal` s)
let loc_union_comm #al #c s1 s2 =
assert (loc_union s1 s2 `loc_equal` loc_union s2 s1)
let loc_union_assoc #al #c s1 s2 s3 =
assert (loc_union s1 (loc_union s2 s3) `loc_equal` loc_union (loc_union s1 s2) s3)
let loc_union_loc_none_l #al #c s =
assert (loc_union loc_none s `loc_equal` s)
let loc_union_loc_none_r #al #c s =
assert (loc_union s loc_none `loc_equal` s)
let loc_of_aloc #al #c #r #n b =
let regions = (Ghost.hide (Set.singleton r)) in
let region_liveness_tags = (Ghost.hide (Set.empty)) in
Loc
regions
region_liveness_tags
(mk_non_live_addrs (fun _ -> GSet.empty))
(mk_live_addrs (fun _ -> GSet.empty))
(Ghost.hide (GSet.singleton (ALoc r n (Some b))))
let loc_of_aloc_not_none #al #c #r #n b = ()
let loc_addresses #al #c preserve_liveness r n =
let regions = (Ghost.hide (Set.singleton r)) in
Loc
regions
(Ghost.hide Set.empty)
(mk_non_live_addrs (fun _ -> if preserve_liveness then GSet.empty else GSet.of_set n))
(mk_live_addrs (fun _ -> GSet.of_set n))
(Ghost.hide (aloc_domain c regions (fun _ -> GSet.of_set n)))
let loc_regions_region_liveness_tags (preserve_liveness: bool) (r: Set.set HS.rid) : Tot (Ghost.erased (Set.set HS.rid)) =
if preserve_liveness then Ghost.hide Set.empty else Ghost.hide r
let loc_regions #al #c preserve_liveness r =
let region_liveness_tags = loc_regions_region_liveness_tags preserve_liveness r in
let addrs (r' : HS.rid { Set.mem r' r } ) : GTot (y: GSet.set nat { r' `Set.mem` (Ghost.reveal region_liveness_tags) ==> GSet.subset (GSet.complement GSet.empty) y } ) =
GSet.complement GSet.empty
in
let live_addrs (r' : HS.rid { Set.mem r' r } ) : GTot (y: GSet.set nat { addrs r' `GSet.subset` y } ) =
addrs r'
in
Loc
(Ghost.hide r)
region_liveness_tags
(mk_non_live_addrs addrs)
(mk_live_addrs live_addrs)
(Ghost.hide (aloc_domain c (Ghost.hide r) addrs))
let aloc_includes (#al: aloc_t) (#c: cls al) (b0 b: aloc c) : GTot Type0 =
b0.region == b.region /\ b0.addr == b.addr /\ Some? b0.loc == Some? b.loc /\ (if Some? b0.loc && Some? b.loc then c.aloc_includes (Some?.v b0.loc) (Some?.v b.loc) else True)
let loc_aux_includes_buffer
(#al: aloc_t) (#c: cls al)
(s: GSet.set (aloc c))
(b: aloc c)
: GTot Type0
(decreases s)
= exists (b0 : aloc c) . b0 `GSet.mem` s /\ b0 `aloc_includes` b
let loc_aux_includes
(#al: aloc_t) (#c: cls al)
(s1 s2: GSet.set (aloc c))
: GTot Type0
(decreases s2)
= forall (b2: aloc c) . GSet.mem b2 s2 ==> loc_aux_includes_buffer s1 b2
let loc_aux_includes_union_l
(#al: aloc_t) (#c: cls al)
(s1 s2 s: GSet.set (aloc c))
: Lemma
(requires (loc_aux_includes s1 s \/ loc_aux_includes s2 s))
(ensures (loc_aux_includes (GSet.union s1 s2) s))
(decreases s)
= ()
let loc_aux_includes_refl
(#al: aloc_t) (#c: cls al)
(s: GSet.set (aloc c))
: Lemma
(loc_aux_includes s s)
= Classical.forall_intro_3 (fun r a b -> c.aloc_includes_refl #r #a b)
let loc_aux_includes_subset
(#al: aloc_t) (#c: cls al)
(s1 s2: GSet.set (aloc c))
: Lemma
(requires (s1 `GSet.subset` s2))
(ensures (loc_aux_includes s2 s1))
= Classical.forall_intro_3 (fun r a b -> c.aloc_includes_refl #r #a b)
let loc_aux_includes_subset'
(#al: aloc_t) (#c: cls al)
(s1 s2: GSet.set (aloc c))
: Lemma
(requires (s1 `GSet.subset` s2))
(ensures (loc_aux_includes s2 s1))
[SMTPatOr [
[SMTPat (s1 `GSet.subset` s2)];
[SMTPat (loc_aux_includes s2 s1)];
]]
= loc_aux_includes_subset s1 s2
let loc_aux_includes_union_l_r
(#al: aloc_t) (#c: cls al)
(s s': GSet.set (aloc c))
: Lemma
(loc_aux_includes (GSet.union s s') s)
= loc_aux_includes_refl s;
loc_aux_includes_union_l s s' s
let loc_aux_includes_union_l_l
(#al: aloc_t) (#c: cls al)
(s s': GSet.set (aloc c))
: Lemma
(loc_aux_includes (GSet.union s' s) s)
= loc_aux_includes_refl s;
loc_aux_includes_union_l s' s s
let loc_aux_includes_buffer_includes
(#al: aloc_t) (#c: cls al)
(s: GSet.set (aloc c))
(b1 b2: aloc c)
: Lemma
(requires (loc_aux_includes_buffer s b1 /\ b1 `aloc_includes` b2))
(ensures (loc_aux_includes_buffer s b2))
= Classical.forall_intro_3 (fun r a b1 -> Classical.forall_intro_2 (fun b2 b3 -> Classical.move_requires (c.aloc_includes_trans #r #a b1 b2) b3))
let loc_aux_includes_loc_aux_includes_buffer
(#al: aloc_t) (#c: cls al)
(s1 s2: GSet.set (aloc c))
(b: aloc c)
: Lemma
(requires (loc_aux_includes s1 s2 /\ loc_aux_includes_buffer s2 b))
(ensures (loc_aux_includes_buffer s1 b))
= Classical.forall_intro_3 (fun s b1 b2 -> Classical.move_requires (loc_aux_includes_buffer_includes #al #c s b1) b2)
let loc_aux_includes_trans
(#al: aloc_t) (#c: cls al)
(s1 s2 s3: GSet.set (aloc c))
: Lemma
(requires (loc_aux_includes s1 s2 /\ loc_aux_includes s2 s3))
(ensures (loc_aux_includes s1 s3))
= Classical.forall_intro_3 (fun r a b1 -> Classical.forall_intro_2 (fun b2 b3 -> Classical.move_requires (c.aloc_includes_trans #r #a b1 b2) b3))
let addrs_of_loc_weak_loc_union
(#al: aloc_t) (#c: cls al)
(l1 l2: loc c)
(r: HS.rid)
: Lemma
(addrs_of_loc_weak (loc_union l1 l2) r == GSet.union (addrs_of_loc_weak l1 r) (addrs_of_loc_weak l2 r))
[SMTPat (addrs_of_loc_weak (loc_union l1 l2) r)]
= assert (GSet.equal (addrs_of_loc_weak (loc_union l1 l2) r) (GSet.union (addrs_of_loc_weak l1 r) (addrs_of_loc_weak l2 r)))
let addrs_of_loc_union
(#al: aloc_t) (#c: cls al)
(l1 l2: loc c)
(r: HS.rid)
: Lemma
(addrs_of_loc (loc_union l1 l2) r == GSet.union (addrs_of_loc l1 r) (addrs_of_loc l2 r))
[SMTPat (addrs_of_loc (loc_union l1 l2) r)]
= assert (GSet.equal (addrs_of_loc (loc_union l1 l2) r) (GSet.union (addrs_of_loc l1 r) (addrs_of_loc l2 r)))
unfold
let loc_includes' #al (#c: cls al) (s1 s2: loc c) =
let regions1 = Ghost.reveal (Loc?.regions s1) in
let regions2 = Ghost.reveal (Loc?.regions s2) in (
Set.subset regions2 regions1 /\
Set.subset (Ghost.reveal (Loc?.region_liveness_tags s2)) (Ghost.reveal (Loc?.region_liveness_tags s1)) /\
(
forall (r: HS.rid { Set.mem r regions2 } ) .
GSet.subset (Loc?.non_live_addrs s2 r) (Loc?.non_live_addrs s1 r)
) /\
(
forall (r: HS.rid) .
GSet.subset (addrs_of_loc_weak s2 r) (addrs_of_loc_weak s1 r)
) /\ (
forall (r: HS.rid) .
GSet.subset (addrs_of_loc s2 r) (addrs_of_loc s1 r)
) /\ (
(Ghost.reveal (Loc?.aux s1)) `loc_aux_includes` (Ghost.reveal (Loc?.aux s2))
)
)
let loc_includes #al #c s1 s2 =
loc_includes' s1 s2
let loc_includes_refl #al #c s =
loc_aux_includes_refl (Ghost.reveal (Loc?.aux s))
let loc_includes_refl'
(#al: aloc_t) (#c: cls al)
(s: loc c)
: Lemma
(loc_includes s s)
[SMTPat (loc_includes s s)]
= loc_includes_refl s
let loc_includes_trans #al #c s1 s2 s3 =
loc_aux_includes_trans (Ghost.reveal (Loc?.aux s1)) (Ghost.reveal (Loc?.aux s2)) (Ghost.reveal (Loc?.aux s3))
let loc_includes_union_r #al #c s s1 s2 = ()
let loc_includes_union_l #al #c s1 s2 s =
let u12 = loc_union s1 s2 in
Classical.or_elim
#(loc_includes s1 s)
#(loc_includes s2 s)
#(fun _ -> loc_includes (loc_union s1 s2) s)
(fun _ ->
loc_aux_includes_union_l_r (Ghost.reveal (Loc?.aux s1)) (Ghost.reveal (Loc?.aux s2));
assert (loc_includes (loc_union s1 s2) s1);
loc_includes_trans u12 s1 s)
(fun _ ->
loc_aux_includes_union_l_l (Ghost.reveal (Loc?.aux s2)) (Ghost.reveal (Loc?.aux s1));
assert (loc_includes (loc_union s1 s2) s2);
loc_includes_trans u12 s2 s)
let loc_includes_none #al #c s = ()
let loc_includes_none_elim #al #c s =
assert (s `loc_equal` loc_none)
let loc_includes_aloc #al #c #r #n b1 b2 = ()
let loc_includes_aloc_elim #aloc #c #r1 #r2 #n1 #n2 b1 b2 = ()
let addrs_of_loc_loc_of_aloc
(#al: aloc_t)
(#c: cls al)
(#r: HS.rid)
(#a: nat)
(p: al r a)
(r': HS.rid)
: Lemma
(addrs_of_loc (loc_of_aloc #_ #c p) r' `GSet.equal` (if r = r' then GSet.singleton a else GSet.empty))
[SMTPat (addrs_of_loc (loc_of_aloc #_ #c p) r')]
= ()
let loc_includes_addresses_aloc #al #c preserve_liveness r s #a p = ()
let loc_includes_region_aloc #al #c preserve_liveness s #r #a b = ()
let loc_includes_region_addresses #al #c s preserve_liveness1 preserve_liveness2 r a = ()
let loc_includes_region_region #al #c preserve_liveness1 preserve_liveness2 s1 s2 = ()
let loc_includes_region_union_l #al #c preserve_liveness l s1 s2 =
assert ((loc_regions #_ #c preserve_liveness (Set.intersect s2 (Set.complement s1)) `loc_union` loc_regions #_ #c preserve_liveness (Set.intersect s2 s1)) `loc_equal` loc_regions preserve_liveness s2);
loc_includes_region_region #_ #c preserve_liveness preserve_liveness s1 (Set.intersect s2 s1);
loc_includes_union_l (loc_regions preserve_liveness s1) l (loc_regions preserve_liveness (Set.intersect s2 (Set.complement s1)));
loc_includes_union_l (loc_regions preserve_liveness s1) l (loc_regions preserve_liveness (Set.intersect s2 s1));
loc_includes_union_r (loc_union (loc_regions preserve_liveness s1) l) (loc_regions preserve_liveness (Set.intersect s2 (Set.complement s1))) (loc_regions preserve_liveness (Set.intersect s2 s1))
let loc_includes_addresses_addresses #al c preserve_liveness1 preserve_liveness2 r s1 s2 = ()
(* Disjointness of two memory locations *)
let aloc_disjoint (#al: aloc_t) (#c: cls al) (b1 b2: aloc c) : GTot Type0 =
if b1.region = b2.region && b1.addr = b2.addr
then Some? b1.loc /\ Some? b2.loc /\ c.aloc_disjoint (Some?.v b1.loc) (Some?.v b2.loc)
else True
let aloc_disjoint_sym (#al: aloc_t) (#c: cls al) (b1 b2: aloc c) : Lemma
(aloc_disjoint b1 b2 <==> aloc_disjoint b2 b1)
= Classical.forall_intro_2 (fun r a -> Classical.forall_intro_2 (fun b1 b2 -> c.aloc_disjoint_sym #r #a b1 b2))
let loc_aux_disjoint
(#al: aloc_t) (#c: cls al)
(l1 l2: GSet.set (aloc c))
: GTot Type0
= forall (b1 b2: aloc c) . (GSet.mem b1 l1 /\ GSet.mem b2 l2) ==> aloc_disjoint b1 b2
let loc_aux_disjoint_union_l
(#al: aloc_t) (#c: cls al)
(ll1 lr1 l2: GSet.set (aloc c))
: Lemma
(ensures (loc_aux_disjoint (GSet.union ll1 lr1) l2 <==> (loc_aux_disjoint ll1 l2 /\ loc_aux_disjoint lr1 l2)))
= ()
let loc_aux_disjoint_union_r
(#al: aloc_t) (#c: cls al)
(l1 ll2 lr2: GSet.set (aloc c))
: Lemma
(loc_aux_disjoint l1 (GSet.union ll2 lr2) <==> (loc_aux_disjoint l1 ll2 /\ loc_aux_disjoint l1 lr2))
= ()
let loc_aux_disjoint_sym
(#al: aloc_t) (#c: cls al)
(l1 l2: GSet.set (aloc c))
: Lemma
(ensures (loc_aux_disjoint l1 l2 <==> loc_aux_disjoint l2 l1))
= Classical.forall_intro_2 (aloc_disjoint_sym #al #c)
let regions_of_loc_loc_union
(#al: aloc_t) (#c: cls al)
(s1 s2: loc c)
: Lemma
(regions_of_loc (loc_union s1 s2) == regions_of_loc s1 `Set.union` regions_of_loc s2)
[SMTPat (regions_of_loc (loc_union s1 s2))]
= assert (regions_of_loc (loc_union s1 s2) `Set.equal` (regions_of_loc s1 `Set.union` regions_of_loc s2))
let regions_of_loc_monotonic
(#al: aloc_t) (#c: cls al)
(s1 s2: loc c)
: Lemma
(requires (loc_includes s1 s2))
(ensures (Set.subset (regions_of_loc s2) (regions_of_loc s1)))
= ()
let loc_disjoint_region_liveness_tags (#al: aloc_t) (#c: cls al) (l1 l2: loc c) : GTot Type0 =
Set.subset (Set.intersect (Ghost.reveal (Loc?.region_liveness_tags l1)) (Ghost.reveal (Loc?.region_liveness_tags l2))) Set.empty
let loc_disjoint_addrs (#al: aloc_t) (#c: cls al) (l1 l2: loc c) : GTot Type0 =
(forall (r: HS.rid) .
GSet.subset (GSet.intersect (addrs_of_loc_weak l1 r) (addrs_of_loc l2 r)) GSet.empty /\
GSet.subset (GSet.intersect (addrs_of_loc l1 r) (addrs_of_loc_weak l2 r)) GSet.empty
)
let loc_disjoint_aux (#al: aloc_t) (#c: cls al) (l1 l2: loc c) : GTot Type0 =
loc_aux_disjoint (Ghost.reveal (Loc?.aux l1)) (Ghost.reveal (Loc?.aux l2))
let loc_disjoint
(#al: aloc_t) (#c: cls al)
(l1 l2: loc c)
: GTot Type0
= loc_disjoint_region_liveness_tags l1 l2 /\
loc_disjoint_addrs l1 l2 /\
loc_disjoint_aux l1 l2
let loc_disjoint_sym #al #c l1 l2 =
Classical.forall_intro_2 (loc_aux_disjoint_sym #al #c)
let loc_disjoint_sym'
(#al: aloc_t) (#c: cls al)
(s1 s2: loc c)
: Lemma
(requires (loc_disjoint s1 s2))
(ensures (loc_disjoint s2 s1))
[SMTPat (loc_disjoint s1 s2)]
= loc_disjoint_sym s1 s2
let loc_disjoint_none_r #al #c s = ()
let loc_disjoint_union_r #al #c s s1 s2 = ()
let aloc_disjoint_includes (#al: aloc_t) (#c: cls al) (b1 b2 b3 : aloc c) : Lemma
(requires (aloc_disjoint b1 b2 /\ aloc_includes b2 b3))
(ensures (aloc_disjoint b1 b3))
= if b1.region = b2.region && b1.addr = b2.addr
then begin
c.aloc_includes_refl (Some?.v b1.loc);
c.aloc_disjoint_includes (Some?.v b1.loc) (Some?.v b2.loc) (Some?.v b1.loc) (Some?.v b3.loc)
end
else ()
let loc_aux_disjoint_loc_aux_includes
(#al: aloc_t) (#c: cls al)
(l1 l2 l3: GSet.set (aloc c))
: Lemma
(requires (loc_aux_disjoint l1 l2 /\ loc_aux_includes l2 l3))
(ensures (loc_aux_disjoint l1 l3))
= // FIXME: WHY WHY WHY do I need this assert?
assert (forall (b1 b3: aloc c) . (GSet.mem b1 l1 /\ GSet.mem b3 l3) ==> (exists (b2: aloc c) . GSet.mem b2 l2 /\ aloc_disjoint b1 b2 /\ aloc_includes b2 b3));
Classical.forall_intro_3 (fun b1 b2 b3 -> Classical.move_requires (aloc_disjoint_includes #al #c b1 b2) b3)
let loc_disjoint_includes #al #c p1 p2 p1' p2' =
regions_of_loc_monotonic p1 p1';
regions_of_loc_monotonic p2 p2';
let l1 = Ghost.reveal (Loc?.aux p1) in
let l2 = Ghost.reveal (Loc?.aux p2) in
let l1' = Ghost.reveal (Loc?.aux p1') in
let l2' = Ghost.reveal (Loc?.aux p2') in
loc_aux_disjoint_loc_aux_includes l1 l2 l2';
loc_aux_disjoint_sym l1 l2';
loc_aux_disjoint_loc_aux_includes l2' l1 l1';
loc_aux_disjoint_sym l2' l1'
let loc_disjoint_aloc_intro #al #c #r1 #a1 #r2 #a2 b1 b2 = ()
let loc_disjoint_aloc_elim #al #c #r1 #a1 #r2 #a2 b1 b2 =
// FIXME: WHY WHY WHY this assert?
assert (aloc_disjoint (ALoc #_ #c r1 a1 (Some b1)) (ALoc #_ #c r2 a2 (Some b2)))
#push-options "--z3rlimit 15"
let loc_disjoint_addresses_intro #al #c preserve_liveness1 preserve_liveness2 r1 r2 n1 n2 =
// FIXME: WHY WHY WHY this assert?
assert (loc_aux_disjoint (Ghost.reveal (Loc?.aux (loc_addresses #_ #c preserve_liveness1 r1 n1))) (Ghost.reveal (Loc?.aux (loc_addresses #_ #c preserve_liveness2 r2 n2))))
#pop-options
let loc_disjoint_addresses_elim #al #c preserve_liveness1 preserve_liveness2 r1 r2 n1 n2 = ()
let loc_disjoint_aloc_addresses_intro #al #c #r' #a' p preserve_liveness r n = ()
let loc_disjoint_aloc_addresses_elim #al #c #r' #a' p preserve_liveness r n = ()
#push-options "--z3rlimit 15"
let loc_disjoint_regions #al #c preserve_liveness1 preserve_liveness2 rs1 rs2 =
// FIXME: WHY WHY WHY this assert?
assert (loc_aux_disjoint (Ghost.reveal (Loc?.aux (loc_regions #_ #c preserve_liveness1 rs1))) (Ghost.reveal (Loc?.aux (loc_regions #_ #c preserve_liveness2 rs2))))
#pop-options
let loc_none_in_some_region #a (c: cls a) (r: HS.rid) : GTot (loc c) =
Loc
(Ghost.hide (Set.singleton r))
(Ghost.hide (Set.empty))
(mk_non_live_addrs (fun _ -> GSet.empty))
(mk_live_addrs (fun _ -> GSet.empty))
(Ghost.hide GSet.empty)
(** Liveness-insensitive memory locations *)
let address_liveness_insensitive_locs #al c =
Loc
(Ghost.hide (Set.complement Set.empty))
(Ghost.hide Set.empty)
(mk_non_live_addrs (fun _ -> GSet.empty))
(mk_live_addrs (fun _ -> GSet.complement GSet.empty))
(Ghost.hide (aloc_domain c (Ghost.hide (Set.complement Set.empty)) (fun _ -> GSet.complement GSet.empty)))
let loc_includes_address_liveness_insensitive_locs_aloc #al #c #r #n a = ()
let loc_includes_address_liveness_insensitive_locs_addresses #al c r a = ()
let region_liveness_insensitive_locs #al c =
Loc
(Ghost.hide (Set.complement Set.empty))
(Ghost.hide Set.empty)
(mk_non_live_addrs (fun _ -> GSet.complement GSet.empty))
(mk_live_addrs (fun _ -> GSet.complement GSet.empty))
(Ghost.hide (aloc_domain c (Ghost.hide (Set.complement Set.empty)) (fun _ -> GSet.complement GSet.empty)))
let loc_includes_region_liveness_insensitive_locs_address_liveness_insensitive_locs #al c = ()
let loc_includes_region_liveness_insensitive_locs_loc_regions #al c r = ()
let loc_includes_region_liveness_insensitive_locs_loc_addresses #al c preserve_liveness r a = ()
let loc_includes_region_liveness_insensitive_locs_loc_of_aloc #al c #r #a x = ()
(** The modifies clause proper *)
let modifies_preserves_livenesses
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= (forall (t: Type) (pre: Preorder.preorder t) (p: HS.mreference t pre) .
let r = HS.frameOf p in (
HS.contains h1 p /\
(Set.mem r (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (Loc?.non_live_addrs s r)))
) ==> (
HS.contains h2 p
))
let modifies_preserves_livenesses_elim
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
(#t: Type)
(#pre: Preorder.preorder t)
(p: HS.mreference t pre)
: Lemma
(requires (modifies_preserves_livenesses s h1 h2 /\ HS.contains h1 p /\ (Set.mem (HS.frameOf p) (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (Loc?.non_live_addrs s (HS.frameOf p))))))
(ensures (HS.contains h2 p))
= ()
let modifies_preserves_livenesses_intro
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
(f: (
(t: Type) ->
(pre: Preorder.preorder t) ->
(p: HS.mreference t pre) ->
Lemma
(requires (
HS.contains h1 p /\
(Set.mem (HS.frameOf p) (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (Loc?.non_live_addrs s (HS.frameOf p))))
))
(ensures (HS.contains h2 p))
))
: Lemma
(modifies_preserves_livenesses s h1 h2)
= let f'
(t : Type)
(pre: Preorder.preorder t)
(p : HS.mreference t pre)
: Lemma
(
(HS.contains h1 p /\ (Set.mem (HS.frameOf p) (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (Loc?.non_live_addrs s (HS.frameOf p))))) ==>
(h2 `HS.contains` p))
= Classical.move_requires (f t pre) p
in
Classical.forall_intro_3 f'
let modifies_preserves_mreferences
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= (forall (t: Type) (pre: Preorder.preorder t) (p: HS.mreference t pre) .
let r = HS.frameOf p in (
HS.contains h1 p /\
(Set.mem r (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (addrs_of_loc s r)))
) ==> (
HS.contains h2 p /\
HS.sel h2 p == HS.sel h1 p
))
let modifies_preserves_mreferences_intro
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
(f: (
(t: Type) ->
(pre: Preorder.preorder t) ->
(p: HS.mreference t pre) ->
Lemma
(requires (
HS.contains h1 p /\
(Set.mem (HS.frameOf p) (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (addrs_of_loc s (HS.frameOf p))))
))
(ensures (HS.contains h2 p /\ HS.sel h2 p == HS.sel h1 p))
))
: Lemma
(modifies_preserves_mreferences s h1 h2)
= let f'
(t : Type)
(pre: Preorder.preorder t)
(p : HS.mreference t pre)
: Lemma
(
(HS.contains h1 p /\ (Set.mem (HS.frameOf p) (regions_of_loc s) ==> ~ (GSet.mem (HS.as_addr p) (addrs_of_loc s (HS.frameOf p))))) ==>
(h2 `HS.contains` p /\ h2 `HS.sel` p == h1 `HS.sel` p))
= Classical.move_requires (f t pre) p
in
Classical.forall_intro_3 f'
let modifies_preserves_alocs
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= (forall (r: HS.rid) (a: nat) (b: al r a) .
loc_aux_disjoint (Ghost.reveal (Loc?.aux s)) (GSet.singleton (ALoc r a (Some b)))
==>
c.aloc_preserved b h1 h2
)
let modifies_preserves_alocs_intro
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
(u: unit { modifies_preserves_mreferences s h1 h2 } )
(f: (
(r: HS.rid) ->
(a: nat) ->
(b: al r a) ->
Lemma
(requires (
Set.mem r (regions_of_loc s) /\
(~ (GSet.mem a (addrs_of_loc_weak s r))) /\
(GSet.mem a (addrs_of_loc_aux s r) /\ loc_aux_disjoint (Ghost.reveal (Loc?.aux s)) (GSet.singleton (ALoc r a (Some b))))
))
(ensures (c.aloc_preserved b h1 h2))
))
: Lemma
(modifies_preserves_alocs s h1 h2)
= let f'
(r: HS.rid)
(a: nat)
(b: al r a)
: Lemma
(requires (loc_aux_disjoint (Ghost.reveal (Loc?.aux s)) (GSet.singleton (ALoc r a (Some b)))))
(ensures (c.aloc_preserved b h1 h2))
= if Set.mem r (regions_of_loc s) && (not (GSet.mem a (addrs_of_loc_weak s r)))
then begin
if GSet.mem a (addrs_of_loc_aux s r)
then
Classical.move_requires (f r a) b
else
c.same_mreference_aloc_preserved b h1 h2 (fun a' pre' r' -> ())
end else if Set.mem r (regions_of_loc s)
then begin
assert (GSet.mem a (addrs_of_loc_weak s r));
assert (GSet.mem (ALoc r a None) (Ghost.reveal (Loc?.aux s)));
assert (aloc_disjoint #_ #c (ALoc r a None) (ALoc r a (Some b)));
assert False
end
else
c.same_mreference_aloc_preserved b h1 h2 (fun a' pre' r' -> ())
in
Classical.forall_intro_3 (fun r a b -> Classical.move_requires (f' r a) b)
let modifies_preserves_regions
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= forall (r: HS.rid) . (HS.live_region h1 r /\ ~ (Set.mem r (Ghost.reveal (Loc?.region_liveness_tags s)))) ==> HS.live_region h2 r
let modifies_preserves_not_unused_in
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= (forall (r: HS.rid) (n: nat) . (
HS.live_region h1 r /\ HS.live_region h2 r /\
n `Heap.addr_unused_in` (HS.get_hmap h2 `Map.sel` r) /\
(Set.mem r (regions_of_loc s) ==> ~ (GSet.mem n (Loc?.non_live_addrs s r)))
) ==> (
n `Heap.addr_unused_in` (HS.get_hmap h1 `Map.sel` r)
))
let modifies_preserves_not_unused_in_intro
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
(f: (
(r: HS.rid) ->
(n: nat) ->
Lemma
(requires (
HS.live_region h1 r /\ HS.live_region h2 r /\
n `Heap.addr_unused_in` (HS.get_hmap h2 `Map.sel` r) /\
(Set.mem r (regions_of_loc s) ==> ~ (GSet.mem n (Loc?.non_live_addrs s r)))
))
(ensures (
n `Heap.addr_unused_in` (HS.get_hmap h1 `Map.sel` r)
))
))
: Lemma
(modifies_preserves_not_unused_in s h1 h2)
= let f'
(r: HS.rid)
(n: nat)
: Lemma
((
HS.live_region h1 r /\ HS.live_region h2 r /\
n `Heap.addr_unused_in` (HS.get_hmap h2 `Map.sel` r) /\
(Set.mem r (regions_of_loc s) ==> ~ (GSet.mem n (Loc?.non_live_addrs s r)))
) ==> (
n `Heap.addr_unused_in` (HS.get_hmap h1 `Map.sel` r)
))
= Classical.move_requires (f r) n
in
Classical.forall_intro_2 f'
let modifies
(#al: aloc_t) (#c: cls al)
(s: loc c)
(h1 h2: HS.mem)
: GTot Type0
= modifies_preserves_regions s h1 h2 /\
modifies_preserves_not_unused_in s h1 h2 /\
modifies_preserves_mreferences s h1 h2 /\
modifies_preserves_livenesses s h1 h2 /\
modifies_preserves_alocs s h1 h2
val modifies_intro_strong
(#al: aloc_t) (#c: cls al) (l: loc c) (h h' : HS.mem)
(regions: (
(r: HS.rid) ->
Lemma
(requires (HS.live_region h r))
(ensures (HS.live_region h' r))
))
(mrefs: (
(t: Type0) ->
(pre: Preorder.preorder t) ->
(b: HS.mreference t pre) ->
Lemma
(requires ((loc_disjoint (loc_mreference b) l) /\ HS.contains h b))
(ensures (HS.contains h' b /\ HS.sel h' b == HS.sel h b))
))
(livenesses: (
(t: Type0) ->
(pre: Preorder.preorder t) ->
(b: HS.mreference t pre) ->
Lemma
(requires (HS.contains h b))
(ensures (HS.contains h' b))
))
(addr_unused_in: (
(r: HS.rid) ->
(n: nat) ->
Lemma
(requires (
(Set.mem r (regions_of_loc l) ==> ~ (GSet.mem n (Loc?.non_live_addrs l r))) /\
HS.live_region h r /\
HS.live_region h' r /\ n `Heap.addr_unused_in` (HS.get_hmap h' `Map.sel` r)
))
(ensures (n `Heap.addr_unused_in` (HS.get_hmap h `Map.sel` r)))
))
(alocs: (
(r: HS.rid) ->
(a: nat) ->
(x: al r a) ->
Lemma
(requires (loc_disjoint (loc_of_aloc x) l))
(ensures (c.aloc_preserved x h h'))
))
: Lemma
(modifies l h h')
#push-options "--z3rlimit 20"
let modifies_intro_strong #al #c l h h' regions mrefs lives unused_ins alocs =
Classical.forall_intro (Classical.move_requires regions);
assert (modifies_preserves_regions l h h');
let aux (t:Type) (pre:Preorder.preorder t) (p:HS.mreference t pre)
:Lemma (requires (HS.contains h p /\
(Set.mem (HS.frameOf p) (regions_of_loc l) ==> ~ (GSet.mem (HS.as_addr p) (addrs_of_loc l (HS.frameOf p))))))
(ensures (HS.contains h' p /\ HS.sel h' p == HS.sel h p))
=
assert_norm (Loc?.region_liveness_tags (loc_mreference #_ #c p) == Ghost.hide Set.empty);
assert (loc_disjoint_region_liveness_tags (loc_mreference p) l);
// FIXME: WHY WHY WHY is this assert necessary?
assert_spinoff (loc_aux_disjoint (Ghost.reveal (Loc?.aux (loc_mreference p))) (Ghost.reveal (Loc?.aux l)));
// FIXME: Now this one is too :)
assert (loc_disjoint_addrs (loc_mreference p) l);
assert ((loc_disjoint (loc_mreference p) l));
mrefs t pre p
in
modifies_preserves_mreferences_intro l h h' aux;
Classical.forall_intro_3 (fun t pre p -> Classical.move_requires (lives t pre) p);
modifies_preserves_not_unused_in_intro l h h' (fun r n ->
unused_ins r n
);
modifies_preserves_alocs_intro l h h' () (fun r a b ->
loc_aux_disjoint_sym (Ghost.reveal (Loc?.aux l)) (Ghost.reveal (Loc?.aux (loc_of_aloc b)));
alocs r a b
)
#pop-options
let modifies_intro #al #c l h h' regions mrefs lives unused_ins alocs =
modifies_intro_strong l h h'
regions
mrefs
lives
(fun r n -> unused_ins r n)
alocs
let modifies_none_intro #al #c h h' regions mrefs unused_ins =
modifies_intro_strong #_ #c loc_none h h'
(fun r -> regions r)
(fun t pre b -> mrefs t pre b)
(fun t pre b -> mrefs t pre b)
(fun r n -> unused_ins r n)
(fun r a x ->
c.same_mreference_aloc_preserved x h h' (fun t pre b -> mrefs t pre b)
)
let modifies_address_intro #al #c r n h h' regions mrefs unused_ins =
Classical.forall_intro (Classical.move_requires regions);
let l : loc c = loc_addresses #_ #c false r (Set.singleton n) in
modifies_preserves_mreferences_intro l h h'
(fun t pre p -> mrefs t pre p)
;
modifies_preserves_livenesses_intro l h h'
(fun t pre p -> mrefs t pre p)
;
modifies_preserves_not_unused_in_intro l h h'
(fun r n -> unused_ins r n)
;
modifies_preserves_alocs_intro l h h' ()
(fun r a b ->
c.same_mreference_aloc_preserved b h h' (fun t pre p -> mrefs t pre p)
)