-
Notifications
You must be signed in to change notification settings - Fork 54
/
read_profile.m
1181 lines (1066 loc) · 35.2 KB
/
read_profile.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%-----------------------------------------------------------------------------%
% vim: ft=mercury ts=4 sw=4 et
%-----------------------------------------------------------------------------%
% Copyright (C) 2001, 2004-2005 The University of Melbourne.
% This file may only be copied under the terms of the GNU General
% Public License - see the file COPYING in the Mercury distribution.
%-----------------------------------------------------------------------------%
%
% Authors: conway, zs.
%
% This module contains code for reading in a deep profiling data file.
% Such files, named Deep.data, are created by deep profiled executables.
:- module read_profile.
:- interface.
:- import_module profile.
:- import_module io.
:- import_module std_util.
:- pred read_call_graph(string::in, maybe_error(initial_deep)::out,
io::di, io::uo) is det.
:- implementation.
:- import_module array_util.
:- import_module io_combinator.
:- import_module measurements.
:- import_module array.
:- import_module bool.
:- import_module char.
:- import_module int.
:- import_module list.
:- import_module require.
:- import_module string.
:- type maybe_error2(T1, T2)
---> ok2(T1, T2)
; error2(string).
:- type ptr_kind
---> ps
; pd
; css
; csd.
read_call_graph(FileName, Res, !IO) :-
io__see_binary(FileName, Res0, !IO),
(
Res0 = ok,
read_id_string(Res1, !IO),
(
Res1 = ok(_),
io_combinator__maybe_error_sequence_10(
read_fixed_size_int,
read_fixed_size_int,
read_fixed_size_int,
read_fixed_size_int,
read_num,
read_num,
read_num,
read_deep_byte,
read_deep_byte,
read_ptr(pd),
(pred(MaxCSD::in, MaxCSS::in,
MaxPD::in, MaxPS::in,
TicksPerSec::in,
InstrumentQuanta::in,
UserQuanta::in,
WordSize::in,
CanonicalFlag::in,
RootPDI::in,
ResInitDeep::out) is det :-
InitDeep0 = init_deep(MaxCSD, MaxCSS,
MaxPD, MaxPS,
TicksPerSec,
InstrumentQuanta, UserQuanta,
WordSize, CanonicalFlag,
RootPDI),
ResInitDeep = ok(InitDeep0)
),
Res2, !IO),
(
Res2 = ok(InitDeep),
read_nodes(InitDeep, Res, !IO),
io__seen_binary(!IO)
;
Res2 = error(Err),
Res = error(Err)
)
;
Res1 = error(Msg),
Res = error(Msg)
)
;
Res0 = error(Err),
io__error_message(Err, Msg),
Res = error(Msg)
).
:- pred read_id_string(maybe_error(string)::out,
io::di, io::uo) is det.
read_id_string(Res, !IO) :-
read_n_byte_string(string__length(id_string), Res0, !IO),
(
Res0 = ok(String),
( String = id_string ->
Res = ok(id_string)
;
Res = error("not a deep profiling data file")
)
;
Res0 = error(Err),
Res = error(Err)
).
:- func id_string = string.
% This must the same string as the one written by MR_write_out_id_string
% in runtime/mercury_deep_profiling.c.
id_string = "Mercury deep profiler data version 1\n".
:- func init_deep(int, int, int, int, int, int, int, int, int, int)
= initial_deep.
init_deep(MaxCSD, MaxCSS, MaxPD, MaxPS, TicksPerSec, InstrumentQuanta,
UserQuanta, WordSize, CanonicalByte, RootPDI) = InitDeep :-
( CanonicalByte = 0 ->
CanonicalFlag = no
;
CanonicalFlag = yes
),
InitStats = profile_stats(MaxCSD, MaxCSS, MaxPD, MaxPS, TicksPerSec,
InstrumentQuanta, UserQuanta, WordSize, CanonicalFlag),
InitDeep = initial_deep(
InitStats,
make_pdptr(RootPDI),
array__init(MaxCSD + 1,
call_site_dynamic(
make_dummy_pdptr,
make_dummy_pdptr,
zero_own_prof_info
)),
array__init(MaxPD + 1, proc_dynamic(make_dummy_psptr, array([]))),
array__init(MaxCSS + 1,
call_site_static(
make_dummy_psptr, -1,
normal_call(make_dummy_psptr, ""), -1, ""
)),
array__init(MaxPS + 1,
proc_static(dummy_proc_id, "", "", "", "", -1, no,
array([]), not_zeroed))
).
:- pred read_nodes(initial_deep::in, maybe_error(initial_deep)::out,
io::di, io::uo) is det.
read_nodes(InitDeep0, Res, !IO) :-
read_byte(Res0, !IO),
(
Res0 = ok(Byte),
( Byte = token_call_site_dynamic ->
read_call_site_dynamic(Res1, !IO),
(
Res1 = ok2(CallSiteDynamic, CSDI),
deep_insert(InitDeep0 ^ init_call_site_dynamics,
CSDI, CallSiteDynamic, CSDs),
InitDeep1 = InitDeep0 ^ init_call_site_dynamics := CSDs,
read_nodes(InitDeep1, Res, !IO)
;
Res1 = error2(Err),
Res = error(Err)
)
; Byte = token_proc_dynamic ->
read_proc_dynamic(Res1, !IO),
(
Res1 = ok2(ProcDynamic, PDI),
deep_insert(InitDeep0 ^ init_proc_dynamics,
PDI, ProcDynamic, PDs),
InitDeep1 = InitDeep0 ^ init_proc_dynamics := PDs,
read_nodes(InitDeep1, Res, !IO)
;
Res1 = error2(Err),
Res = error(Err)
)
; Byte = token_call_site_static ->
read_call_site_static(Res1, !IO),
(
Res1 = ok2(CallSiteStatic, CSSI),
deep_insert(InitDeep0 ^ init_call_site_statics,
CSSI, CallSiteStatic, CSSs),
InitDeep1 = InitDeep0 ^ init_call_site_statics := CSSs,
read_nodes(InitDeep1, Res, !IO)
;
Res1 = error2(Err),
Res = error(Err)
)
; Byte = token_proc_static ->
read_proc_static(Res1, !IO),
(
Res1 = ok2(ProcStatic, PSI),
deep_insert(InitDeep0 ^ init_proc_statics,
PSI, ProcStatic, PSs),
InitDeep1 = InitDeep0 ^ init_proc_statics := PSs,
read_nodes(InitDeep1, Res, !IO)
;
Res1 = error2(Err),
Res = error(Err)
)
;
format("unexpected token %d", [i(Byte)], Msg),
Res = error(Msg)
)
;
Res0 = eof,
Res = ok(InitDeep0)
;
Res0 = error(Err),
io__error_message(Err, Msg),
Res = error(Msg)
).
:- pred read_call_site_static(maybe_error2(call_site_static, int)::out,
io::di, io::uo) is det.
read_call_site_static(Res, !IO) :-
% DEBUGSITE
% io__write_string("reading call_site_static.\n"),
io_combinator__maybe_error_sequence_4(
read_ptr(css),
read_call_site_kind_and_callee,
read_num,
read_string,
(pred(CSSI0::in, Kind::in, LineNumber::in, Str::in, Res0::out)
is det :-
DummyPSPtr = make_dummy_psptr,
DummySlotNum = -1,
CallSiteStatic0 = call_site_static(DummyPSPtr,
DummySlotNum, Kind, LineNumber, Str),
Res0 = ok({CallSiteStatic0, CSSI0})
),
Res1, !IO),
(
Res1 = ok({CallSiteStatic, CSSI}),
Res = ok2(CallSiteStatic, CSSI)
% DEBUGSITE
% io__write_string("read call_site_static ", !IO),
% io__write_int(CSSI, !IO),
% io__write_string(": ", !IO),
% io__write(CallSiteStatic, !IO),
% io__write_string("\n", !IO)
;
Res1 = error(Err),
Res = error2(Err)
).
:- pred read_proc_static(maybe_error2(proc_static, int)::out,
io::di, io::uo) is det.
read_proc_static(Res, !IO) :-
% DEBUGSITE
% io__write_string("reading proc_static.\n", !IO),
io_combinator__maybe_error_sequence_6(
read_ptr(ps),
read_proc_id,
read_string,
read_num,
read_deep_byte,
read_num,
(pred(PSI0::in, Id0::in, F0::in, L0::in, I0::in,
N0::in, Stuff0::out) is det :-
Stuff0 = ok({PSI0, Id0, F0, L0, I0, N0})
),
Res1, !IO),
(
Res1 = ok({PSI, Id, FileName, LineNumber, Interface, N}),
read_n_things(N, read_ptr(css), Res2, !IO),
(
Res2 = ok(CSSIs),
CSSPtrs = list__map(make_cssptr, CSSIs),
DeclModule = decl_module(Id),
RefinedStr = refined_proc_id_to_string(Id),
RawStr = raw_proc_id_to_string(Id),
% The `not_zeroed' for whether the procedure's
% proc_static is ever zeroed is the default. The
% startup phase will set it to `zeroed' in the
% proc_statics which are ever zeroed.
( Interface = 0 ->
IsInInterface = no
;
IsInInterface = yes
),
ProcStatic = proc_static(Id, DeclModule,
RefinedStr, RawStr, FileName, LineNumber,
IsInInterface, array(CSSPtrs), not_zeroed),
Res = ok2(ProcStatic, PSI)
% DEBUGSITE
% io__write_string("read proc_static ", !IO),
% io__write_int(PSI, !IO),
% io__write_string(": ", !IO),
% io__write(ProcStatic, !IO),
% io__write_string("\n", !IO)
;
Res2 = error(Err),
Res = error2(Err)
)
;
Res1 = error(Err),
Res = error2(Err)
).
:- pred read_proc_id(maybe_error(proc_id)::out,
io::di, io::uo) is det.
read_proc_id(Res, !IO) :-
read_deep_byte(Res0, !IO),
(
Res0 = ok(Byte),
( Byte = token_isa_uci_pred ->
read_proc_id_uci_pred(Res, !IO)
; Byte = token_isa_predicate ->
read_proc_id_user_defined(predicate, Res, !IO)
; Byte = token_isa_function ->
read_proc_id_user_defined(function, Res, !IO)
;
format("unexpected proc_id_kind %d", [i(Byte)], Msg),
Res = error(Msg)
)
;
Res0 = error(Err),
Res = error(Err)
).
:- pred read_proc_id_uci_pred(maybe_error(proc_id)::out,
io::di, io::uo) is det.
read_proc_id_uci_pred(Res, !IO) :-
io_combinator__maybe_error_sequence_6(
read_string,
read_string,
read_string,
read_string,
read_num,
read_num,
(pred(TypeName::in, TypeModule::in, DefModule::in,
PredName::in, Arity::in, Mode::in, ProcId::out)
is det :-
ProcId = ok(uci_pred(TypeName, TypeModule,
DefModule, PredName, Arity, Mode))
),
Res, !IO).
:- pred read_proc_id_user_defined(pred_or_func::in, maybe_error(proc_id)::out,
io::di, io::uo) is det.
read_proc_id_user_defined(PredOrFunc, Res, !IO) :-
io_combinator__maybe_error_sequence_5(
read_string,
read_string,
read_string,
read_num,
read_num,
(pred(DeclModule::in, DefModule::in, Name::in,
Arity::in, Mode::in, ProcId::out)
is det :-
ProcId = ok(user_defined(PredOrFunc, DeclModule,
DefModule, Name, Arity, Mode))
),
Res, !IO).
:- func raw_proc_id_to_string(proc_id) = string.
raw_proc_id_to_string(uci_pred(TypeName, TypeModule, _DefModule,
PredName, Arity, Mode)) =
string__append_list(
[PredName, " for ", TypeModule, ".", TypeName,
"/", string__int_to_string(Arity),
" mode ", string__int_to_string(Mode)]).
raw_proc_id_to_string(user_defined(PredOrFunc, DeclModule, _DefModule,
Name, Arity, Mode)) =
string__append_list([DeclModule, ".", Name,
"/", string__int_to_string(Arity),
( PredOrFunc = function -> "+1" ; "" ),
"-", string__int_to_string(Mode)]).
:- func refined_proc_id_to_string(proc_id) = string.
refined_proc_id_to_string(uci_pred(TypeName, TypeModule, _DefModule,
RawPredName, Arity, Mode)) = Name :-
( RawPredName = "__Unify__" ->
PredName = "Unify"
; RawPredName = "__Compare__" ->
PredName = "Compare"
; RawPredName = "__CompareRep__" ->
PredName = "CompareRep"
; RawPredName = "__Index__" ->
PredName = "Index"
; RawPredName = "__Initialise__" ->
PredName = "Initialise"
;
string__append("unknown special predicate name ", RawPredName, Msg),
error(Msg)
),
Name0 = string__append_list([PredName, " for ", TypeModule, ".", TypeName,
"/", string__int_to_string(Arity)]),
( Mode = 0 ->
Name = Name0
;
Name = string__append_list([Name0, " mode ", int_to_string(Mode)])
).
refined_proc_id_to_string(user_defined(PredOrFunc, DeclModule, _DefModule,
ProcName, Arity, Mode)) = Name :-
(
string__append("TypeSpecOf__", ProcName1, ProcName),
( string__append("pred__", ProcName2A, ProcName1) ->
ProcName2 = ProcName2A
; string__append("func__", ProcName2B, ProcName1) ->
ProcName2 = ProcName2B
; string__append("pred_or_func__", ProcName2C, ProcName1) ->
ProcName2 = ProcName2C
;
error("typespec: neither pred nor func")
),
string__to_char_list(ProcName2, ProcName2Chars),
fix_type_spec_suffix(ProcName2Chars, ProcNameChars, SpecInfo)
->
RefinedProcName = string__from_char_list(ProcNameChars),
Name = string__append_list([DeclModule, ".", RefinedProcName,
"/", string__int_to_string(Arity),
( PredOrFunc = function -> "+1" ; "" ),
"-", string__int_to_string(Mode),
" [", SpecInfo, "]"])
;
string__append("IntroducedFrom__", ProcName1, ProcName),
( string__append("pred__", ProcName2A, ProcName1) ->
ProcName2 = ProcName2A
; string__append("func__", ProcName2B, ProcName1) ->
ProcName2 = ProcName2B
;
error("lambda: neither pred nor func")
),
string__to_char_list(ProcName2, ProcName2Chars),
split_lambda_name(ProcName2Chars, Segments),
glue_lambda_name(Segments, ContainingNameChars,
LineNumberChars)
->
string__from_char_list(ContainingNameChars, ContainingName),
string__from_char_list(LineNumberChars, LineNumber),
Name = string__append_list([DeclModule, ".", ContainingName,
" lambda line ", LineNumber,
"/", string__int_to_string(Arity),
( PredOrFunc = function -> "+1" ; "" )])
;
Name = string__append_list([DeclModule, ".", ProcName,
"/", string__int_to_string(Arity),
( PredOrFunc = function -> "+1" ; "" ),
"-", string__int_to_string(Mode)])
).
:- pred fix_type_spec_suffix(list(char)::in, list(char)::out, string::out)
is semidet.
fix_type_spec_suffix(Chars0, Chars, SpecInfoStr) :-
( Chars0 = ['_', '_', '[' | SpecInfo0 ] ->
Chars = [],
list__takewhile(non_right_bracket, SpecInfo0, SpecInfo, _),
string__from_char_list(SpecInfo, SpecInfoStr)
; Chars0 = [Char | TailChars0] ->
fix_type_spec_suffix(TailChars0, TailChars, SpecInfoStr),
Chars = [Char | TailChars]
;
fail
).
:- pred non_right_bracket(char::in) is semidet.
non_right_bracket(C) :-
C \= ']'.
:- pred split_lambda_name(list(char)::in, list(list(char))::out) is det.
split_lambda_name([], []).
split_lambda_name([Char0 | Chars0], StringList) :-
( Chars0 = ['_', '_' | Chars1 ] ->
split_lambda_name(Chars1, StringList0),
StringList = [[Char0] | StringList0]
;
split_lambda_name(Chars0, StringList0),
(
StringList0 = [],
StringList = [[Char0]]
;
StringList0 = [String0 | StringList1],
StringList = [[Char0 | String0] | StringList1]
)
).
:- pred glue_lambda_name(list(list(char))::in, list(char)::out,
list(char)::out) is semidet.
glue_lambda_name(Segments, PredName, LineNumber) :-
( Segments = [LineNumberPrime, _] ->
PredName = [],
LineNumber = LineNumberPrime
; Segments = [Segment | TailSegments] ->
glue_lambda_name(TailSegments, PredName1, LineNumber),
( PredName1 = [] ->
PredName = Segment
;
list__append(Segment, ['_', '_' | PredName1], PredName)
)
;
fail
).
:- pred read_proc_dynamic(maybe_error2(proc_dynamic, int)::out,
io::di, io::uo) is det.
read_proc_dynamic(Res, !IO) :-
% DEBUGSITE
% io__write_string("reading proc_dynamic.\n", !IO),
io_combinator__maybe_error_sequence_3(
read_ptr(pd),
read_ptr(ps),
read_num,
(pred(PDI0::in, PSI0::in, N0::in, Stuff0::out) is det :-
Stuff0 = ok({PDI0, PSI0, N0})
),
Res1, !IO),
(
Res1 = ok({PDI, PSI, N}),
read_n_things(N, read_call_site_slot, Res2, !IO),
(
Res2 = ok(Refs),
PSPtr = make_psptr(PSI),
ProcDynamic = proc_dynamic(PSPtr, array(Refs)),
Res = ok2(ProcDynamic, PDI)
% DEBUGSITE
% io__write_string("read proc_dynamic ", !IO),
% io__write_int(PDI, !IO),
% io__write_string(": ", !IO),
% io__write(ProcDynamic, !IO),
% io__write_string("\n", !IO)
;
Res2 = error(Err),
Res = error2(Err)
)
;
Res1 = error(Err),
Res = error2(Err)
).
:- pred read_call_site_dynamic(maybe_error2(call_site_dynamic, int)::out,
io::di, io::uo) is det.
read_call_site_dynamic(Res, !IO) :-
% DEBUGSITE
% io__write_string("reading call_site_dynamic.\n", !IO),
read_ptr(csd, Res1, !IO),
(
Res1 = ok(CSDI),
read_ptr(pd, Res2, !IO),
(
Res2 = ok(PDI),
read_profile(Res3, !IO),
(
Res3 = ok(Profile),
PDPtr = make_pdptr(PDI),
CallerPDPtr = make_dummy_pdptr,
CallSiteDynamic = call_site_dynamic(
CallerPDPtr, PDPtr, Profile),
Res = ok2(CallSiteDynamic, CSDI)
% DEBUGSITE
% io__write_string("read call_site_dynamic ",
% !IO),
% io__write_int(CSDI, !IO),
% io__write_string(": ", !IO),
% io__write(CallSiteDynamic, !IO),
% io__write_string("\n", !IO)
;
Res3 = error(Err),
Res = error2(Err)
)
;
Res2 = error(Err),
Res = error2(Err)
)
;
Res1 = error(Err),
Res = error2(Err)
).
:- pred read_profile(maybe_error(own_prof_info)::out,
io::di, io::uo) is det.
read_profile(Res, !IO) :-
read_num(Res0, !IO),
(
Res0 = ok(Mask),
% The masks here must correspond exactly with the masks in
% MR_write_out_call_site_dynamic in mercury_deep_profiling.c
% in the runtime.
some [!MaybeError] (
!:MaybeError = no,
% We normally assume that the configuration macro
% MR_DEEP_PROFILING_EXPLICIT_CALL_COUNTS is not
% defined, and thus mercury_deep_profiling.m never
% writes out call counts (instead, call counts are
% computed from other port counts in measurements.m).
% maybe_read_num_handle_error(Mask, 0x0001, Calls,
% !MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0002, Exits,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0004, Fails,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0008, Redos,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0010, Excps,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0020, Quanta,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0040, Mallocs,
!MaybeError, !IO),
maybe_read_num_handle_error(Mask, 0x0080, Words,
!MaybeError, !IO),
LastMaybeError = !.MaybeError
),
(
LastMaybeError = yes(Error),
Res = error(Error)
;
LastMaybeError = no,
Res = ok(compress_profile(Exits, Fails, Redos, Excps,
Quanta, Mallocs, Words))
)
;
Res0 = error(Error),
Res = error(Error)
).
:- pred maybe_read_num_handle_error(int::in, int::in, int::out,
maybe(string)::in, maybe(string)::out,
io::di, io::uo) is det.
maybe_read_num_handle_error(MaskWord, MaskValue, Num, !MaybeError, !IO) :-
( MaskWord /\ MaskValue \= 0 ->
read_num(Res, !IO),
(
Res = ok(Num)
;
Res = error(Error),
Num = 0,
!:MaybeError = yes(Error)
)
;
Num = 0
).
:- pred read_call_site_slot(maybe_error(call_site_array_slot)::out,
io::di, io::uo) is det.
read_call_site_slot(Res, !IO) :-
% DEBUGSITE
% io__write_string("reading call_site_slot.\n", !IO),
read_call_site_kind(Res1, !IO),
(
Res1 = ok(Kind),
( Kind = normal_call ->
read_ptr(csd, Res2, !IO),
(
Res2 = ok(CSDI),
CSDPtr = make_csdptr(CSDI),
Res = ok(normal(CSDPtr))
% DEBUGSITE
% io__write_string("normal call_site slot ",
% !IO),
% io__write_int(CSDI, !IO),
% io__write_string("\n", !IO)
;
Res2 = error(Err),
Res = error(Err)
)
;
(
( Kind = higher_order_call
; Kind = method_call
)
->
Zeroed = zeroed
;
Zeroed = not_zeroed
),
read_multi_call_site_csdis(Res2, !IO),
(
Res2 = ok(CSDIs),
CSDPtrs = list__map(make_csdptr, CSDIs),
Res = ok(multi(Zeroed, array(CSDPtrs)))
% DEBUGSITE
% io__write_string("multi call_site slots ",
% !IO),
% io__write(CSDIs, !IO),
% io__write_string("\n", !IO)
;
Res2 = error(Err),
Res = error(Err)
)
)
;
Res1 = error(Err),
Res = error(Err)
).
:- pred read_multi_call_site_csdis(maybe_error(list(int))::out,
io::di, io::uo) is det.
read_multi_call_site_csdis(Res, !IO) :-
read_multi_call_site_csdis_2([], Res, !IO).
% We keep reading CSD node numbers until we find a zero byte.
% The reason why a zero byte works as a sentinel is that a CSD node
% number in the list of CSD node numbers at a multi call site cannot be
% zero, and our encoding scheme ensures that non-zero node numbers
% cannot start with a zero byte.
%
% We return the list of CSD node numbers in the reversed order, but
% this is OK because our caller does not pay attention to the order
% anyway.
:- pred read_multi_call_site_csdis_2(list(int)::in,
maybe_error(list(int))::out, io::di, io::uo) is det.
read_multi_call_site_csdis_2(CSDIs0, Res, !IO) :-
% DEBUGSITE
% io__format("reading multi_call_site_csdi.\n", [], !IO),
read_deep_byte(Res0, !IO),
(
Res0 = ok(Byte),
( Byte = 0 ->
Res = ok(CSDIs0)
;
putback_byte(Byte, !IO),
read_ptr(csd, Res1, !IO),
(
Res1 = ok(CSDI),
read_multi_call_site_csdis_2([CSDI | CSDIs0], Res, !IO)
;
Res1 = error(Err),
Res = error(Err)
)
)
;
Res0 = error(Err),
Res = error(Err)
).
:- pred read_call_site_kind(maybe_error(call_site_kind)::out,
io::di, io::uo) is det.
read_call_site_kind(Res, !IO) :-
read_deep_byte(Res0, !IO),
(
Res0 = ok(Byte),
( Byte = token_normal_call ->
Res = ok(normal_call)
; Byte = token_special_call ->
Res = ok(special_call)
; Byte = token_higher_order_call ->
Res = ok(higher_order_call)
; Byte = token_method_call ->
Res = ok(method_call)
; Byte = token_callback ->
Res = ok(callback)
;
format("unexpected call_site_kind %d",
[i(Byte)], Msg),
Res = error(Msg)
)
% DEBUGSITE
% io__write_string("call_site_kind ", !IO),
% io__write(Res, !IO),
% io__write_string("\n", !IO)
;
Res0 = error(Err),
Res = error(Err)
).
:- pred read_call_site_kind_and_callee(
maybe_error(call_site_kind_and_callee)::out,
io::di, io::uo) is det.
read_call_site_kind_and_callee(Res, !IO) :-
read_deep_byte(Res0, !IO),
(
Res0 = ok(Byte),
( Byte = token_normal_call ->
read_num(Res1, !IO),
(
Res1 = ok(CalleeProcStatic),
read_string(Res2, !IO),
(
Res2 = ok(TypeSubst),
Res = ok(normal_call(proc_static_ptr(CalleeProcStatic),
TypeSubst))
;
Res2 = error(Err),
Res = error(Err)
)
;
Res1 = error(Err),
Res = error(Err)
)
; Byte = token_special_call ->
Res = ok(special_call)
; Byte = token_higher_order_call ->
Res = ok(higher_order_call)
; Byte = token_method_call ->
Res = ok(method_call)
; Byte = token_callback ->
Res = ok(callback)
;
format("unexpected call_site_kind %d", [i(Byte)], Msg),
Res = error(Msg)
)
% DEBUGSITE
% io__write_string("call_site_kind_and_callee ", !IO),
% io__write(Res, !IO),
% io__write_string("\n", !IO)
;
Res0 = error(Err),
Res = error(Err)
).
%-----------------------------------------------------------------------------%
:- pred read_n_things(int::in, pred(maybe_error(T), io, io)::
in(pred(out, di, uo) is det), maybe_error(list(T))::out,
io::di, io::uo) is det.
read_n_things(N, ThingReader, Res, !IO) :-
read_n_things(N, ThingReader, [], Res0, !IO),
(
Res0 = ok(Things0),
reverse(Things0, Things),
Res = ok(Things)
;
Res0 = error(Err),
Res = error(Err)
).
:- pred read_n_things(int::in, pred(maybe_error(T), io, io)::
in(pred(out, di, uo) is det), list(T)::in, maybe_error(list(T))::out,
io::di, io::uo) is det.
read_n_things(N, ThingReader, Things0, Res, !IO) :-
( N =< 0 ->
Res = ok(Things0)
;
call(ThingReader, Res1, !IO),
(
Res1 = ok(Thing),
read_n_things(N - 1, ThingReader, [Thing | Things0], Res, !IO)
;
Res1 = error(Err),
Res = error(Err)
)
).
%-----------------------------------------------------------------------------%
:- pred read_string(maybe_error(string)::out,
io::di, io::uo) is det.
read_string(Res, !IO) :-
read_num(Res0, !IO),
(
Res0 = ok(Length),
( Length = 0 ->
Res = ok("")
;
read_n_byte_string(Length, Res, !IO)
)
;
Res0 = error(Err),
Res = error(Err)
).
:- pred read_n_byte_string(int::in, maybe_error(string)::out,
io::di, io::uo) is det.
read_n_byte_string(Length, Res, !IO) :-
read_n_bytes(Length, Res1, !IO),
(
Res1 = ok(Bytes),
(
map((pred(I::in, C::out) is semidet :- char__to_int(C, I)),
Bytes, Chars)
->
string__from_char_list(Chars, Str),
Res = ok(Str)
;
Res = error("string contained bad char")
)
;
Res1 = error(Err),
Res = error(Err)
).
% DEBUGSITE
% io__write_string("string ", !IO),
% io__write(Res, !IO),
% io__write_string("\n", !IO).
:- pred read_ptr(ptr_kind::in, maybe_error(int)::out,
io::di, io::uo) is det.
read_ptr(_Kind, Res, !IO) :-
read_num1(0, Res, !IO).
% DEBUGSITE
% io__write_string("ptr ", !IO),
% io__write(Res, !IO),
% io__write_string("\n", !IO).
:- pred read_num(maybe_error(int)::out, io::di, io::uo) is det.
read_num(Res, !IO) :-
read_num1(0, Res, !IO).
% DEBUGSITE
% io__write_string("num ", !IO),
% io__write(Res, !IO),
% io__write_string("\n", !IO).
:- pred read_num1(int::in, maybe_error(int)::out,
io::di, io::uo) is det.
read_num1(Num0, Res, !IO) :-
read_byte(Res0, !IO),
(
Res0 = ok(Byte),
Num1 = (Num0 << 7) \/ (Byte /\ 0x7F),
( Byte /\ 0x80 \= 0 ->
read_num1(Num1, Res, !IO)
;
Res = ok(Num1)
)
;
Res0 = eof,
Res = error("unexpected end of file")
;
Res0 = error(Err),
io__error_message(Err, Msg),
Res = error(Msg)
).
:- func fixed_size_int_bytes = int.
% Must correspond to MR_FIXED_SIZE_INT_BYTES
% in runtime/mercury_deep_profiling.c.
fixed_size_int_bytes = 4.
:- pred read_fixed_size_int(maybe_error(int)::out,
io::di, io::uo) is det.
read_fixed_size_int(Res, !IO) :-
read_fixed_size_int1(fixed_size_int_bytes, 0, 0, Res, !IO).
:- pred read_fixed_size_int1(int::in, int::in, int::in, maybe_error(int)::out,
io::di, io::uo) is det.
read_fixed_size_int1(BytesLeft, Num0, ShiftBy, Res, !IO) :-
( BytesLeft =< 0 ->
Res = ok(Num0)
;
read_deep_byte(Res0, !IO),
(
Res0 = ok(Byte),
Num1 = Num0 \/ ( Byte << ShiftBy),
read_fixed_size_int1(BytesLeft - 1, Num1, ShiftBy + 8, Res, !IO)
;
Res0 = error(Err),
Res = error(Err)
)
).
:- pred read_n_bytes(int::in, maybe_error(list(int))::out,
io::di, io::uo) is det.
read_n_bytes(N, Res, !IO) :-
read_n_bytes(N, [], Res0, !IO),
(
Res0 = ok(Bytes0),
reverse(Bytes0, Bytes),
Res = ok(Bytes)
;