-
Notifications
You must be signed in to change notification settings - Fork 273
/
build.gradle
165 lines (144 loc) · 6.54 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
buildscript {
repositories {
mavenLocal()
mavenCentral()
}
dependencies {
classpath "org.jasig.resourceserver:resource-server-core:${resourceServerVersion}"
classpath "javax.xml.bind:jaxb-api:${jaxbApiVersion}"
classpath 'com.sun.xml.bind:jaxb-xjc:2.3.9'
classpath 'com.sun.xml.bind:jaxb-impl:2.3.9'
}
}
plugins {
id 'war'
}
apply plugin: 'com.github.node-gradle.node'
description = "Apereo uPortal Webapp (WAR)"
/*
* TODO: Groovy-based tests (in src/test/groovy) are not currently run by the Gradle build.
*/
configurations {
// These get packaged with the war in a special way
webjars
}
dependencies {
api project(':uPortal-groups:uPortal-groups-filesystem')
api project(':uPortal-groups:uPortal-groups-grouper')
api project(':uPortal-groups:uPortal-groups-ldap')
api project(':uPortal-groups:uPortal-groups-local')
api project(':uPortal-groups:uPortal-groups-smartldap')
api project(':uPortal-index')
api project(':uPortal-portlets')
api project(':uPortal-security:uPortal-security-authn')
api project(':uPortal-security:uPortal-security-xslt')
api project(':uPortal-security:uPortal-security-filters')
api project(':uPortal-session')
api project(':uPortal-soffit:uPortal-soffit-connector')
api project(':uPortal-utils:uPortal-utils-jmx')
api project(':uPortal-utils:uPortal-utils-url')
compileOnly "org.apereo.service.persondir:person-directory-api:${personDirectoryVersion}"
compileOnly "${servletApiDependency}"
testImplementation "org.apache.portals.pluto:pluto-container-api:${plutoVersion}"
testImplementation "org.apache.portals.pluto:pluto-container-driver-api:${plutoVersion}"
testImplementation "org.skyscreamer:jsonassert:${jsonassertVersion}"
testImplementation "org.codehaus.groovy:groovy-test:${groovyVersion}"
testImplementation "org.spockframework:spock-core:${spockVersion}"
testImplementation "${portletApiDependency}"
testImplementation "${servletApiDependency}"
runtimeOnly "ch.qos.logback:logback-classic:${logbackVersion}"
runtimeOnly "joda-time:joda-time-jsptags:${jodaTimeJsptagsVersion}"
runtimeOnly "org.aspectj:aspectjweaver:${aspectjVersion}"
runtimeOnly "org.codehaus.groovy:groovy-jsr223:${groovyVersion}"
runtimeOnly "org.hibernate:hibernate-entitymanager:${hibernateVersion}"
runtimeOnly "org.jasig.cas.client:cas-client-support-distributed-ehcache:${casClientVersion}"
runtimeOnly "org.jasig.ehcache:ehcache-jgroups3replication:${ehcacheJgroups3ReplicationVersion}"
runtimeOnly "org.jasig.portlet.utils:portlet-ws-util:${apereoPortletUtilsVersion}"
runtimeOnly "org.slf4j:jul-to-slf4j:${slf4jVersion}"
runtimeOnly "org.slf4j:log4j-over-slf4j:${slf4jVersion}"
runtimeOnly "org.springframework.security:spring-security-config:${springSecurityVersion}"
runtimeOnly "com.thoughtworks.xstream:xstream:${xstreamVersion}"
/*
* The HSQL driver jar should always be provided by uPortal-start;
* that way, it has complete control over the version in the deployment.
*/
providedRuntime "org.hsqldb:hsqldb:${hsqldbVersion}"
webjars "org.webjars.npm:bootstrap:${bootstrapVersion}"
webjars "org.webjars.npm:core-js-bundle:${coreJsBundleVersion}"
webjars "org.webjars.npm:jstree:${jstreeVersion}"
webjars "org.webjars.npm:regenerator-runtime:${regeneratorRuntimeVersion}"
webjars "org.webjars.npm:webcomponents__webcomponentsjs:${webComponentPolyfillVersion}"
webjars "org.webjars.npm:whatwg-fetch:${whatwgFetchPolyfillVersion}"
}
node {
version = nodejsVersion
download = true
}
// Support for filtering properties files
import org.apache.tools.ant.filters.ReplaceTokens
processResources {
filter(ReplaceTokens, tokens:['projectVersion': project.version])
}
task prepareSkinResources {
// Unpack WebJars (part of the skin)
configurations.webjars.allDependencies.each {
String webjarName = it.name
String webjarVersion = it.version
String webjarFile = configurations.webjars.files(it).getAt(0)
// Stage 1: Exploded WebJar
doLast {
copy {
from zipTree(webjarFile)
into "${buildDir}/webjars/${webjarName}-${webjarVersion}"
}
}
// Stage 2: Contents of the WebJar included in the skin
doLast {
copy {
from "${buildDir}/webjars/${webjarName}-${webjarVersion}/META-INF/resources/webjars/${webjarName}/${webjarVersion}"
into "${buildDir}/generated-sources/skin/main/webapp/webjars/${webjarName}"
}
}
}
// Add Respondr LESS sources
doLast {
copy {
from 'src/main/webapp/media/skins/respondr'
into "${buildDir}/generated-sources/skin/main/webapp/media/skins/respondr"
}
}
}
import org.jasig.resource.aggr.AggregationRequest
import org.jasig.resource.aggr.ResourcesAggregator
import org.jasig.resource.aggr.ResourcesAggregatorImpl
task aggregateRespondrSkins {
doLast {
final ResourcesAggregator aggr = new ResourcesAggregatorImpl();
aggr.setDisplayJsWarnings(false);
final File resourcesXmlFile = new File(projectDir, 'src/main/webapp/media/skins/respondr/defaultSkin/skin.xml');
final File fullOutputDirectory = new File(buildDir, 'generated-sources/skin/main/webapp/media/skins/respondr/defaultSkin');
final File sharedJavaScriptDirectory = new File(buildDir, 'generated-sources/skin/main/webapp/media/skins/respondr');
// Provide the paths we evaluated in DEBUG logging
logger.debug("resourcesXmlFile=${resourcesXmlFile}");
logger.debug("fullOutputDirectory=${fullOutputDirectory}");
logger.debug("sharedJavaScriptDirectory=${sharedJavaScriptDirectory}");
final AggregationRequest aggregationRequest = new AggregationRequest();
aggregationRequest
.setResourcesXml(resourcesXmlFile)
.setOutputBaseDirectory(fullOutputDirectory)
.addAdditionalSourceDirectory(fullOutputDirectory)
.setSharedJavaScriptDirectory(sharedJavaScriptDirectory);
aggr.aggregate(aggregationRequest);
}
}
// Generate CSS for Respondr skins
project.tasks.getByName('npm_run_compile-less').dependsOn(prepareSkinResources)
aggregateRespondrSkins.dependsOn('npm_run_compile-less')
processResources.dependsOn(aggregateRespondrSkins)
war {
// Add generated CSS for Respondr skins to the war file
with {
from "${buildDir}/generated-sources/skin/main/webapp"
into '/'
}
}