-
Notifications
You must be signed in to change notification settings - Fork 22
/
Types.hs
480 lines (359 loc) · 13.1 KB
/
Types.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
{-# LANGUAGE GADTs #-}
{-# LANGUAGE RankNTypes #-}
{-# LANGUAGE KindSignatures #-}
{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE TemplateHaskell #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE ScopedTypeVariables #-}
module Magic.Types (
-- * Data structures
Bag,
-- * Reference types
PlayerRef, ObjectRef, ZoneRef(..),
-- * World
World(..), players, activePlayer, activeStep, time, turnStructure, exile, battlefield, stack, command,
-- * Turn structure
Step(..), BeginningStep(..), CombatStep(..), EndStep(..),
-- * Players
Player(..), life, manaPool, prestack, library, hand, graveyard, maximumHandSize, failedCardDraw,
-- * Objects
Card(..),
Object(..),
name, colors, types, owner, controller, timestamp, counters,
tapStatus,
stackItem,
power, toughness, damage, deathtouched,
play, staticKeywordAbilities, continuousEffects, activatedAbilities, triggeredAbilities, replacementEffects,
-- * Object properties
Timestamp, Color(..), TapStatus(..), CounterType(..),
-- * Object types
ObjectTypes(..), supertypes, artifactSubtypes, creatureSubtypes,
enchantmentSubtypes, instantSubtypes, landSubtypes,
planeswalkerSubtypes, sorcerySubtypes,
isObjectTypesSubsetOf,
Supertype(..), ArtifactSubtype(..), CreatureSubtype(..),
EnchantmentSubtype(..), SpellSubtype(..), LandSubtype(..),
PlaneswalkerSubtype(..),
-- * Abilities
Ability,
ClosedAbility(..), available, manaCost, additionalCosts, effect,
Action(..), StackItem, ManaCost(..), AdditionalCost(..),
StaticKeywordAbility(..), ContinuousEffect(..), Layer(..),
ReplacementEffect,
PriorityAction(..),
-- * Events
Event(..), OneShotEffect(..), SimpleOneShotEffect(..),
-- * Targets
Target(..), TargetList(..),
-- * Monads
ViewT, View, Magic, Engine,
view,
Ask(..)
) where
import Magic.IdList (Id, IdList)
import Control.Applicative
import Control.Monad.Identity
import Control.Monad.Random (RandT, StdGen)
import Control.Monad.Reader
import Control.Monad.State (StateT)
import qualified Control.Monad.Operational as Operational
import Data.Label (mkLabels)
import Data.Monoid
import Data.Set (Set)
import qualified Data.Set as Set
import Data.Text (Text)
-- DATA STRUCTURES
type Bag = []
-- REFERENCE TYPES
type PlayerRef = Id
type ObjectRef = (ZoneRef, Id)
data ZoneRef = Library PlayerRef | Hand PlayerRef | Battlefield | Graveyard PlayerRef | Stack | Exile | Command
deriving (Eq, Ord, Show)
-- WORLD
-- | Current game situation.
data World = World
{ _players :: IdList Player
, _activePlayer :: PlayerRef
, _activeStep :: Step
, _time :: Timestamp
, _turnStructure :: [(PlayerRef, [Step])]
, _exile :: IdList Object
, _battlefield :: IdList Object
, _stack :: IdList Object
, _command :: IdList Object
}
-- TURN STRUCTURE
data Step
= BeginningPhase BeginningStep
| MainPhase
| CombatPhase CombatStep
| EndPhase EndStep
deriving (Eq, Ord, Show, Read)
data BeginningStep
= UntapStep
| UpkeepStep
| DrawStep
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data CombatStep
= BeginningOfCombatStep
| DeclareAttackersStep
| DeclareBlockersStep
| CombatDamageStep
| EndOfCombatStep
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data EndStep
= EndOfTurnStep
| CleanupStep
deriving (Eq, Ord, Show, Read, Enum, Bounded)
-- PLAYERS
data Player = Player
{ _life :: Int
, _manaPool :: Bag (Maybe Color)
, _prestack :: [Magic Object]
, _library :: IdList Object
, _hand :: IdList Object
, _graveyard :: IdList Object
, _maximumHandSize :: Maybe Int
, _failedCardDraw :: Bool -- [704.5b]
}
-- OBJECTS
data Card = Card
-- timestamp, owner (and controller)
{ instantiateCard :: Timestamp -> PlayerRef-> Object
}
data Object = Object
{ _name :: Maybe Text
, _colors :: Set Color
, _types :: ObjectTypes
, _owner :: PlayerRef
, _controller :: PlayerRef
, _timestamp :: Timestamp
, _counters :: Bag CounterType
-- for permanents on the battlefield
, _tapStatus :: Maybe TapStatus
-- for spells on the stack
, _stackItem :: Maybe StackItem
-- for creatures on the battlefield
, _power :: Maybe Int
, _toughness :: Maybe Int
, _damage :: Maybe Int
, _deathtouched :: Bool
--, _mustBeBlocked :: Maybe Bool
--, _mustAttack :: Maybe Bool
--, _indestructible :: Bool
, _play :: Maybe Ability
, _staticKeywordAbilities :: Bag StaticKeywordAbility
, _continuousEffects :: [ContinuousEffect] -- special form of static ability
, _activatedAbilities :: [Ability]
, _triggeredAbilities :: [Event -> Action]
, _replacementEffects :: [ReplacementEffect]
}
-- OBJECT PROPERTIES
type Timestamp = Int
data Color = White | Blue | Black | Red | Green
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data TapStatus = Untapped | Tapped
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data CounterType
= Charge | Plus1Plus1 | Minus1Minus1 | Poison | Hatchling | Loyalty
deriving (Eq, Ord, Show, Read, Enum, Bounded)
-- OBJECT TYPES
data ObjectTypes = ObjectTypes
{ _supertypes :: Set Supertype
, _artifactSubtypes :: Maybe (Set ArtifactSubtype)
, _creatureSubtypes :: Maybe (Set CreatureSubtype)
, _enchantmentSubtypes :: Maybe (Set EnchantmentSubtype)
, _instantSubtypes :: Maybe (Set SpellSubtype)
, _landSubtypes :: Maybe (Set LandSubtype)
, _planeswalkerSubtypes :: Maybe (Set PlaneswalkerSubtype)
, _sorcerySubtypes :: Maybe (Set SpellSubtype)
} deriving (Eq, Ord, Show)
instance Monoid ObjectTypes where
mempty = ObjectTypes mempty mempty mempty mempty mempty mempty mempty mempty
x `mappend` y = ObjectTypes
{ _supertypes = _supertypes x `mappend` _supertypes y
, _artifactSubtypes = _artifactSubtypes x `mappend` _artifactSubtypes y
, _creatureSubtypes = _creatureSubtypes x `mappend` _creatureSubtypes y
, _enchantmentSubtypes = _enchantmentSubtypes x `mappend` _enchantmentSubtypes y
, _instantSubtypes = _instantSubtypes x `mappend` _instantSubtypes y
, _landSubtypes = _landSubtypes x `mappend` _landSubtypes y
, _planeswalkerSubtypes = _planeswalkerSubtypes x `mappend` _planeswalkerSubtypes y
, _sorcerySubtypes = _sorcerySubtypes x `mappend` _sorcerySubtypes y
}
isObjectTypesSubsetOf :: ObjectTypes -> ObjectTypes -> Bool
isObjectTypesSubsetOf x y =
_supertypes x `Set.isSubsetOf` _supertypes y &&
_artifactSubtypes x `isMaybeSubsetOf` _artifactSubtypes y &&
_creatureSubtypes x `isMaybeSubsetOf` _creatureSubtypes y &&
_enchantmentSubtypes x `isMaybeSubsetOf` _enchantmentSubtypes y &&
_instantSubtypes x `isMaybeSubsetOf` _instantSubtypes y &&
_landSubtypes x `isMaybeSubsetOf` _landSubtypes y &&
_planeswalkerSubtypes x `isMaybeSubsetOf` _planeswalkerSubtypes y &&
_sorcerySubtypes x `isMaybeSubsetOf` _sorcerySubtypes y
where
isMaybeSubsetOf :: Ord a => Maybe (Set a) -> Maybe (Set a) -> Bool
Nothing `isMaybeSubsetOf` _ = True
Just _ `isMaybeSubsetOf` Nothing = False
Just x' `isMaybeSubsetOf` Just y' = x' `Set.isSubsetOf` y'
data Supertype = Basic | Legendary
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data ArtifactSubtype = Equipment
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data CreatureSubtype
-- Races
= Boar
| Human
| Spirit
| Treefolk
| Insect
| Spider
| Devil
| Goblin
-- Roles
| Warrior
| Shaman
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data EnchantmentSubtype = Aura | Curse
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data SpellSubtype = Arcane | Trap
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data LandSubtype = Plains | Island | Swamp | Mountain | Forest | Locus
deriving (Eq, Ord, Show, Read, Enum, Bounded)
data PlaneswalkerSubtype = Chandra | Elspeth | Garruk | Gideon | Jace
| Koth | Liliana | Sorin | Tezzeret | Venser | Karn
deriving (Eq, Ord, Show, Read, Enum, Bounded)
-- ABILITIES
type Ability = ObjectRef -> PlayerRef -> ClosedAbility
data ClosedAbility = ClosedAbility
{ _available :: View Bool -- check for cost is implied
, _manaCost :: ManaCost
, _additionalCosts :: [AdditionalCost]
, _effect :: Action
}
data Action
= SpecialAction (Magic [OneShotEffect])
| StackingAction (Magic StackItem)
type StackItem = TargetList Target (Magic [OneShotEffect])
data ManaCost = ManaCost
{ payColoredMana :: Bag Color
, payColorlessMana :: Int
}
instance Monoid ManaCost where
mempty = ManaCost [] 0
ManaCost cs1 n1 `mappend` ManaCost cs2 n2 = ManaCost (cs1 ++ cs2) (n1 + n2)
data AdditionalCost
= TapPermanentCost (ObjectRef -> Bool)
| SacrificePermanentCost (Object -> Bool)
| ExileObjectCost [ZoneRef] (Object -> Bool) -- exile matching object from any of the listed zones
| DiscardCardCost
| RemoveCounterCost CounterType
data StaticKeywordAbility
= Bloodthirst Int
| Deathtouch
| Defender
| DoubleStrike
| Enchant
| FirstStrike
| Flash
| Flashback ManaCost
| Flying
| Haste
| Hexproof
| Infect
| Intimidate
| Lifelink
| ProtectionFromColor Color
| Reach
| Shroud
| Trample
| Vigilance
data ContinuousEffect = ContinuousEffect
{ _layer :: Layer
, _efTimestamp :: Timestamp
, _efEffect :: World -> World
}
data Layer
= Layer1 -- copy effects
| Layer2 -- control-changing effects
| Layer3 -- text-changing effects
| Layer4 -- type-chaning effects
| Layer5 -- color-changing effects
| Layer6 -- ability-adding and ability-removing effects
| Layer7a -- p/t from characteristic-defining abilities
| Layer7b -- set p/t
| Layer7c -- modify p/t
| Layer7d -- p/t counters
| Layer7e -- switch p/t
| LayerPlayer -- player-affecting effects
| LayerRules -- rules-affecting effects
deriving (Eq, Ord, Show, Read, Enum, Bounded)
type ReplacementEffect = OneShotEffect -> Maybe (Magic [OneShotEffect])
data PriorityAction
= PlayCard ObjectRef
| ActivateAbility Ability
-- EVENTS
-- | Events triggered abilities watch for.
data Event
= Did SimpleOneShotEffect
| DidMoveObject ZoneRef ObjectRef -- old zone, new zone/id
-- Keyword actions [701]
| DidActivateAbility ObjectRef Int -- index of ability
| DidCastSpell PlayerRef ObjectRef -- controller, spell
| DidCounter ObjectRef ObjectRef -- source (spell or ability), target
| DidPlayLand ObjectRef
| DidRevealCard ObjectRef
| DidBeginStep Step
| WillEndStep Step
data OneShotEffect
= Will SimpleOneShotEffect
| WillMoveObject ObjectRef ZoneRef Object -- current zone/id, new zone, suggested form
data SimpleOneShotEffect
= AdjustLife PlayerRef Int
| DamageObject ObjectRef ObjectRef Int Bool Bool -- source, creature/planeswalker, amount, combat damage?, preventable?
| DamagePlayer ObjectRef PlayerRef Int Bool Bool -- source, player, amount, combat damage?, preventable?
| ShuffleLibrary PlayerRef
-- ReorderLibraryCards
| DrawCard PlayerRef -- Drawing is special [120.5]
| DestroyPermanent Id Bool -- object on battlefield, regenerate allowed?
| TapPermanent Id -- object on battlefield
| UntapPermanent Id -- object on battlefield
| AddCounter ObjectRef CounterType
| RemoveCounter ObjectRef CounterType
| CreateObject Object -- create a token, emblem or spell
| AddToManaPool PlayerRef (Maybe Color)
| AttachPermanent ObjectRef (Maybe ObjectRef) (Maybe ObjectRef) -- aura/equipment, old target, new target
| RemoveFromCombat Id
| PlayLand ObjectRef
| LoseGame PlayerRef
-- TARGETS
data Target
= TargetPlayer PlayerRef
| TargetObject ObjectRef
data TargetList t a where
Nil :: a -> TargetList t a
Snoc :: TargetList t (Target -> a) -> t -> TargetList t a
Test :: (x -> a) -> (x -> View Bool) -> TargetList t x -> TargetList t a
instance Functor (TargetList t) where
fmap f (Nil x) = Nil (f x)
fmap f (Snoc xs t) = Snoc (fmap (f .) xs) t
fmap f (Test g ok xs) = Test (f . g) ok xs
instance Applicative (TargetList t) where
pure = Nil
xs <*> Nil b = fmap ($ b) xs
xs <*> Snoc ys t = Snoc ((.) <$> xs <*> ys) t
xs <*> Test f ok ys = Test fst snd ((\g x -> (g (f x), ok x)) <$> xs <*> ys)
-- MONADS
type ViewT = ReaderT World
type View = ViewT Identity
type Magic = ViewT (Operational.Program Ask)
type Engine = StateT World (RandT StdGen (Operational.Program Ask))
data Ask a where
AskKeepHand :: PlayerRef -> Ask Bool
AskPriorityAction :: PlayerRef -> [PriorityAction] -> Ask (Maybe PriorityAction)
AskTarget :: PlayerRef -> [Target] -> Ask Target
AskReorder :: PlayerRef -> [a] -> Ask [a]
AskPickReplacementEffect :: PlayerRef -> [(ReplacementEffect, Magic [OneShotEffect])] -> Ask (Pick (ReplacementEffect, Magic [OneShotEffect]))
type Pick a = (a, [a])
view :: View a -> Magic a
view v = ReaderT $ return . runIdentity . runReaderT v
$(mkLabels [''World, ''Player, ''Object, ''ObjectTypes, ''Action, ''ClosedAbility])