-
Notifications
You must be signed in to change notification settings - Fork 2
/
msg.opa
123 lines (110 loc) · 3.35 KB
/
msg.opa
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
/*
* Twopenny. (C) MLstate - 2011
* @author Adam Koprowski
**/
package mlstate.twopenny
import widgets.dateprinter
type Msg.t = private(
{ author: User.ref
; content : string
; created_at : Date.date
})
type Msg.segment =
{ text : string }
/ { label : Label.ref }
/ { url : Uri.uri }
/ { user : User.ref }
Msg = {{
create(author : User.ref, content : string) : Msg.t =
msg = { ~author ~content created_at=Date.now() }
@wrap(msg)
get_creation_date(msg : Msg.t) : Date.date =
@unwrap(msg).created_at
get_author(msg : Msg.t) : User.ref =
@unwrap(msg).author
get_content(msg : Msg.t) : string =
@unwrap(msg).content
parse(msg : Msg.t) : list(Msg.segment) =
word = parser
/* FIXME we probably want to extend the character set
below. */
| word=([a-zA-Z0-9_\-]*) -> Text.to_string(word)
user_prefix = parser "@" -> void
label_prefix = parser "#" -> void
url_prefix = parser "http://" -> void
special_prefix = parser user_prefix | label_prefix | url_prefix;
segment_parser = parser
| user_prefix user=word -> { user = User.mk_ref(user) }
| label_prefix label=word -> { label = Label.mk_ref(label) }
/* careful here, Uri.uri_parser too liberal, as it parses things like
hey.ho as valid URLs; so we use "http://" prefix to recognize URLs */
| &url_prefix url=Uri.uri_parser -> ~{ url }
/* below we eat a complete [word] or a single non-word character; the
latter case alone may not be enough as we don't want:
sthhttp://sth to pass for an URL. */
| txt=((!special_prefix (. word))+) -> // Warning! + not * ; otherwise it will loop
{ text = Text.to_string(txt) }
msg_parser = parser res=segment_parser* -> res
Parser.parse(msg_parser, Msg.get_content(msg))
render(msg : Msg.t, mode : {preview} / {final}) : xhtml =
render_segment =
| ~{ text } -> <>{text}</>
| ~{ url } ->
// we add spaces around URLs to avoid collapsing them together with adjacent text
<> <a href={url}>{Uri.to_string(url)}</> </>
| ~{ label } -> Label.to_anchor(label)
| ~{ user } -> User.to_anchor(user)
content = List.map(render_segment, parse(msg))
date = WDatePrinter.html(WDatePrinter.default_config,
uniq(), Msg.get_creation_date(msg))
<div class="msg">
<img class="image" src="/img/user.png" />
<div class="content">
<div class="user">{Msg.get_author(msg) |> User.to_anchor}</>
<div class="text">{content}</>
{match mode with
| {final} -> <div class="date">{date}</>
| {preview} -> <></> // don't display date in preview
}
</>
</>
// FIXME WDatePrinter -> "now ago" -> "now"
}}
css = css
.msg {
border-top: 1px dotted black;
border-bottom: 1px dotted black;
width: 540px;
min-height: 48px;
font-size: 15px;
font-family: Helvetica;
background: #F0FFF9;
padding: 15px 0px;
}
.msg:hover {
background: #D9FFF6;
border-top: 1px solid black;
border-bottom: 1px solid black;
}
.msg .image {
width: 48px;
height: 48px;
margin-left: 3px;
float: left;
}
.msg .content {
margin-left: 60px;
}
.msg .user {
line-height: 15px;
color: #333;
font-weight: bold;
}
.msg .text {
line-height: 19px;
color: #444;
}
.msg .date {
font-size: 11px;
color: #999;
}