Add files via upload

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/g++-base.conf

@@ -0,0 +1,38 @@
+#
+# Qmake configuration for the GNU C++ compiler
+#
+# Before making changes to this file, please read the comment in
+# gcc-base.conf, to make sure the change goes in the right place.
+#
+# To verify that your change has the desired effect on the final configuration
+# you can use the manual test in tests/manual/mkspecs.
+#
+
+QMAKE_COMPILER          = gcc
+
+QMAKE_CC                = gcc
+
+QMAKE_LINK_C            = $$QMAKE_CC
+QMAKE_LINK_C_SHLIB      = $$QMAKE_CC
+
+QMAKE_CXX               = g++
+
+QMAKE_LINK              = $$QMAKE_CXX
+QMAKE_LINK_SHLIB        = $$QMAKE_CXX
+
+QMAKE_PCH_OUTPUT_EXT    = .gch
+
+QMAKE_CFLAGS_PRECOMPILE       = -x c-header -c ${QMAKE_PCH_INPUT} -o ${QMAKE_PCH_OUTPUT}
+QMAKE_CFLAGS_USE_PRECOMPILE   = -include ${QMAKE_PCH_OUTPUT_BASE}
+QMAKE_CXXFLAGS_PRECOMPILE     = -x c++-header -c ${QMAKE_PCH_INPUT} -o ${QMAKE_PCH_OUTPUT}
+QMAKE_CXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+
+QMAKE_CXXFLAGS_CXX11    = -std=c++0x
+QMAKE_CXXFLAGS_CXX14    = -std=c++1y
+QMAKE_CXXFLAGS_CXX1Z    = -std=c++1z
+QMAKE_CXXFLAGS_GNUCXX11 = -std=gnu++0x
+QMAKE_CXXFLAGS_GNUCXX14 = -std=gnu++1y
+QMAKE_CXXFLAGS_GNUCXX1Z = -std=gnu++1z
+QMAKE_LFLAGS_CXX11      =
+QMAKE_LFLAGS_CXX14      =
+QMAKE_LFLAGS_CXX1Z      =

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/g++-unix.conf

@@ -0,0 +1,14 @@
+#
+# Qmake configuration for the GNU C++ compiler on *nix-systems
+#
+# Before making changes to this file, please read the comment in
+# gcc-base.conf, to make sure the change goes in the right place.
+#
+# To verify that your change has the desired effect on the final configuration
+# you can use the manual test in tests/manual/mkspecs.
+#
+
+include(g++-base.conf)
+
+QMAKE_LFLAGS_RELEASE   += -Wl,-O1
+QMAKE_LFLAGS_NOUNDEF   += -Wl,--no-undefined

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/gcc-base-unix.conf

@@ -0,0 +1,25 @@
+#
+# Base qmake configuration for GCC on *nix-systems
+#
+# Before making changes to this file, please read the comment in
+# gcc-base.conf, to make sure the change goes in the right place.
+#
+# To verify that your change has the desired effect on the final configuration
+# you can use the manual test in tests/manual/mkspecs.
+#
+
+include(gcc-base.conf)
+
+QMAKE_LFLAGS_SHLIB     += -shared
+QMAKE_LFLAGS_PLUGIN    += $$QMAKE_LFLAGS_SHLIB
+QMAKE_LFLAGS_SONAME    += -Wl,-soname,
+QMAKE_LFLAGS_THREAD    +=
+QMAKE_LFLAGS_RPATH      = -Wl,-rpath,
+QMAKE_LFLAGS_RPATHLINK  = -Wl,-rpath-link,
+QMAKE_LFLAGS_NEW_DTAGS  = -Wl,--enable-new-dtags
+QMAKE_LFLAGS_USE_GOLD   = -fuse-ld=gold
+
+# -Bsymbolic-functions (ld) support
+QMAKE_LFLAGS_BSYMBOLIC_FUNC = -Wl,-Bsymbolic-functions
+QMAKE_LFLAGS_DYNAMIC_LIST   = -Wl,--dynamic-list,
+QMAKE_LFLAGS_VERSION_SCRIPT = -Wl,--version-script,

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/gcc-base.conf

