-
Notifications
You must be signed in to change notification settings - Fork 63
/
context.jl
261 lines (234 loc) · 9.66 KB
/
context.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
"""
mutable struct Context
A handle to a loaded instance of libpython, its interpreter, function pointers, etc.
"""
@kwdef mutable struct Context
is_embedded :: Bool = false
is_initialized :: Bool = false
is_preinitialized :: Bool = false
lib_ptr :: Ptr{Cvoid} = C_NULL
exe_path :: Union{String, Missing} = missing
lib_path :: Union{String, Missing} = missing
dlopen_flags :: UInt32 = RTLD_LAZY | RTLD_DEEPBIND | RTLD_GLOBAL
pyprogname :: Union{String, Missing} = missing
pyprogname_w :: Any = missing
pyhome :: Union{String, Missing} = missing
pyhome_w :: Any = missing
which :: Symbol = :unknown # :CondaPkg, :PyCall, :embedded or :unknown
version :: Union{VersionNumber, Missing} = missing
matches_pycall :: Union{Bool, Missing} = missing
end
const CTX = Context()
function _atpyexit()
if CTX.is_initialized && !CTX.is_preinitialized
@warn "Python exited unexpectedly"
end
CTX.is_initialized = false
return
end
function init_context()
CTX.is_embedded = hasproperty(Base.Main, :__PythonCall_libptr)
if CTX.is_embedded
# In this case, getting a handle to libpython is easy
CTX.lib_ptr = Base.Main.__PythonCall_libptr::Ptr{Cvoid}
init_pointers()
# Check Python is initialized
Py_IsInitialized() == 0 && error("Python is not already initialized.")
CTX.is_initialized = true
CTX.which = :embedded
exe_path = get(ENV, "JULIA_PYTHONCALL_EXE", "")
if exe_path != ""
CTX.exe_path = exe_path
# this ensures PyCall uses the same Python interpreter
get!(ENV, "PYTHON", exe_path)
end
else
# Find Python executable
exe_path = get(ENV, "JULIA_PYTHONCALL_EXE", "")
if exe_path == "" || exe_path == "@CondaPkg"
if CondaPkg.backend() == :Null
exe_path = Sys.which("python")
if exe_path === nothing
error("CondaPkg is using the Null backend but Python is not installed")
end
exe_path::String
else
# By default, we use Python installed by CondaPkg.
exe_path = Sys.iswindows() ? joinpath(CondaPkg.envdir(), "python.exe") : joinpath(CondaPkg.envdir(), "bin", "python")
# It's not sufficient to only activate the env while Python is initialising,
# it must also be active when loading extension modules (e.g. numpy). So we
# activate the environment globally.
# TODO: is this really necessary?
CondaPkg.activate!(ENV)
end
CTX.which = :CondaPkg
elseif exe_path == "@PyCall"
# PyCall compatibility mode
PyCall = Base.require(PYCALL_PKGID)::Module
exe_path = PyCall.python::String
CTX.lib_path = PyCall.libpython::String
CTX.which = :PyCall
elseif startswith(exe_path, "@")
error("invalid JULIA_PYTHONCALL_EXE=$exe_path")
else
# Otherwise we use the Python specified
CTX.which = :unknown
end
# Ensure Python is runnable
try
run(pipeline(`$exe_path --version`, stdout=devnull, stderr=devnull))
catch
error("Python executable $(repr(exe_path)) is not executable.")
end
CTX.exe_path = exe_path
# For calling Python with UTF-8 IO
function python_cmd(args)
env = copy(ENV)
env["PYTHONIOENCODING"] = "UTF-8"
delete!(env, "PYTHONHOME")
setenv(`$(CTX.exe_path) $args`, env)
end
# Find and open Python library
lib_path = something(
CTX.lib_path===missing ? nothing : CTX.lib_path,
get(ENV, "JULIA_PYTHONCALL_LIB", nothing),
Some(nothing)
)
if lib_path !== nothing
lib_ptr = dlopen_e(lib_path, CTX.dlopen_flags)
if lib_ptr == C_NULL
error("Python library $(repr(lib_path)) could not be opened.")
else
CTX.lib_path = lib_path
CTX.lib_ptr = lib_ptr
end
else
for lib_path in readlines(python_cmd([joinpath(@__DIR__, "find_libpython.py"), "--list-all"]))
lib_ptr = dlopen_e(lib_path, CTX.dlopen_flags)
if lib_ptr == C_NULL
@warn "Python library $(repr(lib_path)) could not be opened."
else
CTX.lib_path = lib_path
CTX.lib_ptr = lib_ptr
break
end
end
CTX.lib_path === nothing && error("""
Could not find Python library for Python executable $(repr(CTX.exe_path)).
If you know where the library is, set environment variable 'JULIA_PYTHONCALL_LIB' to its path.
""")
end
# Close the library when Julia exits
atexit() do
dlclose(CTX.lib_ptr)
end
# Get function pointers from the library
init_pointers()
# Initialize the interpreter
with_gil() do
CTX.is_preinitialized = Py_IsInitialized() != 0
if CTX.is_preinitialized
@assert CTX.which == :PyCall
else
@assert CTX.which != :PyCall
# Find ProgramName and PythonHome
script = if Sys.iswindows()
"""
import sys
print(sys.executable)
if hasattr(sys, "base_exec_prefix"):
sys.stdout.write(sys.base_exec_prefix)
else:
sys.stdout.write(sys.exec_prefix)
"""
else
"""
import sys
print(sys.executable)
if hasattr(sys, "base_exec_prefix"):
sys.stdout.write(sys.base_prefix)
sys.stdout.write(":")
sys.stdout.write(sys.base_exec_prefix)
else:
sys.stdout.write(sys.prefix)
sys.stdout.write(":")
sys.stdout.write(sys.exec_prefix)
"""
end
CTX.pyprogname, CTX.pyhome = readlines(python_cmd(["-c", script]))
# Set PythonHome
CTX.pyhome_w = Base.cconvert(Cwstring, CTX.pyhome)
Py_SetPythonHome(pointer(CTX.pyhome_w))
# Set ProgramName
CTX.pyprogname_w = Base.cconvert(Cwstring, CTX.pyprogname)
Py_SetProgramName(pointer(CTX.pyprogname_w))
# Start the interpreter and register exit hooks
Py_InitializeEx(0)
atexit() do
CTX.is_initialized = false
if CTX.version === missing || CTX.version < v"3.6"
Py_Finalize()
else
if Py_FinalizeEx() == -1
@warn "Py_FinalizeEx() error"
end
end
end
end
CTX.is_initialized = true
if Py_AtExit(@cfunction(_atpyexit, Cvoid, ())) == -1
@warn "Py_AtExit() error"
end
end
end
# HACK: If we are using CondaPkg, prevent child processes from using it by explicitly
# setting the executable. Our tests sometimes fail on Windows because Aqua launches a
# child process which causes CondaPkg to re-resolve (should work out why, I assume it's
# a filesystem timestamp thing) which causes some stdlibs to disappear for a bit.
#
# A better solution may be to use some environment variable to "freeze" CondaPkg in
# child processes.
#
# Only done when CI=true since it's a hack.
if (get(ENV, "CI", "false") == "true") && (CTX.which === :CondaPkg)
ENV["JULIA_PYTHONCALL_EXE"] = CTX.exe_path::String
end
# Compare libpath with PyCall
@require PyCall="438e738f-606a-5dbb-bf0a-cddfbfd45ab0" init_pycall(PyCall)
with_gil() do
# Get the python version
verstr = Base.unsafe_string(Py_GetVersion())
vermatch = match(r"^[0-9.]+", verstr)
if vermatch === nothing
error("Cannot parse version from version string: $(repr(verstr))")
end
CTX.version = VersionNumber(vermatch.match)
v"3.5" ≤ CTX.version < v"4" || error(
"Only Python 3.5+ is supported, this is Python $(CTX.version) at $(CTX.exe_path===missing ? "unknown location" : CTX.exe_path).",
)
end
@debug "Initialized PythonCall.jl" CTX.is_embedded CTX.is_initialized CTX.exe_path CTX.lib_path CTX.lib_ptr CTX.pyprogname CTX.pyhome CTX.version
return
end
function Base.show(io::IO, ::MIME"text/plain", ctx::Context)
show(io, typeof(io))
print(io, ":")
for k in fieldnames(Context)
println(io)
print(io, " ", k, " = ")
show(io, getfield(ctx, k))
end
end
const PYTHONCALL_UUID = Base.UUID("6099a3de-0909-46bc-b1f4-468b9a2dfc0d")
const PYTHONCALL_PKGID = Base.PkgId(PYTHONCALL_UUID, "PythonCall")
const PYCALL_UUID = Base.UUID("438e738f-606a-5dbb-bf0a-cddfbfd45ab0")
const PYCALL_PKGID = Base.PkgId(PYCALL_UUID, "PyCall")
function init_pycall(PyCall::Module)
# see if PyCall and PythonCall are using the same interpreter by checking if a couple of memory addresses are the same
ptr1 = Py_GetVersion()
ptr2 = @eval PyCall ccall(@pysym(:Py_GetVersion), Ptr{Cchar}, ())
CTX.matches_pycall = ptr1 == ptr2
if CTX.which == :PyCall
@assert CTX.matches_pycall
end
end