-
Notifications
You must be signed in to change notification settings - Fork 224
/
Probability.m2
1477 lines (1345 loc) · 44.7 KB
/
Probability.m2
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
newPackage("Probability",
Headline => "basic probability functions",
Version => "0.3",
Date => "October 31, 2023",
Authors => {{
Name => "Doug Torrance",
Email => "dtorrance@piedmont.edu",
HomePage => "https://webwork.piedmont.edu/~dtorrance"}})
---------------
-- ChangeLog --
---------------
-*
0.3 (2023-10-31, M2 1.23)
* add Caveats to docs warning user to ensure that pdf's are well-defined
* use ASCII characters for chi-squared distribution
* clarify in docs that the support of a discrete distribution will be a subset
of the integers
* add Caveat to docs mentioning limitations of floating-point arithmetic
0.2 (2022-10-31, M2 1.21)
* fix typos
* adjust some tests after MPFR support added for Boost special functions
0.1 (2022-05-04, M2 1.20)
* initial release
*-
export {
-- classes
"ProbabilityDistribution",
"DiscreteProbabilityDistribution",
"ContinuousProbabilityDistribution",
-- generic constructor methods
"discreteProbabilityDistribution",
"continuousProbabilityDistribution",
-- discrete distributions
"binomialDistribution",
"bernoulliDistribution",
"poissonDistribution",
"geometricDistribution",
"negativeBinomialDistribution",
"hypergeometricDistribution",
-- continuous distributions
"uniformDistribution",
"exponentialDistribution",
"normalDistribution",
"gammaDistribution",
"chiSquaredDistribution",
"tDistribution",
"fDistribution",
"betaDistribution",
-- functions
"density",
"probability",
"quantile",
-- symbols
"DensityFunction",
"DistributionFunction",
"QuantileFunction",
"RandomGeneration",
"Support",
"LowerTail"
}
---------------------------------------------
-- abstract probability distribution class --
---------------------------------------------
ProbabilityDistribution = new Type of HashTable
ProbabilityDistribution.synonym = "probability distribution"
density' := (X, x) -> (
if x < first X.Support or x > last X.Support then 0
else X.DensityFunction x)
density = method()
density(ProbabilityDistribution, Number) :=
density(ProbabilityDistribution, Constant) := density'
probability' := true >> o -> (X, x) -> (
p := if x < first X.Support then 0
else if x > last X.Support then 1
else X.DistributionFunction x;
if o.LowerTail then p else 1 - p)
probability = method(Options => {LowerTail => true})
probability(ProbabilityDistribution, Number) :=
probability(ProbabilityDistribution, Constant) := o -> (X, x) ->
probability'(X, x, o)
quantile' = true >> o -> (X, p) -> (
if p < 0 or p > 1 then error "expected number between 0 and 1"
else if p == 0 and first X.Support == -infinity then -infinity
else if p == 1 and last X.Support == infinity then infinity
else X.QuantileFunction if o.LowerTail then p else 1 - p)
quantile = method(Options => {LowerTail => true})
quantile(ProbabilityDistribution, Number) :=
quantile(ProbabilityDistribution, Constant) := o -> (X, p) -> quantile'(X, p, o)
random ProbabilityDistribution := o -> X -> X.RandomGeneration()
net ProbabilityDistribution := X -> X.Description
texMath ProbabilityDistribution := texMath @@ net
-- helper functions for checking parameters
checkReal := n -> if not isReal n then error(
"expected real parameter: ", n)
checkPositive := n -> if n <= 0 or not isReal n then error(
"expected positive parameter: ", n)
checkNonnegative := n -> if n < 0 or not isReal n then error(
"expected nonnegative parameter: ", n)
checkProbability := p -> if p < 0 or p > 1 or not isReal p then error(
"expected parameter to be between 0 and 1: ", p)
checkSupport := A -> if not (instance(A, Sequence) and length A == 2 and
(isReal first A or isInfinite first A) and
(isReal last A or isInfinite last A) and first A < last A) then error(
"expected an increasing pair of real or infinite numbers: ", A)
----------------------------------------
-- discrete probability distributions --
----------------------------------------
DiscreteProbabilityDistribution = new SelfInitializingType of
ProbabilityDistribution
DiscreteProbabilityDistribution.synonym = "discrete probability distribution"
discreteProbabilityDistribution = method(Options => {
DistributionFunction => null,
QuantileFunction => null,
RandomGeneration => null,
Support => (0, infinity),
Description => "a discrete probability distribution"})
discreteProbabilityDistribution Function := o -> f -> (
checkSupport o.Support;
a := first o.Support;
cdf := if o.DistributionFunction =!= null
then o.DistributionFunction
else x -> sum(a..floor x, f);
quant := if o.QuantileFunction =!= null
then o.QuantileFunction
else p -> (
x := a;
q := f x;
while q < p do (
x = x + 1;
q = q + f x);
x);
rand := if o.RandomGeneration =!= null
then o.RandomGeneration
else () -> quant random 1.;
DiscreteProbabilityDistribution hashTable {
DensityFunction => f,
DistributionFunction => cdf,
QuantileFunction => quant,
RandomGeneration => rand,
Support => o.Support,
Description => o.Description})
density(DiscreteProbabilityDistribution, Number) :=
density(DiscreteProbabilityDistribution, Constant) := (X, x) ->
if x != floor x then 0 else density'(X, x)
probability(DiscreteProbabilityDistribution, Number) :=
probability(DiscreteProbabilityDistribution, Constant) := o -> (X, x) ->
probability'(X, floor x, o)
quantile(DiscreteProbabilityDistribution, Number) :=
quantile(DiscreteProbabilityDistribution, Constant) := o -> (X, p) -> (
maybefloor := x -> if isInfinite x then x else floor x;
maybefloor quantile'(X, p, o))
binomialDistribution = method()
binomialDistribution(ZZ, Number) :=
binomialDistribution(ZZ, Constant) := (n, p) -> (
checkPositive n;
checkProbability p;
discreteProbabilityDistribution(
x -> binomial(n, x) * p^x * (1 - p)^(n - x),
DistributionFunction => x -> regularizedBeta(1 - p, n - x, x + 1),
Support => (0, n),
Description => "B" | toString (n, p)))
bernoulliDistribution = method()
bernoulliDistribution Number :=
bernoulliDistribution Constant := p -> binomialDistribution(1, p)
poissonDistribution = method()
poissonDistribution Number :=
poissonDistribution Constant := lambda -> (
checkPositive lambda;
discreteProbabilityDistribution(x -> lambda^x / x! * exp(-lambda),
DistributionFunction => x -> regularizedGamma(floor(x + 1), lambda),
Description => "Pois(" | toString lambda | ")"))
geometricDistribution = method()
geometricDistribution Number :=
geometricDistribution Constant := p -> (
checkProbability p;
discreteProbabilityDistribution(x -> p * (1 - p)^x,
DistributionFunction => x -> 1 - (1 - p)^(x + 1),
QuantileFunction => q -> ceiling(log((1 - q)/(1 - p)) / log(1 - p)),
Description => "Geo(" | toString p | ")"))
negativeBinomialDistribution = method()
negativeBinomialDistribution(Number, Number) :=
negativeBinomialDistribution(Number, Constant) :=
negativeBinomialDistribution(Constant, Number) :=
negativeBinomialDistribution(Constant, Constant) := (r, p) -> (
checkPositive r;
checkProbability p;
discreteProbabilityDistribution(
x -> Gamma(x + r) / (Gamma r * x!) * p^r * (1 - p)^x,
DistributionFunction => x -> regularizedBeta(p, r, x + 1),
Description => "NB" | toString(r, p)))
hypergeometricDistribution = method()
hypergeometricDistribution(ZZ, ZZ, ZZ) := (m, n, k) -> (
checkNonnegative m;
checkNonnegative n;
checkNonnegative k;
if k > m + n then error(
"expected parameter to be at most ", m + n, ": ", k);
discreteProbabilityDistribution(
x -> binomial(m, x) * binomial(n, k - x) / binomial(m + n, k),
Support => (0, m),
Description => "HG" | toString(m, n, k)))
------------------------------------------
-- continuous probability distributions --
------------------------------------------
ContinuousProbabilityDistribution = new SelfInitializingType of
ProbabilityDistribution
ContinuousProbabilityDistribution.synonym =
"continuous probability distribution"
continuousProbabilityDistribution = method(Options => {
DistributionFunction => null,
QuantileFunction => null,
RandomGeneration => null,
Support => (0, infinity),
Description => "a continuous probability distribution"})
bisectionMethod = (f, a, b, epsilon) -> (
while b - a > epsilon do (
mid := 0.5 * (a + b);
if f(mid) == 0 then break
else if f(a) * f(mid) > 0 then a = mid
else b = mid);
0.5 * (a + b))
continuousProbabilityDistribution Function := o -> f -> (
checkSupport o.Support;
(a, b) := o.Support;
cdf := if o.DistributionFunction =!= null
then o.DistributionFunction
else x -> integrate(f, a, x);
quant := if o.QuantileFunction =!= null
then o.QuantileFunction
else p -> (
c := if a > -infinity then a else 0;
while cdf c > p do c = c - 1;
d := if b < infinity then b else 0;
while cdf d < p do d = d + 1;
bisectionMethod(x -> cdf x - p, c, d, 1e-14));
rand := if o.RandomGeneration =!= null
then o.RandomGeneration
else () -> quant random 1.;
ContinuousProbabilityDistribution hashTable {
DensityFunction => f,
DistributionFunction => cdf,
QuantileFunction => quant,
RandomGeneration => rand,
Support => o.Support,
Description => o.Description})
uniformDistribution = method()
uniformDistribution(Number, Number) :=
uniformDistribution(Number, Constant) :=
uniformDistribution(Constant, Number) :=
uniformDistribution(Constant, Constant) := (a, b) -> (
checkReal a;
checkReal b;
if a >= b then error("expected parameters to be in increasing order: ",
a, ", ", b);
continuousProbabilityDistribution(
x -> 1/(b - a),
DistributionFunction => x -> (x - a) / (b - a),
QuantileFunction => p -> a + p * (b - a),
Support => (a, b),
Description => "U" | toString (a, b)))
installMethod(uniformDistribution, () -> uniformDistribution(0, 1))
exponentialDistribution = method()
exponentialDistribution Number :=
exponentialDistribution Constant := lambda -> (
checkPositive lambda;
continuousProbabilityDistribution(
x -> lambda * exp(-lambda * x),
DistributionFunction => x -> 1 - exp(-lambda * x),
QuantileFunction => p -> -log(1 - p) / lambda,
Description => "Exp(" | toString lambda | ")"))
normalDistribution = method()
normalDistribution(Number, Number) :=
normalDistribution(Number, Constant) :=
normalDistribution(Constant, Number) :=
normalDistribution(Constant, Constant) := (mu, sigma) -> (
checkReal mu;
checkPositive sigma;
continuousProbabilityDistribution(
x -> 1 / (sigma * sqrt(2 * pi)) * exp(-1/2 * ((x - mu) / sigma)^2),
DistributionFunction => x ->
1/2 * (1 + erf((x - mu) / (sigma * sqrt 2))),
QuantileFunction => p ->
mu + sigma * sqrt 2 * inverseErf(2 * p - 1),
-- box muller transform
RandomGeneration => () ->
mu + sigma * sqrt(-2 * log random 1.) * cos (2 * pi * random 1.),
Support => (-infinity, infinity),
Description => "N" | toString (mu, sigma)))
-- standard normal distribution
installMethod(normalDistribution, () -> normalDistribution(0, 1))
gammaDistribution = method()
gammaDistribution(Number, Number) :=
gammaDistribution(Number, Constant) :=
gammaDistribution(Constant, Number) :=
gammaDistribution(Constant, Constant) := (alpha, lambda) -> (
checkPositive alpha;
checkPositive lambda;
continuousProbabilityDistribution(
x -> lambda^alpha / Gamma(alpha) * x^(alpha - 1) * exp(-lambda * x),
DistributionFunction => x -> 1 - regularizedGamma(alpha, lambda * x),
QuantileFunction => p -> inverseRegularizedGamma(alpha, 1 - p) / lambda,
Description => "Gamma" | toString (alpha, lambda)))
chiSquaredDistribution = method()
chiSquaredDistribution Number :=
chiSquaredDistribution Constant := n -> (
checkPositive n;
continuousProbabilityDistribution(
x -> 1/(2^(n/2) * Gamma(n/2)) * x^(n/2 - 1) * exp(-x / 2),
DistributionFunction => x -> 1 - regularizedGamma(n / 2, x / 2),
QuantileFunction => p -> 2 * inverseRegularizedGamma(n / 2, 1 - p),
Description => "chi2(" | toString n | ")"))
tDistribution = method()
tDistribution Number :=
tDistribution Constant := df -> (
checkPositive df;
continuousProbabilityDistribution(
x -> Gamma((df + 1)/2) / (sqrt(df * pi) * Gamma(df / 2)) *
(1 + x^2/df)^(-(df + 1) / 2),
DistributionFunction => x -> (
p := 1 - 1/2*regularizedBeta(df/(x^2 + df), df/2, 1/2);
if x >= 0 then p else 1 - p),
QuantileFunction => p -> (if p >= 0.5
then sqrt(df / inverseRegularizedBeta(2 - 2 * p, df/2, 1/2) - df)
else -sqrt(df / inverseRegularizedBeta(2 * p, df/2, 1/2) - df)),
Support => (-infinity, infinity),
Description => "t(" | toString df | ")"))
fDistribution = method()
fDistribution(Number, Number) :=
fDistribution(Number, Constant) :=
fDistribution(Constant, Number) :=
fDistribution(Constant, Constant) := (d1, d2) -> (
checkPositive d1;
checkPositive d2;
continuousProbabilityDistribution(
x -> sqrt(
(d1 * x)^d1 * d2^d2 / (d1*x + d2)^(d1 + d2)) /
(x * Beta(d1 / 2, d2 / 2)),
DistributionFunction => x ->
regularizedBeta(d1 * x / (d1 * x + d2), d1 / 2, d2 / 2),
QuantileFunction => p ->
d2 / d1 * (1 / (1 - inverseRegularizedBeta(p, d1 / 2, d2 / 2)) - 1),
Description => "F" | toString (d1, d2)))
betaDistribution = method()
betaDistribution(Number, Number) :=
betaDistribution(Number, Constant) :=
betaDistribution(Constant, Number) :=
betaDistribution(Constant, Constant) := (alpha, beta) -> (
checkPositive alpha;
checkPositive beta;
continuousProbabilityDistribution(
x -> x^(alpha - 1) * (1 - x)^(beta - 1) / Beta(alpha, beta),
DistributionFunction => x -> regularizedBeta(x, alpha, beta),
QuantileFunction => p -> inverseRegularizedBeta(p, alpha, beta),
Support => (0, 1),
Description => "Beta" | toString(alpha, beta)))
beginDocumentation()
doc ///
Key
Probability
Headline
basic probability functions
Description
Text
This package provides a number of basic probability functions. In
particular, for both discrete and continuous probability distributions,
there are the following four functions:
@UL {
LI {TO density, ": probability density (or mass) function"},
LI {TO probability, ": cumulative distribution function"},
LI {TO quantile, ": quantile function"},
LI {TO (random, ProbabilityDistribution),
": generate random samples"}}@
A variety of common probability distributions are supported.
@HEADER3 "Discrete distributions"@
@UL {
LI {TO2 {binomialDistribution, "binomial"}},
LI {TO2 {poissonDistribution, "Poisson"}},
LI {TO2 {geometricDistribution, "geometric"}},
LI {TO2 {negativeBinomialDistribution, "negative binomial"}},
LI {TO2 {hypergeometricDistribution, "hypergeometric"}}}@
@HEADER3 "Continuous distributions"@
@UL {
LI {TO2 {uniformDistribution, "uniform"}},
LI {TO2 {exponentialDistribution, "exponential"}},
LI {TO2 {normalDistribution, "normal"}},
LI {TO2 {gammaDistribution, "gamma"}},
LI {TO2 {chiSquaredDistribution, "chi-squared"}},
LI {TO2 {tDistribution, "Student's t"}},
LI {TO2 {fDistribution, "F"}},
LI {TO2 {betaDistribution, "beta"}}}@
You may also define your own probability distributions using
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@.
Caveat
As is always the case when working with real numbers in Macaulay2,
unexpected results may occur due to the limitations of floating
point arithmetic.
///
doc ///
Key
ProbabilityDistribution
DiscreteProbabilityDistribution
ContinuousProbabilityDistribution
(net, ProbabilityDistribution)
Headline
probability distribution class
Description
Text
This is the class of which all probability distribution objects
belong. @TT "ProbabilityDistribution"@ is an abstract class
defining the interface and should not be used directly.
Instead, its subclasses @TT "DiscreteProbabilityDistribution"@ and
@TT "ContinuousProbabilityDistribution"@ should be used.
@TT "ProbabilityDistribution"@ objects are hash tables containing six
key-value pairs:
@DL{
DT {TT "DensityFunction"},
DD {"The probability mass or density function (for discrete or ",
"continuous distributions, respectively). Do not use this ",
"directly. Instead, use ", TO density, "."},
DT {TT "DistributionFunction"},
DD {"The cumulative distribution function. Do not use this ",
"directly. Instead, use ", TO probability, "."},
DT {TT "QuantileFunction"},
DD {"The quantile function. Do not use this directly. Instead, ",
"use ", TO quantile, "."},
DT {TT "RandomGeneration"},
DD {"A function to generate random samples of the distribution. ",
"Do not use this directly. Instead, use ",
TO (random, ProbabilityDistribution), "."},
DT {TT "Support"},
DD {"A sequence of two numbers, the lower and upper bound of the ",
"support of the distribution."},
DT {TT "Description"},
DD {"A string containing a description of the distribution. This ",
"is the return value when a ", TT "ProbabilityDistribution",
" object is passed to ", TO net, "."}
}@
Example
Z = normalDistribution()
ancestors class Z
peek Z
Text
To create a @TT "ProbablityDistribution"@ object, use one of the
constructor methods, @TO discreteProbabilityDistribution@,
@TO continuousProbabilityDistribution@, or any of the various built-in
methods for common distributions.
///
doc ///
Key
DensityFunction
Headline
probability density function
Description
Text
A key in @TO ProbabilityDistribution@ objects and an option for
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@ for setting the probability
density/mass function to be used by @TO density@.
///
doc ///
Key
DistributionFunction
Headline
cumulative density function
Description
Text
A key in @TO ProbabilityDistribution@ objects and an option for
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@ for setting the cumulative
distribution function to be used by @TO probability@.
///
doc ///
Key
QuantileFunction
Headline
quantile function
Description
Text
A key in @TO ProbabilityDistribution@ objects and an option for
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@ for setting the quantile function
to be used by @TO quantile@.
///
doc ///
Key
RandomGeneration
Headline
random generation function
Description
Text
A key in @TO ProbabilityDistribution@ objects and an option for
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@ for setting the random generation
function to be used by @TO (random, ProbabilityDistribution)@.
///
doc ///
Key
Support
Headline
support for probability distribution
Description
Text
A key in @TO ProbabilityDistribution@ objects and an option for
@TO discreteProbabilityDistribution@ and
@TO continuousProbabilityDistribution@ for setting the support of
the probability distribution.
///
doc ///
Key
density
(density, ProbabilityDistribution, Number)
(density, ProbabilityDistribution, Constant)
(density, DiscreteProbabilityDistribution, Number)
(density, DiscreteProbabilityDistribution, Constant)
Headline
probability density (or mass) function
Usage
density_X x
Inputs
X:ProbabilityDistribution
x:RR
Outputs
:RR
Description
Text
For a discrete probability distribution, this returns values of
of the @wikipedia "probability mass function"@ of the distribution, i.e.,
\(f_X(x) = P(X = x)\).
Example
X = binomialDistribution(5, 0.25)
density_X 2
binomial(5, 2) * 0.25^2 * 0.75^3
Text
For a continuous probability distribution, this returns values of
the @wikipedia "probability density function"@ of the distribution, i.e.,
the integrand in \(\int_a^b f_X(x)\,dx = P(a\leq X \leq b)\).
Example
Z = normalDistribution()
density_Z 0
1/sqrt(2 * pi)
integrate(density_Z, -1, 1)
integrate(density_Z, -2, 2)
integrate(density_Z, -3, 3)
///
doc ///
Key
LowerTail
Headline
whether to computer lower tail probabilities
Description
Text
This is an option for @TO probability@ and @TO quantile@.
///
doc ///
Key
probability
(probability, ProbabilityDistribution, Number)
(probability, ProbabilityDistribution, Constant)
(probability, DiscreteProbabilityDistribution, Number)
(probability, DiscreteProbabilityDistribution, Constant)
[probability, LowerTail]
Headline
cumulative distribution function
Usage
probability_X x
Inputs
X:ProbabilityDistribution
x:RR
LowerTail => Boolean
Outputs
:RR
Description
Text
The @wikipedia "cumulative distribution function"@ of the probability
distribution, i.e., the lower tail probability \(F_X(x) = P(X \leq x)\).
Example
Z = normalDistribution()
probability_Z 1.96
Text
If the @TT "LowerTail"@ option is @TT "false"@, then it instead computes
the value of the @wikipedia "survival function"@, i.e., the upper tail
probability \(S_X(x) = P(X > x)\).
Example
probability_Z(1.96, LowerTail => false)
///
doc ///
Key
quantile
(quantile, ProbabilityDistribution, Number)
(quantile, ProbabilityDistribution, Constant)
(quantile, DiscreteProbabilityDistribution, Number)
(quantile, DiscreteProbabilityDistribution, Constant)
[quantile, LowerTail]
Headline
quantile function
Usage
quantile_X p
Inputs
X:ProbabilityDistribution
p:RR
LowerTail => Boolean
Outputs
:RR
Description
Text
For continuous probability distributions, the @wikipedia
"quantile function"@ is the inverse of the cumulative
distribution function, i.e., \(x\) for which \(P(X \leq x) = p\).
Example
Z = normalDistribution()
quantile_Z 0.95
probability_Z oo
Text
For discrete probability distributions, it returns the smallest \(x\)
for which \(P(X \leq x) \geq p\).
Example
X = binomialDistribution(10, 0.25)
quantile_X 0.75
probability_X 2
probability_X 3
Text
If the @TT "LowerTail"@ option is @TT "false"@, then it instead finds
\(x\) for which \(P(X > x) = p\) in the continuous case.
Example
quantile_Z(0.95, LowerTail => false)
probability_Z(oo, LowerTail => false)
Text
In the discrete case, it finds the smallest \(x\) for which
\(P(X > x) \leq p\).
Example
quantile_X(0.75, LowerTail => false)
probability_X(2, LowerTail => false)
probability_X(1, LowerTail => false)
///
doc ///
Key
(random, ProbabilityDistribution)
Headline
randomly generate samples from probability distribution
Usage
random X
Inputs
X:ProbabilityDistribution
Outputs
:RR
Description
Text
Randomly generate samples from the given probability distribution.
Example
Z = normalDistribution()
for i to 10 list random Z
///
doc ///
Key
discreteProbabilityDistribution
(discreteProbabilityDistribution, Function)
[discreteProbabilityDistribution, DistributionFunction]
[discreteProbabilityDistribution, QuantileFunction]
[discreteProbabilityDistribution, RandomGeneration]
[discreteProbabilityDistribution, Support]
[discreteProbabilityDistribution, Description]
Headline
construct a discrete probability distribution
Usage
discreteProbabilityDistribution f
Inputs
f:Function
the probability mass function of @TT "X"@, to be used by
@TO density@.
DistributionFunction => Function
the cumulative distribution function of @TT "X"@, to be used by
@TO probability@. If @TT "null"@, then obtained by adding values of
@TT "f"@.
QuantileFunction => Function
the quantile function of @TT "X"@, to be used by @TO quantile@.
If @TT "null"@, then obtained by adding values of @TT "f"@.
RandomGeneration => Function
a function for generating random samples from @TT "X"@, to be used
by @TO (random, ProbabilityDistribution)@. If @TT "null"@, then obtained
using @wikipedia "inverse transform sampling"@.
Support => Sequence
containing the lower and upper bounds, respectively, of the
@wikipedia("Support (mathematics)", "support")@ of @TT "X"@.
Elements of the support are assumed to be integers.
Description => String
describing the probability distribution.
Outputs
X:DiscreteProbabilityDistribution
Description
Text
To construct a discrete probability distribution, provide the probability
mass function and, if different than the default of \([0, \infty\]), the
support.
Example
X = discreteProbabilityDistribution(x -> 1/6, Support => (1, 6))
density_X 3
Text
Non-integers and values outside the support are automatically sent to 0.
Example
density_X 3.5
density_X 7
Text
The cumulative distribution, quantile, and random generation functions
are set to defaults based on the probability mass function.
Example
probability_X 3
quantile_X 0.2
random X
Text
However, if possible, it is good to provide these directly to
improve performance. A description may also be provided.
Example
X = discreteProbabilityDistribution(x -> 1/6, Support => (1, 6),
DistributionFunction => x -> x / 6,
QuantileFunction => p -> 6 * p,
Description => "six-sided die")
Caveat
When defining a probability mass function, the user must be careful that
it satisfies the definition, i.e., it must be nonnegative and its values
must sum to 1 on its support.
///
doc ///
Key
continuousProbabilityDistribution
(continuousProbabilityDistribution, Function)
[continuousProbabilityDistribution, DistributionFunction]
[continuousProbabilityDistribution, QuantileFunction]
[continuousProbabilityDistribution, RandomGeneration]
[continuousProbabilityDistribution, Support]
[continuousProbabilityDistribution, Description]
Headline
construct a continuous probability distribution
Usage
continuousProbabilityDistribution f
Inputs
f:Function
the probability density function of @TT "X"@, to be used by
@TO density@.
DistributionFunction => Function
the cumulative distribution function of @TT "X"@, to be used by
@TO probability@. If @TT "null"@, then obtained by numerically
integrating @TT "f"@.
QuantileFunction => Function
the quantile function of @TT "X"@, to be used by @TO quantile@.
If @TT "null"@, then obtained by using the @wikipedia "bisection method"@.
RandomGeneration => Function
a function for generating random samples from @TT "X"@, to be used
by @TO (random, ProbabilityDistribution)@. If @TT "null"@, then obtained
using @wikipedia "inverse transform sampling"@.
Support => Sequence
containing the lower and upper bounds, respectively, of the
@wikipedia("Support (mathematics)", "support")@ of @TT "X"@.
Description => String
describing the probability distribution.
Outputs
X:ContinuousProbabilityDistribution
Description
Text
To construct a continuous probability distribution, provide the
probability density function and, if different than the default
of \([0, \infty\]), the support.
Example
X = continuousProbabilityDistribution(x -> 2 * x, Support => (0, 1))
density_X 0.75
Text
Values outside the support are automatically sent to 0.
Example
density_X 2
Text
The cumulative distribution, quantile, and random generation functions
are set to defaults based on the probability density function.
Example
probability_X 0.75
quantile_X 0.5625
random X
Text
However, if possible, it is good to provide these directly to
improve performance. A description may also be provided.
Example
X = continuousProbabilityDistribution(x -> 2 * x, Support => (0, 1),
DistributionFunction => x -> x^2,
QuantileFunction => p -> sqrt p,
Description => "triangular distribution")
Caveat
When defining a probability density function, the user must be careful that
it satisfies the definition, i.e., it must be nonnegative and it must
integrate to 1 on its support.
///
doc ///
Key
binomialDistribution
(binomialDistribution, ZZ, Number)
(binomialDistribution, ZZ, Constant)
bernoulliDistribution
(bernoulliDistribution, Number)
(bernoulliDistribution, Constant)
Headline
binomial distribution
Usage
binomialDistribution(n, p)
bernoulliDistribution p
Inputs
n:ZZ
p:Number -- between 0 and 1
Outputs
:DiscreteProbabilityDistribution
Description
Text
The @wikipedia "binomial distribution"@, the distribution of the number
of successes in a sequence of @TT "n"@ Bernoulli trials, where the
probability of success is @TT "p"@.
Example
X = binomialDistribution(10, 0.1)
density_X 2
probability_X 3
quantile_X 0.4
random X
Text
A special case is the @wikipedia "Bernoulli distribution"@, where
@TT "n"@ is 1.
Example
Y = bernoulliDistribution 0.1
///
doc ///
Key
poissonDistribution
(poissonDistribution, Number)
(poissonDistribution, Constant)
Headline
Poisson distribution
Usage
poissonDistribution lambda
Inputs
lambda:Number -- the rate parameter
Outputs
:DiscreteProbabilityDistribution
Description
Text
The @wikipedia "Poisson distribution"@, the distribution of the number
of events to occur during some interval of time when the expected number
of events is @TT "lambda"@.
Example
X = poissonDistribution 10
density_X 2
probability_X 3
quantile_X 0.4
random X
///
doc ///
Key
geometricDistribution
(geometricDistribution, Number)
(geometricDistribution, Constant)
Headline
geometric distribution
Usage
geometricDistribution p
Inputs
p:Number -- between 0 and 1
Outputs
:DiscreteProbabilityDistribution
Description
Text
The @wikipedia "geometric distribution"@, the distribution of the number
of a failures in a sequence of Bernoulli trials before the first success,
where @TT "p"@ is the probability of a success.
Example
X = geometricDistribution 0.1
density_X 2
probability_X 3
quantile_X 0.4
random X
Caveat
Some probability texts define the geometric distribution as the number
of Bernoulli trials until the first success, and so the values will be
one greater than ours. Our definition is consistent with R.
///
doc ///
Key
negativeBinomialDistribution
(negativeBinomialDistribution, Number, Number)
(negativeBinomialDistribution, Number, Constant)
(negativeBinomialDistribution, Constant, Number)
(negativeBinomialDistribution, Constant, Constant)
Headline
negative binomial distribution
Usage
negativeBinomialDistribution(r, p)
Inputs
r:Number -- positive
p:Number -- between 0 and 1
Outputs
:DiscreteProbabilityDistribution
Description
Text
The @wikipedia "negative binomial distribution"@, the distribution of
the number of failures in a sequence of Bernoulli trials (with probability
of success @TT "p"@) until the @TT "r"@th success.
Example
X = negativeBinomialDistribution(5, 0.1)
density_X 20
probability_X 30
quantile_X 0.4
random X
Caveat
Probability texts define the negative binomial distribution in a variety
of different ways. Our definition is consistent with R.
///
doc ///
Key
hypergeometricDistribution
(hypergeometricDistribution, ZZ, ZZ, ZZ)
Headline
hypergeometric distribution
Usage
hypergeometricDistribution(m, n, k)
Inputs
m:ZZ -- nonnegative
n:ZZ -- nonnegative
k:ZZ -- between 0 and @TT "m + n"@
Outputs