@@ -0,0 +1,96 @@
+#
+# This file is used as a basis for the following compilers:
+#
+# - The GNU C++ compiler (g++)
+# - LLVM
+# - Clang
+#
+# Platform-specific options shared by these compilers are put into:
+#
+# - gcc-base-mac.conf
+# - gcc-base-unix.conf
+#
+# These base files are then combined with configurations for each compiler:
+#
+# - g++-base.conf
+# - g++-macx.conf
+# - g++-unix.conf
+# - llvm.conf
+# - clang.conf
+#
+# The combination happens in the top level mkspec, by including a platform-
+# specific version of the base-file, for example gcc-base-mac.conf, and then
+# a (possibly platform-specific) version of the actual compiler configuration,
+# for example g++-macx.conf.
+#
+# If you are making changes to any of these files, please consider the
+# possible effect it may have due to these include-rules, and whether it
+# might make more sense to share the rule or make it more specific.
+#
+# To verify that your change has the desired effect on the final configuration
+# you can use the manual test in tests/manual/mkspecs.
+#
+
+QMAKE_CFLAGS_OPTIMIZE      = -O2
+QMAKE_CFLAGS_OPTIMIZE_FULL = -O3
+
+QMAKE_CFLAGS               += -pipe
+QMAKE_CFLAGS_DEPS          += -M
+QMAKE_CFLAGS_WARN_ON       += -Wall -W
+QMAKE_CFLAGS_WARN_OFF      += -w
+QMAKE_CFLAGS_RELEASE       += $$QMAKE_CFLAGS_OPTIMIZE
+QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO += $$QMAKE_CFLAGS_OPTIMIZE -g
+QMAKE_CFLAGS_DEBUG         += -g
+QMAKE_CFLAGS_SHLIB         += -fPIC
+QMAKE_CFLAGS_STATIC_LIB    += -fPIC
+QMAKE_CFLAGS_APP           += -fPIC
+QMAKE_CFLAGS_ISYSTEM        = -isystem
+QMAKE_CFLAGS_YACC          += -Wno-unused -Wno-parentheses
+QMAKE_CFLAGS_HIDESYMS      += -fvisibility=hidden
+QMAKE_CFLAGS_EXCEPTIONS_OFF += -fno-exceptions
+QMAKE_CFLAGS_SPLIT_SECTIONS += -ffunction-sections
+QMAKE_CFLAGS_LTCG           = -flto -fno-fat-lto-objects
+QMAKE_CFLAGS_LTCG_FATOBJECTS = -ffat-lto-objects
+QMAKE_CFLAGS_DISABLE_LTCG   = -fno-lto
+
+QMAKE_CXXFLAGS            += $$QMAKE_CFLAGS
+QMAKE_CXXFLAGS_DEPS       += $$QMAKE_CFLAGS_DEPS
+QMAKE_CXXFLAGS_WARN_ON    += $$QMAKE_CFLAGS_WARN_ON
+QMAKE_CXXFLAGS_WARN_OFF   += $$QMAKE_CFLAGS_WARN_OFF
+QMAKE_CXXFLAGS_RELEASE    += $$QMAKE_CFLAGS_RELEASE
+QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO += $$QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO
+QMAKE_CXXFLAGS_DEBUG      += $$QMAKE_CFLAGS_DEBUG
+QMAKE_CXXFLAGS_SHLIB      += $$QMAKE_CFLAGS_SHLIB
+QMAKE_CXXFLAGS_STATIC_LIB += $$QMAKE_CFLAGS_STATIC_LIB
+QMAKE_CXXFLAGS_APP        += $$QMAKE_CFLAGS_APP
+QMAKE_CXXFLAGS_YACC       += $$QMAKE_CFLAGS_YACC
+QMAKE_CXXFLAGS_HIDESYMS   += $$QMAKE_CFLAGS_HIDESYMS -fvisibility-inlines-hidden
+QMAKE_CXXFLAGS_EXCEPTIONS_OFF += $$QMAKE_CFLAGS_EXCEPTIONS_OFF
+QMAKE_CXXFLAGS_SPLIT_SECTIONS += $$QMAKE_CFLAGS_SPLIT_SECTIONS
+QMAKE_CXXFLAGS_LTCG        = $$QMAKE_CFLAGS_LTCG
+QMAKE_CXXFLAGS_LTCG_FATOBJECTS = $$QMAKE_CFLAGS_LTCG_FATOBJECTS
+QMAKE_CXXFLAGS_DISABLE_LTCG   = $$QMAKE_CFLAGS_DISABLE_LTCG
+
+QMAKE_LFLAGS           +=
+QMAKE_LFLAGS_DEBUG     +=
+QMAKE_LFLAGS_APP       +=
+QMAKE_LFLAGS_RELEASE   +=
+QMAKE_LFLAGS_RELEASE_WITH_DEBUGINFO +=
+QMAKE_LFLAGS_EXCEPTIONS_OFF +=
+QMAKE_LFLAGS_LTCG       = $$QMAKE_CFLAGS_LTCG -fuse-linker-plugin
+
+QMAKE_CFLAGS_SSE2      += -msse2
+QMAKE_CFLAGS_SSE3      += -msse3
+QMAKE_CFLAGS_SSSE3     += -mssse3
+QMAKE_CFLAGS_SSE4_1    += -msse4.1
+QMAKE_CFLAGS_SSE4_2    += -msse4.2
+QMAKE_CFLAGS_AVX       += -mavx
+QMAKE_CFLAGS_AVX2      += -mavx2
+QMAKE_CFLAGS_NEON      += -mfpu=neon
+
+# Wrapper tools that understand .o/.a files with GIMPLE instead of machine code
+QMAKE_AR_LTCG           = gcc-ar cqs
+QMAKE_NM_LTCG           = gcc-nm -P
+QMAKE_RANLIB_LTCG       = true          # No need to run since gcc-ar has "s"
+
+include(sanitize.conf)

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/linux.conf

