-
Notifications
You must be signed in to change notification settings - Fork 3
/
couchDB_views.ml
449 lines (375 loc) · 11.1 KB
/
couchDB_views.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
(* Ohm is © 2012 Victor Nicollet *)
open BatPervasives
module ImplParser = CouchDB_parser
module ImplTypes = CouchDB_types
module ImplCache = CouchDB_cache
module ImplDB = CouchDB_database
module Views = struct
let designs = Hashtbl.create 30
let register ~database ~design ~name ~map ~reduce =
let views =
try Hashtbl.find designs (database,design)
with Not_found ->
let views = Hashtbl.create 10 in
Hashtbl.add designs (database,design) views ; views
in
let current =
try Some (Hashtbl.find views name)
with Not_found -> None
in
let with_reduce, previous_reduce =
(* This may be a second part of the re-definition, so keep
previous values to avoid overwriting them. *)
match current with
| Some (_,reduce,with_reduce) -> with_reduce, reduce
| None -> ref false, None
in
let reduce =
(* We added a reduce function, so update the "with_reduce"
references so that map views modules know they need to
provide a ?reduce=false argument in the URL
*)
if reduce <> None then (with_reduce := true ; reduce)
else previous_reduce
in
Hashtbl.add views name (map,reduce,with_reduce) ;
with_reduce
let compile () =
designs
|> Hashtbl.iter begin fun (database,design) views ->
(* Prepare data for writing *)
let id = "_design/" ^ design in
let url = database.ImplDB.db_prefix ^ id in
let views =
Hashtbl.fold begin fun name (map,reduce,_) list ->
Util.log "CouchDB: compile: %s/_design/%s/_view/%s"
database.ImplDB.db_name design name ;
let map = Json.String ("(function(doc){"^map^"})") in
let reduce =
Json.of_opt
(fun s -> Json.String ("(function(keys,values,rereduce){"^s^"})"))
reduce
in
let options = Json.Object ["collation", Json.String "raw"] in
( name, Json.Object [
"map", map ;
"reduce", reduce ;
"options", options ]) :: list
end views []
in
let put =
[ "_id", Json.String id ;
"views", Json.Object views ;
"language", Json.String "javascript" ]
in
let rec aux rev =
try let put =
match rev with
| None -> put
| Some rev -> ( "_rev" , rev ) :: put
in
let json = Json.Object put in
let json_str = Json.to_string json in
Util.logreq "PUT %s %s" url json_str ;
let response = Http_client.Convenience.http_put url json_str in
ignore response
with
| Http_client.Http_protocol error ->
Util.log "CouchDB: HTTP error : %s" (Printexc.to_string error)
| Http_client.Http_error (409,_) ->
Util.logreq "GET %s" url ;
let response = Http_client.Convenience.http_get url in
let rev =
Json.of_string response
|> Json.to_object (fun ~opt ~req -> req "_rev")
in aux (Some rev)
in
try aux None
with exn -> Util.log "CouchDB: FAIL: %s" (Printexc.to_string exn)
end
end
let compile_views () = Views.compile ()
(* A common utility function for generating view urls *)
let view_query_url
~database
~design
~name
~keyfmt
?startkey
?startid
?endkey
?endid
?limit
?(descending=false)
?(include_docs=false)
?(endinclusive=true)
?(reduce=true)
?group_level
?(group=false)
() =
let key k = Json.to_string (keyfmt k) in
let keep = function (x, None) -> None | (x, Some y) -> Some (x,y) in
let args = BatList.filter_map keep [
"include_docs", (if include_docs then Some "true" else None) ;
"limit", (BatOption.map string_of_int limit) ;
"inclusive_end", (if not endinclusive then Some "false" else None) ;
"reduce", (if not reduce then Some "false" else None) ;
"group_level", (BatOption.map string_of_int group_level) ;
"group", (if group then Some "true" else None) ;
"descending", (if descending then Some "true" else None) ;
"startkey", (BatOption.map key startkey) ;
"endkey", (BatOption.map key endkey) ;
"startkey_docid", (BatOption.map Id.str startid) ;
"endkey_docid", (BatOption.map Id.str endid) ;
] in
let url =
String.concat "" [
database.ImplDB.db_prefix ;
String.concat "/" ["_design";design;"_view";name] ;
"?" ;
Netencoding.Url.mk_url_encoded_parameters args
]
in
url
(* A common utility function for extracting and traversing view results. This
is actully a monad that retrieves a list of JSON items from the view
response, so it may be manipulated from then on.
*)
let rec process_view_results ?(retries=5) url =
try Util.logreq "GET %s" url ;
let json_str = Http_client.Convenience.http_get url in
try Run.return begin
Json.of_string json_str
|> Json.to_object (fun ~opt ~req -> Json.to_array (req "rows"))
end
with Json.Error error as exn ->
Util.log "CouchDB : `%s` : `%s` on: %s" url error json_str ;
if retries <= 0 then raise exn else process_view_results ~retries:(retries-1) url
with
| Http_client.Http_error (status,desc) as exn ->
Util.log "CouchDB : `%s` : %d %s`" url status desc ;
if retries <= 0 then raise exn else process_view_results ~retries:(retries-1) url
| Http_client.Http_protocol (exn') as exn ->
Util.log "CouchDB : `%s` : %s" url (Printexc.to_string exn') ;
if retries <= 0 then raise exn else process_view_results ~retries:(retries-1) url
(* Implementing the views *)
module MapView = functor (Def:ImplTypes.MAP_DEF) -> struct
type map_key = Def.Key.t
type map_value = Def.Value.t
type map_iv = <
id : Id.t ;
value : map_value
> ;;
type map_kiv = <
id : Id.t ;
key : map_key ;
value : map_value
>
let with_reduce = Views.register
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~map:Def.map
~reduce:None
let view = Def.(
Design.(Database.database.ImplDB.db_name ^ "/" ^ name) ^ "/" ^ name
)
let query
?startkey
?startid
?endkey
?endid
?limit
?descending
?endinclusive
() =
let run url =
Run.of_call process_view_results url |> Run.bind begin fun list ->
let list = list |> List.map begin function item ->
Json.to_object (fun ~opt ~req ->
Def.Key.of_json_safe (req "key"),
Id.of_json_safe (req "id"),
Def.Value.of_json_safe (req "value")
) item
end |> BatList.filter_map begin function
| (Some k, Some i, Some v) -> Some
(object
method key = k
method id = i
method value = v
end)
| _ -> None
end in
Run.return list
end
in
let reduce = if !with_reduce then Some false else None in
let url = view_query_url
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~keyfmt:Def.Key.to_json
?startkey
?startid
?endkey
?endid
?limit
?descending
?endinclusive
?reduce
()
in
run url
let by_key key =
Run.map (List.map (fun x -> (x :> map_iv))) (query ~startkey:key ~endkey:key ())
end
module DocView = functor (Def:ImplTypes.DOC_DEF) -> struct
type doc_key = Def.Key.t
type doc_value = Def.Value.t
type doc_doc = Def.Doc.t
type doc_ivd = <
id : Id.t ;
value : doc_value ;
doc : doc_doc
>
type doc_kivd = <
key : doc_key ;
id : Id.t ;
value : doc_value ;
doc : doc_doc
>
let with_reduce = Views.register
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~map:Def.map
~reduce:None
let view = Def.(Design.(Database.database.ImplDB.db_name ^ "/" ^ name) ^ "/" ^ name)
let doc_query
?startkey
?startid
?endkey
?endid
?limit
?descending
?endinclusive
() =
let run url =
Run.of_call process_view_results url |> Run.bind begin fun list ->
(* Extract the fields of each row *)
let list =
List.map begin function item ->
Json.to_object (fun ~opt ~req ->
req "key", req "id", req "value", req "doc") item
end list
in
(* Add all found documents to the cache *)
let docs =
BatList.filter_map begin fun (_,i,_,d) ->
match Id.of_json_safe i with None -> None | Some i ->
let key = ImplCache.CacheKey.make Def.Design.Database.database i in
let doc = ImplCache.cached_of_json d in
Some (key, Some doc)
end list
in
ImplCache.cache_values docs |> Run.bind begin fun () ->
(* Eliminate unparseable documents *)
let list =
list |> List.map begin function (k,i,v,d) ->
Def.Key.of_json_safe k,
Id.of_json_safe i,
Def.Value.of_json_safe v,
Def.Doc.of_json_safe d
end |> BatList.filter_map begin function
| Some k, Some i, Some v, Some d -> Some
(object
method key = k
method id = i
method value = v
method doc = d
end)
| _ -> None
end
in
Run.return list
end
end
in
let reduce = if !with_reduce then Some false else None in
let url = view_query_url
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~keyfmt:Def.Key.to_json
?startkey
?startid
?endkey
?endid
?limit
?descending
?endinclusive
~include_docs:true
?reduce
()
in
run url
let doc key =
Run.map (List.map (fun x -> (x :> doc_ivd))) (doc_query ~startkey:key ~endkey:key ())
let doc_query_first ?startkey ?startid ?endkey ?endid ?descending ?endinclusive () =
doc_query ?startkey ?startid ?endkey ?endid ?descending ?endinclusive ~limit:1 ()
|> Run.bind begin function
| [] -> Run.return None
| h :: _ -> Run.return (Some h)
end
end
module ReduceView = functor (Def:ImplTypes.REDUCE_DEF) -> struct
type reduce_key = Def.Key.t
type reduce_value = Def.Value.t
let _ = Views.register
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~map:Def.map
~reduce:(Some Def.reduce)
let view = Def.(Design.(Database.database.ImplDB.db_name ^ "/" ^ name) ^ "/" ^ name)
let reduce_query
?startkey
?endkey
?limit
?endinclusive
() =
let run url =
Run.of_call process_view_results url |> Run.bind begin fun list ->
let list = list |> List.map begin function item ->
Json.to_object (fun ~opt ~req ->
Def.Key.of_json_safe (req "key"),
Def.Value.of_json_safe (req "value")
) item
end |> BatList.filter_map begin function
| (Some k, Some v) -> Some (k,v)
| _ -> None
end in
Run.return list
end
in
let url = view_query_url
~database:Def.Design.Database.database
~design:Def.Design.name
~name:Def.name
~keyfmt:Def.Key.to_json
?startkey
?endkey
?limit
?endinclusive
?group_level:Def.level
~group:Def.group
()
in
run url
let reduce key =
let keep = function
| [] -> None
| (_,v) :: _ -> Some v
in
Run.map keep (reduce_query ~startkey:key ~endkey:key ~limit:1 ())
end