-
Notifications
You must be signed in to change notification settings - Fork 8
/
StudyEditService.groovy
567 lines (459 loc) · 20.5 KB
/
StudyEditService.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
package dbnp.studycapturing
import groovy.sql.Sql
import org.codehaus.groovy.grails.orm.hibernate.cfg.GrailsDomainBinder
import org.dbnp.gdt.*
class StudyEditService {
def dataSource
/**
* Returns a proper list of data to generate a datatable with templated entities.
* @param params Parameters to search
int offset Display start point in the current data set.
int max Number of records that the table can display in the current draw. It is expected that the number of records returned will be equal to this number, unless the server has fewer records to return.
string search Global search field
int sortColumn Column being sorted on (you will need to decode this number for your database)
string sortDirection Direction to be sorted - "desc" or "asc".
Template template Template for the entities to read
* @return A map with all data. For example:
List entities List with all entities
int total Total number of records in the whole dataset (without taking search, offset and max into account)
int totalFiltered Total number of records in the search (without taking offset and max into account)
int ids Total list of filtered ids
*/
def getEntitiesForTemplate( searchParams, study, template ) {
def query = generateHQL( searchParams, study, template )
// Also count the total number of results in the dataset
def output = generateOutput( query, searchParams, template.entity )
output.total = template.entity.countByParentAndTemplate( study, template )
output
}
/**
* Returns a proper list of samples to generate a datatable with samples for assay selection.
* @param params Parameters to search
int offset Display start point in the current data set.
int max Number of records that the table can display in the current draw. It is expected that the number of records returned will be equal to this number, unless the server has fewer records to return.
string search Global search field
int sortColumn Column being sorted on (you will need to decode this number for your database)
string sortDirection Direction to be sorted - "desc" or "asc".
Template template Template for the entities to read
* @return A map with all data. For example:
List entities List with all entities
int total Total number of records in the whole dataset (without taking search, offset and max into account)
int totalFiltered Total number of records in the search (without taking offset and max into account)
int ids Total list of filtered ids
*/
def getSamplesForAssaySamplePage( searchParams, study ) {
def query = generateHQLForAssaySamples( searchParams, study )
// Also count the total number of results in the dataset
def output = generateOutput( query, searchParams, Sample )
output.total = Sample.countByParent( study )
output
}
/**
* Returns a proper list of subjects samples to generate a datatable for subject selection in a group
* @param params Parameters to search
int offset Display start point in the current data set.
int max Number of records that the table can display in the current draw. It is expected that the number of records returned will be equal to this number, unless the server has fewer records to return.
string search Global search field
int sortColumn Column being sorted on (you will need to decode this number for your database)
string sortDirection Direction to be sorted - "desc" or "asc".
Template template Template for the entities to read
* @return A map with all data. For example:
List entities List with all entities
int total Total number of records in the whole dataset (without taking search, offset and max into account)
int totalFiltered Total number of records in the search (without taking offset and max into account)
int ids Total list of filtered ids
*/
def getSubjectsForSubjectSelection( searchParams, study ) {
def query = generateHQLForSubjectSelection( searchParams, study )
// Also count the total number of results in the dataset
def output = generateOutput( query, searchParams, Subject )
output.total = Subject.countByParent( study )
output
}
/**
* Returns a proper list of samples to generate a datatable with templated entities.
* @param query Different parts of the HQL query to execute
* @return A map with all data. For example:
List entities List with all entities
int totalFiltered Total number of records in the search (without taking offset and max into account)
int ids Total list of filtered ids
*/
def generateOutput( query, searchParams, entity ) {
def output = [:]
// First select the number of results
def filteredIds = entity.executeQuery( "SELECT DISTINCT s.id FROM " + query.from + " WHERE " + query.where, query.params )
output.totalFiltered = filteredIds.size()
output.ids = filteredIds
// Now if filteredIds is not empty find the results themselves by that list
if ( filteredIds.size() != 0 ) {
def hql = "SELECT " + query.select + " FROM " + entity.simpleName + " " + query.select + " WHERE id IN :ids" + ( query.order ? " ORDER BY " + query.order : "" )
output.entities = entity.executeQuery( hql, [ ids: filteredIds ], [ max: searchParams.max, offset: searchParams.offset ] )
}
else {
output.entities = []
}
if( query.chooseFirst ) {
output.entities = output.entities.collect { it[0] }
}
output
}
/**
* Generates the HQL to search
* @return Map
* select
* from
* where
* order
* params
*/
def generateHQL( searchParams, study, template ) {
def entity = template.entity
def domainFields = entity.domainFields
// Find the table name from the entity
def tableName = entity.simpleName
// Create an HQL query as it gives us the most flexibility in searching and ordering
def from = tableName + " s "
def joins = []
def whereClause = []
def hqlParams = [ study: study, template: template ]
def orderBy = ""
// First add searching
if( searchParams.search ) {
// With searching, retrieving the data requires joining all text and term fields
def searchTerm = searchParams.search.toLowerCase()
// Only allow for searching in textual fields
def fieldTypesAllowed = [
TemplateFieldType.STRING,
TemplateFieldType.TEXT,
TemplateFieldType.STRINGLIST,
TemplateFieldType.EXTENDABLESTRINGLIST,
TemplateFieldType.ONTOLOGYTERM,
TemplateFieldType.TEMPLATE
]
// List of field types that have a reference to another table (and use
// the name in the other table as value), instead of a direct value
def fieldTypesAsReference = [
TemplateFieldType.STRINGLIST,
TemplateFieldType.EXTENDABLESTRINGLIST,
TemplateFieldType.ONTOLOGYTERM,
TemplateFieldType.TEMPLATE
]
// Domain fields are handled differently from template fields
domainFields.each { field ->
// Continue if this type is not allowed
if( !( field.type in fieldTypesAllowed ) )
return true;
if( field.type in fieldTypesAsReference ) {
def joinName = "domainField" + field.name
joins << "s." + field.name + " as " + joinName
whereClause << "lower( " + joinName + ".name ) LIKE :search"
} else {
whereClause << "lower( s." + field + " ) LIKE :search"
}
hqlParams[ "search" ] = "%" + searchTerm + "%"
}
template.fields.each { field ->
// Continue if this type is not allowed
if( !( field.type in fieldTypesAllowed ) )
return true;
def store = "template${field.type.casedName}Fields"
def joinName = "templateField" + field.id
joins << "s." + store + " as " + joinName + " WITH index( " + joinName + " ) = :fieldName${joinName}"
hqlParams[ "fieldName${joinName}" ] = field.name
if( field.type in fieldTypesAsReference )
whereClause << "lower( ${joinName}.name ) LIKE :search"
else
whereClause << "lower( ${joinName} ) LIKE :search"
hqlParams[ "search" ] = "%" + searchTerm + "%"
}
}
// Add ordering; to determine the column to sort on
def sortColumnIndex = searchParams.sortColumn ?: 0
def sortOrder = searchParams.sortDirection ?: "ASC"
//In order to have a natural 'order by' for the domainField 'name' we have to use a custom sort
def naturalSort = domainFields[ sortColumnIndex ]?.name.equals('name') ? true : false
// Prepare for differences in selection
def select = "DISTINCT s"
// Custom 'order by' is not allowed when using DISTINCT
if ( naturalSort ) {
select = "s"
}
def chooseFirst = false
if( sortColumnIndex != null || sortColumnIndex >= ( domainFields.size() + template.fields.size() ) ) {
if( sortColumnIndex < domainFields.size() ) {
def sortOn = domainFields[ sortColumnIndex ]?.name
orderBy = "s." + sortOn + " " + sortOrder
if ( naturalSort ) {
orderBy = "length(s." + sortOn + ") " + sortOrder + ", s." + sortOn + " " + sortOrder
}
} else {
// Sort on template field: use a join in the sql
// select * from subjects inner join template_fields sortField on ....
def sortField = template.fields[ sortColumnIndex - domainFields.size() ]
def store = "template${sortField.type.casedName}Fields"
joins << "s." + store + " as orderJoin WITH index( orderJoin ) = :sortField"
hqlParams[ "sortField" ] = sortField.name
orderBy = "orderJoin " + sortOrder
// When ordering by a templatefield, we have to include it in the query as well
// However, in order to handle the object properly, we will need to tell the
// calling method that only the first object should be chosen.
select += ", orderJoin"
chooseFirst = true
}
}
// Now build up the query, except for the SELECT part.
if( joins )
from += " LEFT JOIN " + joins.join( " LEFT JOIN " )
def where = "s.parent = :study AND s.template = :template"
if( whereClause )
where += " AND (" + whereClause.join( " OR " ) + ") "
[
select: select,
from: from,
where: where,
order: orderBy,
params: hqlParams,
chooseFirst: chooseFirst
]
}
/**
* Generates the HQL to search assay samples
* @return Map
* select
* from
* where
* order
* params
*/
def generateHQLForAssaySamples( searchParams, study ) {
def entity = Sample
// Search in
// sample name
// subject name
// eventgroup name
// samplingevent.sampleTemplate name
// Create an HQL query as it gives us the most flexibility in searching and ordering
def from = " Sample s"
def joins = []
def whereClause = []
def hqlParams = [ study: study ]
def orderBy = ""
// Add joins for related information
joins << "s.parentSubject as subject"
joins << "s.parentEvent as eventInstance"
joins << "eventInstance.eventGroup as eventGroup"
joins << "eventInstance.event as samplingEvent"
joins << "s.template as template"
joins << "s.parentSubjectEventGroup as subjectEventGroup"
// First add searching
if( searchParams.search ) {
// With searching, retrieving the data requires joining all text and term fields
def searchTerm = searchParams.search.toLowerCase()
hqlParams[ "search" ] = "%" + searchTerm + "%"
whereClause << "lower(s.name) LIKE :search"
whereClause << "lower(subject.name) LIKE :search"
whereClause << "lower(eventGroup.name) LIKE :search"
whereClause << "lower(samplingEvent.name) LIKE :search"
whereClause << "lower(template.name) LIKE :search"
}
// Add ordering; to determine the column to sort on
def sortColumnIndex = searchParams.sortColumn ?: 0
def sortOrder = searchParams.sortDirection ?: "ASC"
def fields = [
"s.name",
"subject.name",
"eventGroup.name",
"samplingEvent.name",
"template.name",
"( eventInstance.startTime + subjectEventGroup.startTime )"
]
if( sortColumnIndex != null || sortColumnIndex < fields.size() ) {
//In order to have a natural 'order by' for sample names we have to use a custom sort for that field
if ( sortColumnIndex == 0 ) {
orderBy = "length(" + fields[ sortColumnIndex ] + ") " + sortOrder + ", " + fields[ sortColumnIndex ] + " " + sortOrder
}
else {
orderBy = fields[ sortColumnIndex ] + " " + sortOrder
}
}
// Now build up the query, except for the SELECT part.
if( joins )
from += " LEFT JOIN " + joins.join( " LEFT JOIN " )
def where = "s.parent = :study"
if( whereClause )
where += " AND (" + whereClause.join( " OR " ) + ") "
[
select: "s, " + fields.join( ", " ),
from: from,
where: where,
order: orderBy,
params: hqlParams
]
}
/**
* Generates the HQL to search assay samples
* @return Map
* select
* from
* where
* order
* params
*/
def generateHQLForSubjectSelection( searchParams, study ) {
def entity = Subject
// Search in
// subject name
// subject template name
// subject speciies
// Create an HQL query as it gives us the most flexibility in searching and ordering
def from = " Subject s "
def joins = []
def whereClause = []
def hqlParams = [ study: study ]
def orderBy = ""
// Add joins for related information
joins << "s.template as template"
// First add searching
if( searchParams.search ) {
// With searching, retrieving the data requires joining all text and term fields
def searchTerm = searchParams.search.toLowerCase()
hqlParams[ "search" ] = "%" + searchTerm + "%"
whereClause << "lower(s.name) LIKE :search"
whereClause << "lower(template.name) LIKE :search"
whereClause << "lower(s.species.name) LIKE :search"
}
// Add ordering; to determine the column to sort on
def sortColumnIndex = searchParams.sortColumn ?: 0
def sortOrder = searchParams.sortDirection ?: "ASC"
def fields = [
"s.name",
"template.name",
"s.species.name",
]
if( sortColumnIndex != null || sortColumnIndex < fields.size() ) {
//In order to have a natural 'order by' for subject names we have to use a custom sort for that field
if ( sortColumnIndex == 0 ) {
orderBy = "length(" + fields[ sortColumnIndex ] + ") " + sortOrder + ", " + fields[ sortColumnIndex ] + " " + sortOrder
}
else {
orderBy = fields[ sortColumnIndex ] + " " + sortOrder
}
}
// Now build up the query, except for the SELECT part.
if( joins )
from += " LEFT JOIN " + joins.join( " LEFT JOIN " )
def where = "s.parent = :study"
if( whereClause )
where += " AND (" + whereClause.join( " OR " ) + ") "
[
select: "s, " + fields.join( ", " ),
from: from,
where: where,
order: orderBy,
params: hqlParams
]
}
def putParentIntoEntity( entity, params ) {
// Was a parentID given
if( params.parentId ) {
entity.parent = Study.read( params.long( 'parentId' ) )
}
}
def putParamsIntoEntity( entity, params ) {
// did the template change?
if (params.get('template') && entity.template?.name != params.get('template')) {
// set the template
entity.template = Template.findAllByName(params.remove('template') ).find { it.entity == entity.class }
}
// does the study have a template set?
if (entity.template && entity.template instanceof Template) {
// yes, iterate through template fields
entity.giveFields().each() {
// and set their values
entity.setFieldValue(it.name, params.get(it.escapedName()))
}
}
return entity
}
/**
* Generate new samples for a newly created subjectEventGroup
* @param study the study
* @param subjectEventGroups list of SubjectEventGroups
* @return Number of inserts/updates
*/
protected Integer generateSamples( Study study, List subjectEventGroups ) {
def numChanged = 0
def samples = Sample.executeQuery("SELECT id, name FROM Sample WHERE parent = :study", [ study: study ])
def sampleIds
def sampleNames
if ( samples ) {
sampleIds = samples.collect() { it[0] }
sampleNames = samples.collect() { it[1] }
}
def sql = new Sql(dataSource)
sql.withBatch( 250, "INSERT INTO sample(id, version, name, parent_id, parent_event_id, parent_subject_id, template_id, parent_subject_event_group_id) VALUES (nextval('hibernate_sequence'), 0, :name, :study, :event, :subject, :template, :subjectEventGroup)" ) { preparedStatement ->
subjectEventGroups.each { SubjectEventGroup subjectEventGroup ->
subjectEventGroup.subjectGroup.subjects?.each { subject ->
subjectEventGroup.eventGroup.samplingEventInstances?.each { samplingEventInstance ->
def newSample = new Sample(
parent: subjectEventGroup.parent,
parentSubject: subject,
parentEvent: samplingEventInstance,
parentSubjectEventGroup: subjectEventGroup,
template: samplingEventInstance.event.sampleTemplate
)
newSample.name = newSample.generateName()
def sampleIndex = -1
if ( sampleNames ) {
sampleIndex = sampleNames.indexOf(newSample.name)
}
if ( sampleIndex == -1 ) {
preparedStatement.addBatch( [ name: newSample.name, study: newSample.parent.id, event: newSample.parentEvent.id, subject: newSample.parentSubject.id, template: newSample.template.id, subjectEventGroup: newSample.parentSubjectEventGroup.id ] )
numChanged++
}
else {
def oldSample = Sample.read( sampleIds[sampleIndex] )
if ( oldSample.template != newSample.template ) {
oldSample.template = newSample.template
oldSample.save()
numChanged++
}
}
}
}
}
}
return numChanged
}
/**
* Regenerate sampleNames for all samples in a study.
* @param study the study
* @return Number of updates
*/
protected Integer regenerateSampleNames( Study study ) {
def count = 0
def sql = new Sql(dataSource)
sql.withBatch( 250, "UPDATE sample SET name = :name WHERE id = :sampleId" ) { preparedStatement ->
study.samples.each() { Sample sample ->
preparedStatement.addBatch( [sampleId: sample.id, name: java.util.UUID.randomUUID().toString() ] )
}
}
def samples = []
sql.withBatch( 250, "UPDATE sample SET name = :name WHERE id = :sampleId" ) { preparedStatement ->
study.samples.each() { Sample sample ->
String generatedSampleName = sample.generateName()
if (samples.contains(generatedSampleName)) {
def i = 1
while (samples.contains(generatedSampleName + '_' + i.toString())) {
i++
}
generatedSampleName = generatedSampleName + '_' + i.toString()
}
samples << generatedSampleName
preparedStatement.addBatch( [sampleId: sample.id, name: generatedSampleName ] )
count++
}
}
return count
}
}