@@ -0,0 +1,58 @@
+#
+# qmake configuration for common linux
+#
+
+QMAKE_PLATFORM         += linux
+
+include(unix.conf)
+
+QMAKE_CFLAGS_THREAD    += -D_REENTRANT
+QMAKE_CXXFLAGS_THREAD  += $$QMAKE_CFLAGS_THREAD
+QMAKE_LFLAGS_GCSECTIONS = -Wl,--gc-sections
+
+QMAKE_LFLAGS_REL_RPATH  = -Wl,-z,origin
+QMAKE_REL_RPATH_BASE    = $ORIGIN
+
+QMAKE_INCDIR            =
+QMAKE_LIBDIR            =
+QMAKE_INCDIR_X11        =
+QMAKE_LIBDIR_X11        =
+QMAKE_INCDIR_OPENGL     =
+QMAKE_LIBDIR_OPENGL     =
+QMAKE_INCDIR_OPENGL_ES2 = $$QMAKE_INCDIR_OPENGL
+QMAKE_LIBDIR_OPENGL_ES2 = $$QMAKE_LIBDIR_OPENGL
+QMAKE_INCDIR_EGL        =
+QMAKE_LIBDIR_EGL        =
+QMAKE_INCDIR_OPENVG     =
+QMAKE_LIBDIR_OPENVG     =
+
+QMAKE_LIBS              =
+QMAKE_LIBS_DYNLOAD      = -ldl
+QMAKE_LIBS_X11          = -lXext -lX11 -lm
+QMAKE_LIBS_NIS          = -lnsl
+QMAKE_LIBS_EGL          = -lEGL
+QMAKE_LIBS_OPENGL       = -lGL
+QMAKE_LIBS_OPENGL_ES2   = -lGLESv2
+QMAKE_LIBS_OPENVG       = -lOpenVG
+QMAKE_LIBS_THREAD       = -lpthread
+QMAKE_LIBS_LIBUDEV      = -ludev
+
+QMAKE_CFLAGS_WAYLAND    =
+QMAKE_INCDIR_WAYLAND    =
+QMAKE_LIBS_WAYLAND_CLIENT = -lwayland-client
+QMAKE_LIBS_WAYLAND_SERVER = -lwayland-server
+QMAKE_LIBDIR_WAYLAND    =
+QMAKE_DEFINES_WAYLAND   =
+QMAKE_WAYLAND_SCANNER   = wayland-scanner
+
+QMAKE_CFLAGS_XCB        =
+QMAKE_LIBS_XCB          =
+QMAKE_DEFINES_XCB       =
+
+QMAKE_AR                = ar cqs
+QMAKE_OBJCOPY           = objcopy
+QMAKE_NM                = nm -P
+QMAKE_RANLIB            =
+
+QMAKE_STRIP             = strip
+QMAKE_STRIPFLAGS_LIB   += --strip-unneeded

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/sanitize.conf

