Less accurate answers than BenchmarkTools on some microbenchmarks

[LilithHafner]

g is a little faster than f, as justified by these macrobenchmarks and analysis of generated code. Chairmarks fails to detect this while BenchmarkTools succeeds.

Originally reported by @matthias314 here with macrobenchmarks by @MasonProtter here

julia> function macro_benchmark_5!(out, f)
           for j ∈ axes(out, 2)
               x = UInt128(j)
               for i ∈ axes(out, 1)
                   out[i, j] = f(x, i)
               end
           end
       end;

julia> function macro_benchmark_5_noinline!(out, f)
           for j ∈ axes(out, 2)
               x = UInt128(j)
               for i ∈ axes(out, 1)
                   out[i, j] = @noinline f(x, i)
               end
           end
       end;

julia> function macro_benchmark_6!(f, N)
           for j ∈ 1:N
               x = UInt128(j)
               for i ∈ 1:N
                   Base.donotdelete(f(x, i))
               end
           end
       end;

julia> function macro_benchmark_6_noinline!(f, N)
           for j ∈ 1:N
               x = UInt128(j)
               for i ∈ 1:N
                   Base.donotdelete(@noinline f(x, i))
               end
           end
       end;

julia> f(x, n) = x << n;

julia> g(x, n) = x << (n & 63);

julia> let
           out = Matrix{UInt128}(undef, 10_000, 10_000)
           @time macro_benchmark_5!(out, f)
           @time macro_benchmark_5!(out, g)
           println()
           @time macro_benchmark_5_noinline!(out, f)
           @time macro_benchmark_5_noinline!(out, g)
           println()
           @time macro_benchmark_6!(f, 10_000)
           @time macro_benchmark_6!(g, 10_000)
           println()
           @time macro_benchmark_6_noinline!(f, 10_000)
           @time macro_benchmark_6_noinline!(g, 10_000)
       end
  0.185143 seconds
  0.121225 seconds

  0.220452 seconds
  0.181451 seconds

  0.114753 seconds
  0.115903 seconds

  0.258359 seconds
  0.204093 seconds

julia> x = UInt128(1); n = 1;

julia> @btime f($x, $n);
  2.500 ns (0 allocations: 0 bytes)

julia> @btime g($x, $n);
  1.958 ns (0 allocations: 0 bytes)

julia> @b f($x, $n)
1.137 ns

julia> @b g($x, $n)
1.137 ns