Add gamepad support

configure.ac

@@ -51,6 +51,8 @@ PKG_CHECK_MODULES(GNOME_GAMES, [
 	glib-2.0 >= $GLIB_MIN_VERSION
 	grilo-0.3
 	gtk+-3.0
+	gudev-1.0
+	libevdev
 	retro-gobject-0.6
 	retro-gtk-0.6
 	tracker-sparql-1.0

data/org.gnome.Games.gresource.xml

@@ -2,6 +2,7 @@
 <gresources>
   <gresource prefix="/org/gnome/Games">
     <file>gtk-style.css</file>
+    <file>gamepads/gamecontrollerdb.txt</file>
     <file preprocess="xml-stripblanks">gtk/menus.ui</file>
     <file preprocess="xml-stripblanks">ui/application-window.ui</file>
     <file preprocess="xml-stripblanks">ui/collection-icon-view.ui</file>

src/Makefile.am

@@ -53,10 +53,28 @@ gnome_games_SOURCES = \
 	dummy/dummy-icon.vala \
 	dummy/dummy-runner.vala \
 	\
+	gamepad/raw-gamepad-monitor.vala \
+	gamepad/raw-gamepad.vala \
+	gamepad/linux/linux-guid-helpers.vala \
+	gamepad/linux/linux-raw-gamepad-monitor.vala \
+	gamepad/linux/linux-raw-gamepad.vala \
+	gamepad/gamepad-monitor.vala \
+	gamepad/gamepad.vala \
+	gamepad/helpers.vala \
+	gamepad/input-type.vala \
+	gamepad/mapped-event.vala \
+	gamepad/mapping-error.vala \
+	gamepad/mapping.vala \
+	gamepad/mappings-manager.vala \
+	gamepad/standard-gamepad-axis.vala \
+	gamepad/standard-gamepad-button.vala \
+	\
 	grilo/grilo-cover.vala \
 	grilo/grilo-media.vala \
 	\
 	retro/retro-error.vala \
+	retro/retro-gamepad.vala \
+	retro/retro-input-manager.vala \
 	retro/retro-log.vala \
 	retro/retro-runner.vala \
 	\
@@ -99,13 +117,18 @@ gnome_games_SOURCES = \
 
 gnome_games_VALAFLAGS = \
 	--target-glib=@GLIB_MIN_VERSION@ \
+	--vapidir=gamepad/linux/ \
 	--pkg gio-2.0 \
 	--pkg glib-2.0 \
 	--pkg grilo-0.3 \
 	--pkg gtk+-3.0 \
 	--pkg tracker-sparql-1.0 \
 	--pkg retro-gobject-0.6 \
 	--pkg retro-gtk-0.6 \
+	--pkg gudev-1.0 \
+	--pkg libevdev \
+	--pkg linux \
+	--pkg posix \
 	--gresources $(gresource_file) \
 	--vapi $(vapi_file) \
 	-H $(header_file) \

src/gamepad/gamepad-monitor.vala

@@ -0,0 +1,59 @@
+// This file is part of GNOME Games. License: GPLv3
+
+/**
+ * This class provides a way to the client to monitor gamepads
+ *
+ * The client interfaces with this class primarily
+ */
+public class LibGamepad.GamepadMonitor : Object {
+	/**
+	 * Emitted when a gamepad is plugged in
+	 * @param  gamepad    The gamepad
+	 */
+	public signal void gamepad_plugged (Gamepad gamepad);
+
+	public delegate void GamepadCallback (Gamepad gamepad);
+
+	private static GamepadMonitor instance;
+
+	private SList <Gamepad> gamepads;
+	private RawGamepadMonitor raw_gamepad_monitor;
+
+	private GamepadMonitor () {
+		if (gamepads == null)
+			gamepads = new SList <Gamepad> ();
+
+		raw_gamepad_monitor = LinuxRawGamepadMonitor.get_instance ();
+
+		raw_gamepad_monitor.gamepad_plugged.connect (on_raw_gamepad_plugged);
+
+		raw_gamepad_monitor.foreach_gamepad ((raw_gamepad) => add_gamepad (raw_gamepad));
+	}
+
+	public static GamepadMonitor get_instance () {
+		if (instance == null)
+			instance = new GamepadMonitor ();
+
+		return instance;
+	}
+
+	/**
+	 * This function allows to iterate over all gamepads
+	 * @param    callback          The callback
+	 */
+	public void foreach_gamepad (GamepadCallback callback) {
+		gamepads.foreach ((gamepad) => callback (gamepad));
+	}
+
+	private Gamepad add_gamepad (RawGamepad raw_gamepad) {
+		var gamepad = new Gamepad (raw_gamepad);
+		gamepads.append (gamepad);
+		gamepad.unplugged.connect (() => gamepads.remove (gamepad));
+
+		return gamepad;
+	}
+
+	private void on_raw_gamepad_plugged (RawGamepad raw_gamepad) {
+		gamepad_plugged (add_gamepad (raw_gamepad));
+	}
+}

src/gamepad/gamepad.vala

@@ -0,0 +1,98 @@
+// This file is part of GNOME Games. License: GPLv3
+
+/**
+ * This class represents a gamepad
+ *
+ * The client interfaces with this class primarily
+ */
+public class LibGamepad.Gamepad : Object {
+
+	/**
+	 * Emitted when a button is pressed/released
+	 * @param  button        The button pressed
+	 * @param  value         True if pressed, False if released
+	 */
+	public signal void button_event (StandardGamepadButton button, bool value);
+
+	/**
+	 * Emitted when an axis's value changes
+	 * @param  axis          The axis number from 0 to axes_number
+	 * @param  value         The value of the axis ranging from -1 to 1
+	 */
+	public signal void axis_event (StandardGamepadAxis axis, double value);
+
+	/**
+	 * Emitted when the gamepad is unplugged
+	 */
+	public signal void unplugged ();
+
+
+	/**
+	 * The guid
+	 */
+	public string? guid { get; private set; }
+
+	/**
+	 * The name present in our database
+	 */
+	public string? name { get; private set; }
+
+	/**
+	 * The raw gamepad behind this gamepad
+	 */
+	public RawGamepad raw_gamepad { get; private set; }
+
+	/**
+	 * Whether this gamepad is mapped
+	 */
+	public bool mapped { get; private set; }
+
+	/**
+	 * The mapping object
+	 */
+	public Mapping? mapping { get; private set; }
+
+	public Gamepad (RawGamepad raw_gamepad) throws FileError {
+		this.raw_gamepad = raw_gamepad;
+		guid = raw_gamepad.guid;
+		name = MappingsManager.get_name (guid) ?? raw_gamepad.name;
+		try {
+			mapping = new Mapping.from_sdl_string (MappingsManager.get_mapping (guid));
+			mapped = true;
+			raw_gamepad.button_event.connect (on_raw_button_event);
+			raw_gamepad.axis_event.connect (on_raw_axis_event);
+			raw_gamepad.dpad_event.connect (on_raw_dpad_event);
+		} catch (MappingError e) {
+			debug ("%s - for %s/%s", e.message, guid, name);
+			mapping = null;
+			mapped = false;
+		}
+		raw_gamepad.unplugged.connect (() => unplugged ());
+	}
+
+	private void on_raw_button_event (int button, bool value) {
+		var event = mapping.get_button_mapping (button);
+		emit_event (event, value ? 1 : 0);
+	}
+
+	private void on_raw_axis_event (int axis, double value) {
+		var event = mapping.get_axis_mapping (axis);
+		emit_event (event, value);
+	}
+
+	private void on_raw_dpad_event (int dpad_index, int axis, int value) {
+		var event = mapping.get_dpad_mapping (dpad_index, axis, value);
+		emit_event (event, value.abs ());
+	}
+
+	private void emit_event (MappedEvent event, double value) {
+		switch (event.type) {
+		case InputType.AXIS:
+			axis_event (event.axis, value);
+			break;
+		case InputType.BUTTON:
+			button_event (event.button, (bool) value);
+			break;
+		}
+	}
+}

src/gamepad/helpers.vala

@@ -0,0 +1,24 @@
+// This file is part of GNOME Games. License: GPLv3
+
+namespace LibGamepad {
+	private const int GUID_LENGTH = 8;
+
+	private string uint16s_to_hex_string (uint16[] data)
+	               requires (data.length == GUID_LENGTH)
+	{
+		const string hex_to_ascii_map = "0123456789abcdef";
+
+		var builder = new StringBuilder ();
+		foreach (uint16 el in data) {
+			uint8 c = (uint8) el;
+			builder.append_unichar (hex_to_ascii_map[c >> 4]);
+			builder.append_unichar (hex_to_ascii_map[c & 0x0F]);
+
+			c = (uint8) (el >> 8);
+			builder.append_unichar (hex_to_ascii_map[c >> 4]);
+			builder.append_unichar (hex_to_ascii_map[c & 0x0F]);
+		}
+
+		return builder.str;
+	}
+}

src/gamepad/input-type.vala

@@ -0,0 +1,11 @@
+// This file is part of GNOME Games. License: GPLv3
+
+public enum LibGamepad.InputType {
+	AXIS,
+	BUTTON,
+	INVALID;
+
+	public static uint length () {
+		return InputType.INVALID + 1;
+	}
+}

src/gamepad/linux/libevdev.vapi

@@ -0,0 +1,39 @@
+// This file is part of GNOME Games. License: GPLv3
+
+[CCode (cheader_filename = "libevdev/libevdev.h")]
+namespace Libevdev {
+
+	[CCode (cname = "libevdev_read_flag", cprefix = "LIBEVDEV_READ_FLAG_", has_type_id = false)]
+	[Flags]
+	public enum ReadFlag {
+		SYNC,
+		NORMAL,
+		FORCE_SYNC,
+		BLOCKING
+	}
+
+	[CCode (cname = "struct libevdev", cprefix = "libevdev_", free_function = "libevdev_free")]
+	[Compact]
+	public class Evdev {
+		[CCode (cname = "libevdev_new")]
+		public Evdev ();
+
+		public int get_fd ();
+		public int set_fd (int fd);
+
+		public string name { get; set; }
+
+		public int id_bustype { get; set; }
+		public int id_vendor { get; set; }
+		public int id_product { get; set; }
+		public int id_version { get; set; }
+
+		public unowned Linux.Input.AbsInfo? get_abs_info (uint code);
+		public bool has_event_code (uint type, uint code);
+		public int has_event_pending ();
+		public int next_event (uint flags, out Linux.Input.Event ev);
+
+		public static unowned string event_code_get_name(uint type, uint code);
+	}
+
+}

src/gamepad/linux/linux-guid-helpers.vala

@@ -0,0 +1,31 @@
+// This file is part of GNOME Games. License: GPLv3
+
+private class LibGamepad.LinuxGuidHelpers : Object {
+	public static string from_dev (Libevdev.Evdev device) {
+		uint16 guid[8];
+		guid[0] = (uint16) device.id_bustype.to_little_endian ();
+		guid[1] = 0;
+		guid[2] = (uint16) device.id_vendor.to_little_endian ();
+		guid[3] = 0;
+		guid[4] = (uint16) device.id_product.to_little_endian ();
+		guid[5] = 0;
+		guid[6] = (uint16) device.id_version.to_little_endian ();
+		guid[7] = 0;
+		return uint16s_to_hex_string (guid);
+	}
+
+	public static string from_file (string file_name) throws FileError {
+		var fd = Posix.open (file_name, Posix.O_RDONLY | Posix.O_NONBLOCK);
+
+		if (fd < 0)
+			throw new FileError.FAILED (@"Unable to open file $file_name: $(Posix.strerror (Posix.errno))");
+
+		var device = new Libevdev.Evdev ();
+		if (device.set_fd (fd) < 0)
+			throw new FileError.FAILED (@"Evdev error on opening file $file_name: $(Posix.strerror (Posix.errno))");
+
+		var guid = from_dev (device);
+		Posix.close (fd);
+		return guid;
+	}
+}