@@ -0,0 +1,23 @@
+#
+# Qmake configuration for the GCC / Clang sanitize features
+#
+
+QMAKE_COMMON_SANITIZE_CFLAGS   = -fno-omit-frame-pointer
+QMAKE_COMMON_SANITIZE_CXXFLAGS = -fno-omit-frame-pointer
+
+QMAKE_SANITIZE_ADDRESS_CFLAGS     = -fsanitize=address
+QMAKE_SANITIZE_ADDRESS_CXXFLAGS   = -fsanitize=address
+QMAKE_SANITIZE_ADDRESS_LFLAGS     = -fsanitize=address
+
+QMAKE_SANITIZE_THREAD_CFLAGS      = -fsanitize=thread
+QMAKE_SANITIZE_THREAD_CXXFLAGS    = -fsanitize=thread
+QMAKE_SANITIZE_THREAD_LFLAGS      = -fsanitize=thread
+
+QMAKE_SANITIZE_MEMORY_CFLAGS      = -fsanitize=memory
+QMAKE_SANITIZE_MEMORY_CXXFLAGS    = -fsanitize=memory
+QMAKE_SANITIZE_MEMORY_LFLAGS      = -fsanitize=memory
+
+QMAKE_SANITIZE_UNDEFINED_CFLAGS   = -fsanitize=undefined
+QMAKE_SANITIZE_UNDEFINED_CXXFLAGS = -fsanitize=undefined
+QMAKE_SANITIZE_UNDEFINED_LFLAGS   = -fsanitize=undefined
+

usr/lib/x86_64-linux-gnu/qt5/mkspecs/common/unix.conf

@@ -0,0 +1,17 @@
+#
+# qmake configuration for common unix
+#
+
+QMAKE_PLATFORM         += unix posix
+
+QMAKE_LEX               = flex
+QMAKE_LEXFLAGS         +=
+QMAKE_YACC              = yacc
+QMAKE_YACCFLAGS        += -d
+QMAKE_YACCFLAGS_MANGLE += -p $base -b $base
+QMAKE_YACC_HEADER       = $base.tab.h
+QMAKE_YACC_SOURCE       = $base.tab.c
+QMAKE_PREFIX_SHLIB      = lib
+QMAKE_EXTENSION_SHLIB   = so
+QMAKE_PREFIX_STATICLIB  = lib
+QMAKE_EXTENSION_STATICLIB = a

usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/default_post.prf

