forked from ocaml/opam
-
Notifications
You must be signed in to change notification settings - Fork 4
/
server.ml
337 lines (278 loc) · 10.2 KB
/
server.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
(***********************************************************************)
(* *)
(* Copyright 2012 OCamlPro *)
(* Copyright 2012 INRIA *)
(* *)
(* All rights reserved. This file is distributed under the terms of *)
(* the GNU Public License version 3.0. *)
(* *)
(* TypeRex is distributed in the hope that it will be useful, *)
(* but WITHOUT ANY WARRANTY; without even the implied warranty of *)
(* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *)
(* GNU General Public License for more details. *)
(* *)
(***********************************************************************)
open Namespace
open Path
open File
open Unix
open Uri
module type SERVER =
sig
type t
(** [apiVersion t client] returns whether the API version for the
server. If the server cannot handle the [client] version, it
raises an exception. If the client cannot handle the server
version, it should take the appropriate decisions.*)
val apiVersion : t -> int -> int
(** Return the list of the available versions for all packages. *)
val getList : t -> name_version list
(** Returns the spec file for the corresponding package version. *)
val getSpec : t -> name_version -> raw_binary
(** Returns the corresponding package archive. [None] means that the
server does not mirror the associated archive. *)
val getArchive : t -> name_version -> raw_binary option
(** Process a first upload: it contains a spec file and a possible
corresponding archive.
The function returns the secret key associated to
all the packages having the same name *)
val newArchive : t -> name_version -> raw_binary -> raw_binary -> security_key
(** Same as [newArchive] but for subsequent upload (using the secret key) *)
val updateArchive : t -> name_version -> raw_binary -> raw_binary -> security_key -> unit
end
type server_state =
{ home : Path.t (* ~/.opam-server *)
; opam_version : int }
let server_init home =
{ home = Path.init home
; opam_version = Globals.api_version }
exception Server_error of string
let error fmt =
Printf.kprintf (fun s -> raise (Server_error s)) fmt
(* Used by the server to process things *)
module Server : SERVER with type t = server_state = struct
type t = server_state
(* Return all the .opam files *)
let read_index home =
List.fold_left
(fun map nv ->
let file = File.Spec.find_err (Path.index home (Some nv)) in
NV_map.add nv file map)
NV_map.empty
(Path.index_list home)
let string_of_nv (n, v) = Namespace.string_of_nv n v
let apiVersion t client =
if client <> Globals.api_version then
error "incompatible API version. client=%d server=%d"
client Globals.api_version
else
Globals.api_version
let getList t =
Path.index_list t.home
let getSpec t n_v =
let index = read_index t.home in
try Raw_binary (File.Spec.to_string (NV_map.find n_v index))
with Not_found -> error "%S not found" (string_of_nv n_v)
let getArchive t n_v =
let spec = File.Spec.find_err (Path.index t.home (Some n_v)) in
(* look at an archive in the same path
having the right name *)
let p = Path.archives_targz t.home (Some n_v) in
match Path.find_binary p with
| Path.File s -> Some s
| _ ->
match File.Spec.urls spec with
| [] -> error "Cannot find %S in local repository and no external url provided" (string_of_nv n_v)
| urls ->
(* if some urls are provided, check for external urls *)
let external_urls =
List.fold_left (fun accu -> function External (_,s) -> s::accu | _ -> accu) [] urls in
if external_urls <> [] then
(* clients can fetch archives *)
None
else
error "No archive associated to package %S" (string_of_nv n_v)
let storeArchive t n_v opam archive =
let opam_file = Path.index t.home (Some n_v) in
let archive_file = Path.archives_targz t.home (Some n_v) in
begin match opam with
| Raw_binary s -> File.Spec.add opam_file (File.Spec.parse s)
end;
Path.add archive_file (Path.File (Binary archive))
let processArchive o_key t (name, v) spec archive =
let hashes = Path.hashes t.home name in
let key =
match o_key, File.Security_key.find hashes with
| None, None ->
let key = Random_key.new_key () in
File.Security_key.add hashes key;
key
| Some k0, Some k1 ->
if k0 = k1 then
k0
else
error
"secret keys differ for package %S"
(Namespace.string_of_name name)
| Some _, None ->
error
"no previous keys stored for package %S"
(Namespace.string_of_name name)
| None, Some _ ->
error
"no key given and the package %S has already been uploaded"
(Namespace.string_of_name name) in
storeArchive t (name, v) spec archive;
key
let newArchive = processArchive None
let updateArchive t n_v spec archive key =
let (_ : security_key) = processArchive (Some key) t n_v spec archive in
()
end
exception Connection_error of string
let connection_error fmt =
Printf.kprintf (fun str ->
raise (Connection_error str)
) fmt
(* Used by the client to communicate with the server *)
module RemoteServer : SERVER with type t = url = struct
open Protocol
type t = url
(* untyped message exchange *)
let send url m =
if url.uri = Some Git then
connection_error "%s is not a valid OPAM server" url.hostname;
let host =
try (gethostbyname url.hostname).h_addr_list.(0)
with Not_found ->
connection_error "%s is not a valid host address" url.hostname in
let port = match url.port with
| None -> Globals.error_and_exit "No port provided"
| Some p -> p in
let addr = ADDR_INET (host, port) in
try
Protocol.find (open_connection addr) m
with _ ->
connection_error
"The server (%s) is unreachable. Please check your network configuration."
(string_of_url url)
let dyn_error str =
Globals.error_and_exit "Protocol error: %S" str
let error msg =
Globals.error_and_exit "SERVER: %s" msg
let apiVersion t s =
match send t (C2S_apidVersion s) with
| S2C_apiVersion nl -> nl
| S2C_error s -> error s
| _ -> dyn_error "apiVersion"
let check_version t =
let server_version = apiVersion t Globals.api_version in
if server_version <> Globals.api_version then
Globals.error_and_exit "API version error. client=%d server=%d"
Globals.api_version server_version
let getList t =
check_version t;
match send t C2S_getList with
| S2C_getList nl -> nl
| S2C_error s -> error s
| _ -> dyn_error "getList"
let getSpec t name_version =
check_version t;
match send t (C2S_getSpec name_version) with
| S2C_getSpec o -> o
| S2C_error s -> error s
| _ -> dyn_error "getOpam"
let getArchive t nv =
check_version t;
match send t (C2S_getArchive nv) with
| S2C_getArchive a -> a
| S2C_error s -> error s
| _ -> dyn_error "getArchive"
let newArchive t nv opam archive =
check_version t;
match send t (C2S_newArchive (nv, opam, archive)) with
| S2C_newArchive o -> o
| S2C_error s -> error s
| _ -> dyn_error "newArchive"
let updateArchive t nv opam archive k =
check_version t;
match send t (C2S_updateArchive (nv, opam, archive, k)) with
| S2C_updateArchive -> ()
| S2C_error s -> error s
| _ -> dyn_error "updateArchive"
end
module Daemon = struct
open Protocol
let log id fmt =
Globals.log (Printf.sprintf "[%s]" id) fmt
let protect f x =
try f x
with e ->
let msg = Printexc.to_string e in
Globals.error "%s" msg;
S2C_error msg
let file = Filename.temp_file "lock" "dat"
let flock id =
let l = ref 0 in
let rec loop () =
if Sys.file_exists id && !l < 5 then begin
log id "Filesytem busy. Waiting 1s (%d)" !l;
sleep 1;
loop ()
end else if Sys.file_exists id then begin
log id "Too many attemps. Cancelling ...";
error "Too many attemps. Cancelling ...";
end else begin
let oc = open_out file in
output_string oc id;
flush oc;
close_out oc;
log id "lock %s" id;
end in
loop ()
let funlock id =
if Sys.file_exists file then
let ic = open_in file in
let s = input_line ic in
if s = id then begin
log id "unlock %s" id;
Unix.unlink file;
end
let with_flock id f =
try
flock id;
let r = f () in
funlock id;
r
with e ->
funlock id;
raise e
let process t id request =
log id "Processing an incoming request";
match request with
| C2S_apidVersion s ->
log id "acceptedVersion";
protect (fun () -> S2C_apiVersion (Server.apiVersion t s)) ()
| C2S_getList ->
log id "getList";
protect (fun () -> S2C_getList (Server.getList t)) ()
| C2S_getSpec nv ->
log id "getSpec";
protect (fun () -> S2C_getSpec (Server.getSpec t nv)) ()
| C2S_getArchive nv ->
log id "getArchive";
protect (fun () -> S2C_getArchive (Server.getArchive t nv)) ()
| C2S_newArchive (nv, opam, archive) ->
log id "newArchive";
protect
(with_flock id)
(fun () -> S2C_newArchive (Server.newArchive t nv opam archive))
| C2S_updateArchive (nv, opam, archive, k) ->
log id "updateArchive [%s]"
(Digest.to_hex (Digest.string (match k with Random s -> s)));
protect
(with_flock id)
(fun () ->
Server.updateArchive t nv opam archive k;
S2C_updateArchive)
end