-
Notifications
You must be signed in to change notification settings - Fork 71
/
Example - Color Tabs.ahk
509 lines (438 loc) · 15.1 KB
/
Example - Color Tabs.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
/*
In this example, the color of the tabs are set.
Disclaimer: This is a very limited example that was created by trial and
error. It certainly can be improved and it's possible that it contains bugs
that should be fixed before using something like this in production
environment.
*/
#NoEnv
#SingleInstance Force
ListLines Off
;-- Tab control styles
TCS_RIGHTJUSTIFY :=0x0
TCS_SINGLELINE :=0x0
TCS_EX_FLATSEPARATORS :=0x1
TCS_SCROLLOPPOSITE :=0x1
TCS_RIGHT :=0x2
TCS_BOTTOM :=0x2
TCS_MULTISELECT :=0x4
TCS_FLATBUTTONS :=0x8
TCS_FORCEICONLEFT :=0x10
TCS_FORCELABELLEFT :=0x20
TCS_HOTTRACK :=0x40
TCS_VERTICAL :=0x80
TCS_BUTTONS :=0x100
TCS_MULTILINE :=0x200
TCS_FIXEDWIDTH :=0x400
TCS_RAGGEDRIGHT :=0x800
TCS_FOCUSONBUTTONDOWN :=0x1000
TCS_OWNERDRAWFIXED :=0x2000
TCS_TOOLTIPS :=0x4000
TCS_FOCUSNEVER :=0x8000
;-- Initialize
MarginX :=10
MarginY :=10
;-- Create GUI
gui -DPIScale ; -MinimizeBox
gui Margin,%MarginX%,%MarginY%
;-- Add the tab control
TabStyle :=0
gui Add,Tab3,xm w300 h250 %TabStyle% hWndhTab gSelectedTab vMyTab,A-C|D-F|G-J|K-M|N-Q|R-T|U-Z
gui Font
;-- Increase the height of the tabs so that the tab colors are a bit more
; prominent.
hFont :=Fnt_GetFont(hTab)
TAB_SetItemSize(hTab,1,Fnt_GetFontHeight(hFont)+10)
;-- Add the TCS_OWNERDRAWFIXED style
; Note: This is performed after the tab control is created. In most cases,
; AutoHotkey will automatically remove this style if it exists when the tab
; control is created.
TAB_SetStyle(hTab,TCS_OWNERDRAWFIXED)
;-- Reset the tab control
; This will force the tab control to reposition. Note: This is not necessary
; for the Tab and Tab2 controls but it remains for completeness.
GUIControl,,%hTab%
;-- Get the display area
TAB_GetDisplayArea(hTab,DisplayAreaX,DisplayAreaY,DisplayAreaW,DisplayAreaH)
;-- Adjust for margins
EditX :=DisplayAreaX+MarginX
EditY :=DisplayAreaY+MarginY
EditW :=DisplayAreaW-(MarginX*2)
EditH :=DisplayAreaH-(MarginY*2)
;-- Populate the tabs
gui Tab,A-C
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH% vMyEditAC,
(ltrim
1205`tAdam Sandler
6791`tAl Pacino
7852`tAngelina Jolie
5532`tAnne Hathaway
3600`tArnold Schwarzenegger
4815`tBen Affleck
7506`tBill Murray
4691`tBrad Pitt
9208`tBradley Cooper
6440`tBruce Willis
6294`tCameron Diaz
9654`tChanning Tatum
4115`tCharles Chaplin
7713`tChris Hemsworth
4414`tClint Eastwood
)
;-- Collect the text from the first Edit control and then empty the control
; This text is used later to populate the control after the screen is showing.
GUIControlGet MyEditAC,,MyEditAC
GUIControl,,MyEditAC
gui Tab,D-F
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
9024`tDaniel Craig
4349`tDaniel Radcliffe
5398`tDwayne Johnson
6156`tEdward Norton
2138`tEmma Stone
5795`tEmma Watson
)
gui Tab,G-J
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
3558`tGeorge Clooney
4425`tHalle Berry
4413`tHarrison Ford
4566`tHugh Jackman
4332`tIan McKellen
7349`tJack Nicholson
7772`tJackie Chan
1785`tJake Gyllenhaal
7314`tJames Cameron
9799`tJames McAvoy
1827`tJennifer Aniston
6004`tJessica Alba
7009`tJim Carrey
8804`tJohnny Depp
3266`tJulia Roberts
)
gui Tab,K-M
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
1107`tKate Beckinsale
5952`tKate Winslet
3344`tKeanu Reeves
8697`tKeira Knightley
8436`tLeonardo DiCaprio
7299`tLiam Neeson
2940`tMacaulay Culkin
1018`tMark Wahlberg
7715`tMarlon Brando
8379`tMatt Damon
1147`tMegan Fox
2412`tMel Gibson
4666`tMorgan Freeman
)
gui Tab,N-Q
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
7708`tNatalie Portman
6901`tNicolas Cage
3068`tOrlando Bloom
5592`tOwen Wilson
1728`tPeter Jackson
8429`tPierce Brosnan
3836`tSandra Bullock
)
gui Tab,R-T
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
7643`tRachel McAdams
9188`tRobert De Niro
5758`tRobert Downey Jr.
1048`tRowan Atkinson
2732`tRussell Crowe
3346`tSamuel L. Jackson
5501`tScarlett Johansson
4337`tSean Connery
3101`tSigourney Weaver
9449`tSteven Spielberg
3972`tSylvester Stallone
2309`tTim Allen
2148`tTom Cruise
3583`tTom Hanks
)
gui Tab,U-Z
gui Add,Edit,x%EditX% y%EditY% w%EditW% h%EditH%,
(ltrim
2395`tVin Diesel
2777`tWill Ferrell
4585`tWill Smith
3176`tZach Galifianakis
)
;-- After this, all GUI controls are added outside of the tab control
gui Tab
;-- Misc. controls
gui Add,Button,xm vReload gReload,%A_Space%Reload...%A_Space%
gui Add,StatusBar
;-- Show it
SplitPath A_ScriptName,,,,$ScriptName
gui Show,AutoSize,%$ScriptName%
gosub UpdateSB
;-- Reload the first Edit control
; This keeps the control from selecting all text
GUIControl,,MyEditAC,%MyEditAC%
;-- Monitor WM_DRAWITEM
WM_DRAWITEM :=0x2B
OnMessage(WM_DRAWITEM,"OnDrawItem")
;-- Reset the tab control
; This will force the tab control (and text) to redraw
GUIControl,,%hTab%
return
SelectedTab:
gui Submit,NoHide
gosub UpdateSB
return
GUIEscape:
GUIClose:
ExitApp
Reload:
Reload
return
UpdateSB:
SelectedTab :=TAB_GetCurSel(hTab)
SBText :=""
. "There are " . TAB_GetItemCount(hTab) . " tabs. "
. (SelectedTab ? "Tab """ . TAB_GetText(hTab,SelectedTab) . """ is selected.":"No tab is selected.")
SB_SetText(SBText)
return
;*******************
;* *
;* Functions *
;* *
;*******************
OnDrawItem(wParam,lParam,Msg,hWnd)
{
Global DrawItem
Static Dummy15968469
,Color1,Color2,Color3,Color4,Color5,Color6,Color7,Color8,Color9
;-- CtlType - Control Types
,ODT_MENU :=1
,ODT_LISTBOX :=2
,ODT_COMBOBOX:=3
,ODT_BUTTON :=4
,ODT_STATIC :=5
,ODT_TAB :=101
,ODT_LISTVIEW:=102
;-- itemAction - Required drawing action
,ODA_DRAWENTIRE:=0x1
,ODA_SELECT :=0x2
,ODA_FOCUS :=0x4
;-- itemState - The visual state of the item after the current drawing
; action takes place.
,ODS_SELECTED :=0x1
,ODS_GRAYED :=0x2
,ODS_DISABLED :=0x4
,ODS_CHECKED :=0x8
,ODS_DEFAULT :=0x20
,ODS_HOTLIGHT :=0x40
,ODS_INACTIVE :=0x80
,ODS_NOACCEL :=0x100
,ODS_NOFOCUSRECT :=0x200
,ODS_COMBOBOXEDIT:=0x1000
;-- DrawText flags
,DT_LEFT :=0x0
,DT_TOP :=0x0
,DT_CENTER :=0x1
,DT_RIGHT :=0x2
,DT_VCENTER :=0x4
,DT_BOTTOM :=0x8
,DT_WORDBREAK :=0x10
,DT_SINGLELINE :=0x20
,DT_EXPANDTABS :=0x40
,DT_TABSTOP :=0x80
,DT_NOCLIP :=0x100
,DT_EXTERNALLEADING :=0x200
,DT_CALCRECT :=0x400
,DT_NOPREFIX :=0x800
,DT_INTERNAL :=0x1000
,DT_EDITCONTROL :=0x2000
,DT_PATH_ELLIPSIS :=0x4000
,DT_END_ELLIPSIS :=0x8000
,DT_MODIFYSTRING :=0x10000
,DT_RTLREADING :=0x20000
,DT_WORD_ELLIPSIS :=0x40000
,DT_NOFULLWIDTHCHARBREAK:=0x80000
,DT_HIDEPREFIX :=0x100000
,DT_PREFIXONLY :=0x200000
;-- System colors
,COLOR_MENU :=4
,COLOR_WINDOW :=5
,COLOR_3DFACE :=15
,COLOR_BTNFACE:=15
;-- Misc.
,CXEDGE
,CYEDGE
,FirstCall:=True
,hFontSelected
,hFontUnselected
/*
Programming notes:
This example only has one tab control and so all WM_DRAWITEM messages
are from that control. This function does not check to verify if the
message are for the tab control but if other controls that trigger the
WM_DRAWITEM message were added, the function would need to verify that
only the messages from the specified tab control are processed.
*/
/*
DRAWITEMSTRUCT structure
Provides information that the owner window uses to determine how to paint an
owner-drawn control or menu item. The owner window of the owner-drawn control or
menu item receives a pointer to this structure as the lParam parameter of the
WM_DRAWITEM message.
[Member] [Type] [32bitA] [32bitU] [64bitU]
1 CtlType UINT [00] 4 [00] 4 [00] 4
2 CtlID UINT [04] 4 [04] 4 [04] 4
3 itemID UINT [08] 4 [08] 4 [08] 4
4 itemAction UINT [12] 4 [12] 4 [12] 4
5 itemState UINT [16] 4 [16] 4 [16] 4
6 hwndItem HWND [20] 4 [20] 4 [24] 8
7 hDC HDC [24] 4 [24] 4 [32] 8
8 rcItem.left int [28] 4 [28] 4 [40] 4
9 rcItem.top int [32] 4 [32] 4 [44] 4
10 rcItem.right int [36] 4 [36] 4 [48] 4
11 rcItem.bottom int [40] 4 [40] 4 [52] 4
12 itemData ULONG_PTR [44] 4 [44] 4 [56] 8
-- -- --
48 48 64
*/
;[============================]
;[ Extract values from ]
;[ DRAWITEMSTRUCT structure ]
;[============================]
CtlType:=NumGet(lParam+0,0,"UInt")
;-- For this example, the value is always ODT_TAB (101). Only need to
; check if there are are other controls that send the WM_DRAWITEM
; message.
CtlID:=NumGet(lParam+0,4,"UInt")
;-- For this example, the value is always 3. Not sure if this value is
; important for this message. Not likely.
itemID:=NumGet(lParam+0,8,"UInt")
;-- Contains the 0-based tab index
iTab:=itemID+1
;-- 1-based tab index. Used by the TAB library.
itemAction:=NumGet(lParam+0,12,"UInt")
;-- For this example, the value is always ODA_DRAWENTIRE (0x1). This
; may contain other values if the tab has an icon.
itemState:=NumGet(lParam+0,16,"UInt")
;-- For this example, the value is either ODS_SELECTED (0x1) or 0 (no
; constant value) which indicates "not selected".
hTab:=hwndItem:=NumGet(lParam+0,A_PtrSize=8 ? 24:20,"Ptr")
;-- The handle to the tab control. Used by the TAB library.
hDC:=NumGet(lParam+0,A_PtrSize=8 ? 32:24,"Ptr")
;-- The handle to a device context. msdn: This device context must be
; used when performing drawing operations on the control.
;[===============]
;[ First call? ]
;[===============]
if FirstCall
{
FirstCall:=False
;------------------
;-- System metrics
;------------------
SysGet CXEDGE,45
SysGet CYEDGE,46
;-- Dimensions of a 3-D border, in pixels
;---------------
;-- Create font
;---------------
;-- Get the tab control's font
hFont:=Fnt_GetFont(hTab)
;-- Create new fonts using the attributes of the tab control's font.
; This is not the same as cloning. Not sure why.
; Note: In this example, the fonts remain static and are not deleted
; until the script ends. This may not be the best approach in all
; situations.
hFontSelected :=Fnt_CreateFont(Fnt_GetFontName(hFont),Fnt_GetFontOptions(hFont) . " Bold")
hFontUnselected:=Fnt_CreateFont(Fnt_GetFontName(hFont),Fnt_GetFontOptions(hFont))
;------------------------
;-- Determine the colors
;-- for the tabs
;------------------------
Count:=0
MaxColors:=TAB_GetItemCount(hTab)
Loop
{
Random,Color,0x000000,0xFFFFFF
;-- Color is used as BGR so this color should be assumed to be
; in BGR format.
;-- Convert to HSV
R:=(Color&0xFF)/255
G:=((Color>>8)&0xFF)/255
B:=((Color>>16)&0xFF)/255
HSV:=HSV_Convert2HSV(R,G,B)
;-- Pastel(ish) colors only
; Note: Pastel colors are used because they are easy to view but
; also because it doesn't require the text color to change. This
; will work on most themes because the text color is black but it
; won't always work as expected. On themes with dark background
; and light text color, the results may not be usable.
if (HSV.V<0.7 or HSV.S>0.4)
Continue
Count++
Color%Count%:=Color
if (Count>=MaxColors)
Break
}
}
;[============]
;[ Draw tab ]
;[============]
if (itemState=ODS_SELECTED)
{
hBrush:=DllCall("CreateSolidBrush","UInt",Color%iTab%)
DllCall("FillRect","Ptr",hDC,"Ptr",lParam+(A_PtrSize=8 ? 40:28),"Ptr",hBrush)
DllCall("DeleteObject","Ptr",hBrush)
;-- Set the text background color
DllCall("SetBkColor","Ptr",hDC,"Int",Color%iTab%)
;-- Set font
hFont:=hFontSelected
}
else ;-- Tab is not selected
{
;-- Copy the RECT so that we can make minor changes
; The rectangle defines the boundaries of the control to be drawn.
VarSetCapacity(RECT,16,0)
DllCall("CopyRect","Ptr",&RECT,"Ptr",lParam+(A_PtrSize=8 ? 40:28))
;-- Paint the tab
hBrush:=DllCall("CreateSolidBrush","UInt",Color%iTab%)
Bottom:=NumGet(RECT,12,"Int")
NumPut(Bottom+CYEDGE,RECT,12,"Int")
DllCall("FillRect","Ptr",hDC,"Ptr",&RECT,"Ptr",hBrush)
DllCall("DeleteObject","Ptr",hBrush)
;-- Set the text background color
DllCall("SetBkColor","Ptr",hDC,"Int",Color%iTab%)
;-- Set font
hFont:=hFontUnselected
}
;[=================]
;[ Draw the text ]
;[=================]
;-- Select the font into the device context provided by this message
hFont_Old:=DllCall("SelectObject","Ptr",hDC,"Ptr",hFont)
;-- Draw the text
uFormat:=DT_CENTER|DT_VCENTER|DT_SINGLELINE
RC:=DllCall("DrawText"
,"Ptr",hDC ;-- hDC
,"Str",TAB_GetText(hTab,iTab) ;-- lpchText
,"Int",-1 ;-- nCount
,"Ptr",lParam+(A_PtrSize=8 ? 40:28) ;-- lpRect
,"UInt",uFormat) ;-- uFormat
;-- Release the objects needed by the "DrawText" function
DllCall("SelectObject","Ptr",hDC,"Ptr",hFont_Old)
;-- Necessary to avoid memory leak
;-- Notify the system that this message has been processed. The OS will
; not draw the tab when is this done.
Return True
}
#include %A_ScriptDir%/_Functions
#include TAB.ahk
#include Fnt.ahk
#include HSV.ahk