@@ -0,0 +1,118 @@
+# This file is loaded by qmake right after loading the actual project file.
+
+contains(TEMPLATE, ".*(lib|app)"):CONFIG += have_target
+
+!have_target:!force_qt: CONFIG -= qt
+
+load(resolve_config)
+
+exclusive_builds: load(exclusive_builds_post)
+
+# If the TARGET looks like a path, split it into DESTDIR and the resulting TARGET
+target_dir_part = $$dirname(TARGET)
+!isEmpty(target_dir_part) {
+    isEmpty(DESTDIR): \
+        DESTDIR = $$target_dir_part
+    else: \
+        DESTDIR = $$DESTDIR/$$target_dir_part
+
+    TARGET = $$basename(TARGET)
+    DESTDIR = $$clean_path($$DESTDIR)
+}
+
+QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
+!isEmpty(QT_BREAKPAD_ROOT_PATH): \   # quick test first whether requested ...
+        !static:release:have_target: \   # is it applicable?
+        !contains(TARGET, .*phony_target.*): \   # monster hack, you don't really see this here, right? ;)
+        system($$QT_BREAKPAD_ROOT_PATH/qtbreakpadsymbols --breakpad-exists) {    # do we really have it?
+    CONFIG += breakpad force_debug_info
+    CONFIG -= no_debug_info separate_debug_info
+}
+
+force_debug_info|debug: \
+    CONFIG += debug_info
+
+force_debug_info {
+    QMAKE_CFLAGS_RELEASE = $$QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO
+    QMAKE_CXXFLAGS_RELEASE = $$QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO
+    QMAKE_LFLAGS_RELEASE = $$QMAKE_LFLAGS_RELEASE_WITH_DEBUGINFO
+}
+
+optimize_full {
+    !isEmpty(QMAKE_CFLAGS_OPTIMIZE):!isEmpty(QMAKE_CFLAGS_OPTIMIZE_FULL)  {
+        QMAKE_CFLAGS_RELEASE -= $$QMAKE_CFLAGS_OPTIMIZE
+        QMAKE_CXXFLAGS_RELEASE -= $$QMAKE_CFLAGS_OPTIMIZE
+        QMAKE_CFLAGS_RELEASE += $$QMAKE_CFLAGS_OPTIMIZE_FULL
+        QMAKE_CXXFLAGS_RELEASE += $$QMAKE_CFLAGS_OPTIMIZE_FULL
+    }
+}
+
+debug {
+    QMAKE_CFLAGS += $$QMAKE_CFLAGS_DEBUG
+    QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_DEBUG
+    QMAKE_LFLAGS += $$QMAKE_LFLAGS_DEBUG
+    QMAKE_LIBFLAGS += $$QMAKE_LIBFLAGS_DEBUG
+} else {
+    QMAKE_CFLAGS += $$QMAKE_CFLAGS_RELEASE
+    QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_RELEASE
+    QMAKE_LFLAGS += $$QMAKE_LFLAGS_RELEASE
+    QMAKE_LIBFLAGS += $$QMAKE_LIBFLAGS_RELEASE
+}
+
+# disable special linker flags for host builds (no proper test for host support yet)
+!host_build {
+    use_gold_linker: QMAKE_LFLAGS += $$QMAKE_LFLAGS_USE_GOLD
+    enable_new_dtags: QMAKE_LFLAGS += $$QMAKE_LFLAGS_NEW_DTAGS
+}
+
+dll:win32: QMAKE_LFLAGS += $$QMAKE_LFLAGS_DLL
+static:mac: QMAKE_LFLAGS += $$QMAKE_LFLAGS_STATIC_LIB
+staticlib:unix {
+    QMAKE_CFLAGS += $$QMAKE_CFLAGS_STATIC_LIB
+    QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_STATIC_LIB
+}
+
+incredibuild_xge {
+    CONFIG -= incredibuild_xge
+    CONFIG = incredibuild_xge $$CONFIG
+}
+
+silent {
+    # Ensure that we process silent.prf last, as it will mangle QMAKE_CXX
+    # and friends in a way that some of the other features (sdk.prf and
+    # simd.prf eg) do not handle.
+    CONFIG -= silent
+    CONFIG = silent $$CONFIG
+}
+
+breakpad {
+    load(resolve_target)
+    DEBUGFILENAME = $$shell_quote($$system_path($$QMAKE_RESOLVED_TARGET))
+    PROJECTPATH = $$shell_quote($$system_path($$OUT_PWD))
+
+    !isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK = $$QMAKE_POST_LINK$$escape_expand(\\n\\t)
+    QMAKE_POST_LINK = $$QMAKE_POST_LINK$$quote($${QT_BREAKPAD_ROOT_PATH}$${QMAKE_DIR_SEP}qtbreakpadsymbols $$DEBUGFILENAME $$PROJECTPATH)
+    !isEmpty(QMAKE_STRIP):QMAKE_POST_LINK = $$QMAKE_POST_LINK$$escape_expand(\\n\\t)$$quote($$QMAKE_STRIP $$DEBUGFILENAME)
+}
+
+# Disable special compiler flags for host builds (needs to be changed for 5.7
+# to fall back to c++11 because since 5.7 c++11 is required everywhere,
+# including host builds).
+if(!host_build|!cross_compile):if(c++11|c++14|c++1z) {
+    c++1z:       cxxstd = CXX1Z
+    else: c++14: cxxstd = CXX14
+    else:        cxxstd = CXX11
+
+    # Check if we should disable the GNU extensions or not
+    !strict_c++:!isEmpty(QMAKE_CXXFLAGS_GNU$$cxxstd): cxxstd = GNU$$cxxstd
+
+    QMAKE_CXXFLAGS += $$eval(QMAKE_CXXFLAGS_$$cxxstd)
+    QMAKE_LFLAGS += $$eval(QMAKE_LFLAGS_$$cxxstd)
+
+    unset(cxxstd)
+}
+
+!precompile_header: SOURCES += $$NO_PCH_SOURCES
+
+QMAKE_INCDIR += $$QMAKE_INCDIR_POST
+QMAKE_LIBDIR += $$QMAKE_LIBDIR_POST