tools/MINGW-packages: added OpenColorIO 2.1

Ref NatronGitHub/openfx-io#4

tools/MINGW-packages/makepkg.sh

@@ -1,3 +1,3 @@
 #!/bin/sh
-MINGW_INSTALLS=mingw64 makepkg-mingw -dLfC
+MINGW_INSTALLS=mingw64 makepkg-mingw -LfC
 

tools/MINGW-packages/mingw-w64-expat/002-fix-tests.patch

@@ -0,0 +1,15 @@
+--- expat-2.2.1/run.sh.in.orig	2017-06-26 02:47:32.339456800 -0400
++++ expat-2.2.1/run.sh.in	2017-06-26 02:55:25.747253400 -0400
+@@ -4,7 +4,11 @@
+
+ case "@host@" in
+ *-mingw*)
+-    exec wine "$@"
++    if [ "$(uname -o)"=="Msys" ]; then
++      exec "$@"
++    else
++      exec wine "$@"
++    fi
+     ;;
+ *)
+     exec "$@"

tools/MINGW-packages/mingw-w64-expat/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Alexey Pavlov <alexpux@gmail.com>
+# Contributor: Renato Silva <br.renatosilva@gmail.com>
+
+_realname=expat
+pkgbase=mingw-w64-${_realname}
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
+pkgver=2.2.10
+pkgrel=1
+pkgdesc="An XML parser library (mingw-w64)"
+arch=('any')
+url="https://libexpat.github.io/"
+license=(MIT)
+makedepends=("${MINGW_PACKAGE_PREFIX}-gcc" "${MINGW_PACKAGE_PREFIX}-pkg-config")
+options=('strip' 'staticlibs')
+source=("https://downloads.sourceforge.net/${_realname}/${_realname}-${pkgver}.tar.bz2"
+        002-fix-tests.patch)
+sha256sums=('b2c160f1b60e92da69de8e12333096aeb0c3bf692d41c60794de278af72135a5'
+            'abcf34b90ed801cc2810f6d333bca2997aadfe95dbedd1509bd54c14ecca1042')
+
+prepare() {
+  cd "${srcdir}/${_realname}-${pkgver}"
+
+  patch -p1 -i ${srcdir}/002-fix-tests.patch
+  autoreconf -fiv
+}
+
+build() {
+  [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}"
+  mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}"
+
+  ../${_realname}-${pkgver}/configure \
+    --prefix=${MINGW_PREFIX} \
+    --build=${MINGW_CHOST} \
+    --host=${MINGW_CHOST} \
+    --target=${MINGW_CHOST} \
+    --enable-shared \
+    --enable-static
+
+  make
+}
+
+check() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make check
+}
+
+package() {
+  cd "${srcdir}/build-${MINGW_CHOST}"
+  make DESTDIR="${pkgdir}" install
+  install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
+}

tools/MINGW-packages/mingw-w64-opencolorio2-git/OpenColorIO.pc

@@ -0,0 +1,8 @@
+libdir=/mingw64/lib
+includedir=/mingw64/include
+
+Name: OpenColorIO
+Description: A color management framework for visual effects and animation
+Version: 2.1.1
+Cflags: -I${includedir}
+Libs: -L${libdir} -lOpenColorIO

tools/MINGW-packages/mingw-w64-opencolorio2-git/PKGBUILD

@@ -0,0 +1,73 @@
+# Maintainer: ole.andre.rodlie@gmail.com
+
+_realname=opencolorio
+pkgbase=mingw-w64-${_realname}-git
+pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}-git"
+gitcommit=32b01f6 # 2.1.1
+pkgver=1343.32b01f64
+pkgrel=1
+pkgdesc="A color management framework for visual effects and animation (mingw-w64)"
+arch=('any')
+url="http://opencolorio.org"
+license=('BSD')
+provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
+depends=("${MINGW_PACKAGE_PREFIX}-glew"
+         "${MINGW_PACKAGE_PREFIX}-lcms2"
+         "${MINGW_PACKAGE_PREFIX}-tinyxml"
+         "${MINGW_PACKAGE_PREFIX}-yaml-cpp"
+         "${MINGW_PACKAGE_PREFIX}-expat"
+         "${MINGW_PACKAGE_PREFIX}-openexr")
+makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
+             "${MINGW_PACKAGE_PREFIX}-pkg-config"
+             "git")
+options=('strip')
+source=("${_realname}"::"git+https://github.com/imageworks/OpenColorIO.git#commit=${gitcommit}"
+        OpenColorIO.pc
+        ocio-2.1.1.patch)
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_realname}"
+  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_realname}
+  patch -p1 -i ${srcdir}/ocio-2.1.1.patch
+}
+
+build() {
+  [[ -d "build-${MINGW_CHOST}" ]] && rm -rf "build-${MINGW_CHOST}"
+  mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST}
+
+  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
+  ${MINGW_PREFIX}/bin/cmake \
+    -G"MSYS Makefiles" \
+    -Wno-dev \
+    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
+    -DOCIO_BUILD_APPS=OFF \
+    -DOCIO_BUILD_NUKE=OFF \
+    -DOCIO_BUILD_DOCS=OFF \
+    -DOCIO_BUILD_TESTS=OFF \
+    -DOCIO_BUILD_GPU_TESTS=OFF \
+    -DOCIO_BUILD_PYTHON=OFF \
+    -DOCIO_USE_OPENEXR_HALF=ON \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_CXX_STANDARD=11 \
+    -DCMAKE_VISIBILITY_INLINES_HIDDEN=ON \
+    -DCMAKE_CXX_VISIBILITY_PRESET=hidden \
+    -DOCIO_INLINES_HIDDEN=ON \
+    ../${_realname}
+  make
+}
+
+package() {
+  cd build-${MINGW_CHOST}
+  make DESTDIR=${pkgdir} install
+  rm -r ${pkgdir}/msys64*
+  mkdir -p ${pkgdir}/mingw64/lib/pkgconfig
+  cp ${srcdir}/OpenColorIO.pc ${pkgdir}/mingw64/lib/pkgconfig/
+}

tools/MINGW-packages/mingw-w64-opencolorio2-git/ocio-2.1.1.patch

@@ -0,0 +1,16 @@
+diff --git a/src/utils/NumberUtils.h b/src/utils/NumberUtils.h
+index d0a7471f..ad473981 100644
+--- a/src/utils/NumberUtils.h
++++ b/src/utils/NumberUtils.h
+@@ -98,8 +98,10 @@ really_inline from_chars_result from_chars(const char *first, const char *last,
+     char *endptr = nullptr;
+
+     float
+-#ifdef _WIN32
++#ifdef _MSC_VER
+     tempval = _strtof_l(first, &endptr, loc.local);
++#elif _WIN32
++    tempval = static_cast<float>(_strtod_l(first, &endptr, loc.local));
+ #elif __APPLE__
+     // On OSX, strtod_l is for some reason drastically faster than strtof_l.
+     tempval = static_cast<float>(::strtod_l(first, &endptr, loc.local));