forked from surrealdb/surrealdb.java
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
104 lines (88 loc) · 2.74 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
plugins {
id 'java'
id 'java-library'
id 'checkstyle'
id 'maven-publish'
id "com.diffplug.spotless" version "6.17.0"
}
group 'com.surrealdb'
version '0.1.0'
repositories {
mavenCentral()
}
java {
toolchain {
languageVersion = JavaLanguageVersion.of(17)
}
}
ext {
slf4jVersion = "2.0.1"
logbackVersion = "1.3.1"
lombokVersion = "1.18.26"
junitVersion = "5.8.1"
testcontainersVersion = "1.17.6"
}
dependencies {
// Java-WebSocket
implementation 'org.java-websocket:Java-WebSocket:1.5.3'
// Gson
implementation 'com.google.code.gson:gson:2.9.1'
// logging
implementation "org.slf4j:slf4j-api:${slf4jVersion}"
testRuntimeOnly "ch.qos.logback:logback-core:${logbackVersion}"
testRuntimeOnly "ch.qos.logback:logback-classic:${logbackVersion}"
// lombok
compileOnly "org.projectlombok:lombok:${lombokVersion}"
annotationProcessor "org.projectlombok:lombok:${lombokVersion}"
testCompileOnly "org.projectlombok:lombok:${lombokVersion}"
testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"
// junit
testImplementation "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
testImplementation "org.junit.jupiter:junit-jupiter:${junitVersion}"
testImplementation "org.testcontainers:testcontainers:${testcontainersVersion}"
testImplementation "org.testcontainers:junit-jupiter:${testcontainersVersion}"
}
spotless {
java {
cleanthat()
googleJavaFormat().aosp()
formatAnnotations()
indentWithSpaces(4)
}
}
test {
useJUnitPlatform()
environment('TEST_SURREAL_HOST', 'localhost')
environment('TEST_SURREAL_PORT', 8000)
environment('TEST_SURREAL_USERNAME', 'root')
environment('TEST_SURREAL_PASSWORD', 'root')
environment('TEST_SURREAL_NAMESPACE', 'test')
environment('TEST_SURREAL_DATABASE', 'test')
}
checkstyle {
toolVersion = "10.9.3"
configFile = resources.text.fromUri("https://raw.githubusercontent.com/checkstyle/checkstyle/checkstyle-${toolVersion}/src/main/resources/google_checks.xml").asFile()
}
task fatJar(type: Jar) {
manifest {
attributes 'Main-Class': 'com.surrealdb.driver.SyncSurrealDriver'
}
from {
configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
}
duplicatesStrategy = DuplicatesStrategy.EXCLUDE
with jar
}
publishing {
repositories {
maven {
name = "GitHubPackages"
url = "https://maven.pkg.github.com/surrealdb/surrealdb.java"
credentials {
username = System.getenv("GITHUB_ACTOR")
password = System.getenv("GITHUB_TOKEN")
}
}
}
}