/
PlmSchmidt_d1.f95
340 lines (288 loc) · 10.7 KB
/
PlmSchmidt_d1.f95
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
subroutine PlmSchmidt_d1(p, dp1, lmax, z, csphase, cnorm, exitstatus)
!------------------------------------------------------------------------------
!
! This function evalutates all of the normalized associated Legendre
! functions up to degree lmax. The functions are initially scaled by
! 10^280 sin^m in order to minimize the effects of underflow at large m
! near the poles (see Holmes and Featherstone 2002, J. Geodesy, 76, 279-299).
! On a macOS system with a maximum allowable double precision value of
! 2.225073858507203E-308 the scaled portion of the algorithm will not overflow
! for degrees less than or equal to 2800.
!
! For each value of m, the rescaling factor is computed as
! rescalem=rescalem*sin(theta), with the intial value of rescalem being equal
! to 1/scalef (which is here equal to 10^280). This will gradually reduce this
! huge number to a tiny number, and will ultimately underflow. In order to
! prevent this underflow, when rescalem becomes less than 10^(-280), the
! subsequent rescaling factors of sin(theta) will be directly applied to Plm,
! and then this number will be multipled by the old value of rescalem.
!
! Temporary variables in saved in an allocated array. In order to explicitly
! deallocate this memory, call this routine with a spherical harmonic degree
! of -1.
!
! Calling Parameters
!
! IN
! lmax Maximum spherical harmonic degree to compute.
! z cos(colatitude) or sin(latitude).
!
! OPTIONAL (IN)
! csphase 1: Do not include the phase factor of (-1)^m
! -1: Apply the phase factor of (-1)^m.
! cnorm 0: Use real normalization.
! 1: Use complex normalization.
!
! OUT
! p A vector of all associated Legendgre polynomials
! evaluated at z up to lmax. The lenght must by greater
! or equal to (lmax+1)*(lmax+2)/2.
! dp1 A vector of all first derivatives of the normalized
! Legendgre polynomials evaluated at z up to lmax with
! dimension (lmax+1).
!
! OPTIONAL (OUT)
! exitstatus If present, instead of executing a STOP when an error
! is encountered, the variable exitstatus will be
! returned describing the error.
! 0 = No errors;
! 1 = Improper dimensions of input array;
! 2 = Improper bounds for input variable;
! 3 = Error allocating memory;
! 4 = File IO error.
!
! Notes:
!
! 1. The employed normalization is the "Schmidt semi-normalized convention."
! The integral of (PlmSchmidt*cos(m theta))**2 or
! (PlmSchmidt*sin (m theta))**2 over all space is 4 pi/(2L+1).
! 2. The integral of PlmSchmidt**2 over (-1,1) is 2 * (2 - delta(0,m)) /
! (2L+1). If CNORM = 1, then this is equal to 2/(2l+1).
! 3. The index of the array p corresponds to l*(l+1)/2 + m + 1. As such
! the array p should be dimensioned as (lmax+1)*(lmax+2)/2 in the
! calling routine.
! 4. Derivatives are calculated using the unnormalized identities
! P'l,m = ( (l+m) Pl-1,m - l z Plm ) / (1-z**2) (for l>m), and
! P'll = - l z Pll / (1-z**2) (for l=m).
! 5. The derivative is not defined at z=+-1 for all m>0, and is therefore not
! calculated here.
! 6. The default is to exlude the Condon-Shortley phase of (-1)^m.
!
! Copyright (c) 2005-2019, SHTOOLS
! All rights reserved.
!
!------------------------------------------------------------------------------
use SHTOOLS, only: CSPHASE_DEFAULT
use ftypes
implicit none
integer, intent(in) :: lmax
real(dp), intent(out) :: p(:), dp1(:)
real(dp), intent(in) :: z
integer, intent(in), optional :: csphase, cnorm
integer, intent(out), optional :: exitstatus
real(dp) :: pm2, pm1, pmm, plm, rescalem, u, scalef
real(dp), save, allocatable :: f1(:), f2(:), sqr(:)
integer :: k, kstart, m, l, sdim, astat(3)
integer, save :: lmax_old = 0
integer(int1) :: phase
!$OMP threadprivate(f1, f2, sqr, lmax_old)
if (present(exitstatus)) exitstatus = 0
if (lmax == -1) then
if (allocated (sqr)) deallocate (sqr)
if (allocated (f1)) deallocate (f1)
if (allocated (f2)) deallocate (f2)
lmax_old = 0
return
end if
sdim = (lmax+1)*(lmax+2)/2
if (size(p) < sdim) then
print*, "Error --- PlmSchmidt_d1"
print*, "P must be dimensioned as (LMAX+1)*(LMAX+2)/2 " // &
"where LMAX is ", lmax
print*, "Input array is dimensioned ", size(p)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (size(dp1) < sdim) then
print*, "Error --- PlmSchmidt_d1"
print*, "DP1 must be dimensioned as (LMAX+1)*(LMAX+2)/2 " // &
"where LMAX is ", lmax
print*, "Input array is dimensioned ", size(dp1)
if (present(exitstatus)) then
exitstatus = 1
return
else
stop
end if
else if (lmax < 0) then
print*, "Error --- PlmSchmidt_d1"
print*, "LMAX must be greater than or equal to 0."
print*, "Input value is ", lmax
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
else if (abs(z) > 1.0_dp) then
print*, "Error --- PlmSchmidt_d1"
print*, "ABS(Z) must be less than or equal to 1."
print*, "Input value is ", z
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
else if (abs(z) == 1.0_dp) then
print*, "Error --- PlmSchmidt_d1"
print*, "Derivative can not be calculated at Z = 1 or -1."
print*, "Input value is ", z
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
end if
if (present(csphase)) then
if (csphase == -1) then
phase = -1
else if (csphase == 1) then
phase = 1
else
print*, "Error --- PlmSchmidt_d1"
print*, "CSPHASE must be 1 (exclude) or -1 (include)."
print*, "Input value is ", csphase
if (present(exitstatus)) then
exitstatus = 2
return
else
stop
end if
end if
else
phase = CSPHASE_DEFAULT
end if
scalef = 1.0e-280_dp
if (lmax > lmax_old) then
if (allocated (sqr)) deallocate (sqr)
if (allocated (f1)) deallocate (f1)
if (allocated (f2)) deallocate (f2)
allocate (sqr(2*lmax+1), stat=astat(1))
allocate (f1((lmax+1)*(lmax+2)/2), stat=astat(2))
allocate (f2((lmax+1)*(lmax+2)/2), stat=astat(3))
if (astat(1) /= 0 .or. astat(2) /= 0 .or. astat(3) /= 0) then
print*, "Error --- PlmSchmidt_d1"
print*, "Problem allocating arrays SQR, F1 and F2", astat(1), &
astat(2), astat(3)
if (present(exitstatus)) then
exitstatus = 3
return
else
stop
end if
end if
!----------------------------------------------------------------------
!
! Precompute square roots of integers that are used several times.
!
!----------------------------------------------------------------------
do l = 1, 2 * lmax+1
sqr(l) = sqrt(dble(l))
end do
!----------------------------------------------------------------------
!
! Precompute multiplicative factors used in recursion relationships
! PlmSchmidt(l,m) = x*f1(l,m)*PlmSchmidt(l-1,m) -
! PlmSchmidt(l-2,m)*f2(l,m)
! k = l*(l+1)/2 + m + 1
! Note that prefactors are not used for the case when m=l and m=l-1,
! as a different recursion is used for these two values.
!
!----------------------------------------------------------------------
k = 3
do l = 2, lmax, 1
k = k + 1
f1(k) = dble(2*l-1) / dble(l)
f2(k) = dble(l-1) / dble(l)
do m = 1, l-2
k = k + 1
f1(k) = dble(2*l-1) / sqr(l+m) / sqr(l-m)
f2(k) = sqr(l-m-1) * sqr(l+m-1) / sqr(l+m) / sqr(l-m)
end do
k = k + 2
end do
lmax_old = lmax
end if
!--------------------------------------------------------------------------
!
! Calculate P(l,0). These are not scaled.
!
!--------------------------------------------------------------------------
u = sqrt((1.0_dp - z) * (1.0_dp + z)) ! sin(theta)
pm2 = 1.0_dp
p(1) = 1.0_dp
dp1(1) = 0.0_dp
if (lmax == 0) return
pm1 = z
p(2) = pm1
dp1(2) = 1.0_dp
k = 2
do l = 2, lmax, 1
k = k + l
plm = f1(k) * z * pm1 - f2(k) * pm2
p(k) = plm
dp1(k) = l * (pm1 - z * plm) / u**2
pm2 = pm1
pm1 = plm
end do
!--------------------------------------------------------------------------
!
! Calculate P(m,m), P(m+1,m), and P(l,m)
!
!--------------------------------------------------------------------------
if (present(cnorm)) then
if (cnorm == 1) then
pmm = scalef
else
pmm = sqr(2) * scalef
end if
else
pmm = sqr(2) * scalef
end if
rescalem = 1.0_dp / scalef
kstart = 1
do m = 1, lmax - 1, 1
rescalem = rescalem * u
! Calculate P(m,m)
kstart = kstart + m + 1
pmm = phase * pmm * sqr(2*m+1) / sqr(2*m)
p(kstart) = pmm * rescalem / sqr(2*m+1)
dp1(kstart) = -m * z * p(kstart) / u**2
pm2 = pmm / sqr(2*m+1)
! Calculate P(m+1,m)
k = kstart + m + 1
pm1 = z * sqr(2*m+1) * pm2
p(k) = pm1 * rescalem
dp1(k) = (p(k-m-1) * sqr(2*m+1) - z * (m+1) * p(k)) / u**2
! Calculate P(l,m)
do l = m + 2, lmax, 1
k = k + l
plm = z * f1(k) * pm1 - f2(k) * pm2
p(k) = plm * rescalem
dp1(k) = ( sqr(l+m) * sqr(l-m) * p(k-l) - l * z * p(k) ) / u**2
pm2 = pm1
pm1 = plm
end do
end do
! Calculate P(lmax,lmax)
rescalem = rescalem * u
kstart = kstart + m + 1
pmm = phase * pmm / sqr(2*lmax)
p(kstart) = pmm*rescalem
dp1(kstart) = -lmax * z * p(kstart) / u**2
end subroutine PlmSchmidt_d1