-
Notifications
You must be signed in to change notification settings - Fork 6
/
CRTM_Tangent_Linear_Module.f90
1450 lines (1308 loc) · 67.8 KB
/
CRTM_Tangent_Linear_Module.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!
!
!
! CRTM_Tangent_Linear_Module
!
! Module containing the CRTM tangent-linear model function.
!
! CREATION HISTORY:
! Written by: Paul van Delst, 29-Jun-2004
! paul.vandelst@noaa.gov
! Added openMP Quanhua (Mark) Liu, 18-11-2020
MODULE CRTM_Tangent_Linear_Module
! ------------
! Module usage
! ------------
USE Type_Kinds, ONLY: fp, LLong
USE Message_Handler, ONLY: SUCCESS, FAILURE, WARNING, Display_Message
USE CRTM_Parameters, ONLY: SET,NOT_SET,ZERO,ONE, &
MAX_N_LAYERS , &
MAX_N_PHASE_ELEMENTS, &
MAX_N_LEGENDRE_TERMS, &
MAX_N_STOKES , &
MAX_N_ANGLES , &
MAX_N_AZIMUTH_FOURIER, &
MAX_SOURCE_ZENITH_ANGLE, &
MAX_N_STREAMS, &
AIRCRAFT_PRESSURE_THRESHOLD, &
MIN_COVERAGE_THRESHOLD, &
SCATTERING_ALBEDO_THRESHOLD
USE CRTM_SpcCoeff, ONLY: SC, &
SpcCoeff_IsVisibleSensor, &
SpcCoeff_IsMicrowaveSensor, &
SpcCoeff_IsInfraredSensor, &
SpcCoeff_IsUltravioletSensor
USE CRTM_Atmosphere_Define, ONLY: CRTM_Atmosphere_type, &
CRTM_Atmosphere_Destroy, &
CRTM_Atmosphere_IsValid, &
CRTM_Get_PressureLevelIdx
USE CRTM_Surface_Define, ONLY: CRTM_Surface_type, &
CRTM_Surface_IsValid
USE CRTM_Geometry_Define, ONLY: CRTM_Geometry_type, &
CRTM_Geometry_IsValid
USE CRTM_ChannelInfo_Define, ONLY: CRTM_ChannelInfo_type, &
CRTM_ChannelInfo_n_Channels
USE CRTM_RTSolution_Define, ONLY: CRTM_RTSolution_type , &
CRTM_RTSolution_Destroy, &
CRTM_RTSolution_Zero, &
CRTM_RTSolution_Inspect
USE CRTM_Options_Define, ONLY: CRTM_Options_type, &
CRTM_Options_IsValid
USE CRTM_Atmosphere, ONLY: CRTM_Atmosphere_AddLayers , &
CRTM_Atmosphere_AddLayers_TL , &
CRTM_Atmosphere_IsFractional , &
CRTM_Atmosphere_Coverage , &
CRTM_Atmosphere_ClearSkyCopy , &
CRTM_Atmosphere_ClearSkyCopy_TL
USE CRTM_GeometryInfo_Define, ONLY: CRTM_GeometryInfo_type, &
CRTM_GeometryInfo_SetValue, &
CRTM_GeometryInfo_GetValue
USE CRTM_GeometryInfo, ONLY: CRTM_GeometryInfo_Compute
USE CRTM_Predictor_Define, ONLY: CRTM_Predictor_type , &
CRTM_Predictor_Associated, &
CRTM_Predictor_Destroy , &
CRTM_Predictor_Create
USE CRTM_Predictor, ONLY: CRTM_PVar_type => iVar_type, &
CRTM_Compute_Predictors , &
CRTM_Compute_Predictors_TL
USE CRTM_AtmAbsorption, ONLY: CRTM_AAvar_type => iVar_type, &
CRTM_Compute_AtmAbsorption , &
CRTM_Compute_AtmAbsorption_TL
USE CRTM_AtmOptics_Define, ONLY: CRTM_AtmOptics_type , &
CRTM_AtmOptics_Associated, &
CRTM_AtmOptics_Create , &
CRTM_AtmOptics_Destroy , &
CRTM_AtmOptics_Zero
USE CRTM_AerosolScatter, ONLY: CRTM_Compute_AerosolScatter , &
CRTM_Compute_AerosolScatter_TL
USE CRTM_CloudScatter, ONLY: CRTM_Compute_CloudScatter , &
CRTM_Compute_CloudScatter_TL
USE CRTM_AtmOptics, ONLY: CRTM_Include_Scattering, &
CRTM_Compute_Transmittance , &
CRTM_Compute_Transmittance_TL , &
CRTM_AtmOptics_Combine , &
CRTM_AtmOptics_Combine_TL , &
CRTM_AtmOptics_NoScatterCopy , &
CRTM_AtmOptics_NoScatterCopy_TL
USE CRTM_SfcOptics_Define, ONLY: CRTM_SfcOptics_type , &
CRTM_SfcOptics_Associated, &
CRTM_SfcOptics_Create , &
CRTM_SfcOptics_Zero, &
CRTM_SfcOptics_Destroy
USE CRTM_SfcOptics, ONLY: CRTM_Compute_SurfaceT , &
CRTM_Compute_SurfaceT_TL
USE CRTM_RTSolution, ONLY: CRTM_Compute_nStreams , &
CRTM_Compute_RTSolution , &
CRTM_Compute_RTSolution_TL
USE CRTM_AntennaCorrection, ONLY: CRTM_Compute_AntCorr, &
CRTM_Compute_AntCorr_TL
USE CRTM_MoleculeScatter, ONLY: CRTM_Compute_MoleculeScatter, &
CRTM_Compute_MoleculeScatter_TL
USE CRTM_AncillaryInput_Define, ONLY: CRTM_AncillaryInput_type
USE CRTM_CloudCoeff, ONLY: CRTM_CloudCoeff_IsLoaded
USE CRTM_AerosolCoeff, ONLY: CRTM_AerosolCoeff_IsLoaded
USE CRTM_NLTECorrection, ONLY: NLTE_Predictor_type , &
NLTE_Predictor_IsActive , &
Compute_NLTE_Predictor , &
Compute_NLTE_Predictor_TL , &
Compute_NLTE_Correction , &
Compute_NLTE_Correction_TL
USE ACCoeff_Define, ONLY: ACCoeff_Associated
USE NLTECoeff_Define, ONLY: NLTECoeff_Associated
USE CRTM_Planck_Functions, ONLY: CRTM_Planck_Temperature , &
CRTM_Planck_Temperature_TL
USE CRTM_CloudCover_Define, ONLY: CRTM_CloudCover_type
USE CRTM_Active_Sensor, ONLY: CRTM_Compute_Reflectivity, &
CRTM_Compute_Reflectivity_TL, &
Calculate_Cloud_Water_Density
! Internal variable definition modules
! ...AtmOptics
USE AOvar_Define, ONLY: AOvar_type, &
AOvar_Associated, &
AOvar_Destroy , &
AOvar_Create
! ...CloudScatter
USE CSvar_Define, ONLY: CSvar_type, &
CSvar_Associated, &
CSvar_Destroy , &
CSvar_Create
! ...AerosolScatter
USE ASvar_Define, ONLY: ASvar_type, &
ASvar_Associated, &
ASvar_Destroy , &
ASvar_Create
! ...Radiative transfer
USE RTV_Define, ONLY: RTV_type, &
RTV_Associated, &
RTV_Destroy , &
RTV_Create
! ...OpenMP
USE omp_lib
! -----------------------
! Disable implicit typing
! -----------------------
IMPLICIT NONE
! ------------
! Visibilities
! ------------
! Everything private by default
PRIVATE
! Public procedures
PUBLIC :: CRTM_Tangent_Linear
! -----------------
! Module parameters
! -----------------
CONTAINS
!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
! CRTM_Tangent_Linear
!
! PURPOSE:
! Function that calculates tangent-linear top-of-atmosphere (TOA)
! radiances and brightness temperatures for an input atmospheric
! profile or profile set and user specified satellites/channels.
!
! CALLING SEQUENCE:
! Error_Status = CRTM_Tangent_Linear( Atmosphere , &
! Surface , &
! Atmosphere_TL , &
! Surface_TL , &
! Geometry , &
! ChannelInfo , &
! RTSolution , &
! RTSolution_TL , &
! Options = Options )
!
! INPUTS:
! Atmosphere: Structure containing the Atmosphere data.
! UNITS: N/A
! TYPE: CRTM_Atmosphere_type
! DIMENSION: Rank-1 (n_Profiles)
! ATTRIBUTES: INTENT(IN)
!
! Surface: Structure containing the Surface data.
! UNITS: N/A
! TYPE: CRTM_Surface_type
! DIMENSION: Same as input Atmosphere structure
! ATTRIBUTES: INTENT(IN)
!
! Atmosphere_TL: Structure containing the tangent-linear Atmosphere data.
! UNITS: N/A
! TYPE: CRTM_Atmosphere_type
! DIMENSION: Same as input Atmosphere structure
! ATTRIBUTES: INTENT(IN)
!
! Surface_TL: Structure containing the tangent-linear Surface data.
! UNITS: N/A
! TYPE: CRTM_Surface_type
! DIMENSION: Same as input Atmosphere structure
! ATTRIBUTES: INTENT(IN)
!
! Geometry: Structure containing the view geometry
! information.
! UNITS: N/A
! TYPE: CRTM_Geometry_type
! DIMENSION: Same as input Atmosphere structure
! ATTRIBUTES: INTENT(IN)
!
! ChannelInfo: Structure returned from the CRTM_Init() function
! that contains the satellite/sensor channel index
! information.
! UNITS: N/A
! TYPE: CRTM_ChannelInfo_type
! DIMENSION: Rank-1 (n_Sensors)
! ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
! RTSolution: Structure containing the solution to the RT equation
! for the given inputs.
! UNITS: N/A
! TYPE: CRTM_RTSolution_type
! DIMENSION: Rank-2 (n_Channels x n_Profiles)
! ATTRIBUTES: INTENT(IN OUT)
!
! RTSolution_TL: Structure containing the solution to the tangent-
! linear RT equation for the given inputs.
! UNITS: N/A
! TYPE: CRTM_RTSolution_type
! DIMENSION: Rank-2 (n_Channels x n_Profiles)
! ATTRIBUTES: INTENT(IN OUT)
!
! OPTIONAL INPUTS:
! Options: Options structure containing the optional forward model
! arguments for the CRTM.
! UNITS: N/A
! TYPE: CRTM_Options_type
! DIMENSION: Same as input Atmosphere structure
! ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
! Error_Status: The return value is an integer defining the error status.
! The error codes are defined in the Message_Handler module.
! If == SUCCESS the computation was sucessful
! == FAILURE an unrecoverable error occurred
! UNITS: N/A
! TYPE: INTEGER
! DIMENSION: Scalar
!
! COMMENTS:
! - The Options optional input structure arguments contain
! spectral information (e.g. emissivity) that must have the same
! spectral dimensionality (the "L" dimension) as the output
! RTSolution structures.
!
!:sdoc-:
!--------------------------------------------------------------------------------
FUNCTION CRTM_Tangent_Linear( &
Atmosphere , & ! FWD Input, M
Surface , & ! FWD Input, M
Atmosphere_TL, & ! TL Input, M
Surface_TL , & ! TL Input, M
Geometry , & ! Input, M
ChannelInfo , & ! Input, n_Sensors
RTSolution , & ! FWD Output, L x M
RTSolution_TL, & ! TL Output, L x M
Options ) & ! Optional FWD input, M
RESULT( Error_Status )
! Arguments
!! USE OMP_LIB
USE CRTM_CloudCoeff, ONLY: CloudC
USE CRTM_AerosolCoeff, ONLY: AeroC
TYPE(CRTM_Atmosphere_type), INTENT(IN OUT) :: Atmosphere(:) ! M
TYPE(CRTM_Surface_type), INTENT(IN) :: Surface(:) ! M
TYPE(CRTM_Atmosphere_type), INTENT(IN) :: Atmosphere_TL(:) ! M
TYPE(CRTM_Surface_type), INTENT(IN) :: Surface_TL(:) ! M
TYPE(CRTM_Geometry_type), INTENT(IN) :: Geometry(:) ! M
TYPE(CRTM_ChannelInfo_type), INTENT(IN) :: ChannelInfo(:) ! n_Sensors
TYPE(CRTM_RTSolution_type), INTENT(IN OUT) :: RTSolution(:,:) ! L x M
TYPE(CRTM_RTSolution_type), INTENT(IN OUT) :: RTSolution_TL(:,:)! L x M
TYPE(CRTM_Options_type), OPTIONAL, INTENT(IN) :: Options(:) ! M
! Function result
INTEGER :: Error_Status
! Local parameters
CHARACTER(*), PARAMETER :: ROUTINE_NAME = 'CRTM_Forward'
! Local variables
CHARACTER(256) :: Message
LOGICAL :: Options_Present
INTEGER :: n_Sensors
INTEGER :: n_Channels
INTEGER :: m, n_Profiles, nc
! Local ancillary input structure
TYPE(CRTM_AncillaryInput_type) :: AncillaryInput
! Local options structure for default and use values
TYPE(CRTM_Options_type) :: Default_Options, Opt
! Local variables required by threading, timing, and output verification
INTEGER(LLong) :: count_rate, count_start, count_end
REAL :: elapsed
REAL :: elapsed_running = 0. ! running total of elapsed times
LOGICAL, PARAMETER :: enable_timing = .FALSE.
LOGICAL, PARAMETER :: output_verification = .FALSE.
INTEGER :: ret(SIZE(Atmosphere)) ! return codes from profile_solution
INTEGER :: nfailure ! number of non-success calls to profile_solution
INTEGER :: n_omp_threads
INTEGER :: n_profile_threads
INTEGER :: n_channel_threads
INTEGER :: Status_FWD, Status_TL
! ------
! SET UP
! ------
Error_Status = SUCCESS
IF (enable_timing) THEN
CALL SYSTEM_CLOCK (count_rate=count_rate)
CALL SYSTEM_CLOCK (count=count_start)
END IF
! If no sensors or channels, simply return
n_Sensors = SIZE(ChannelInfo)
n_Channels = SUM(CRTM_ChannelInfo_n_Channels(ChannelInfo))
IF ( n_Sensors == 0 .OR. n_Channels == 0 ) RETURN
! Check output array
IF ( SIZE(RTSolution,DIM=1) < n_Channels ) THEN
Error_Status = FAILURE
WRITE( Message,'("Output RTSolution structure array too small (",i0,&
&") to hold results for the number of requested channels (",i0,")")') &
SIZE(RTSolution,DIM=1), n_Channels
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! Check the number of profiles
! ...Number of atmospheric profiles.
n_Profiles = SIZE(Atmosphere)
! ...Check the profile dimensionality of the other mandatory arguments
IF ( SIZE(Surface) /= n_Profiles .OR. &
SIZE(Geometry) /= n_Profiles .OR. &
SIZE(RTSolution,DIM=2) /= n_Profiles ) THEN
Error_Status = FAILURE
Message = 'Inconsistent profile dimensionality for input arguments.'
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! ...Check the profile dimensionality of the other optional arguments
Options_Present = .FALSE.
IF ( PRESENT(Options) ) THEN
Options_Present = .TRUE.
IF ( SIZE(Options) /= n_Profiles ) THEN
Error_Status = FAILURE
Message = 'Inconsistent profile dimensionality for Options optional input argument.'
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
END IF
! -------
! OpenMP
! -------
!$OMP PARALLEL
!$OMP SINGLE
n_omp_threads = OMP_GET_NUM_THREADS()
!$OMP END SINGLE
!$OMP END PARALLEL
! Determine how many threads to use for profiles and channels
! After profiles get what they need, we use the left-over threads
! to parallelize channels
IF ( n_omp_threads <= n_Profiles .OR. n_Profiles == 0) THEN
n_profile_threads = n_omp_threads
n_channel_threads = 1
CALL OMP_SET_MAX_ACTIVE_LEVELS(1)
ELSE
n_profile_threads = n_Profiles
n_channel_threads = MIN(n_Channels, n_omp_threads / n_Profiles)
! There may have bug for MW and IR cases by using openMP over channels
! IF(SpcCoeff_IsInfraredSensor(SC(1)) .OR. &
! SpcCoeff_IsMicrowaveSensor(SC(1)) ) THEN
! n_channel_threads = 1
! END IF
IF(n_channel_threads > 1) THEN
CALL OMP_SET_MAX_ACTIVE_LEVELS(2)
ELSE
CALL OMP_SET_MAX_ACTIVE_LEVELS(1)
END IF
END IF
! WRITE(6,*)
! WRITE(6,'(" Using",i3," OpenMP threads =",i3," for profiles and",i3," for channels.")') &
! n_omp_threads, n_profile_threads, n_channel_threads
! ------------
! PROFILE LOOPS
! ------------
!JR First loop just checks validity of Atmosphere(m) contents
!$OMP PARALLEL DO PRIVATE ( nc, Message ) NUM_THREADS(n_profile_threads)
Profile_Loop1: DO m = 1, n_Profiles
! Fix for cloud_Fraction < MIN_COVERAGE_THRESHOLD
IF ( Atmosphere(m)%n_Clouds > 0) THEN
!** clear clouds where cloud_fraction < threshold
DO nc = 1, Atmosphere(m)%n_clouds
WHERE (Atmosphere(m)%Cloud_Fraction(:) < MIN_COVERAGE_THRESHOLD)
Atmosphere(m)%Cloud_Fraction(:) = ZERO
Atmosphere(m)%Cloud(nc)%Water_Content(:) = ZERO
Atmosphere(m)%Cloud(nc)%Effective_Radius(:) = ZERO
END WHERE
END DO
! Check the cloud and aerosol coeff. data for cases with clouds and aerosol
IF( .NOT. CRTM_CloudCoeff_IsLoaded() )THEN
Error_Status = FAILURE
WRITE( Message,'("The CloudCoeff data must be loaded (with CRTM_Init routine) ", &
&"for the cloudy case profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
CYCLE Profile_Loop1
END IF
END IF
IF( Atmosphere(m)%n_Aerosols > 0 .AND. .NOT. CRTM_AerosolCoeff_IsLoaded() )THEN
Error_Status = FAILURE
WRITE( Message,'("The AerosolCoeff data must be loaded (with CRTM_Init routine) ", &
&"for the aerosol case profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
CYCLE Profile_Loop1
END IF
END DO Profile_Loop1
!$OMP END PARALLEL DO
IF (Error_Status == FAILURE) THEN
RETURN
END IF
!$OMP PARALLEL DO PRIVATE ( m, Opt, AncillaryInput ) NUM_THREADS(n_profile_threads) SCHEDULE ( runtime )
Profile_Loop2: DO m = 1, n_Profiles
! Check the optional Options structure argument
Opt = Default_Options
IF ( Options_Present ) THEN
Opt = Options(m)
! Copy over ancillary input (just add AncillaryInput structure to options?)
AncillaryInput%SSU = Options(m)%SSU
AncillaryInput%Zeeman = Options(m)%Zeeman
END IF
ret(m) = profile_solution (m, Opt, AncillaryInput)
END DO Profile_Loop2
!$OMP END PARALLEL DO
nfailure = COUNT (ret(:) /= SUCCESS)
IF (nfailure > 0) THEN
Error_Status = FAILURE
WRITE(Message,'(i0," profiles failed")') nfailure
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
IF (enable_timing) THEN
CALL SYSTEM_CLOCK (count=count_end)
elapsed = REAL (count_end - count_start) / REAL (count_rate)
elapsed_running = elapsed_running + elapsed
WRITE(6,*) 'CRTM_Forward elapsed =',elapsed
WRITE(6,*) 'CRTM_Forward elapsed running total=',elapsed_running
END IF
IF (output_verification) THEN
WRITE(6,*)'CRTM_Forward inspecting RTSolution...'
CALL CRTM_RTSolution_Inspect (RTSolution(:,:))
END IF
RETURN
CONTAINS
! Function profile_solution contains all the computational code inside of CRTM_Forward that
! is contained inside an OMP loop. It is "contain"ed inside the function mainly so it can
! access arrays which are arguments to CRTM_Forward. Subroutine Post_Process_RTSolution also
! accesses CRTM_Forward data, but multi-level function "contain" clauses cause compiler
! errors so arguments to this function were needed.
FUNCTION profile_solution (m, Opt, AncillaryInput) RESULT( Error_Status )
USE ADA_Module, ONLY: CRTM_SurfRef
INTEGER, INTENT(in) :: m ! profile index
TYPE(CRTM_Options_type), INTENT(IN) :: Opt
TYPE(CRTM_AncillaryInput_type), INTENT(IN) :: AncillaryInput
! Local variables
INTEGER :: Error_Status
CHARACTER(256) :: Message
LOGICAL :: compute_antenna_correction
LOGICAL :: Atmosphere_Invalid, Surface_Invalid, Geometry_Invalid, Options_Invalid
INTEGER :: iFOV
INTEGER :: n, l ! sensor index, channel index
INTEGER :: SensorIndex
INTEGER :: ChannelIndex
INTEGER :: ln, nc, ks
INTEGER :: n_Full_Streams, mth_Azi
INTEGER :: cloud_coverage_flag
REAL(fp) :: Source_ZA, r_cloudy
REAL(fp) :: Wavenumber
REAL(fp) :: transmittance, transmittance_clear
REAL(fp) :: transmittance_TL, transmittance_clear_TL
! Local OpenMP-related variables:
INTEGER :: nt, start_ch, end_ch, chunk_ch, n_sensor_channels
INTEGER :: n_inactive_channels(n_channel_threads+1)
! Local atmosphere structure for extra layering
TYPE(CRTM_Atmosphere_type) :: Atm, Atm_TL
! Clear sky structures
TYPE(CRTM_Atmosphere_type) :: Atm_Clear, Atm_Clear_TL
TYPE(CRTM_AtmOptics_type) :: AtmOptics_Clear(n_channel_threads),AtmOptics_Clear_TL(n_channel_threads)
TYPE(CRTM_SfcOptics_type) :: SfcOptics_Clear(n_channel_threads),SfcOptics_Clear_TL(n_channel_threads)
TYPE(CRTM_RTSolution_type) :: RTSolution_Clear(n_channel_threads),RTSolution_Clear_TL(n_channel_threads)
TYPE(RTV_type) :: RTV_Clear(n_channel_threads)
! Component variables
TYPE(CRTM_GeometryInfo_type) :: GeometryInfo
!! TYPE(CRTM_Predictor_type) :: Predictor(n_channel_threads)
TYPE(CRTM_Predictor_type) :: Predictor(n_channel_threads),Predictor_TL(n_channel_threads)
TYPE(CRTM_AtmOptics_type) :: AtmOptics(n_channel_threads),AtmOptics_TL(n_channel_threads)
TYPE(CRTM_SfcOptics_type) :: SfcOptics(n_channel_threads),SfcOptics_TL(n_channel_threads)
! Component variable internals
TYPE(CRTM_PVar_type) :: PVar(n_channel_threads) ! Predictor
TYPE(CRTM_AAvar_type) :: AAvar(n_channel_threads) ! AtmAbsorption
TYPE(CSvar_type) :: CSvar(n_channel_threads) ! CloudScatter
TYPE(ASvar_type) :: ASvar(n_channel_threads) ! AerosolScatter
TYPE(AOvar_type) :: AOvar(n_channel_threads) ! AtmOptics
TYPE(RTV_type) :: RTV(n_channel_threads) ! RTSolution
! NLTE correction term predictor
TYPE(NLTE_Predictor_type) :: NLTE_Predictor, NLTE_Predictor_TL
! Cloud cover object
TYPE(CRTM_CloudCover_type) :: CloudCover, CloudCover_TL
Error_Status = SUCCESS
! Reinitialise the output RTSolution
CALL CRTM_RTSolution_Zero(RTSolution(:,m))
! Allocate the profile independent surface opticss local structure
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads) PRIVATE(Message)
DO nt = 1, n_channel_threads
IF ( Options_Present ) THEN
! ...Assign the option specific SfcOptics input
IF( Opt%n_Stokes > 0 ) RTV(nt)%n_Stokes = Opt%n_Stokes
RTV(nt)%RT_Algorithm_Id = Opt%RT_Algorithm_Id
END IF
CALL CRTM_SfcOptics_Create( SfcOptics(nt) , MAX_N_ANGLES, MAX_N_STOKES )
CALL CRTM_SfcOptics_Create( SfcOptics_TL(nt), MAX_N_ANGLES, MAX_N_STOKES )
IF ( (.NOT. CRTM_SfcOptics_Associated(SfcOptics(nt) )) .OR. &
(.NOT. CRTM_SfcOptics_Associated(SfcOptics_TL(nt))) ) THEN
Error_Status = FAILURE
Message = 'Error allocating SfcOptics data structures'
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
CYCLE
END IF
SfcOptics(nt)%n_Stokes = RTV(nt)%n_Stokes
SfcOptics_TL(nt)%n_Stokes = RTV(nt)%n_Stokes
END DO
!$OMP END PARALLEL DO
IF ( Error_Status == FAILURE) RETURN
! ...Assign the option specific SfcOptics input
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads)
DO nt = 1, n_channel_threads
SfcOptics(nt)%Use_New_MWSSEM = .NOT. Opt%Use_Old_MWSSEM
SfcOptics_TL(nt)%Use_New_MWSSEM = .NOT. Opt%Use_Old_MWSSEM
END DO
!$OMP END PARALLEL DO
! Check whether to skip this profile
IF ( Opt%Skip_Profile ) RETURN
! Check the input data if required
IF ( Opt%Check_Input ) THEN
! ...Mandatory inputs
Atmosphere_Invalid = .NOT. CRTM_Atmosphere_IsValid( Atmosphere(m) )
Surface_Invalid = .NOT. CRTM_Surface_IsValid( Surface(m) )
Geometry_Invalid = .NOT. CRTM_Geometry_IsValid( Geometry(m) )
IF ( Atmosphere_Invalid .OR. Surface_Invalid .OR. Geometry_Invalid ) THEN
Error_Status = FAILURE
WRITE( Message,'("Input data check failed for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! ...Optional input
IF ( Options_Present ) THEN
Options_Invalid = .NOT. CRTM_Options_IsValid( Options(m) )
IF ( Options_Invalid ) THEN
Error_Status = FAILURE
WRITE( Message,'("Options data check failed for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! Are the channel dimensions consistent if emissivity is passed?
IF ( Options(m)%Use_Emissivity ) THEN
IF ( Options(m)%n_Channels < n_Channels ) THEN
Error_Status = FAILURE
WRITE( Message,'( "Input Options channel dimension (", i0, ") is less ", &
&"than the number of requested channels (",i0, ")" )' ) &
Options(m)%n_Channels, n_Channels
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
END IF
! Check value for user-defined n_Streams
IF ( Options(m)%Use_N_Streams ) THEN
IF ( Options(m)%n_Streams <= 0 .OR. MOD(Options(m)%n_Streams,2) /= 0 .OR. &
Options(m)%n_Streams > MAX_N_STREAMS ) THEN
Error_Status = FAILURE
WRITE( Message,'( "Input Options n_Streams (", i0, ") is invalid" )' ) &
Options(m)%n_Streams
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
END IF
END IF
END IF
! Process geometry
! ...Compute derived geometry
CALL CRTM_GeometryInfo_SetValue( GeometryInfo, Geometry=Geometry(m) )
CALL CRTM_GeometryInfo_Compute( GeometryInfo )
! ...Retrieve components into local variable
CALL CRTM_GeometryInfo_GetValue( &
GeometryInfo, &
iFOV = iFOV, &
Source_Zenith_Angle = Source_ZA )
! Add extra layers to current atmosphere profile
! if necessary to handle upper atmosphere
Error_Status = CRTM_Atmosphere_AddLayers( Atmosphere(m), Atm )
IF ( Error_Status /= SUCCESS ) THEN
Error_Status = FAILURE
WRITE( Message,'("Error adding extra layers to profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! Calculate cloud water density
CALL Calculate_Cloud_Water_Density(Atm)
Error_Status = CRTM_Atmosphere_AddLayers_TL( Atmosphere(m), Atmosphere_TL(m), Atm_TL )
IF ( Error_Status /= SUCCESS ) THEN
Error_Status = FAILURE
WRITE( Message,'("Error adding TL extra layers to profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
Atm_TL%Height = Atm%Height
! ...Check the total number of Atm layers
IF ( Atm%n_Layers > MAX_N_LAYERS .OR. Atm_TL%n_Layers > MAX_N_LAYERS) THEN
Error_Status = FAILURE
WRITE( Message,'("Added layers [",i0,"] cause total [",i0,"] to exceed the ",&
&"maximum allowed [",i0,"] for profile #",i0)' ) &
Atm%n_Added_Layers, Atm%n_Layers, MAX_N_LAYERS, m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
IF( (CloudC%N_PHASE_ELEMENTS /= AeroC%N_PHASE_ELEMENTS) .or. &
(RTV(1)%n_Stokes > 1.and.CloudC%N_PHASE_ELEMENTS < 6) ) THEN
Error_Status = FAILURE
WRITE( Message,'("N_PHASE_ELEMENTS NOT RIGHT FW ",i0)' ) CloudC%N_PHASE_ELEMENTS
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads) PRIVATE(Message)
DO nt = 1, n_channel_threads
! Prepare the atmospheric optics structures
! ...Allocate the AtmOptics structure based on Atm extension
CALL CRTM_AtmOptics_Create( AtmOptics(nt), &
Atm%n_Layers , &
MAX_N_LEGENDRE_TERMS, &
CloudC%N_PHASE_ELEMENTS )
CALL CRTM_AtmOptics_Create( AtmOptics_TL(nt), &
Atm%n_Layers , &
MAX_N_LEGENDRE_TERMS, &
CloudC%N_PHASE_ELEMENTS )
IF ( Options_Present ) THEN
AtmOptics(nt)%depolarization = Opt%depolarization
AtmOptics_TL(nt)%depolarization = Opt%depolarization
IF( Opt%n_Stokes > 0 ) RTV(nt)%n_Stokes = Opt%n_Stokes
AtmOptics(nt)%n_Stokes = RTV(nt)%n_Stokes
AtmOptics_TL(nt)%n_Stokes = RTV(nt)%n_Stokes
AtmOptics(nt)%Include_Scattering = Opt%Include_Scattering
AtmOptics_TL(nt)%Include_Scattering = Opt%Include_Scattering
END IF
IF ( (.NOT. CRTM_AtmOptics_Associated( Atmoptics(nt) )) .OR. &
(.NOT. CRTM_AtmOptics_Associated( Atmoptics_TL(nt) )) ) THEN
Error_Status = FAILURE
WRITE( Message,'("Error allocating AtmOptics data structure for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
END IF
! ...Set the scattering switch
! ...Allocate the atmospheric optics internal structure
CALL AOvar_Create( AOvar(nt), Atm%n_Layers )
! Allocate the scattering internal variables if necessary
! ...Cloud
IF ( Atm%n_Clouds > 0 ) THEN
CALL CSvar_Create( CSvar(nt), &
MAX_N_LEGENDRE_TERMS, &
CloudC%N_PHASE_ELEMENTS, &
Atm%n_Layers , &
Atm%n_Clouds )
END IF
! ...Aerosol
IF ( Atm%n_Aerosols > 0 ) THEN
CALL ASvar_Create( ASvar(nt), &
MAX_N_LEGENDRE_TERMS, &
AeroC%N_PHASE_ELEMENTS, &
Atm%n_Layers , &
Atm%n_Aerosols )
END IF
END DO
!$OMP END PARALLEL DO
IF ( Error_Status == FAILURE) RETURN
! Determine the type of cloud coverage
cloud_coverage_flag = CRTM_Atmosphere_Coverage( atm )
! Setup for fractional cloud coverage
IF ( CRTM_Atmosphere_IsFractional(cloud_coverage_flag) ) THEN
! Compute cloudcover
Status_FWD = CloudCover%Compute_CloudCover(atm, Overlap = opt%Overlap_Id)
Status_TL = CloudCover_TL%Compute_CloudCover_TL(CloudCover, atm, atm_TL)
IF ( Status_FWD /= SUCCESS .OR. Status_TL /= SUCCESS ) THEN
Error_Status = FAILURE
WRITE( Message,'("Error computing cloud cover for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
! Allocate all the CLEAR sky structures for fractional cloud coverage
! ...A clear sky atmosphere
Status_FWD = CRTM_Atmosphere_ClearSkyCopy(Atm, Atm_Clear)
Status_TL = CRTM_Atmosphere_ClearSkyCopy_TL(Atm, Atm_TL, Atm_Clear_TL)
IF ( Status_FWD /= SUCCESS .OR. Status_TL /= SUCCESS ) THEN
Error_status = FAILURE
WRITE( Message,'("Error copying CLEAR SKY Atmopshere structures for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
RETURN
END IF
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads) PRIVATE(Message)
Para_Loop1: DO nt = 1, n_channel_threads
! ...Clear sky SfcOptics
CALL CRTM_SfcOptics_Create( SfcOptics_Clear(nt) , MAX_N_ANGLES, MAX_N_STOKES )
CALL CRTM_SfcOptics_Create( SfcOptics_Clear_TL(nt), MAX_N_ANGLES, MAX_N_STOKES )
IF ( (.NOT. CRTM_SfcOptics_Associated(SfcOptics_Clear(nt))) .OR. &
(.NOT. CRTM_SfcOptics_Associated(SfcOptics_Clear_TL(nt)))) THEN
Error_Status = FAILURE
WRITE( Message,'("Error allocating CLEAR SKY SfcOptics data structures for profile #",i0)' ) m
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
CYCLE Para_Loop1 !RETURN
END IF
! ...Copy over surface optics input
SfcOptics_Clear(nt)%Use_New_MWSSEM = .NOT. Opt%Use_Old_MWSSEM
SfcOptics_Clear_TL(nt)%Use_New_MWSSEM = .NOT. Opt%Use_Old_MWSSEM
SfcOptics_Clear(nt)%n_Stokes = RTV(nt)%n_Stokes ! It may be changed for CSEM.
SfcOptics_Clear_TL(nt)%n_Stokes = RTV(nt)%n_Stokes ! It may be changed for CSEM.
! ...CLEAR SKY average surface skin temperature for multi-surface types
CALL CRTM_Compute_SurfaceT( Surface(m), SfcOptics_Clear(nt) )
CALL CRTM_Compute_SurfaceT_TL( Surface(m), Surface_TL(m), SfcOptics_Clear_TL(nt) )
END DO Para_Loop1
!$OMP END PARALLEL DO
IF ( Error_Status == FAILURE) RETURN
END IF
! Average surface skin temperature for multi-surface types
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads)
DO nt = 1, n_channel_threads
CALL CRTM_Compute_SurfaceT( Surface(m), SfcOptics(nt) )
CALL CRTM_Compute_SurfaceT_TL( Surface(m), Surface_TL(m), SfcOptics_TL(nt) )
END DO
!$OMP END PARALLEL DO
! -----------
! SENSOR LOOP
! -----------
! Initialise channel counter for channel(l)/sensor(n) count
ln = 0
Sensor_Loop: DO n = 1, n_Sensors
! Shorter name
SensorIndex = ChannelInfo(n)%Sensor_Index
! Check if antenna correction to be applied for current sensor
compute_antenna_correction = ( Opt%Use_Antenna_Correction .AND. &
ACCoeff_Associated( SC(SensorIndex)%AC ) .AND. &
iFOV /= 0 )
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads) PRIVATE(Message)
DO nt = 1, n_channel_threads
! Compute predictors for AtmAbsorption calcs
! ...Allocate the predictor structures
CALL CRTM_Predictor_Create( &
Predictor(nt) , &
atm%n_Layers, &
SensorIndex , &
SaveFWV = 1 )
CALL CRTM_Predictor_Create( &
Predictor_TL(nt), &
atm%n_Layers, &
SensorIndex )
IF ( (.NOT. CRTM_Predictor_Associated(Predictor(nt))) .OR. &
(.NOT. CRTM_Predictor_Associated(Predictor_TL(nt))) ) THEN
Error_Status=FAILURE
WRITE( Message,'("Error allocating predictor structures for profile #",i0, &
&" and ",a," sensor.")' ) m, SC(SensorIndex)%Sensor_Id
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
CYCLE !RETURN
END IF
! ...And now fill them
CALL CRTM_Compute_Predictors( SensorIndex , & ! Input
Atm , & ! Input
GeometryInfo , & ! Input
AncillaryInput, & ! Input
Predictor(nt) , & ! Output
PVar(nt) ) ! Internal variable output
CALL CRTM_Compute_Predictors_TL( SensorIndex , & ! Input
Atm , & ! Input
Predictor(nt) , & ! Input
Atm_TL , & ! Input
AncillaryInput, & ! Input
Predictor_TL(nt) , & ! Output
PVar(nt) ) ! Internal variable input
! Compute predictors for AtmAbsorption calcs
! ...Allocate the predictor structure
! Allocate the RTV structure if necessary
IF( ( Atm%n_Clouds > 0 .OR. &
Atm%n_Aerosols > 0 .OR. &
SpcCoeff_IsUltravioletSensor(SC(SensorIndex)) .OR. &
SpcCoeff_IsVisibleSensor(SC(SensorIndex)) ) .AND. &
AtmOptics(nt)%Include_Scattering ) THEN
! Assign algorithm selector
RTV(nt)%RT_Algorithm_Id = Opt%RT_Algorithm_Id
CALL RTV_Create( RTV(nt), MAX_N_ANGLES, MAX_N_LEGENDRE_TERMS, Atm%n_Layers )
IF ( .NOT. RTV_Associated(RTV(nt)) ) THEN
Error_Status=FAILURE
WRITE( Message,'("Error allocating RTV structure for profile #",i0, &
&" and ",a," sensor.")' ) m, TRIM(SC(SensorIndex)%Sensor_Id)
CALL Display_Message( ROUTINE_NAME, Message, Error_Status )
END IF
END IF
END DO
!$OMP END PARALLEL DO
IF ( Error_Status == FAILURE ) RETURN
! Compute NLTE correction predictors
IF ( Opt%Apply_NLTE_Correction ) THEN
CALL Compute_NLTE_Predictor( &
SC(SensorIndex)%NC, & ! Input
Atm , & ! Input
GeometryInfo , & ! Input
NLTE_Predictor ) ! Output
CALL Compute_NLTE_Predictor_TL( &
NLTE_Predictor , & ! FWD Input
Atm_TL , & ! TL Input
NLTE_Predictor_TL ) ! TL Output
END IF
! ----------------------------
! counters for thread loop
! -----------------------------
n_sensor_channels = ChannelInfo(n)%n_Channels
! chunk_ch = n_sensor_channels / n_channel_threads
chunk_ch = CEILING( REAL(n_sensor_channels) / REAL(n_channel_threads) )
!count inactive channels in each chunk
n_inactive_channels(:) = 0
DO l = 1, n_sensor_channels
IF ( .NOT. ChannelInfo(n)%Process_Channel(l) ) THEN
! nt = l / chunk_ch + 1
nt = FLOOR( REAL(l) / REAL(chunk_ch) ) + 1
n_inactive_channels(nt) = n_inactive_channels(nt) + 1
END IF
END DO
DO nt = 2, n_channel_threads
n_inactive_channels(nt) = n_inactive_channels(nt) + n_inactive_channels(nt - 1)
END DO
DO nt = n_channel_threads+1, 2, -1
n_inactive_channels(nt) = n_inactive_channels(nt - 1)
END DO
n_inactive_channels(1) = 0
!end count
! ------------
! THREAD LOOP
! ------------
!$OMP PARALLEL DO NUM_THREADS(n_channel_threads) &
!$OMP FIRSTPRIVATE(ln, r_cloudy) &
!$OMP PRIVATE(Message, ChannelIndex, n_Full_Streams, AAvar, &
!$OMP start_ch, end_ch, Wavenumber, transmittance, transmittance_TL, &
!$OMP transmittance_clear, transmittance_clear_TL, l, mth_Azi, ks, Status_FWD,Status_TL)
Thread_Loop: DO nt = 1, n_channel_threads
start_ch = (nt - 1) * chunk_ch + 1
IF ( nt == n_channel_threads) THEN
end_ch = n_sensor_channels
ELSE
end_ch = start_ch + chunk_ch - 1
END IF
ln = (start_ch - 1) - n_inactive_channels(nt)
! -------------
! CHANNEL LOOP
! -------------
Channel_Loop: DO l = start_ch, end_ch
! Channel setup
! ...Skip channel if requested
IF ( .NOT. ChannelInfo(n)%Process_Channel(l) ) CYCLE Channel_Loop
! ...Shorter name
ChannelIndex = ChannelInfo(n)%Channel_Index(l)
! ...Increment the processed channel counter
ln = ln + 1
! ...Assign sensor+channel information to output
RTSolution(ln,m)%Sensor_Id = ChannelInfo(n)%Sensor_Id
RTSolution(ln,m)%WMO_Satellite_Id = ChannelInfo(n)%WMO_Satellite_Id
RTSolution(ln,m)%WMO_Sensor_Id = ChannelInfo(n)%WMO_Sensor_Id
RTSolution(ln,m)%Sensor_Channel = ChannelInfo(n)%Sensor_Channel(l)
RTSolution_TL(ln,m)%Sensor_Id = ChannelInfo(n)%Sensor_Id
RTSolution_TL(ln,m)%WMO_Satellite_Id = ChannelInfo(n)%WMO_Satellite_Id
RTSolution_TL(ln,m)%WMO_Sensor_Id = ChannelInfo(n)%WMO_Sensor_Id
RTSolution_TL(ln,m)%Sensor_Channel = ChannelInfo(n)%Sensor_Channel(l)
! Initialisations
CALL CRTM_AtmOptics_Zero( AtmOptics(nt) )
CALL CRTM_AtmOptics_Zero( AtmOptics_TL(nt) )
CALL CRTM_AtmOptics_Zero( AtmOptics_Clear(nt) )
CALL CRTM_AtmOptics_Zero( AtmOptics_Clear_TL(nt) )
CALL CRTM_RTSolution_Zero( RTSolution_Clear(nt) )
CALL CRTM_RTSolution_Zero( RTSolution_Clear_TL(nt) )
! CALL CRTM_SfcOptics_Zero( SfcOptics(nt) )
! CALL CRTM_SfcOptics_Zero( SfcOptics_TL(nt) )
! Determine the number of streams (n_Full_Streams) in up+downward directions
IF ( Opt%Use_N_Streams ) THEN
n_Full_Streams = Opt%n_Streams
RTSolution(ln,m)%n_Full_Streams = n_Full_Streams + 2
RTSolution(ln,m)%Scattering_Flag = .TRUE.
ELSE
n_Full_Streams = CRTM_Compute_nStreams( Atm , & ! Input
SensorIndex , & ! Input
ChannelIndex , & ! Input
RTSolution(ln,m) ) ! Output
END IF
! ...Transfer stream count to scattering structure
AtmOptics(nt)%n_Legendre_Terms = n_Full_Streams
AtmOptics_TL(nt)%n_Legendre_Terms = n_Full_Streams
! Compute the gas absorption
CALL CRTM_Compute_AtmAbsorption( SensorIndex , & ! Input
ChannelIndex , & ! Input
AncillaryInput, & ! Input
Predictor(nt) , & ! Input
AtmOptics(nt) , & ! Output
AAvar(nt) ) ! Internal variable output