Continuation of polar axis

CairoMakie/src/overrides.jl

@@ -115,7 +115,7 @@ draw_poly(scene::Scene, screen::Screen, poly, circle::Circle) = draw_poly(scene,
 function draw_poly(scene::Scene, screen::Screen, poly, polygons::AbstractArray{<:Polygon})
     model = poly.model[]
     space = to_value(get(poly, :space, :data))
-    projected_polys = project_polygon.(Ref(scene), space, polygons, Ref(model))
+    projected_polys = project_polygon.(Ref(poly), space, polygons, Ref(model))
 
     color = to_cairo_color(poly.color[], poly)
     strokecolor = to_cairo_color(poly.strokecolor[], poly)

CairoMakie/src/utils.jl

@@ -2,13 +2,13 @@
 #                             Projection utilities                             #
 ################################################################################
 
-function project_position(scene, transform_func::T, space, point, model, yflip::Bool = true) where T
+function project_position(scene::Scene, transform_func::T, space, point, model::Mat4, yflip::Bool = true) where T
     # use transform func
     point = Makie.apply_transform(transform_func, point, space)
     _project_position(scene, space, point, model, yflip)
 end
 
-function _project_position(scene, space, point, model, yflip)
+function _project_position(scene::Scene, space, point, model, yflip::Bool)
     res = scene.camera.resolution[]
     p4d = to_ndim(Vec4f, to_ndim(Vec3f, point, 0f0), 1f0)
     clip = Makie.space_to_clip(scene.camera, space) * model * p4d
@@ -24,8 +24,9 @@ function _project_position(scene, space, point, model, yflip)
     return p_0_to_1 .* res
 end
 
-function project_position(scene, space, point, model, yflip::Bool = true)
-    project_position(scene, scene.transformation.transform_func[], space, point, model, yflip)
+function project_position(scenelike, space, point, model, yflip::Bool = true)
+    scene = Makie.get_scene(scenelike)
+    project_position(scene, Makie.transform_func(scenelike), space, point, model, yflip)
 end
 
 function project_scale(scene::Scene, space, s::Number, model = Mat4f(I))
@@ -46,23 +47,23 @@ function project_scale(scene::Scene, space, s, model = Mat4f(I))
     end
 end
 
-function project_rect(scene, space, rect::Rect, model)
-    mini = project_position(scene, space, minimum(rect), model)
-    maxi = project_position(scene, space, maximum(rect), model)
+function project_rect(scenelike, space, rect::Rect, model)
+    mini = project_position(scenelike, space, minimum(rect), model)
+    maxi = project_position(scenelike, space, maximum(rect), model)
     return Rect(mini, maxi .- mini)
 end
 
-function project_polygon(scene, space, poly::P, model) where P <: Polygon
+function project_polygon(scenelike, space, poly::P, model) where P <: Polygon
     ext = decompose(Point2f, poly.exterior)
     interiors = decompose.(Point2f, poly.interiors)
     Polygon(
-        Point2f.(project_position.(Ref(scene), space, ext, Ref(model))),
-        [Point2f.(project_position.(Ref(scene), space, interior, Ref(model))) for interior in interiors],
+        Point2f.(project_position.(Ref(scenelike), space, ext, Ref(model))),
+        [Point2f.(project_position.(Ref(scenelike), space, interior, Ref(model))) for interior in interiors],
     )
 end
 
-function project_multipolygon(scene, space, multipoly::MP, model) where MP <: MultiPolygon
-    return MultiPolygon(project_polygon.(Ref(scene), Ref(space), multipoly.polygons, Ref(model)))
+function project_multipolygon(scenelike, space, multipoly::MP, model) where MP <: MultiPolygon
+    return MultiPolygon(project_polygon.(Ref(scenelike), Ref(space), multipoly.polygons, Ref(model)))
 end
 
 scale_matrix(x, y) = Cairo.CairoMatrix(x, 0.0, 0.0, y, 0.0, 0.0)

NEWS.md

@@ -2,6 +2,8 @@
 
 ## master
 
+- Added a new Axis type, `PolarAxis`, which is an axis with a polar projection.  Input is in `(r, theta)` coordinates and is transformed to `(x, y)` coordinates using the standard polar-to-cartesian transformation.  Generally, its attributes are very similar to the usual `Axis` attributes, but `x` is replaced by `r` and `y` by `θ`.  It also inherits from the theme of `Axis` in this manner, so should work seamlessly with Makie themes. [#2990](https://github.com/MakieOrg/Makie.jl/pull/2990)
+- `inherit` now has a new signature `inherit(scene, attrs::NTuple{N, Symbol}, default_value)`, allowing recipe authors to access nested attributes when trying to inherit from the parent Scene.  For example, one could inherit from `scene.Axis.yticks` by `inherit(scene, (:Axis, :yticks), $default_value)`. [#2990](https://github.com/MakieOrg/Makie.jl/pull/2990)
 - Deprecated `flatten_plots` in favor of `collect_atomic_plots`. Using the new `collect_atomic_plots` fixed a bug in CairoMakie where the z-level of plots within recipes was not respected. [#2793](https://github.com/MakieOrg/Makie.jl/pull/2793)
 - Fixed incorrect line depth in GLMakie [#2843](https://github.com/MakieOrg/Makie.jl/pull/2843)
 - Fixed incorrect line alpha in dense lines in GLMakie [#2843](https://github.com/MakieOrg/Makie.jl/pull/2843)
@@ -165,7 +167,7 @@ role as `datalimits` in `violin` [#2137](https://github.com/MakieOrg/Makie.jl/pu
 
 ## v0.17.7
 
-- Improved `Menu` performance, now it should me much harder to reach the boundary of 255 scenes in GLMakie. `Menu` also takes a `default` keyword argument now and can be scrolled if there is too little space available.
+- Improved `Menu` performance, now it should be much harder to reach the boundary of 255 scenes in GLMakie. `Menu` also takes a `default` keyword argument now and can be scrolled if there is too little space available.
 
 ## v0.17.6
 

ReferenceTests/src/tests/figures_and_makielayout.jl

@@ -136,3 +136,49 @@ end
     surface!(ax, xs, ys, zs)
     fig
 end
+
+@reference_test "PolarAxis surface" begin
+    f = Figure()
+    ax = PolarAxis(f[1, 1])
+    zs = [r*cos(phi) for r in range(1, 2, length=100), phi in range(0, 4pi, length=100)]
+    p = surface!(ax, 0..10, 0..2pi, zs, shading = false, colormap = :coolwarm, colorrange=(-2, 2))
+    Colorbar(f[1, 2], p)
+    f
+end
+
+# may fail in WGLMakie due to missing dashes
+@reference_test "PolarAxis scatterlines spine" begin
+    f = Figure(resolution = (800, 400))
+    ax1 = PolarAxis(f[1, 1], title = "No spine", spinevisible = false)
+    scatterlines!(ax1, range(0, 1, length=100), range(0, 10pi, length=100), color = 1:100)
+
+    ax2 = PolarAxis(f[1, 2], title = "Modified spine")
+    ax2.spinecolor[] = :red
+    ax2.spinestyle[] = :dash
+    ax2.spinewidth[] = 5
+    scatterlines!(ax2, range(0, 1, length=100), range(0, 10pi, length=100), color = 1:100)
+
+    f
+end
+
+# may fail in CairoMakie due to different text stroke handling
+# and in WGLMakie due to missing stroke
+@reference_test "PolarAxis decorations" begin
+    f = Figure(resolution = (400, 400), backgroundcolor = :black)
+    ax = PolarAxis(
+        f[1, 1], 
+        backgroundcolor = :black,
+        rminorgridvisible = true, rminorgridcolor = :red, 
+        rminorgridwidth = 1.0, rminorgridstyle = :dash,
+        thetaminorgridvisible = true, thetaminorgridcolor = :blue,
+        thetaminorgridwidth = 1.0, thetaminorgridstyle = :dash,
+        rgridwidth = 2, rgridcolor = :red,
+        thetagridwidth = 2, thetagridcolor = :blue,
+        rticklabelsize = 18, rticklabelcolor = :red,
+        rticklabelstrokewidth = 1, rticklabelstrokecolor = :white,
+        thetaticklabelsize = 18, thetaticklabelcolor = :blue,
+        thetaticklabelstrokewidth = 1, thetaticklabelstrokecolor = :white,
+    )
+
+    f
+end

docs/examples/blocks/polaraxis.md

@@ -0,0 +1,125 @@
+# PolarAxis
+
+The `PolarAxis` is an axis for data in polar coordinates `(radius, angle)`. It 
+is currently an experimental feature, meaning that some functionality might be
+missing or broken, and that the `PolarAxis` is (more) open to breaking changes.
+
+## Creating a PolarAxis
+
+Creating a `PolarAxis` works the same way as creating an `Axis`.
+
+\begin{examplefigure}{svg = true}
+```julia
+using CairoMakie
+CairoMakie.activate!() # hide
+
+f = Figure()
+
+ax = PolarAxis(f[1, 1], title = "Title")
+
+f
+```
+\end{examplefigure}
+
+## Plotting into an PolarAxis
+
+Like with an `Axis` you can use mutating 2D plot functions directly on a 
+`PolarAxis`. The input arguments of the plot functions will then be interpreted
+in polar coordinates, i.e. as a radius and angle (in radians).
+
+\begin{examplefigure}{svg = true}
+```julia
+lineobject = lines!(ax, 0..10, sin, color = :red)
+scatobject = scatter!(0:0.5:10, cos, color = :orange)
+
+f
+```
+\end{examplefigure}
+
+Note that not every plot type is compatible with polar transforms. For example 
+`image` is not as it expects to be drawn on a rectangle. `heatmap` works to a 
+degree in CairoMakie, but not GLMakie due to differences in the backend 
+implementation. `surface` works in both, as it is designed to generate a 
+triangle mesh.
+
+\begin{examplefigure}{svg = false}
+```julia
+f = Figure()
+ax = PolarAxis(f[1, 1])
+# The first two arguments should be set to a sensible radial and angular range
+zs = [r*cos(phi) for r in range(1, 2, length=100), phi in range(0, 4pi, length=100)]
+p = surface!(ax, 0..10, 0..2pi, zs, shading = false, colormap = :coolwarm, colorrange=(-2, 2))
+Colorbar(f[1, 2], p)
+f
+```
+\end{examplefigure}
+
+## Hiding spines and decorations
+
+For a `PolarAxis` we interpret the outer ring limitting the plotting are as the
+axis spine. You can manipulate it with the `spine...` attributes.
+
+\begin{examplefigure}{svg = true}
+```julia
+f = Figure(resolution = (800, 400))
+ax1 = PolarAxis(f[1, 1], title = "No spine", spinevisible = false)
+scatterlines!(ax1, range(0, 1, length=100), range(0, 10pi, length=100), color = 1:100)
+
+ax2 = PolarAxis(f[1, 2], title = "Modified spine")
+ax2.spinecolor[] = :red
+ax2.spinestyle[] = :dash
+ax2.spinewidth[] = 5
+scatterlines!(ax2, range(0, 1, length=100), range(0, 10pi, length=100), color = 1:100)
+
+f
+```
+\end{examplefigure}
+
+Decorations such as grid lines and tick labels can be adjusted through 
+attributes in much the same way.
+
+\begin{examplefigure}{svg = true}
+```julia
+f = Figure(resolution = (600, 600), backgroundcolor = :black)
+ax = PolarAxis(
+    f[1, 1], 
+    backgroundcolor = :black,
+    # r minor grid
+    rminorgridvisible = true, rminorgridcolor = :red, 
+    rminorgridwidth = 1.0, rminorgridstyle = :dash,
+    # theta minor grid
+    thetaminorgridvisible = true, thetaminorgridcolor = :lightblue,
+    thetaminorgridwidth = 1.0, thetaminorgridstyle = :dash,
+    # major grid
+    rgridwidth = 2, rgridcolor = :red,
+    thetagridwidth = 2, thetagridcolor = :lightblue,
+    # r labels
+    rticklabelsize = 18, rticklabelcolor = :red,
+    rticklabelstrokewidth = 1.0, rticklabelstrokecolor = :white,
+    # theta labels
+    thetaticklabelsize = 18, thetaticklabelcolor = :lightblue
+)
+
+f
+```
+\end{examplefigure}
+
+## Interactivity
+
+The `PolarAxis` currently implements zooming by scrolling and allows you to 
+reset the view with left control + left mouse button. You can change the key
+combination for resetting the view with the `reset_button` attribute, which 
+accepts anything `ispressed` accepts.
+
+Note that `PolarAxis` currently does not implement the interaction itnerface 
+used by `Axis`.
+
+## Other Notes
+
+### Plotting outside a PolarAxis
+
+Currently there is a scatter and poly plot outside the area of the `PolarAxis`
+which clips the content to the relevant area. If you want to draw outside the
+circle limiting the polar axis but still within it's scene area, you will need
+to translate those plots to a z range between `9000` and `10_000` or disable 
+clipping via the `clip` attribute.

src/layouting/transformation.jl

@@ -414,6 +414,57 @@ function is_identity_transform(t)
 end
 
 
+################################################################################
+### Polar Transformation
+################################################################################
+
+"""
+    Polar(theta_0::Float64 = 0.0, direction::Int = +1)
+
+This struct defines a general polar-to-cartesian transformation, i.e.,
+```math
+(r, theta) -> (r \\cos(direction * (theta + theta_0)), r \\sin(direction * (theta + theta_0)))
+```
+
+where theta is assumed to be in radians.
+
+`direction` should be either -1 or +1, and `theta_0` may be any value.
+"""
+struct Polar
+    theta_0::Float64
+    direction::Int
+    Polar(theta_0 = 0.0, direction = +1) = new(theta_0, direction)
+end
+
+Base.broadcastable(x::Polar) = (x,)
+
+function apply_transform(trans::Polar, point::VecTypes{2, T}) where T <: Real
+    y, x = point[1] .* sincos((point[2] + trans.theta_0) * trans.direction)
+    return Point2{T}(x, y)
+end
+
+# Point2 may get expanded to Point3. In that case we leave z untransformed
+function apply_transform(f::Polar, point::VecTypes{N2, T}) where {N2, T}
+    p_dim = to_ndim(Point2f, point, 0.0)
+    p_trans = apply_transform(f, p_dim)
+    if 2 < N2
+        p_large = ntuple(i-> i <= 2 ? p_trans[i] : point[i], N2)
+        return Point{N2, Float32}(p_large)
+    else
+        return to_ndim(Point{N2, Float32}, p_trans, 0.0)
+    end
+end
+
+function inverse_transform(trans::Polar)
+    return Makie.PointTrans{2}() do point
+        typeof(point)(
+            hypot(point[1], point[2]), 
+            mod(trans.direction * atan(point[2], point[1]) - trans.theta_0, 0..2pi)
+        )
+    end
+end
+
+
 # this is a simplification which will only really work with non-rotated or
 # scaled scene transformations, but for 2D scenes this should work well enough.
 # and this way we can use the z-value as a means to shift the drawing order

src/makielayout/MakieLayout.jl

@@ -21,6 +21,7 @@ include("lineaxis.jl")
 include("interactions.jl")
 include("blocks/axis.jl")
 include("blocks/axis3d.jl")
+include("blocks/polaraxis.jl")
 include("blocks/colorbar.jl")
 include("blocks/label.jl")
 include("blocks/slider.jl")
@@ -36,6 +37,7 @@ include("blocks/textbox.jl")
 
 export Axis
 export Axis3
+export PolarAxis
 export Slider
 export SliderGrid
 export IntervalSlider
@@ -60,7 +62,7 @@ export labelslider!, labelslidergrid!
 export addmouseevents!
 export interactions, register_interaction!, deregister_interaction!, activate_interaction!, deactivate_interaction!
 export MouseEventTypes, MouseEvent, ScrollEvent, KeysEvent
-# export hlines!, vlines!, abline!, hspan!, vspan!
+export hlines!, vlines!, abline!, hspan!, vspan!
 export Cycle
 export Cycled