/
wide-subprecategories.lagda.md
457 lines (377 loc) · 15.5 KB
/
wide-subprecategories.lagda.md
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
# Wide subprecategories
```agda
module category-theory.wide-subprecategories where
```
<details><summary>Imports</summary>
```agda
open import category-theory.composition-operations-on-binary-families-of-sets
open import category-theory.faithful-functors-precategories
open import category-theory.functors-precategories
open import category-theory.maps-precategories
open import category-theory.precategories
open import category-theory.subprecategories
open import foundation.dependent-pair-types
open import foundation.equivalences
open import foundation.function-types
open import foundation.identity-types
open import foundation.iterated-dependent-product-types
open import foundation.propositions
open import foundation.sets
open import foundation.subtypes
open import foundation.unit-type
open import foundation.universe-levels
```
</details>
## Idea
A **wide subprecategory** of a [precategory](category-theory.precategories.md)
`C` is a [subprecategory](category-theory.subprecategories.md) that contains all
the objects of `C`.
## Definitions
### The predicate of being a wide subprecategory
```agda
module _
{l1 l2 l3 l4 : Level}
(C : Precategory l1 l2)
(P : Subprecategory l3 l4 C)
where
is-wide-prop-Subprecategory : Prop (l1 ⊔ l3)
is-wide-prop-Subprecategory =
Π-Prop (obj-Precategory C) (subtype-obj-Subprecategory C P)
is-wide-Subprecategory : UU (l1 ⊔ l3)
is-wide-Subprecategory = type-Prop is-wide-prop-Subprecategory
is-prop-is-wide-Subprecategory : is-prop (is-wide-Subprecategory)
is-prop-is-wide-Subprecategory = is-prop-type-Prop is-wide-prop-Subprecategory
```
### Wide sub-hom-families of precategories
```agda
module _
{l1 l2 : Level} (l3 : Level)
(C : Precategory l1 l2)
where
subtype-hom-wide-Precategory : UU (l1 ⊔ l2 ⊔ lsuc l3)
subtype-hom-wide-Precategory =
(x y : obj-Precategory C) → subtype l3 (hom-Precategory C x y)
```
### Categorical predicates on wide sub-hom-families
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P₁ : subtype-hom-wide-Precategory l3 C)
where
contains-id-prop-subtype-hom-wide-Precategory : Prop (l1 ⊔ l3)
contains-id-prop-subtype-hom-wide-Precategory =
Π-Prop (obj-Precategory C) (λ x → P₁ x x (id-hom-Precategory C))
contains-id-subtype-hom-wide-Precategory : UU (l1 ⊔ l3)
contains-id-subtype-hom-wide-Precategory =
type-Prop contains-id-prop-subtype-hom-wide-Precategory
is-prop-contains-id-subtype-hom-wide-Precategory :
is-prop contains-id-subtype-hom-wide-Precategory
is-prop-contains-id-subtype-hom-wide-Precategory =
is-prop-type-Prop contains-id-prop-subtype-hom-wide-Precategory
is-closed-under-composition-subtype-hom-wide-Precategory : UU (l1 ⊔ l2 ⊔ l3)
is-closed-under-composition-subtype-hom-wide-Precategory =
(x y z : obj-Precategory C) →
(g : hom-Precategory C y z) →
(f : hom-Precategory C x y) →
is-in-subtype (P₁ y z) g →
is-in-subtype (P₁ x y) f →
is-in-subtype (P₁ x z) (comp-hom-Precategory C g f)
is-prop-is-closed-under-composition-subtype-hom-wide-Precategory :
is-prop is-closed-under-composition-subtype-hom-wide-Precategory
is-prop-is-closed-under-composition-subtype-hom-wide-Precategory =
is-prop-iterated-Π 7
( λ x y z g f _ _ →
is-prop-is-in-subtype (P₁ x z) (comp-hom-Precategory C g f))
is-closed-under-composition-prop-subtype-hom-wide-Precategory :
Prop (l1 ⊔ l2 ⊔ l3)
pr1 is-closed-under-composition-prop-subtype-hom-wide-Precategory =
is-closed-under-composition-subtype-hom-wide-Precategory
pr2 is-closed-under-composition-prop-subtype-hom-wide-Precategory =
is-prop-is-closed-under-composition-subtype-hom-wide-Precategory
```
### The predicate on a subtype of the hom-sets of being a wide subprecategory
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P₁ : subtype-hom-wide-Precategory l3 C)
where
is-wide-subprecategory-Prop : Prop (l1 ⊔ l2 ⊔ l3)
is-wide-subprecategory-Prop =
prod-Prop
( contains-id-prop-subtype-hom-wide-Precategory C P₁)
( is-closed-under-composition-prop-subtype-hom-wide-Precategory C P₁)
is-wide-subprecategory : UU (l1 ⊔ l2 ⊔ l3)
is-wide-subprecategory = type-Prop is-wide-subprecategory-Prop
is-prop-is-wide-subprecategory : is-prop (is-wide-subprecategory)
is-prop-is-wide-subprecategory = is-prop-type-Prop is-wide-subprecategory-Prop
contains-id-is-wide-subprecategory :
is-wide-subprecategory → contains-id-subtype-hom-wide-Precategory C P₁
contains-id-is-wide-subprecategory = pr1
is-closed-under-composition-is-wide-subprecategory :
is-wide-subprecategory →
is-closed-under-composition-subtype-hom-wide-Precategory C P₁
is-closed-under-composition-is-wide-subprecategory = pr2
```
### Wide subprecategories
```agda
Wide-Subprecategory :
{l1 l2 : Level} (l3 : Level)
(C : Precategory l1 l2) →
UU (l1 ⊔ l2 ⊔ lsuc l3)
Wide-Subprecategory l3 C =
Σ (subtype-hom-wide-Precategory l3 C) (is-wide-subprecategory C)
```
#### Objects in wide subprecategories
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P : Wide-Subprecategory l3 C)
where
subtype-obj-Wide-Subprecategory : subtype lzero (obj-Precategory C)
subtype-obj-Wide-Subprecategory _ = unit-Prop
obj-Wide-Subprecategory : UU l1
obj-Wide-Subprecategory = obj-Precategory C
inclusion-obj-Wide-Subprecategory :
obj-Wide-Subprecategory → obj-Precategory C
inclusion-obj-Wide-Subprecategory = id
```
#### Morphisms in wide subprecategories
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P : Wide-Subprecategory l3 C)
where
subtype-hom-Wide-Subprecategory : subtype-hom-wide-Precategory l3 C
subtype-hom-Wide-Subprecategory = pr1 P
hom-Wide-Subprecategory : (x y : obj-Wide-Subprecategory C P) → UU (l2 ⊔ l3)
hom-Wide-Subprecategory x y =
type-subtype (subtype-hom-Wide-Subprecategory x y)
inclusion-hom-Wide-Subprecategory :
(x y : obj-Wide-Subprecategory C P) →
hom-Wide-Subprecategory x y →
hom-Precategory C
( inclusion-obj-Wide-Subprecategory C P x)
( inclusion-obj-Wide-Subprecategory C P y)
inclusion-hom-Wide-Subprecategory x y =
inclusion-subtype (subtype-hom-Wide-Subprecategory x y)
```
The predicate on a morphism between any objects of being contained in the wide
subprecategory:
```agda
is-in-hom-Wide-Subprecategory :
(x y : obj-Precategory C) (f : hom-Precategory C x y) → UU l3
is-in-hom-Wide-Subprecategory x y =
is-in-subtype (subtype-hom-Wide-Subprecategory x y)
is-prop-is-in-hom-Wide-Subprecategory :
(x y : obj-Precategory C) (f : hom-Precategory C x y) →
is-prop (is-in-hom-Wide-Subprecategory x y f)
is-prop-is-in-hom-Wide-Subprecategory x y =
is-prop-is-in-subtype (subtype-hom-Wide-Subprecategory x y)
is-in-hom-inclusion-hom-Wide-Subprecategory :
(x y : obj-Wide-Subprecategory C P)
(f : hom-Wide-Subprecategory x y) →
is-in-hom-Wide-Subprecategory
( inclusion-obj-Wide-Subprecategory C P x)
( inclusion-obj-Wide-Subprecategory C P y)
( inclusion-hom-Wide-Subprecategory x y f)
is-in-hom-inclusion-hom-Wide-Subprecategory x y =
is-in-subtype-inclusion-subtype (subtype-hom-Wide-Subprecategory x y)
```
Wide subprecategories are wide subprecategories:
```agda
is-wide-subprecategory-Wide-Subprecategory :
is-wide-subprecategory C subtype-hom-Wide-Subprecategory
is-wide-subprecategory-Wide-Subprecategory = pr2 P
contains-id-Wide-Subprecategory :
contains-id-subtype-hom-wide-Precategory C
( subtype-hom-Wide-Subprecategory)
contains-id-Wide-Subprecategory =
contains-id-is-wide-subprecategory C
( subtype-hom-Wide-Subprecategory)
( is-wide-subprecategory-Wide-Subprecategory)
is-closed-under-composition-Wide-Subprecategory :
is-closed-under-composition-subtype-hom-wide-Precategory C
( subtype-hom-Wide-Subprecategory)
is-closed-under-composition-Wide-Subprecategory =
is-closed-under-composition-is-wide-subprecategory C
( subtype-hom-Wide-Subprecategory)
( is-wide-subprecategory-Wide-Subprecategory)
```
Wide subprecategories are subprecategories:
```agda
subtype-hom-subprecategory-Wide-Subprecategory :
subtype-hom-Precategory l3 C (subtype-obj-Wide-Subprecategory C P)
subtype-hom-subprecategory-Wide-Subprecategory x y _ _ =
subtype-hom-Wide-Subprecategory x y
is-subprecategory-Wide-Subprecategory :
is-subprecategory C
( subtype-obj-Wide-Subprecategory C P)
( subtype-hom-subprecategory-Wide-Subprecategory)
pr1 is-subprecategory-Wide-Subprecategory x _ =
contains-id-Wide-Subprecategory x
pr2 is-subprecategory-Wide-Subprecategory x y z g f _ _ _ =
is-closed-under-composition-Wide-Subprecategory x y z g f
subprecategory-Wide-Subprecategory : Subprecategory lzero l3 C
pr1 subprecategory-Wide-Subprecategory = subtype-obj-Wide-Subprecategory C P
pr1 (pr2 subprecategory-Wide-Subprecategory) =
subtype-hom-subprecategory-Wide-Subprecategory
pr2 (pr2 subprecategory-Wide-Subprecategory) =
is-subprecategory-Wide-Subprecategory
is-wide-Wide-Subprecategory :
is-wide-Subprecategory C (subprecategory-Wide-Subprecategory)
is-wide-Wide-Subprecategory _ = star
```
### The underlying precategory of a wide subprecategory
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P : Wide-Subprecategory l3 C)
where
hom-set-Wide-Subprecategory :
(x y : obj-Wide-Subprecategory C P) → Set (l2 ⊔ l3)
hom-set-Wide-Subprecategory x y =
set-subset
( hom-set-Precategory C x y)
( subtype-hom-Wide-Subprecategory C P x y)
is-set-hom-Wide-Subprecategory :
(x y : obj-Wide-Subprecategory C P) →
is-set (hom-Wide-Subprecategory C P x y)
is-set-hom-Wide-Subprecategory x y =
is-set-type-Set (hom-set-Wide-Subprecategory x y)
id-hom-Wide-Subprecategory :
{x : obj-Wide-Subprecategory C P} → hom-Wide-Subprecategory C P x x
pr1 id-hom-Wide-Subprecategory = id-hom-Precategory C
pr2 (id-hom-Wide-Subprecategory {x}) = contains-id-Wide-Subprecategory C P x
comp-hom-Wide-Subprecategory :
{x y z : obj-Wide-Subprecategory C P} →
hom-Wide-Subprecategory C P y z →
hom-Wide-Subprecategory C P x y →
hom-Wide-Subprecategory C P x z
pr1 (comp-hom-Wide-Subprecategory {x} {y} {z} g f) =
comp-hom-Precategory C
( inclusion-hom-Wide-Subprecategory C P y z g)
( inclusion-hom-Wide-Subprecategory C P x y f)
pr2 (comp-hom-Wide-Subprecategory {x} {y} {z} g f) =
is-closed-under-composition-Wide-Subprecategory C P x y z
( inclusion-hom-Wide-Subprecategory C P y z g)
( inclusion-hom-Wide-Subprecategory C P x y f)
( is-in-hom-inclusion-hom-Wide-Subprecategory C P y z g)
( is-in-hom-inclusion-hom-Wide-Subprecategory C P x y f)
associative-comp-hom-Wide-Subprecategory :
{x y z w : obj-Wide-Subprecategory C P}
(h : hom-Wide-Subprecategory C P z w)
(g : hom-Wide-Subprecategory C P y z)
(f : hom-Wide-Subprecategory C P x y) →
( comp-hom-Wide-Subprecategory
( comp-hom-Wide-Subprecategory h g) f) =
( comp-hom-Wide-Subprecategory h
( comp-hom-Wide-Subprecategory g f))
associative-comp-hom-Wide-Subprecategory {x} {y} {z} {w} h g f =
eq-type-subtype
( subtype-hom-Wide-Subprecategory C P x w)
( associative-comp-hom-Precategory C
( inclusion-hom-Wide-Subprecategory C P z w h)
( inclusion-hom-Wide-Subprecategory C P y z g)
( inclusion-hom-Wide-Subprecategory C P x y f))
left-unit-law-comp-hom-Wide-Subprecategory :
{x y : obj-Wide-Subprecategory C P}
(f : hom-Wide-Subprecategory C P x y) →
comp-hom-Wide-Subprecategory (id-hom-Wide-Subprecategory) f = f
left-unit-law-comp-hom-Wide-Subprecategory {x} {y} f =
eq-type-subtype
( subtype-hom-Wide-Subprecategory C P x y)
( left-unit-law-comp-hom-Precategory C
( inclusion-hom-Wide-Subprecategory C P x y f))
right-unit-law-comp-hom-Wide-Subprecategory :
{x y : obj-Wide-Subprecategory C P}
(f : hom-Wide-Subprecategory C P x y) →
comp-hom-Wide-Subprecategory f (id-hom-Wide-Subprecategory) = f
right-unit-law-comp-hom-Wide-Subprecategory {x} {y} f =
eq-type-subtype
( subtype-hom-Wide-Subprecategory C P x y)
( right-unit-law-comp-hom-Precategory C
( inclusion-hom-Wide-Subprecategory C P x y f))
associative-composition-operation-Wide-Subprecategory :
associative-composition-operation-binary-family-Set
( hom-set-Wide-Subprecategory)
pr1 associative-composition-operation-Wide-Subprecategory =
comp-hom-Wide-Subprecategory
pr2 associative-composition-operation-Wide-Subprecategory =
associative-comp-hom-Wide-Subprecategory
is-unital-composition-operation-Wide-Subprecategory :
is-unital-composition-operation-binary-family-Set
( hom-set-Wide-Subprecategory)
( comp-hom-Wide-Subprecategory)
pr1 is-unital-composition-operation-Wide-Subprecategory x =
id-hom-Wide-Subprecategory
pr1 (pr2 is-unital-composition-operation-Wide-Subprecategory) =
left-unit-law-comp-hom-Wide-Subprecategory
pr2 (pr2 is-unital-composition-operation-Wide-Subprecategory) =
right-unit-law-comp-hom-Wide-Subprecategory
precategory-Wide-Subprecategory : Precategory l1 (l2 ⊔ l3)
pr1 precategory-Wide-Subprecategory = obj-Wide-Subprecategory C P
pr1 (pr2 precategory-Wide-Subprecategory) = hom-set-Wide-Subprecategory
pr1 (pr2 (pr2 precategory-Wide-Subprecategory)) =
associative-composition-operation-Wide-Subprecategory
pr2 (pr2 (pr2 precategory-Wide-Subprecategory)) =
is-unital-composition-operation-Wide-Subprecategory
```
### The inclusion functor of a wide subprecategory
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P : Wide-Subprecategory l3 C)
where
inclusion-map-Wide-Subprecategory :
map-Precategory (precategory-Wide-Subprecategory C P) C
pr1 inclusion-map-Wide-Subprecategory = inclusion-obj-Wide-Subprecategory C P
pr2 inclusion-map-Wide-Subprecategory {x} {y} =
inclusion-hom-Wide-Subprecategory C P x y
is-functor-inclusion-Wide-Subprecategory :
is-functor-map-Precategory
( precategory-Wide-Subprecategory C P)
( C)
( inclusion-map-Wide-Subprecategory)
pr1 is-functor-inclusion-Wide-Subprecategory g f = refl
pr2 is-functor-inclusion-Wide-Subprecategory x = refl
inclusion-Wide-Subprecategory :
functor-Precategory (precategory-Wide-Subprecategory C P) C
pr1 inclusion-Wide-Subprecategory = inclusion-obj-Wide-Subprecategory C P
pr1 (pr2 inclusion-Wide-Subprecategory) {x} {y} =
inclusion-hom-Wide-Subprecategory C P x y
pr2 (pr2 inclusion-Wide-Subprecategory) =
is-functor-inclusion-Wide-Subprecategory
```
## Properties
### The inclusion functor is faithful and an equivalence on objects
```agda
module _
{l1 l2 l3 : Level}
(C : Precategory l1 l2)
(P : Wide-Subprecategory l3 C)
where
is-faithful-inclusion-Wide-Subprecategory :
is-faithful-functor-Precategory
( precategory-Wide-Subprecategory C P)
( C)
( inclusion-Wide-Subprecategory C P)
is-faithful-inclusion-Wide-Subprecategory x y =
is-emb-inclusion-subtype (subtype-hom-Wide-Subprecategory C P x y)
is-equiv-obj-inclusion-Wide-Subprecategory :
is-equiv
( obj-functor-Precategory
( precategory-Wide-Subprecategory C P)
( C)
( inclusion-Wide-Subprecategory C P))
is-equiv-obj-inclusion-Wide-Subprecategory = is-equiv-id
```
## External links
- [Wide subcategories](https://1lab.dev/Cat.Functor.WideSubcategory.html) at
1lab
- [wide subcategory](https://ncatlab.org/nlab/show/wide+subcategory) at $n$Lab