build.gradle

plugins {
    id 'com.android.application'
    id 'kotlin-android'
    id 'kotlin-parcelize'
    id 'kotlin-kapt'
    id 'com.google.devtools.ksp'
    id 'androidx.navigation.safeargs'
    id 'com.google.gms.google-services'
    id 'com.google.firebase.crashlytics'
    id 'com.google.dagger.hilt.android'
}

android {
    namespace 'org.imaginativeworld.simplemvvm'
    compileSdk 34

    defaultConfig {
        applicationId "org.imaginativeworld.simplemvvm"
        minSdk 21
        targetSdk 34
        versionCode 1
        versionName "1.0.0.000000" // Major.Minor.Patch.YYMMDD
        vectorDrawables.useSupportLibrary = true

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

        signingConfig signingConfigs.debug

        // Constants
        Properties properties = new Properties()
        properties.load(project.rootProject.file('local.properties').newDataInputStream())

        buildConfigField "String", "API_KEY", "\"${properties.getProperty('API_KEY')}\""

        javaCompileOptions {
            annotationProcessorOptions {
                arguments = ["room.schemaLocation": "$projectDir/schemas"]
            }
        }
    }

    buildTypes {
        local { // Local
            initWith debug
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'

            loadConfigurationProperties it, "config/internal.properties"

            matchingFallbacks = ['debug']
        }

        debug { // Development
            debuggable true
            minifyEnabled false
            applicationIdSuffix ".debug"
            versionNameSuffix "-debug"
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'

            loadConfigurationProperties it, "config/development.properties"
        }

        staging { // Staging
            initWith debug
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'

            loadConfigurationProperties it, "config/staging.properties"

            matchingFallbacks = ['release']
        }

        release { // Production
            debuggable false
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'

            loadConfigurationProperties it, "config/release.properties"
        }
    }

//    flavorDimensions "feature"
//    productFlavors {
//        flavorone {
//            dimension "feature"
//            applicationIdSuffix ".flavorone"
//            versionNameSuffix "-flavorone"
//        }
//        flavortwo {
//            dimension "feature"
//            applicationIdSuffix ".flavortwo"
//            versionNameSuffix "-flavortwo"
//        }
//    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    kotlinOptions {
        jvmTarget = "17"
        freeCompilerArgs += "-opt-in=kotlin.RequiresOptIn"
    }

    buildFeatures {
        viewBinding true
        dataBinding true

        // Disable unused AGP features
        resValues false
        shaders false
    }

    hilt {
        enableAggregatingTask = true
    }

    signingConfigs {
        debug {
            storeFile file('../debug.keystore')
            storePassword 'android'
            keyAlias 'androiddebugkey'
            keyPassword 'android'
        }
    }
}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation 'androidx.appcompat:appcompat:1.6.1'
    implementation 'androidx.core:core-ktx:1.12.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.4'

    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.1.5'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.5.1'

    // Fragment
    implementation "androidx.fragment:fragment-ktx:1.6.2"

    // Material Design
    implementation 'com.google.android.material:material:1.11.0'

    // Retrofit
    implementation 'com.squareup.retrofit2:retrofit:2.11.0'
    implementation 'com.squareup.okhttp3:logging-interceptor:4.12.0'

    // Moshi
    implementation 'com.squareup.retrofit2:converter-moshi:2.11.0'
    implementation "com.squareup.moshi:moshi-kotlin:1.15.1"
    ksp "com.squareup.moshi:moshi-kotlin-codegen:1.15.1"

    // Gson
    implementation 'com.google.code.gson:gson:2.10.1'

    // ViewModel and LiveData
    implementation "androidx.lifecycle:lifecycle-viewmodel-ktx:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-livedata-ktx:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-common:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-runtime-ktx:$lifecycle_version"

    // Kotlin Coroutines
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:1.8.0"
    implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:1.8.1-Beta"

    // Room Persistence Library
    implementation "androidx.room:room-runtime:$room_version"
    ksp "androidx.room:room-compiler:$room_version"

    // Room: Kotlin Extensions and Coroutines support for Room
    implementation "androidx.room:room-ktx:$room_version"

    // Android Navigation Architecture
    implementation "androidx.navigation:navigation-fragment-ktx:2.7.7"
    implementation "androidx.navigation:navigation-ui-ktx:2.7.7"

    // Splash Screen
    implementation "androidx.core:core-splashscreen:1.0.1"

    // Glide
    implementation 'com.github.bumptech.glide:glide:4.16.0'
    ksp 'com.github.bumptech.glide:ksp:4.16.0'

    // Paging
    implementation "androidx.paging:paging-runtime-ktx:3.2.1"

    // Permission
    implementation 'com.karumi:dexter:6.2.3'

    // Timber
    implementation 'com.jakewharton.timber:timber:5.0.1'

    // Hilt
    implementation "com.google.dagger:hilt-android:$hilt_version"
    ksp "com.google.dagger:hilt-compiler:$hilt_version"

    // Shimmer
    implementation 'com.facebook.shimmer:shimmer:0.5.0'

    // Firebase BoM
    implementation platform('com.google.firebase:firebase-bom:32.8.1')

    // Firebase Libraries
    implementation 'com.google.firebase:firebase-analytics-ktx'
    implementation 'com.google.firebase:firebase-messaging-ktx'

    // Maps
    implementation 'com.google.android.gms:play-services-maps:18.2.0'

    // Location
    implementation 'com.google.android.gms:play-services-location:21.2.0'

    // Image compressor
    implementation 'id.zelory:compressor:3.0.1'

    // No Internet Library
    implementation 'org.imaginativeworld.oopsnointernet:oopsnointernet:2.0.0'

    // Image Carousel
    implementation "org.imaginativeworld.whynotimagecarousel:whynotimagecarousel:2.1.0"

    // OneSignal SDK
    implementation 'com.onesignal:OneSignal:4.8.6'

    // Coil
    implementation("io.coil-kt:coil:2.6.0")

    // Palette
    implementation 'androidx.palette:palette-ktx:1.0.0'

    // Markdown
    implementation "io.noties.markwon:core:$markwon_version"
    implementation "io.noties.markwon:ext-latex:$markwon_version"
    implementation "io.noties.markwon:inline-parser:$markwon_version"

    // Latex
    implementation "ru.noties:jlatexmath-android:$jlatexmath_version"
    // for Cyrillic symbols
    implementation "ru.noties:jlatexmath-android-font-cyrillic:$jlatexmath_version"
    // for Greek symbols
    implementation "ru.noties:jlatexmath-android-font-greek:$jlatexmath_version"
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
    kotlinOptions {
        jvmTarget = "17"
    }
}

/**
 * Load properties from configuration file.
 */
def loadConfigurationProperties(buildType, String fileLocation) {
    Properties properties = new Properties()
    properties.load(project.rootProject.file(fileLocation).newDataInputStream())

    buildType.buildConfigField "String", "BASE_URL", "\"${properties.getProperty("baseUrl")}\""
}