/
NM_ArtTab.ipf
4924 lines (3329 loc) · 112 KB
/
NM_ArtTab.ipf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#pragma rtGlobals=3 // Use modern global access method and strict wave access.
#pragma hide = 1
//****************************************************************
//
// NeuroMatic: data aquisition, analyses and simulation software that runs with the Igor Pro environment
// Copyright (C) 2024 The Silver Lab, UCL
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// ( at your option ) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <https://www.gnu.org/licenses/>.
//
// Contact Jason@ThinkRandom.com
// www.NeuroMatic.ThinkRandom.com
//
//****************************************************************
//
// Stimulus Artefact Subtraction
//
// NM tab entry "Art"
//
//****************************************************************
//
// Default Values
//
//****************************************************************
Static StrConstant k_ArtShape = "PN"
// "PN" - artefact ends with large positive peak followed by small negative peak
// "NP" - artefact ends with large negative peak followed by small positive peak
Static Constant k_ArtWidth = 0.5 // approximate length of artefact
Static Constant k_ArtLevelDetection = 50 // threshold for artefact level detection
Static Constant k_ArtLevelDetectionEdge = 1 // see Igor FindLevels edge
Static Constant k_ArtFitWin = 0.2 // artefact decay fit window
Static Constant k_ArtPeakDT = 0 // artefact peak detection offset for computing decay fit window, 0 - no time shift
StrConstant k_ArtFitFxnList = "Exp;2Exp;"
Static StrConstant k_ArtFitFxn = "Exp" // decay function for artefact tail fit // "Exp" or "2Exp"
Static Constant k_SubtractWin = 2 // subtraction window
// SubtractWin should include extrapolation after ArtFitWin to allow decay to fall back to baseline
//StrConstant k_ArtBslnFxnList = "Avg;Line;Exp;2Exp;Zero;" // 2Exp NOT WORKING
StrConstant k_ArtBslnFxnList = "Avg;Line;Exp;Zero;"
Static StrConstant k_BslnFxn = "Avg" // baseline function to compute within BslnWin:
// "Avg" - baseline is average value, i.e. line with zero slope
// "Line" - fits a line to baseline data; use if your baseline is not always flat
// "Exp" - fits an 1-exp to baseline data; use if your baseline has exp decay
// "Zero" - baseline is zero
Static Constant k_BslnWin = 1.5 // baseline window size; baseline is computed immediately before artefact time
Static Constant k_BslnDT = 0.1 // baseline time shift negative from artefact time, 0 - no time shift
Static Constant k_BslnConvergeWin = 0.5 // length of steady-state convergence test window
Static Constant k_BslnConvergeNstdv = 1 // steady-state convergence test between baseline and artefact fit, number of stdv of the data wave
Static Constant k_BslnExpSlopeThreshold = 0
// compute baseline exp fit if baseline slope > +threshold, otherwise compute baseline avg
// compute baseline exp fit if baseline slope < -threshold, otherwise compute baseline avg
Static Constant k_DragWaveAll = 1 // (0) drag waves adjust current artefact (1) drag waves adjust all artefacts
Static Constant k_SaveFitParameters = 1 // 0 or 1
Static Constant k_SaveSubtractedArt = 1 // 0 or 1 // AT_A_ waves
// Static StrConstant k_WaveNameFormat = "v2" // old
Static StrConstant k_WaveNameFormat = "v3p"
//****************************************************************
Static StrConstant NMArtDF = "root:Packages:NeuroMatic:Art:"
//****************************************************************
Menu "NeuroMatic"
Submenu StrVarOrDefault( NMDF + "NMMenuShortcuts" , "\\M1(Keyboard Shortcuts" )
StrVarOrDefault( NMDF + "NMMenuShortcutArt0" , "" )
StrVarOrDefault( NMDF + "NMMenuShortcutArt1" , "" ), /Q, NMArtCall( "NextArt" )
StrVarOrDefault( NMDF + "NMMenuShortcutArt2" , "" ), /Q, NMArtCall( "SubtractToggle" )
End
End // NeuroMatic menu
//****************************************************************
Function NMMenuBuildArt()
if ( NMVarGet( "NMOn" ) && StringMatch( CurrentNMTabName(), "Art" ) )
SetNMstr( NMDF + "NMMenuShortcutArt0", "-" )
SetNMstr( NMDF + "NMMenuShortcutArt1", "Next Artefact/4" )
SetNMstr( NMDF + "NMMenuShortcutArt2", "Subtract/5" )
else
SetNMstr( NMDF + "NMMenuShortcutArt0", "" )
SetNMstr( NMDF + "NMMenuShortcutArt1", "" )
SetNMstr( NMDF + "NMMenuShortcutArt2", "" )
endif
End // NMMenuBuildArt
//****************************************************************
Function /S NMTabPrefix_Art()
return "AT_"
End // NMTabPrefix_Art
//****************************************************************
Function NMArtTab( enable )
Variable enable // ( 0 ) disable ( 1 ) enable tab
Variable autoFit //, error = NaN
if ( enable )
CheckPackage( "Art", 0 ) // declare globals if necessary
NMArtCheck()
autoFit = NMArtVarGet( "AutoFit" )
//error = NMArtWavesCheck( forceMakeFits=autoFit )
NMArtMake( 0 ) // make tab controls if necessary
NMArtWaveOfArtTimesSet( "UPDATE", artNum=-1, forceMakeFits=autoFit ) // calls NMArtWavesCheck()
endif
if ( !DataFolderExists( NMArtDF ) )
return 0
endif
NMArtDisplay( enable )
NMArtChanGraphControls( enable )
if ( enable && autoFit )
NMArtFit( checkWaves=0 )
endif
End // NMArtTab
//****************************************************************
Function NMArtTabKill( what )
String what
String df = NMArtDF
strswitch( what )
case "waves":
break
case "globals":
if ( DataFolderExists( df ) )
// KillDataFolder $df
endif
break
endswitch
End // NMArtTabKill
//****************************************************************
Function NMArtAuto() // called when wave number is incremented or wave-prefix changes
Variable autoFit = NMArtVarGet( "AutoFit" )
NMArtWaveOfArtTimesSet( "UPDATE", artNum=-1, forceMakeFits=autoFit ) // calls NMArtWavesCheck()
if ( autoFit )
NMArtFit( checkWaves=0 )
endif
return 0
End // NMArtAuto
//****************************************************************
Function NMArtCheck() // check globals
String df = NMArtDF
if ( !DataFolderExists( df ) )
return 0 // Art folder does not exist
endif
// panel control parameters
CheckNMVar( df+"NumArtefacts", 0 )
CheckNMVar( df+"ArtNum", NumVarOrDefault( df+"StimNum", 0 ) )
CheckNMVar( df+"ArtTime", NaN )
CheckNMVar( df+"BslnValue1", Nan )
CheckNMVar( df+"BslnValue2", Nan )
CheckNMVar( df+"BslnChi", Nan )
CheckNMVar( df+"DcayValue1", Nan )
CheckNMVar( df+"DcayValue2", Nan )
CheckNMVar( df+"DcayChi", Nan )
CheckNMVar( df+"AutoFit", 1 )
CheckNMVar( df+"FitFlag", NaN )
CheckNMStr( df+"ArtTimeWName", StrVarOrDefault( df+"StimTimeWName", "" ) )
// drag wave variables
CheckNMVar( df+"BslnXbgn", NaN )
CheckNMVar( df+"BslnXend", NaN )
CheckNMVar( df+"Xbgn", NaN )
CheckNMVar( df+"Xend", NaN )
// fit variables
CheckNMStr( df+"BslnFxn", k_BslnFxn )
CheckNMVar( df+"BslnDT", abs( k_BslnDT ) )
CheckNMVar( df+"BslnWin", abs( k_BslnWin ) )
CheckNMVar( df+"BslnSubtract", 0 )
CheckNMVar( df+"BslnConvergeWin", abs( k_BslnConvergeWin ) )
CheckNMVar( df+"BslnConvergeNstdv", abs( k_BslnConvergeNstdv ) )
CheckNMStr( df+"ArtShape", k_ArtShape )
CheckNMVar( df+"ArtWidth", abs( k_ArtWidth ) )
CheckNMVar( df+"ArtFitWin", abs( NumVarOrDefault( df+"DecayWin", k_ArtFitWin ) ) )
CheckNMVar( df+"ArtPeakDT", k_ArtPeakDT )
CheckNMStr( df+"ArtFitFxn", StrVarOrDefault( df+"DecayFxn", k_ArtFitFxn ) )
CheckNMVar( df+"SubtractWin", abs( k_SubtractWin ) )
CheckNMVar( df+"SaveFitParameters", k_SaveFitParameters )
CheckNMVar( df+"SaveSubtractedArt", k_SaveSubtractedArt )
CheckNMStr( df+"WaveNameFormat", k_WaveNameFormat )
// channel display waves
CheckNMWave( df+"AT_Display", 0, Nan )
CheckNMWave( df+"AT_Fit", 0, Nan )
CheckNMWave( df+"AT_FitB", 0, Nan )
CheckNMWave( df+"AT_TimeX", 0, Nan )
CheckNMWave( df+"AT_TimeY", 0, Nan )
// see NMArtWavesCheck()
End // NMArtCheck
//****************************************************************
Function NMArtWavesCheck( [ forceMake, forceMakeFits ] )
Variable forceMake, forceMakeFits
//print GetRTStackInfo( 1 ), GetRTStackInfo( 2 )
Variable count1, aflag, newWave = 0
String wList, txt, prefixFolder, groupName
String df = NMArtDF
if ( !z_NMArtWaveSelectOK() )
return -1
endif
Variable saveSubtractedArt = NMArtVarGet( "SaveSubtractedArt" )
Variable currentChan = CurrentNMChannel()
//Variable currentWave = CurrentNMWave()
Variable currentGroup = NMGroupsNum( -1 )
String currentWavePrefix = CurrentNMWavePrefix()
String wName = CurrentNMWaveName()
String dwName = ChanDisplayWave( -1 )
String noArtName = NMArtSubWaveName( "no_art" )
String artName = NMArtSubWaveName( "art" )
String fwName = NMArtSubWaveName( "finished" )
//wName = NMWaveSelected( currentChan, currentWave )
//wList = NMWaveSelectList( -1 )
String xList = NMSetsWaveList( "SetX", currentChan )
Variable excludeThisWave = NMSetXType() && ( WhichListItem( wName, xList ) >= 0 )
if ( excludeThisWave )
if ( WaveExists( $noArtName ) || WaveExists( $artName ) || WaveExists( $fwName ) )
txt = "NMArtWavesCheck: Art waves exist for " + NMQuotes( wName ) + ". "
txt += "Do you want to delete them?"
aflag = NMDoAlert( txt, title="NM Art Tab", alertType=2 )
if ( aflag == 1 )
KillWaves /Z $noArtName
KillWaves /Z $artName
KillWaves /Z $fwName
endif
endif
return 0
endif
if ( WaveExists( $dwName ) )
if ( forceMake || !WaveExists( $noArtName ) )
Duplicate /O $dwname $noArtName
newWave = 1
endif
if ( saveSubtractedArt && ( forceMake || !WaveExists( $artName ) ) )
Duplicate /O $dwname $artName
Wave wtemp = $artName
wtemp = NaN
endif
if ( forceMakeFits || forceMake || !WaveExists( $df+"AT_Fit" ) )
Duplicate /O $dwname $df+"AT_Fit"
Wave wtemp = $df+"AT_Fit"
wtemp = NaN
endif
if ( forceMakeFits || forceMake || !WaveExists( $df+"AT_FitB" ) )
Duplicate /O $dwname $df+"AT_FitB"
Wave wtemp = $df+"AT_FitB"
wtemp = NaN
endif
endif
count1 = z_NMArtWavesCheck_TimeXY( forceMake ) // check AT_TimeX and AT_TimeY
z_NMArtWavesCheck_F( forceMake, count1 ) // check AT_F_ wave
wList = WaveList( "AT_" + currentWavePrefix + "*", ";", "" )
if ( ItemsInList( wList ) > 0 )
NMPrefixAdd( "AT_" + currentWavePrefix )
endif
if ( newWave && WaveExists( $noArtName ) )
prefixFolder = NMPrefixFolderDF( "", "AT_" + currentWavePrefix )
if ( DataFolderExists( prefixFolder ) )
groupName = NMGroupsName( currentGroup )
if ( strlen( groupName ) > 0 )
NMSetsWaveListAdd( noArtName, groupName, currentChan, prefixFolder=prefixFolder )
endif
endif
endif
return 0
End // NMArtWavesCheck
//****************************************************************
Static Function z_NMArtWavesCheck_TimeXY( forceMake )
Variable forceMake
Variable icnt, pnts, numArtefacts = 0, count2 = 0, ok = 0
Variable pbgn, pend
String wList, wName, xName, yName
String df = NMArtDF
String xWave = NMXwave()
Variable artWidth = NMArtVarGet( "ArtWidth" )
String waveNameOrSpikeSubfolder = NMArtStrGet( "ArtTimeWName" )
Variable currentWave = CurrentNMWave()
String dwName = ChanDisplayWave( -1 )
if ( WaveExists( $waveNameOrSpikeSubfolder ) )
wName = waveNameOrSpikeSubfolder
Wave wtemp = $wName
for ( icnt = 0 ; icnt < numpnts( wtemp ) ; icnt += 1 )
if ( numtype( wtemp[ icnt ] ) == 0 )
numArtefacts += 1
endif
endfor
if ( WaveExists( $df+"AT_TimeX" ) )
pnts = numpnts( $df+"AT_TimeX" )
else
pnts = 0
endif
if ( forceMake || ( pnts != numArtefacts ) )
Make /O/N=( numArtefacts ) $df+"AT_TimeX" = NaN
Make /O/N=( numArtefacts ) $df+"AT_TimeY" = NaN
Wave twave = $df+"AT_TimeX"
for ( icnt = 0 ; icnt < numpnts( wtemp ) ; icnt += 1 )
if ( numtype( wtemp[ icnt ] ) == 0 )
twave[ count2 ] = wtemp[ icnt ]
count2 += 1
endif
endfor
endif
ok = WaveExists( $df+"AT_TimeX" ) && ( numpnts( $df+"AT_TimeX" ) == numArtefacts )
elseif ( ( strlen( waveNameOrSpikeSubfolder ) > 0 ) && DataFolderExists( waveNameOrSpikeSubfolder ) )
wList = NMSpikeSubfolderRasterList( waveNameOrSpikeSubfolder, 1, 1 )
if ( ItemsInList( wList ) == 2 )
xName = StringFromList( 0, wList )
yName = StringFromList( 1, wList )
if ( numpnts( $xName ) == numpnts( $yName ) )
Wave wtemp = $xName
Wave ytemp = $yName
for ( icnt = 0 ; icnt < numpnts( wtemp ) ; icnt += 1 )
if ( ( numtype( wtemp[ icnt ] ) == 0 ) && ( ytemp[ icnt ] == currentWave ) )
numArtefacts += 1
endif
endfor
if ( WaveExists( $df+"AT_TimeX" ) )
pnts = numpnts( $df+"AT_TimeX" )
else
pnts = 0
endif
if ( forceMake || ( pnts != numArtefacts) )
Make /O/N=( numArtefacts ) $df+"AT_TimeX" = NaN
Make /O/N=( numArtefacts ) $df+"AT_TimeY" = NaN
Wave twave = $df+"AT_TimeX"
for ( icnt = 0 ; icnt < numpnts( wtemp ) ; icnt += 1 )
if ( ( numtype( wtemp[ icnt ] ) == 0 ) && ( ytemp[ icnt ] == currentWave ) )
twave[ count2 ] = wtemp[ icnt ]
count2 += 1
endif
endfor
endif
endif
endif
ok = WaveExists( $df+"AT_TimeX" ) && ( numpnts( $df+"AT_TimeX" ) == numArtefacts )
endif
if ( ok ) // set y-values for AT_TimeY
Wave twave = $df+"AT_TimeX"
Wave ywave = $df+"AT_TimeY"
for ( icnt = 0; icnt < numpnts( twave ); icnt += 1 )
if ( numtype( ywave[ icnt ] ) == 0 )
continue
endif
pbgn = z_NMX2Pnt( dwName, xWave, twave[ icnt ] - 2 * artWidth )
pend = z_NMX2Pnt( dwName, xWave, twave[ icnt ] - 1 * artWidth )
WaveStats /Q/R=[ pbgn, pend ] $dwName
ywave[ icnt ] = V_avg
endfor
else
Make /O/N=0 $df+"AT_TimeX"
Make /O/N=0 $df+"AT_TimeY"
endif
return numArtefacts
End // z_NMArtWavesCheck_TimeXY
//****************************************************************
Static Function z_NMX2Pnt( yWave, xWave, xValue )
String yWave, xWave
Variable xValue
if ( !WaveExists( $yWave ) )
return NaN
endif
if ( WaveExists( $xWave ) )
return NMX2Pnt( xWave, xValue )
else
return x2pnt( $yWave, xValue )
endif
End // z_NMX2Pnt
//****************************************************************
Static Function z_NMArtWavesCheck_F( forceMake, numArtefacts)
Variable forceMake
Variable numArtefacts
Variable icnt, jcnt
String df = NMArtDF
Variable saveFitParameters = NMArtVarGet( "SaveFitParameters" )
String fwName = NMArtSubWaveName( "finished" )
if ( ( numtype( numArtefacts ) > 0 ) || ( numArtefacts <= 0 ) )
return NaN
endif
if ( forceMake || !WaveExists( $fwName ) || ( ( numArtefacts > 0 ) && ( DimSize( $fwName, 0 ) != numArtefacts ) ) )
if ( saveFitParameters )
Make /O/N=( numArtefacts, 12 ) $fwName = NaN
else
Make /O/N=( numArtefacts, 6 ) $fwName = NaN
endif
endif
if ( DimSize( $fwName, 1 ) == 2 ) // old format
Duplicate /O $fwName $df+"F_Save"
Wave f_old = $df+"F_Save"
if ( saveFitParameters )
Make /O/N=( numArtefacts, 12 ) $fwName = NaN
else
Make /O/N=( numArtefacts, 6 ) $fwName = NaN
endif
Wave ftemp = $fwName
for ( icnt = 0; icnt < numArtefacts; icnt += 1 )
ftemp[ icnt ][ 0 ] = f_old[ icnt ][ 0 ]
ftemp[ icnt ][ 1 ] = f_old[ icnt ][ 1 ]
endfor
endif
if ( DimSize( $fwName, 1 ) == 8 ) // old format
Duplicate /O $fwName $df+"F_Save"
Wave f_old = $df+"F_Save"
Make /O/N=( numArtefacts, 12 ) $fwName = NaN
Wave ftemp = $fwName
for ( icnt = 0; icnt < numArtefacts; icnt += 1 )
ftemp[ icnt ][ 0 ] = f_old[ icnt ][ 0 ]
ftemp[ icnt ][ 1 ] = f_old[ icnt ][ 1 ]
ftemp[ icnt ][ 4 ] = f_old[ icnt ][ 2 ]
ftemp[ icnt ][ 5 ] = f_old[ icnt ][ 3 ]
ftemp[ icnt ][ 6 ] = f_old[ icnt ][ 4 ]
ftemp[ icnt ][ 9 ] = f_old[ icnt ][ 5 ]
ftemp[ icnt ][ 10 ] = f_old[ icnt ][ 6 ]
ftemp[ icnt ][ 11 ] = f_old[ icnt ][ 7 ]
endfor
endif
Wave ftemp = $fwName
//SetDimLabel 0, -1, artN, ftemp
SetDimLabel 1, 0, onset, ftemp
SetDimLabel 1, 1, finished, ftemp
if ( DimSize( ftemp, 1 ) == 6 )
SetDimLabel 1, 2, b_bgn, ftemp
SetDimLabel 1, 3, b_end, ftemp
SetDimLabel 1, 4, a_bgn, ftemp
SetDimLabel 1, 5, a_end, ftemp
elseif ( DimSize( ftemp, 1 ) == 12 )
SetDimLabel 1, 2, b_bgn, ftemp
SetDimLabel 1, 3, b_end, ftemp
SetDimLabel 1, 4, b_k1, ftemp
SetDimLabel 1, 5, b_k2, ftemp
SetDimLabel 1, 6, b_chi, ftemp
SetDimLabel 1, 7, a_bgn, ftemp
SetDimLabel 1, 8, a_end, ftemp
SetDimLabel 1, 9, a_k1, ftemp
SetDimLabel 1, 10, a_k2, ftemp
SetDimLabel 1, 11, a_chi, ftemp
else
return NaN
endif
return 0
End // z_NMArtWavesCheck_F
//****************************************************************
Function NMArtConfigs()
NMConfigStr( "Art", "ArtShape", k_ArtShape, "artefact end polarity, Pos-Neg or Neg-Pos", "PN;NP;" )
NMConfigVar( "Art", "ArtWidth", abs( k_ArtWidth ), "approx artefact width", "" )
NMConfigVar( "Art", "ArtPeakDT", k_ArtPeakDT, "artefact peak detection offset for fit to artefact decay", "" )
NMConfigVar( "Art", "BslnSubtract", 0, "subtract baseline: 0-no, 1-yes", "boolean" )
NMConfigVar( "Art", "BslnConvergeNstdv", abs( k_BslnConvergeNstdv ), "steady-state convergence test between baseline and artefact fit, number of data stdv", "" )
NMConfigVar( "Art", "BslnConvergeWin", abs( k_BslnConvergeWin ), "length of steady-state convergence test window", "" )
NMConfigVar( "Art", "BslnExpSlopeThreshold", k_BslnExpSlopeThreshold, "slope threshold for baseline exp fit", "" )
NMConfigVar( "Art", "SaveFitParameters", k_SaveFitParameters, "Save baseline and artefact fit parameters", "boolean" )
NMConfigVar( "Art", "SaveSubtractedArt", k_SaveSubtractedArt, "Save subtracted artefacts to AT_A_ wave", "boolean" )
NMConfigStr( "Art", "WaveNameFormat", k_WaveNameFormat, "output wave name format", "v2;v3p;" )
NMConfigVar( "Art", "t1_hold", NaN, "fit hold value of t1", "" )
NMConfigVar( "Art", "t1_min", NaN, "t1 min value", "" )
NMConfigVar( "Art", "t1_max", NaN, "t1 max value", "" )
NMConfigVar( "Art", "t2_hold", NaN, "fit hold value of t2", "" )
NMConfigVar( "Art", "t2_min", NaN, "t2 min value", "" )
NMConfigVar( "Art", "t2_max", NaN, "t2 max value", "" )
NMConfigStr( "Art", "BaseColor", NMGreenStr, "baseline display color", "RGB" )
NMConfigStr( "Art", "DecayColor", NMRedStr, "decay display color", "RGB" )
NMConfigVar( "Art", "DisplayPrecision", 2, "decimal numbers to display", "" )
End // NMArtConfigs
//****************************************************************
Function NMArtVarGet( varName )
String varName
Variable defaultVal = NaN
strswitch( varName )
case "ArtNum":
defaultVal = 0
break
case "ArtWidth":
defaultVal = abs( k_ArtWidth )
break
case "ArtFitWin":
defaultVal = abs( k_ArtFitWin )
break
case "ArtPeakDT":
defaultVal = k_ArtPeakDT
break
case "SubtractWin":
defaultVal = abs( k_SubtractWin )
break
case "BslnWin":
defaultVal = abs( k_BslnWin )
break
case "BslnDT":
defaultVal = abs( k_BslnDT )
break
case "BslnSubtract":
defaultVal = 0
break
case "BslnConvergeNstdv":
defaultVal = abs( k_BslnConvergeNstdv )
break
case "BslnConvergeWin":
defaultVal = abs( k_BslnConvergeWin )
break
case "BslnExpSlopeThreshold":
defaultVal = k_BslnExpSlopeThreshold
break
case "SaveFitParameters":
defaultVal = k_SaveFitParameters
break
case "SaveSubtractedArt":
defaultVal = k_SaveSubtractedArt
break
case "AutoFit":
defaultVal = 1
break
case "DragWaveAll":
defaultVal = k_DragWaveAll
break
case "FitFlag":
defaultVal = NaN
break
case "ArtTime":
case "t1_hold":
case "t1_min":
case "t1_max":
case "t2_hold":
case "t2_min":
case "t2_max":
break // NaN
case "DisplayPrecision":
defaultVal = 2 // decimal places
break
default:
NM2Error( 13, varName, "" )
return NaN
endswitch
return NumVarOrDefault( NMArtDF+varName, defaultVal )
End // NMArtVarGet
//****************************************************************
Function /S NMArtStrGet( varName )
String varName
String defaultVal = ""
strswitch( varName )
case "ArtShape":
defaultVal = k_ArtShape
break
case "BslnFxn":
defaultVal = k_BslnFxn
break
case "ArtFitFxn":
defaultVal = k_ArtFitFxn
break
case "DecayColor":
defaultVal = NMRedStr
break
case "BaseColor":
defaultVal = NMGreenStr
break
case "ArtTimeWName":
break
case "WaveNameFormat":
defaultVal = k_WaveNameFormat
break
default:
NM2Error( 23, varName, "" )
return ""
endswitch
return StrVarOrDefault( NMArtDF+varName, defaultVal )
End // NMArtStrGet
//****************************************************************
Function /S NMArtSubWaveName( wtype [ wName ] )
String wtype
String wName
if ( ParamIsDefault( wName ) )
wName = CurrentNMWaveName()
endif
if ( strlen( wName ) == 0 )
return ""
endif
if ( StringMatch( wtype, "finished" ) )
return "AT_F_" + wName
endif
String format = NMArtStrGet( "WaveNameFormat" )
strswitch( format )
case "v2": // old format
strswitch( wtype )
case "art":
return "AT_" + wName + "_stim"
case "no_art":
return "AT_" + wName + "_nostim"
endswitch
return ""
case "v3p":
default:
strswitch( wtype )
case "art":
return "AT_A_" + wName
case "no_art":
return "AT_" + wName
endswitch
return ""
endswitch
End // NMArtSubWaveName
//****************************************************************
Function NMArtDisplay( appnd ) // append/remove Art display waves to current channel graph
Variable appnd // // ( 0 ) remove ( 1 ) append
Variable icnt, drag = appnd
String gName = CurrentChanGraphName()
String xWave = NMXwave()
String df = NMArtDF
STRUCT NMRGB ac
STRUCT NMRGB bc
NMColorList2RGB( NMArtStrGet( "DecayColor" ), ac )
NMColorList2RGB( NMArtStrGet( "BaseColor" ), bc )
if ( !DataFolderExists( df ) || !WaveExists( $df+"AT_Display" ) )
return 0 // Art has not been initialized yet
endif
if ( Wintype( gName ) == 0 )
return -1 // window does not exist
endif
String wName = df+"AT_Display"
if ( !NMVarGet( "DragOn" ) || !StringMatch( CurrentNMTabName(), "Art" ) )
drag = 0
endif
RemoveFromGraph /Z/W=$gName AT_Display, AT_Fit, AT_FitB, AT_TimeY
RemoveFromGraph /Z/W=$gName DragBgnY, DragEndY
RemoveFromGraph /Z/W=$gName DragBslnBgnY, DragBslnEndY
if ( appnd )
if ( WaveExists( $xWave ) )
AppendToGraph /W=$gName $df+"AT_Display" vs $xWave
else
AppendToGraph /W=$gName $df+"AT_Display"
endif
if ( WaveExists( $df+"AT_FitB" ) )
if ( WaveExists( $xWave ) )
AppendToGraph /W=$gName $df+"AT_FitB" vs $xWave
else
AppendToGraph /W=$gName $df+"AT_FitB"
endif
endif
if ( WaveExists( $df+"AT_Fit" ) )
if ( WaveExists( $xWave ) )
AppendToGraph /W=$gName $df+"AT_Fit" vs $xWave
else
AppendToGraph /W=$gName $df+"AT_Fit"
endif
endif
if ( WaveExists( $df+"AT_TimeY" ) && WaveExists( $df+"AT_TimeX" ) )
AppendToGraph /W=$gName $df+"AT_TimeY" vs $df+"AT_TimeX"
endif
ModifyGraph /W=$gName rgb( AT_Display )=( 0,0,65280 ), lsize( AT_Display )=2
ModifyGraph /W=$gName mode( AT_TimeY )=3, marker( AT_TimeY )=10, rgb( AT_TimeY )=( 65280,0,0 ), msize( AT_TimeY )=20, mrkThick( AT_TimeY )=2
ModifyGraph /W=$gName mode( AT_FitB )=0, lsize( AT_FitB )=2, rgb( AT_FitB )=( bc.r, bc.g, bc.b )
endif
NMDragEnable( drag, "DragBgn", "", df+"Xbgn", "NMArtDragTrigger", gName, "bottom", "min", ac.r, ac.g, ac.b )
NMDragEnable( drag, "DragEnd", "", df+"Xend", "NMArtDragTrigger", gName, "bottom", "max", ac.r, ac.g, ac.b )
NMDragEnable( drag, "DragBslnBgn", "", df+"BslnXbgn", "NMArtDragTrigger", gName, "bottom", "min", bc.r, bc.g, bc.b )
NMDragEnable( drag, "DragBslnEnd", "", df+"BslnXend", "NMArtDragTrigger", gName, "bottom", "max", bc.r, bc.g, bc.b )
End // NMArtDisplay
//****************************************************************
Function NMArtChanGraphControls( enable )
Variable enable
Variable ccnt, displayWin, lim1, lim2, inc, y0 = 8
Variable currentChan = CurrentNMChannel()
String gName, title
String computer = NMComputerType()
if ( StringMatch( computer, "mac" ) )
y0 = 4
endif
for ( ccnt = 0; ccnt < 10; ccnt += 1 ) // remove from all possible channel graphs
if ( enable && ( ccnt == currentChan ) )
continue
endif
gName = ChanGraphName( ccnt )
if ( Wintype( gName ) == 0 )
continue
endif
KillControl /W=$gName AT_dragWaveAll
endfor
if ( enable )
gName = ChanGraphName( currentChan )
if ( Wintype( gName ) != 1 )
return NaN
endif
if ( NMArtVarGet( "DragWaveAll" ) )
title = "Drag (all artefacts)"
else
title = "Drag (current artefact)"
endif
Checkbox AT_dragWaveAll, title=title, pos={500, y0}, size={100,50}, value=1, proc=NMArtCheckbox, win=$gName
endif
End // NMArtChanGraphControls
//****************************************************************
Static Function z_UpdateDragWaveAllCheckbox()
Variable currentChan = CurrentNMChannel()
String gName = ChanGraphName( currentChan )
if ( NMArtVarGet( "DragWaveAll" ) )
Checkbox AT_dragWaveAll, title="Drag (all artefacts)", value=1, win=$gName
else
Checkbox AT_dragWaveAll, title="Drag (current artefact)", value=1, win=$gName
endif
End // z_UpdateDragWaveAllCheckbox