Allow using dynamically generated address in LB modules NEGs

[ludoo]

This will also need to be implemented for the GLB module before this PR is ready. Fixes #1055

Tested with this example:

resource "google_compute_address" "ilb-l7-test" {
  project      = module.project-svc-gce.project_id
  name         = "test-ilb-l7"
  subnetwork   = local.subnet_self_links["gce:ew8"]
  address_type = "INTERNAL"
  region       = "europe-west8"
}

module "ilb-l7-test-0" {
  source     = "../cloud-foundation-fabric/modules/net-ilb-l7"
  project_id = module.project-svc-gce.project_id
  region     = "europe-west8"
  name       = "test-0"
  address    = google_compute_address.ilb-l7-test.address
  backend_service_configs = {
    default = {
      project_id = module.project-svc-gce.project_id
      backends = [
        for k, v in module.gce-nginx-ew8 : { group = v.group.id }
      ]
    }
  }
  vpc_config = {
    network    = module.vpc-shared.self_link
    subnetwork = local.subnet_self_links["gce:ew8"]
  }
}

module "ilb-l7-test-1" {
  source     = "../cloud-foundation-fabric/modules/net-ilb-l7"
  project_id = module.project-svc-gce.project_id
  region     = "europe-west8"
  name       = "test-1"
  backend_service_configs = {
    default = {
      backends = [{
        balancing_mode = "RATE"
        group          = "neg-0"
        max_rate       = { per_endpoint = 1 }
      }]
    }
  }
  neg_configs = {
    neg-0 = {
      hybrid = {
        zone = "europe-west8-b"
        endpoints = {
          e-0 = {
            ip_address = google_compute_address.ilb-l7-test.address
            port       = 80
          }
        }
      }
    }
  }
  vpc_config = {
    network    = module.vpc-shared.self_link
    subnetwork = local.subnet_self_links["gce:ew8"]
  }
}