Add files via upload

buttsimpjoy_02d.ino

@@ -0,0 +1,200 @@
+//Simple buttonbox sketch
+//Supports up to 25 buttons and up to 4 encoders
+//version 0.2 by TOPMO3
+//
+//
+//Arduino IDE 1.6.6 (or above) !
+//
+//Joystick library from  Matthew Heironimus, https://github.com/MHeironimus/ArduinoJoystickLibrary
+// 
+//Encoders code from Ben Buxton
+//More info: http://www.buxtronix.net/2011/10/rotary-encoders-done-properly.html
+// 
+//Thank you guys! :)
+//
+
+
+
+//Uncomment this for HALFSTEP encoder operation
+//#define HALF_STEP
+
+#include <Keypad.h>
+#include <Joystick.h>
+
+
+
+#define ENABLE_PULLUPS
+#define NUMROTARIES 4
+#define NUMBUTTONS 25
+#define NUMROWS 5
+#define NUMCOLS 5
+
+
+//define the symbols on the buttons of the keypads
+byte buttons[NUMROWS][NUMCOLS] = {
+  {1,2,3,4,5},
+  {6,7,8,9,10},
+  {11,12,13,14,15},
+  {16,17,18,19,20},
+  {21,22,23,24,25},
+};
+
+
+
+struct rotariesdef {
+  byte pin1;
+  byte pin2;
+  int ccwchar;
+  int cwchar;
+  volatile unsigned char state;
+};
+
+rotariesdef rotaries[NUMROTARIES] {
+  {0,1,26,27,0},
+  {2,3,28,29,0},
+  {4,5,30,31,0},
+  {6,7,32,33,0},
+};
+
+
+
+#define DIR_CCW 0x10
+#define DIR_CW 0x20
+#define R_START 0x0
+
+#ifdef HALF_STEP
+// Use the half-step state table (emits a code at 00 and 11)
+#define R_CCW_BEGIN 0x1
+#define R_CW_BEGIN 0x2
+#define R_START_M 0x3
+#define R_CW_BEGIN_M 0x4
+#define R_CCW_BEGIN_M 0x5
+const unsigned char ttable[6][4] = {
+  // R_START (00)
+  {R_START_M,            R_CW_BEGIN,     R_CCW_BEGIN,  R_START},
+  // R_CCW_BEGIN
+  {R_START_M | DIR_CCW, R_START,        R_CCW_BEGIN,  R_START},
+  // R_CW_BEGIN
+  {R_START_M | DIR_CW,  R_CW_BEGIN,     R_START,      R_START},
+  // R_START_M (11)
+  {R_START_M,            R_CCW_BEGIN_M,  R_CW_BEGIN_M, R_START},
+  // R_CW_BEGIN_M
+  {R_START_M,            R_START_M,      R_CW_BEGIN_M, R_START | DIR_CW},
+  // R_CCW_BEGIN_M
+  {R_START_M,            R_CCW_BEGIN_M,  R_START_M,    R_START | DIR_CCW},
+};
+#else
+// Use the full-step state table (emits a code at 00 only)
+#define R_CW_FINAL 0x1
+#define R_CW_BEGIN 0x2
+#define R_CW_NEXT 0x3
+#define R_CCW_BEGIN 0x4
+#define R_CCW_FINAL 0x5
+#define R_CCW_NEXT 0x6
+
+const unsigned char ttable[7][4] = {
+  // R_START
+  {R_START,    R_CW_BEGIN,  R_CCW_BEGIN, R_START},
+  // R_CW_FINAL
+  {R_CW_NEXT,  R_START,     R_CW_FINAL,  R_START | DIR_CW},
+  // R_CW_BEGIN
+  {R_CW_NEXT,  R_CW_BEGIN,  R_START,     R_START},
+  // R_CW_NEXT
+  {R_CW_NEXT,  R_CW_BEGIN,  R_CW_FINAL,  R_START},
+  // R_CCW_BEGIN
+  {R_CCW_NEXT, R_START,     R_CCW_BEGIN, R_START},
+  // R_CCW_FINAL
+  {R_CCW_NEXT, R_CCW_FINAL, R_START,     R_START | DIR_CCW},
+  // R_CCW_NEXT
+  {R_CCW_NEXT, R_CCW_FINAL, R_CCW_BEGIN, R_START},
+};
+#endif
+
+
+byte rowPins[NUMROWS] = {21,20,19,18,15}; //connect to the row pinouts of the keypad
+byte colPins[NUMCOLS] = {14,16,10,9,8}; //connect to the column pinouts of the keypad
+
+//initialize an instance of class NewKeypad
+Keypad buttbx = Keypad( makeKeymap(buttons), rowPins, colPins, NUMROWS, NUMCOLS); 
+
+//initialize an Joystick with 34 buttons;
+Joystick_ Joystick(JOYSTICK_DEFAULT_REPORT_ID, 
+  JOYSTICK_TYPE_JOYSTICK, 34, 0,
+  false, false, false, false, false, false,
+  false, false, false, false, false);
+
+
+void setup() {
+  Joystick.begin();
+  rotary_init();
+}
+
+
+
+void loop() { 
+
+  CheckAllEncoders();
+
+  CheckAllButtons();
+
+}
+
+
+void CheckAllButtons(void) {
+      if (buttbx.getKeys())
+    {
+       for (int i=0; i<LIST_MAX; i++)   // Scan the whole key list.
+        {
+           if ( buttbx.key[i].stateChanged )   // Only find keys that have changed state.
+            {
+            switch (buttbx.key[i].kstate) {  // Report active key state : IDLE, PRESSED, HOLD, or RELEASED
+                    case PRESSED:
+                    case HOLD:
+                              Joystick.setButton(buttbx.key[i].kchar, 1);
+                              break;
+                    case RELEASED:
+                    case IDLE:
+                              Joystick.setButton(buttbx.key[i].kchar, 0);
+                              break;
+            }
+           }   
+         }
+     }
+}
+
+
+/* Call this once in setup(). */
+void rotary_init() {
+  for (int i=0;i<NUMROTARIES;i++) {
+    pinMode(rotaries[i].pin1, INPUT);
+    pinMode(rotaries[i].pin2, INPUT);
+    #ifdef ENABLE_PULLUPS
+      digitalWrite(rotaries[i].pin1, HIGH);
+      digitalWrite(rotaries[i].pin2, HIGH);
+    #endif
+  }
+}
+
+
+/* Read input pins and process for events. Call this either from a
+ * loop or an interrupt (eg pin change or timer).
+ *
+ * Returns 0 on no event, otherwise 0x80 or 0x40 depending on the direction.
+ */
+unsigned char rotary_process(int _i) {
+   unsigned char pinstate = (digitalRead(rotaries[_i].pin2) << 1) | digitalRead(rotaries[_i].pin1);
+  rotaries[_i].state = ttable[rotaries[_i].state & 0xf][pinstate];
+  return (rotaries[_i].state & 0x30);
+}
+
+void CheckAllEncoders(void) {
+  for (int i=0;i<NUMROTARIES;i++) {
+    unsigned char result = rotary_process(i);
+    if (result == DIR_CCW) {
+      Joystick.setButton(rotaries[i].ccwchar, 1); delay(50); Joystick.setButton(rotaries[i].ccwchar, 0);
+    };
+    if (result == DIR_CW) {
+      Joystick.setButton(rotaries[i].cwchar, 1); delay(50); Joystick.setButton(rotaries[i].cwchar, 0);
+    };
+  }
+}