unescape results from PPI::Token::QuoteLike::Words::literal

fixes #124
fixes #127

lib/PPI/Token/QuoteLike/Words.pm

@@ -42,20 +42,27 @@ BEGIN {
 
 =head2 literal
 
-Returns the words contained.  Note that this method does not check the
+Returns the words contained as a list.  Note that this method does not check the
 context that the token is in; it always returns the list and not merely
 the last element if the token is in scalar context.
 
 =cut
 
 sub literal {
-	my $self    = shift;
-	my $section = $self->{sections}->[0];
-	return split ' ', substr(
-		$self->{content},
-		$section->{position},
-		$section->{size},
-	);
+	my ( $self ) = @_;
+
+	my $content = $self->_section_content(0);
+	return if !defined $content;
+
+	# Undo backslash escaping of '\', the left delimiter,
+	# and the right delimiter.  The right delimiter will
+	# only exist with paired delimiters: qw() qw[] qw<> qw{}.
+	my ( $left, $right ) = ( $self->_delimiters, '', '' );
+	$content =~ s/\\([\Q$left$right\\\E])/$1/g;
+
+	my @words = split ' ', $content;
+
+	return @words;
 }
 
 1;

t/ppi_token_quotelike_words.t

@@ -3,7 +3,7 @@
 # Unit testing for PPI::Token::QuoteLike::Words
 
 use t::lib::PPI::Test::pragmas;
-use Test::More tests => 1381;
+use Test::More tests => 1941;
 use Test::Deep;
 
 use PPI;
@@ -52,14 +52,39 @@ LITERAL: {
 
 	my $bs = '\\'; # a single backslash character
 
+	# escaped opening and closing
+	permute_test ["$bs)"],   '(', ')', [')'];
+	permute_test ["$bs("],   '(', ')', ['('];
+	permute_test ["$bs}"],   '{', '}', ['}'];
+	permute_test ["${bs}{"], '{', '}', ['{'];
+	permute_test ["$bs]"],   '[', ']', [']'];
+	permute_test ["${bs}["], '[', ']', ['['];
+	permute_test ["$bs<"],   '<', '>', ['<'];
+	permute_test ["$bs>"],   '<', '>', ['>'];
+	permute_test ["$bs/"],   '/', '/', ['/'];
+	permute_test ["$bs'"],   "'", "'", ["'"];
+	permute_test [$bs.'"'],  '"', '"', ['"'];
+
+	# alphanum delims have to be separated from qw
+	assemble_and_run " ",  ['a', "${bs}1"], '1', " ",  " ",  '1', ['a', '1'];
+	assemble_and_run " ",  ["${bs}a"],      'a', " ",  " ",  'a', ['a'];
+	assemble_and_run "\n", ["${bs}a"],      'a', "\n", "\n", 'a', ['a'];
+
 	# '#' delims cannot be separated from qw
 	assemble_and_run '',  ['a'],      '#', '',   ' ',  '#', ['a'];
 	assemble_and_run '',  ['a'],      '#', ' ',  ' ',  '#', ['a'];
+	assemble_and_run '',  ["$bs#"],   '#', '',   ' ',  '#', ['#'];
+	assemble_and_run '',  ["$bs#"],   '#', ' ',  ' ',  '#', ['#'];
+	assemble_and_run '',  ["$bs#"],   '#', "\n", "\n", '#', ['#'];
 
 	# a single backslash represents itself
 	assemble_and_run '',  [$bs],  '(', ' ',  ' ', ')', [$bs];
 	assemble_and_run '',  [$bs],  '(', "\n", ' ', ')', [$bs];
 
+	# a double backslash represents itself
+	assemble_and_run '',  ["$bs$bs"],  '(', ' ',  ' ', ')', [$bs];
+	assemble_and_run '',  ["$bs$bs"],  '(', "\n", ' ', ')', [$bs];
+
 	# even backslash can be a delimiter, in when it is, backslashes
 	# can't be embedded or escaped.
 	assemble_and_run '',   [],    $bs, ' ',  ' ',  $bs, [];