New log Point and New Teleport Red crate. (btc_gear_object & btc_create_object) #1092

Raz0rLegend · 2021-05-04T21:24:57Z

Raz0rLegend
May 4, 2021

Hi everyone, i'm working on one start static fob on H&M, the FOB is pretty big, and i would like to add several btc_gear_object and btc_create_object.

Where can i find and add references to add several names to call the good script ?

Answered by Raz0rLegend

May 4, 2021

And for the red crate redeploy and Arsenal option, could i edit something like this ?

 //Re-deploy
 private _actions = [];
 _actions pushBack ["redeploy", localize "STR_BTC_HAM_ACTION_BIRESPAWN", "\A3\ui_f\data\igui\cfg\simpleTasks\types\run_ca.paa", {
     if ([] call btc_fnc_fob_redeployCheck) then {
         player setPos [10, 10, 10];
         player hideObject true;
         forceRespawn player;
     };
 }, {!btc_log_placing}];
 _actions pushBack ["base", localize "STR_BTC_HAM_ACTION_REDEPLOYBASE", getText (configfile >> "CfgMarkers" >> getMarkerType "btc_base" >> "icon"), {
     if ([] call btc_fnc_fob_redeployCheck) then {[_player, btc_respawn_marker, false] call BIS_fnc_moveToResp…

View full answer

Vdauphin · 2021-05-04T21:28:23Z

Vdauphin
May 4, 2021
Maintainer

Hello,

Just add variables names here: https://github.com/Vdauphin/HeartsAndMinds/blob/master/%3DBTC%3Dco%4030_Hearts_and_Minds.Altis/core/fnc/int/add_actions.sqf#L82

like this

} forEach [[btc_create_object, btc_create_object_point], [btc_create_object_1, btc_create_object_point_1]];

Cheers

0 replies

Vdauphin · 2021-05-04T21:30:45Z

Vdauphin
May 4, 2021
Maintainer

For teleport, just create a fob and enable teleportation from fob in mission parameters

0 replies

Raz0rLegend · 2021-05-04T21:41:45Z

Raz0rLegend
May 4, 2021
Author

And for the red crate redeploy and Arsenal option, could i edit something like this ?

 //Re-deploy
 private _actions = [];
 _actions pushBack ["redeploy", localize "STR_BTC_HAM_ACTION_BIRESPAWN", "\A3\ui_f\data\igui\cfg\simpleTasks\types\run_ca.paa", {
     if ([] call btc_fnc_fob_redeployCheck) then {
         player setPos [10, 10, 10];
         player hideObject true;
         forceRespawn player;
     };
 }, {!btc_log_placing}];
 _actions pushBack ["base", localize "STR_BTC_HAM_ACTION_REDEPLOYBASE", getText (configfile >> "CfgMarkers" >> getMarkerType "btc_base" >> "icon"), {
     if ([] call btc_fnc_fob_redeployCheck) then {[_player, btc_respawn_marker, false] call BIS_fnc_moveToRespawnPosition};
 }, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, "Base"];
 _actions pushBack ["rallypoints", localize "STR_BTC_HAM_ACTION_REDEPLOYRALLY", "\A3\ui_f\data\igui\cfg\simpleTasks\types\wait_ca.paa", {}, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, ""];
 _actions pushBack ["FOB", localize "STR_BTC_HAM_ACTION_REDEPLOYFOB", "\A3\Ui_f\data\Map\Markers\NATO\b_hq.paa", {}, {!btc_log_placing}];
 {
     private _action = _x call ace_interact_menu_fnc_createAction;
    [btc_gear_object, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;
     if (btc_p_respawn_fromFOBToBase) then {
         [btc_fob_flag, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToClass;
     };
 } forEach _actions;
 {
     _x params ["_cardinal", "_degrees"];
 
     _action = ["FOB" + _cardinal, localize _cardinal, "\A3\ui_f\data\igui\cfg\simpleTasks\types\map_ca.paa", {}, {true}, {_this call btc_fnc_fob_redeploy}, _degrees] call ace_interact_menu_fnc_createAction;
     [btc_gear_object, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToObject;
     if (btc_p_respawn_fromFOBToBase) then {
         [btc_fob_flag, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToClass;
     };
 } forEach [["str_q_north_east", [0, 90]], ["str_q_south_east", [90, 180]], ["str_q_south_west", [180, 270]], ["str_q_north_west", [270, 360]]];
 
 _actions pushBack ["redeploy", localize "STR_BTC_HAM_ACTION_BIRESPAWN", "\A3\ui_f\data\igui\cfg\simpleTasks\types\run_ca.paa", {
     if ([] call btc_fnc_fob_redeployCheck) then {
         player setPos [10, 10, 10];
         player hideObject true;
         forceRespawn player;
     };
 }, {!btc_log_placing}];
 _actions pushBack ["base", localize "STR_BTC_HAM_ACTION_REDEPLOYBASE", getText (configfile >> "CfgMarkers" >> getMarkerType "btc_base" >> "icon"), {
     if ([] call btc_fnc_fob_redeployCheck) then {[_player, btc_respawn_marker, false] call BIS_fnc_moveToRespawnPosition};
 }, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, "Base"];
 _actions pushBack ["rallypoints", localize "STR_BTC_HAM_ACTION_REDEPLOYRALLY", "\A3\ui_f\data\igui\cfg\simpleTasks\types\wait_ca.paa", {}, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, ""];
 _actions pushBack ["FOB", localize "STR_BTC_HAM_ACTION_REDEPLOYFOB", "\A3\Ui_f\data\Map\Markers\NATO\b_hq.paa", {}, {!btc_log_placing}];
 {
     private _action = _x call ace_interact_menu_fnc_createAction;
     [btc_gear_object_1, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;
     if (btc_p_respawn_fromFOBToBase) then {
         [btc_fob_flag, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToClass;
     };
 } forEach _actions;
 {
     _x params ["_cardinal", "_degrees"];
 
     _action = ["FOB" + _cardinal, localize _cardinal, "\A3\ui_f\data\igui\cfg\simpleTasks\types\map_ca.paa", {}, {true}, {_this call btc_fnc_fob_redeploy}, _degrees] call ace_interact_menu_fnc_createAction;
     [btc_gear_object_1, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToObject;
     if (btc_p_respawn_fromFOBToBase) then {
        [btc_fob_flag, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToClass;
     };
 } forEach [["str_q_north_east", [0, 90]], ["str_q_south_east", [90, 180]], ["str_q_south_west", [180, 270]], ["str_q_north_west", [270, 360]]];
 
 //Arsenal
 //BIS
 if (btc_p_arsenal_Type < 3) then {
     btc_gear_object addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_BIS", "['Open', [!(btc_p_arsenal_Restrict isEqualTo 1), _this select 0]] call bis_fnc_arsenal;"];
 };
 if (btc_p_arsenal_Type < 3) then {
     btc_gear_object_1 addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_BIS", "['Open', [!(btc_p_arsenal_Restrict isEqualTo 1), _this select 0]] call bis_fnc_arsenal;"];
 };
 //ACE
 if (btc_p_arsenal_Type > 0) then {
     [btc_gear_object, !(btc_p_arsenal_Restrict isEqualTo 1), false] call ace_arsenal_fnc_initBox;
     if (btc_p_arsenal_Type in [2, 4]) then {
         btc_gear_object addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_ACE", "[btc_gear_object, player] call ace_arsenal_fnc_openBox;"];
     };
 	if (btc_p_arsenal_Type in [2, 4]) then {
         btc_gear_object_1 addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_ACE", "[btc_gear_object_1, player] call ace_arsenal_fnc_openBox;"];
     };
 };
if !(btc_p_arsenal_Restrict isEqualTo 0) then {[btc_gear_object, btc_gear_object_1, btc_p_arsenal_Type, btc_p_arsenal_Restrict, btc_custom_arsenal] call btc_fnc_arsenal_data;};

1 reply

Vdauphin May 4, 2021
Maintainer

Why not like this:

//Re-deploy
private _actions = [];
_actions pushBack ["redeploy", localize "STR_BTC_HAM_ACTION_BIRESPAWN", "\A3\ui_f\data\igui\cfg\simpleTasks\types\run_ca.paa", {
    if ([] call btc_fnc_fob_redeployCheck) then {
        player setPos [10, 10, 10];
        player hideObject true;
        forceRespawn player;
    };
}, {!btc_log_placing}];
_actions pushBack ["base", localize "STR_BTC_HAM_ACTION_REDEPLOYBASE", getText (configfile >> "CfgMarkers" >> getMarkerType "btc_base" >> "icon"), {
    if ([] call btc_fnc_fob_redeployCheck) then {[_player, btc_respawn_marker, false] call BIS_fnc_moveToRespawnPosition};
}, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, "Base"];
_actions pushBack ["rallypoints", localize "STR_BTC_HAM_ACTION_REDEPLOYRALLY", "\A3\ui_f\data\igui\cfg\simpleTasks\types\wait_ca.paa", {}, {!btc_log_placing}, {_this call btc_fnc_fob_redeploy}, ""];
_actions pushBack ["FOB", localize "STR_BTC_HAM_ACTION_REDEPLOYFOB", "\A3\Ui_f\data\Map\Markers\NATO\b_hq.paa", {}, {!btc_log_placing}];
{
    private _action = _x call ace_interact_menu_fnc_createAction;
    [btc_gear_object, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;
    [btc_gear_object_1, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToObject;
    if (btc_p_respawn_fromFOBToBase) then {
        [btc_fob_flag, 0, ["ACE_MainActions"], _action] call ace_interact_menu_fnc_addActionToClass;
    };
} forEach _actions;
{
    _x params ["_cardinal", "_degrees"];

    _action = ["FOB" + _cardinal, localize _cardinal, "\A3\ui_f\data\igui\cfg\simpleTasks\types\map_ca.paa", {}, {true}, {_this call btc_fnc_fob_redeploy}, _degrees] call ace_interact_menu_fnc_createAction;
    [btc_gear_object, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToObject;
    [btc_gear_object_1, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToObject;
    if (btc_p_respawn_fromFOBToBase) then {
        [btc_fob_flag, 0, ["ACE_MainActions", "FOB"], _action] call ace_interact_menu_fnc_addActionToClass;
    };
} forEach [["str_q_north_east", [0, 90]], ["str_q_south_east", [90, 180]], ["str_q_south_west", [180, 270]], ["str_q_north_west", [270, 360]]];

//Arsenal
//BIS
if (btc_p_arsenal_Type < 3) then {
    btc_gear_object addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_BIS", "['Open', [!(btc_p_arsenal_Restrict isEqualTo 1), _this select 0]] call bis_fnc_arsenal;"];
    btc_gear_object_1 addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_BIS", "['Open', [!(btc_p_arsenal_Restrict isEqualTo 1), _this select 0]] call bis_fnc_arsenal;"];
};
//ACE
if (btc_p_arsenal_Type > 0) then {
    [btc_gear_object, !(btc_p_arsenal_Restrict isEqualTo 1), false] call ace_arsenal_fnc_initBox;
    [btc_gear_object_1, !(btc_p_arsenal_Restrict isEqualTo 1), false] call ace_arsenal_fnc_initBox;
    if (btc_p_arsenal_Type in [2, 4]) then {
        btc_gear_object addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_ACE", "[btc_gear_object, player] call ace_arsenal_fnc_openBox;"];
        btc_gear_object_1 addAction [localize "STR_BTC_HAM_ACTION_ARSENAL_OPEN_ACE", "[btc_gear_object, player] call ace_arsenal_fnc_openBox;"];
    };
};
if !(btc_p_arsenal_Restrict isEqualTo 0) then {
    [btc_gear_object, btc_p_arsenal_Type, btc_p_arsenal_Restrict, btc_custom_arsenal] call btc_fnc_arsenal_data;
    [btc_gear_object_1, btc_p_arsenal_Type, btc_p_arsenal_Restrict, btc_custom_arsenal] call btc_fnc_arsenal_data;
};

Basically with this you add interaction to btc_gear_object and then to btc_gear_object_1

Raz0rLegend · 2021-05-04T22:00:34Z

Raz0rLegend
May 4, 2021
Author

You're right ! The first one worked, but it's barbare ! it worked more than i wanted ! ahaha

0 replies

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

New log Point and New Teleport Red crate. (btc_gear_object & btc_create_object) #1092

{{title}}

Replies: 4 comments 1 reply

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

Select a reply

New log Point and New Teleport Red crate. (btc_gear_object & btc_create_object) #1092

Raz0rLegend May 4, 2021

Replies: 4 comments · 1 reply

Vdauphin May 4, 2021 Maintainer

Vdauphin May 4, 2021 Maintainer

Raz0rLegend May 4, 2021 Author

Vdauphin May 4, 2021 Maintainer

Raz0rLegend May 4, 2021 Author

Raz0rLegend
May 4, 2021

Replies: 4 comments 1 reply

Vdauphin
May 4, 2021
Maintainer

Vdauphin
May 4, 2021
Maintainer

Raz0rLegend
May 4, 2021
Author

Vdauphin May 4, 2021
Maintainer

Raz0rLegend
May 4, 2021
Author