-
Notifications
You must be signed in to change notification settings - Fork 32
/
AbstractSingleton.jl
419 lines (292 loc) · 8.42 KB
/
AbstractSingleton.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
export AbstractSingleton,
element
"""
AbstractSingleton{N} <: AbstractHyperrectangle{N}
Abstract type for sets with a single value.
### Notes
Every concrete `AbstractSingleton` must define the following function:
- `element(::AbstractSingleton)` -- return the single element
- `element(::AbstractSingleton, i::Int)` -- return the single element at index
`i`
```jldoctest; setup = :(using LazySets: subtypes)
julia> subtypes(AbstractSingleton)
2-element Vector{Any}:
Singleton
ZeroSet
```
"""
abstract type AbstractSingleton{N} <: AbstractHyperrectangle{N} end
isconvextype(::Type{<:AbstractSingleton}) = true
"""
element(S::AbstractSingleton, i::Int)
Return the i-th entry of the element of a set with a single value.
### Input
- `S` -- set with a single value
- `i` -- dimension of interest
### Output
The i-th entry of the element.
"""
function element(S::AbstractSingleton, i::Int)
@boundscheck _check_bounds(S, i)
return element(S)[i]
end
"""
radius_hyperrectangle(S::AbstractSingleton{N}, i::Int) where {N}
Return the box radius of a set with a single value in a given dimension.
### Input
- `S` -- set with a single value
- `i` -- dimension of interest
### Output
Zero.
"""
function radius_hyperrectangle(S::AbstractSingleton{N}, i::Int) where {N}
@boundscheck _check_bounds(S, i)
return zero(N)
end
"""
radius_hyperrectangle(S::AbstractSingleton{N}) where {N}
Return the box radius of a set with a single value in every dimension.
### Input
- `S` -- set with a single value
### Output
The zero vector.
"""
function radius_hyperrectangle(S::AbstractSingleton{N}) where {N}
return zeros(N, dim(S))
end
"""
high(S::AbstractSingleton)
Return the higher coordinates of a set with a single value.
### Input
- `S` -- set with a single value
### Output
A vector with the higher coordinates.
"""
function high(S::AbstractSingleton)
return element(S)
end
"""
high(S::AbstractSingleton, i::Int)
Return the higher coordinate of a set with a single value in the given
dimension.
### Input
- `S` -- set with a single value
- `i` -- dimension of interest
### Output
The higher coordinate in the given dimension.
"""
function high(S::AbstractSingleton, i::Int)
@boundscheck _check_bounds(S, i)
return element(S)[i]
end
"""
low(S::AbstractSingleton)
Return the lower coordinates of a set with a single value.
### Input
- `S` -- set with a single value
### Output
A vector with the lower coordinates.
"""
function low(S::AbstractSingleton)
return element(S)
end
"""
low(S::AbstractSingleton, i::Int)
Return the lower coordinate of a set with a single value in the given
dimension.
### Input
- `S` -- set with a single value
- `i` -- dimension of interest
### Output
The lower coordinate in the given dimension.
"""
function low(S::AbstractSingleton, i::Int)
@boundscheck _check_bounds(S, i)
return element(S)[i]
end
"""
genmat(S::AbstractSingleton{N}) where {N}
Return the (empty) generator matrix of a set with a single value.
### Input
- `S` -- set with a single value
### Output
A matrix with no columns representing the generators of `S`.
"""
function genmat(S::AbstractSingleton{N}) where {N}
return Matrix{N}(undef, dim(S), 0)
end
"""
generators(S::AbstractSingleton{N}) where {N}
Return an (empty) iterator over the generators of a set with a single value.
### Input
- `S` -- set with a single value
### Output
An empty iterator.
"""
function generators(S::AbstractSingleton{N}) where {N}
return EmptyIterator{Vector{N}}()
end
"""
ngens(S::AbstractSingleton)
Return the number of generators of a set with a single value.
### Input
- `H` -- set with a single value
### Output
The number of generators, which is ``0``.
"""
function ngens(S::AbstractSingleton)
return 0
end
"""
center(S::AbstractSingleton)
Return the center of a set with a single value.
### Input
- `S` -- set with a single value
### Output
The center of the set.
"""
function center(S::AbstractSingleton)
return element(S)
end
"""
center(S::AbstractSingleton, i::Int)
Return the center of a set with a single value in a given dimension.
### Input
- `S` -- set with a single value
- `i` -- dimension of interest
### Output
The `i`-th entry of the center of the set.
"""
function center(S::AbstractSingleton, i::Int)
@boundscheck _check_bounds(S, i)
return element(S, i)
end
"""
vertices(S::AbstractSingleton{N}) where {N}
Construct an iterator over the vertices of a set with a single value.
### Input
- `S` -- set with a single value
### Output
An iterator with a single value.
"""
function vertices(S::AbstractSingleton{N}) where {N}
return SingletonIterator(element(S))
end
"""
vertices_list(S::AbstractSingleton)
Return the list of vertices of a set with a single value.
### Input
- `S` -- set with a single value
### Output
A list containing only a single vertex.
"""
function vertices_list(S::AbstractSingleton)
return [element(S)]
end
"""
σ(d::AbstractVector, S::AbstractSingleton)
Return the support vector of a set with a single value.
### Input
- `d` -- direction
- `S` -- set with a single value
### Output
The support vector, which is the set's vector itself, irrespective of the given
direction.
"""
function σ(d::AbstractVector, S::AbstractSingleton)
return element(S)
end
"""
ρ(d::AbstractVector, S::AbstractSingleton)
Evaluate the support function of a set with a single value in a given direction.
### Input
- `d` -- direction
- `S` -- set with a single value
### Output
The support value in the given direction.
"""
function ρ(d::AbstractVector, S::AbstractSingleton)
return dot(d, element(S))
end
"""
∈(x::AbstractVector, S::AbstractSingleton)
Check whether a given point is contained in a set with a single value.
### Input
- `x` -- point/vector
- `S` -- set with a single value
### Output
`true` iff ``x ∈ S``.
### Notes
This implementation performs an approximate comparison to account for
imprecision in floating-point computations.
"""
function ∈(x::AbstractVector, S::AbstractSingleton)
return _isapprox(x, element(S))
end
# this operation is forbidden, but it is a common error
function ∈(S::AbstractSingleton, X::LazySet)
throw(ArgumentError("cannot make a point-in-set check if the left-hand " *
"side is a set; either check for set inclusion, as in `S ⊆ X`, or " *
"check for membership, as in `element(S) ∈ X` (the results are " *
"equivalent, but the implementations may differ)"))
end
function chebyshev_center_radius(S::AbstractSingleton{N}) where {N}
return element(S), zero(N)
end
"""
plot_recipe(S::AbstractSingleton{N}, [ε]=zero(N)) where {N}
Convert a singleton to a pair `(x, y)` of points for plotting.
### Input
- `S` -- singleton
- `ε` -- (optional, default: `0`) ignored, used for dispatch
### Output
A pair `(x, y)` of one point that can be plotted.
"""
function plot_recipe(S::AbstractSingleton{N}, ε=zero(N)) where {N}
n = dim(S)
if n == 1
return [element(S)[1]], [zero(N)]
elseif n == 2
return [element(S)[1]], [element(S)[2]]
elseif n == 3
return [element(S)[1]], [element(S)[2]], [element(S)[3]]
else
throw(ArgumentError("cannot plot a $n-dimensional $(typeof(S))"))
end
end
"""
reflect(S::AbstractSingleton)
Concrete reflection of a set with a single value `S`, resulting in the reflected
set `-S`.
### Input
- `S` -- set with a single value
### Output
A `Singleton` representing `-S`.
"""
function reflect(S::AbstractSingleton)
return Singleton(-element(S))
end
function constraints_list(S::AbstractSingleton; min_constraints::Bool=false)
if min_constraints
# fewest constraints (n+1) but more expensive to represent (`Vector`)
return _constraints_list_singleton(S)
else
# more constraints (2n) but cheaper to represent (`SingleEntryVector`)
return _constraints_list_hyperrectangle(S)
end
end
# fewest constraints (n+1)
function _constraints_list_singleton(S::AbstractSingleton{N}) where {N}
n = dim(S)
constraints = Vector{HalfSpace{N,Vector{N}}}(undef, n + 1)
e = element(S)
@inbounds for i in 1:n
# x_i >= e
ai = zeros(N, n)
ai[i] = -one(N)
constraints[i] = HalfSpace(ai, -e[i])
end
# (∑_i x_i) <= ∑_i e_i
@inbounds constraints[end] = HalfSpace(ones(N, n), sum(e))
return constraints
end