/
flattening-lemma-coequalizers.lagda.md
203 lines (179 loc) · 7.71 KB
/
flattening-lemma-coequalizers.lagda.md
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
# The flattening lemma for coequalizers
```agda
module synthetic-homotopy-theory.flattening-lemma-coequalizers where
```
<details><summary>Imports</summary>
```agda
open import foundation.action-on-identifications-functions
open import foundation.coproduct-types
open import foundation.dependent-pair-types
open import foundation.equality-dependent-pair-types
open import foundation.equivalences
open import foundation.function-types
open import foundation.functoriality-dependent-pair-types
open import foundation.homotopies
open import foundation.identity-types
open import foundation.transport-along-identifications
open import foundation.type-arithmetic-coproduct-types
open import foundation.universe-levels
open import synthetic-homotopy-theory.coforks
open import synthetic-homotopy-theory.dependent-universal-property-coequalizers
open import synthetic-homotopy-theory.flattening-lemma-pushouts
open import synthetic-homotopy-theory.universal-property-coequalizers
open import synthetic-homotopy-theory.universal-property-pushouts
```
</details>
## Idea
The {{#concept "flattening lemma" Disambiguation="coequalizers"}} for
[coequalizers](synthetic-homotopy-theory.coequalizers.md) states that
coequalizers commute with
[dependent pair types](foundation.dependent-pair-types.md). More precisely,
given a coequalizer
```text
g
-----> e
A -----> B -----> X
f
```
with homotopy `H : e ∘ f ~ e ∘ g`, and a type family `P : X → 𝓤` over `X`, the
cofork
```text
----->
Σ (a : A) P(efa) -----> Σ (b : B) P(eb) ---> Σ (x : X) P(x)
```
is again a coequalizer.
## Definitions
### The statement of the flattening lemma for coequalizers
```agda
module _
{ l1 l2 l3 l4 : Level} {A : UU l1} {B : UU l2} (f g : A → B) {X : UU l3}
( P : X → UU l4) (e : cofork f g X)
where
bottom-map-cofork-flattening-lemma-coequalizer :
Σ A (P ∘ map-cofork f g e ∘ f) → Σ B (P ∘ map-cofork f g e)
bottom-map-cofork-flattening-lemma-coequalizer =
map-Σ-map-base f (P ∘ map-cofork f g e)
top-map-cofork-flattening-lemma-coequalizer :
Σ A (P ∘ map-cofork f g e ∘ f) → Σ B (P ∘ map-cofork f g e)
top-map-cofork-flattening-lemma-coequalizer =
map-Σ (P ∘ map-cofork f g e) g (λ a → tr P (coherence-cofork f g e a))
cofork-flattening-lemma-coequalizer :
cofork
( bottom-map-cofork-flattening-lemma-coequalizer)
( top-map-cofork-flattening-lemma-coequalizer)
( Σ X P)
pr1 cofork-flattening-lemma-coequalizer = map-Σ-map-base (map-cofork f g e) P
pr2 cofork-flattening-lemma-coequalizer =
coherence-square-maps-map-Σ-map-base P g f
( map-cofork f g e)
( map-cofork f g e)
( coherence-cofork f g e)
flattening-lemma-coequalizer-statement : UUω
flattening-lemma-coequalizer-statement =
( {l : Level} → dependent-universal-property-coequalizer l f g e) →
{ l : Level} →
universal-property-coequalizer l
( bottom-map-cofork-flattening-lemma-coequalizer)
( top-map-cofork-flattening-lemma-coequalizer)
( cofork-flattening-lemma-coequalizer)
```
## Properties
### Proof of the flattening lemma for coequalizers
To show that the cofork of total spaces is a coequalizer, it
[suffices to show](synthetic-homotopy-theory.universal-property-coequalizers.md)
that the induced cocone is a pushout. This is accomplished by constructing a
[commuting cube](foundation.commuting-cubes-of-maps.md) where the bottom is this
cocone, and the top is the cocone of total spaces for the cocone induced by the
cofork.
Assuming that the given cofork is a coequalizer, we get that its induced cocone
is a pushout, so by the
[flattening lemma for pushouts](synthetic-homotopy-theory.flattening-lemma-pushouts.md),
the top square is a pushout as well. The vertical maps of the cube are
[equivalences](foundation.equivalences.md), so it follows that the bottom square
is a pushout.
```agda
module _
{ l1 l2 l3 l4 : Level} {A : UU l1} {B : UU l2} (f g : A → B) {X : UU l3}
( P : X → UU l4) (e : cofork f g X)
where
abstract
flattening-lemma-coequalizer :
flattening-lemma-coequalizer-statement f g P e
flattening-lemma-coequalizer dup-coequalizer =
universal-property-coequalizer-universal-property-pushout
( bottom-map-cofork-flattening-lemma-coequalizer f g P e)
( top-map-cofork-flattening-lemma-coequalizer f g P e)
( cofork-flattening-lemma-coequalizer f g P e)
( universal-property-pushout-bottom-universal-property-pushout-top-cube-is-equiv
( vertical-map-span-cocone-cofork
( bottom-map-cofork-flattening-lemma-coequalizer f g P e)
( top-map-cofork-flattening-lemma-coequalizer f g P e))
( horizontal-map-span-cocone-cofork
( bottom-map-cofork-flattening-lemma-coequalizer f g P e)
( top-map-cofork-flattening-lemma-coequalizer f g P e))
( horizontal-map-cocone-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( vertical-map-cocone-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( vertical-map-span-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( horizontal-map-span-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( horizontal-map-cocone-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( vertical-map-cocone-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( map-equiv
( right-distributive-Σ-coprod A A
( ( P) ∘
( horizontal-map-cocone-cofork f g e) ∘
( vertical-map-span-cocone-cofork f g))))
( id)
( id)
( id)
( coherence-square-cocone-flattening-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e))
( ind-Σ (ind-coprod _ (ev-pair refl-htpy) (ev-pair refl-htpy)))
( ind-Σ (ind-coprod _ (ev-pair refl-htpy) (ev-pair refl-htpy)))
( refl-htpy)
( refl-htpy)
( coherence-square-cocone-cofork
( bottom-map-cofork-flattening-lemma-coequalizer f g P e)
( top-map-cofork-flattening-lemma-coequalizer f g P e)
( cofork-flattening-lemma-coequalizer f g P e))
( ind-Σ
( ind-coprod _
( ev-pair refl-htpy)
( ev-pair (λ t → ap-id _ ∙ inv right-unit))))
( is-equiv-map-equiv
( right-distributive-Σ-coprod A A
( ( P) ∘
( horizontal-map-cocone-cofork f g e) ∘
( vertical-map-span-cocone-cofork f g))))
( is-equiv-id)
( is-equiv-id)
( is-equiv-id)
( flattening-lemma-pushout P
( vertical-map-span-cocone-cofork f g)
( horizontal-map-span-cocone-cofork f g)
( cocone-codiagonal-cofork f g e)
( dependent-universal-property-pushout-dependent-universal-property-coequalizer
( f)
( g)
( e)
( dup-coequalizer))))
```