Merge pull request #12 from Zellius/feature/fix_publishing

Fix maven publishing

build.gradle

@@ -8,8 +8,10 @@ buildscript {
     ext.kotlin_version = '1.1.1'
     dependencies {
         classpath 'com.android.tools.build:gradle:2.3.1'
-        classpath 'com.novoda:bintray-release:0.4.0'
         classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.8.1'
+        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
+        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'
+        classpath 'org.jetbrains.dokka:dokka-android-gradle-plugin:0.9.13'
         classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
 
         // NOTE: Do not place your application dependencies here; they belong
@@ -25,8 +27,8 @@ allprojects {
 subprojects {
     if (!name.contains('sample')) {
         apply plugin: 'jacoco'
-        apply plugin: 'com.novoda.bintray-release'
         apply plugin: 'com.android.library'
+        apply from: '../publish.gradle'
 
         android {
             compileSdkVersion 25

kotlin/build.gradle

@@ -12,11 +12,8 @@ dependencies {
     compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
 }
 
-publish {
-    groupId = 'com.github.zellius'
-    artifactId = 'rxlocationmanager.kotlin'
-    publishVersion = '0.1.1'
-    desc = 'Android library written on Kotlin that helps to get location using standart LocationManager and RxJava'
-    licences = ['MIT']
-    website = 'https://github.com/Zellius/RxLocationManager'
-}
+ext.lib_version = '0.1.1'
+ext.lib_name = 'KotlinRxLocationManager'
+ext.lib_description = 'Android library written on Kotlin that helps to get location using standart LocationManager and RxJava'
+
+archivesBaseName = 'rxlocationmanager.kotlin'

publish.gradle

@@ -0,0 +1,100 @@
+ext.lib_version = ''
+ext.lib_name = ''
+ext.lib_description = ''
+
+def repository_url = 'https://github.com/Zellius/RxLocationManager'
+
+apply plugin: 'com.jfrog.bintray'
+apply plugin: 'com.github.dcendents.android-maven'
+
+afterEvaluate {
+    group 'com.github.zellius'
+    version lib_version
+
+    install {
+        repositories.mavenInstaller {
+            pom {
+                project {
+                    packaging 'aar'
+
+                    name lib_name
+                    description lib_description
+                    url repository_url
+
+                    licenses {
+                        license {
+                            name 'MIT'
+                            url 'https://raw.github.com/zellius/RxLocationManager/master/LICENSE'
+                        }
+                    }
+
+                    developers {
+                        developer {
+                            id 'zellius'
+                            name 'Sergey Solodovnikov'
+                            email 'elementa.ru@gmail.com'
+                        }
+                    }
+
+                    scm {
+                        url repository_url
+                        connection "scm:${repository_url}.git"
+                        developerConnection "scm:${repository_url}.git"
+
+                    }
+                }
+            }
+        }
+    }
+
+    bintray {
+        user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
+        key = project.hasProperty('bintrayApiKey') ? project.property('bintrayApiKey') : System.getenv('BINTRAY_API_KEY')
+
+        configurations = ['archives']
+        pkg {
+            repo = 'maven'
+            name = lib_name
+            desc = lib_description
+            licenses = ['MIT']
+            websiteUrl = repository_url
+            issueTrackerUrl = "$repository_url/issues"
+            vcsUrl = "${repository_url}.git"
+
+            labels = ['android', 'location', 'rxJava', 'locationmanager']
+
+            githubRepo = "Zellius/RxLocationManager"
+            githubReleaseNotesFile = 'README.md'
+
+            version {
+                name = lib_version
+                vcsTag = "v$lib_version"
+                released = new Date()
+            }
+        }
+    }
+
+    apply plugin: 'org.jetbrains.dokka-android'
+
+    dokka {
+        outputFormat = 'javadoc'
+        sourceDirs = android.sourceSets.main.java.srcDirs
+        outputDirectory = "$buildDir/javadoc"
+    }
+
+    task androidJavadocsJar(type: Jar, dependsOn: dokka) {
+        classifier 'javadoc'
+        from dokka.outputDirectory
+    }
+
+
+    task androidSourcesJar(type: Jar) {
+        classifier 'sources'
+        from android.sourceSets.main.java.srcDirs
+    }
+
+    artifacts {
+        archives androidSourcesJar
+        archives androidJavadocsJar
+    }
+}

rxlocationmanager/build.gradle

@@ -1,8 +1,3 @@
-publish {
-    groupId = 'com.github.zellius'
-    artifactId = 'rxlocationmanager'
-    publishVersion = '0.1.2'
-    desc = 'Android library that helps to get location using standart LocationManager and RxJava'
-    licences = ['MIT']
-    website = 'https://github.com/Zellius/RxLocationManager'
-}
+ext.lib_version = '0.1.2'
+ext.lib_name = 'RxLocationManager'
+ext.lib_description = 'Android library that helps to get location using standart LocationManager and RxJava'