-
Notifications
You must be signed in to change notification settings - Fork 1
/
eks.tf
235 lines (204 loc) · 7.6 KB
/
eks.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
resource "aws_eks_cluster" "eks_cluster" {
name = local.name
role_arn = aws_iam_role.cluster_service_role.arn
version = "1.29"
vpc_config {
endpoint_private_access = false
endpoint_public_access = true
public_access_cidrs = ["0.0.0.0/0"]
security_group_ids = [aws_security_group.cluster.id]
subnet_ids = var.create_vpc ? module.vpc[0].list_of_subnet_ids : var.list_of_subnet_ids
}
### InvalidParameterException: bootstrapClusterCreatorAdminPermissions must be true if cluster authentication mode is set to CONFIG_MAP
access_config {
authentication_mode = "CONFIG_MAP" # CONFIG_MAP | API | API_AND_CONFIG_MAP
bootstrap_cluster_creator_admin_permissions = true
}
enabled_cluster_log_types = [
"api",
"audit",
"authenticator",
"controllerManager",
"scheduler"
]
dynamic "encryption_config" {
for_each = var.kms_key_arn != "" ? [1] : []
content {
provider {
key_arn = var.kms_key_arn
}
resources = ["secrets"]
}
}
tags = local.default_tags
# Ensure that IAM Role permissions are created before and deleted after EKS Cluster handling.
# Otherwise, EKS will not be able to properly delete EKS managed EC2 infrastructure such as Security Groups.
depends_on = [
aws_iam_role_policy_attachment.example-AmazonEKSClusterPolicy,
aws_iam_role_policy_attachment.example-AmazonEKSVPCResourceController,
aws_iam_role_policy_attachment.example-AmazonEKSServicePolicy
]
}
resource "aws_security_group" "cluster" {
name = format("%s-clustersecuritygroup", local.name)
description = "Cluster security group"
vpc_id = var.create_vpc ? module.vpc[0].vpc_id : var.vpc_id
tags = local.default_tags
}
resource "aws_security_group_rule" "cluster" {
type = "ingress"
from_port = 443
to_port = 443
protocol = "tcp"
source_security_group_id = aws_security_group.node.id
security_group_id = aws_security_group.cluster.id
description = "Node groups to cluster API"
}
data "aws_iam_policy_document" "assume_role" {
statement {
effect = "Allow"
principals {
type = "Service"
identifiers = ["eks.amazonaws.com"]
}
actions = ["sts:AssumeRole"]
}
}
resource "aws_iam_role" "cluster_service_role" {
name = "eks-cluster-example"
assume_role_policy = data.aws_iam_policy_document.assume_role.json
tags = local.default_tags
}
resource "aws_iam_policy" "cluster_encryption" {
count = var.kms_key_arn != "" ? 1 : 0
name = format("%s-ClusterEncryption", local.name)
path = "/"
description = "Cluster encryption policy to allow cluster role to utilize CMK provided"
# Terraform's "jsonencode" function converts a
# Terraform expression result to valid JSON syntax.
policy = jsonencode(
{
Statement = [
{
Action = [
"kms:Encrypt",
"kms:Decrypt",
"kms:ListGrants",
"kms:DescribeKey",
]
Effect = "Allow"
Resource = var.kms_key_arn
},
]
Version = "2012-10-17"
}
)
tags = local.default_tags
}
resource "aws_iam_role_policy_attachment" "cluster_encryption" {
count = var.kms_key_arn != "" ? 1 : 0
policy_arn = aws_iam_policy.cluster_encryption[0].arn
role = aws_iam_role.cluster_service_role.name
}
resource "aws_iam_role_policy_attachment" "example-AmazonEKSClusterPolicy" {
policy_arn = "arn:aws:iam::aws:policy/AmazonEKSClusterPolicy"
role = aws_iam_role.cluster_service_role.name
}
resource "aws_iam_role_policy_attachment" "example-AmazonEKSServicePolicy" {
policy_arn = "arn:aws:iam::aws:policy/AmazonEKSServicePolicy"
role = aws_iam_role.cluster_service_role.name
}
resource "aws_iam_role_policy_attachment" "example-AmazonEKSVPCResourceController" {
policy_arn = "arn:aws:iam::aws:policy/AmazonEKSVPCResourceController"
role = aws_iam_role.cluster_service_role.name
}
### https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/eks_addon
### Enable pod networking within your cluster.
resource "aws_eks_addon" "vpc-cni" {
cluster_name = aws_eks_cluster.eks_cluster.name
addon_name = "vpc-cni"
addon_version = "v1.16.0-eksbuild.1"
}
### Enable service networking within your cluster.
resource "aws_eks_addon" "kube-proxy" {
cluster_name = aws_eks_cluster.eks_cluster.name
addon_name = "kube-proxy"
addon_version = "v1.29.0-eksbuild.1"
}
## ---------------------------------------------------------------------------------------
## Node Group
## ---------------------------------------------------------------------------------------
resource "aws_iam_role" "node_group" {
count = var.create_node_group ? 1 : 0
name = "eks-node-group-iam-role"
assume_role_policy = jsonencode({
Statement = [{
Action = "sts:AssumeRole"
Effect = "Allow"
Principal = {
Service = "ec2.amazonaws.com"
}
}]
Version = "2012-10-17"
})
tags = local.default_tags
}
resource "aws_iam_role_policy_attachment" "node_group-AmazonEKSWorkerNodePolicy" {
count = var.create_node_group ? 1 : 0
policy_arn = "arn:aws:iam::aws:policy/AmazonEKSWorkerNodePolicy"
role = aws_iam_role.node_group[0].name
}
resource "aws_iam_role_policy_attachment" "node_group-AmazonEKS_CNI_Policy" {
count = var.create_node_group ? 1 : 0
policy_arn = "arn:aws:iam::aws:policy/AmazonEKS_CNI_Policy"
role = aws_iam_role.node_group[0].name
}
resource "aws_iam_role_policy_attachment" "node_group-AmazonEC2ContainerRegistryReadOnly" {
count = var.create_node_group ? 1 : 0
policy_arn = "arn:aws:iam::aws:policy/AmazonEC2ContainerRegistryReadOnly"
role = aws_iam_role.node_group[0].name
}
data "aws_ssm_parameter" "eks_ami_release_version" {
name = "/aws/service/eks/optimized-ami/${aws_eks_cluster.eks_cluster.version}/amazon-linux-2/recommended/release_version"
}
resource "aws_security_group" "node" {
name = format("%s-nodesecuritygroup", local.name)
description = "Security group for all nodes in the cluster."
vpc_id = var.create_vpc ? module.vpc[0].vpc_id : var.vpc_id
tags = local.default_tags
}
resource "aws_security_group_rule" "node" {
type = "ingress"
from_port = 0
to_port = 0
protocol = "-1"
cidr_blocks = ["0.0.0.0/0"]
security_group_id = aws_security_group.node.id
description = "Node groups to cluster API"
}
resource "aws_eks_node_group" "managed_node_group" {
count = var.create_node_group ? 1 : 0
cluster_name = aws_eks_cluster.eks_cluster.name
node_group_name = "eks-node-group"
version = aws_eks_cluster.eks_cluster.version
release_version = nonsensitive(data.aws_ssm_parameter.eks_ami_release_version.value)
node_role_arn = aws_iam_role.node_group[0].arn
subnet_ids = module.vpc[0].list_of_subnet_ids
scaling_config {
desired_size = 1
max_size = 1
min_size = 1
}
update_config {
max_unavailable = 1
}
capacity_type = "SPOT" # ON_DEMAND | SPOT
# Ensure that IAM Role permissions are created before and deleted after EKS Node Group handling.
# Otherwise, EKS will not be able to properly delete EC2 Instances and Elastic Network Interfaces.
depends_on = [
aws_iam_role_policy_attachment.node_group-AmazonEKSWorkerNodePolicy,
aws_iam_role_policy_attachment.node_group-AmazonEKS_CNI_Policy,
aws_iam_role_policy_attachment.node_group-AmazonEC2ContainerRegistryReadOnly,
]
tags = local.default_tags
}