-
Notifications
You must be signed in to change notification settings - Fork 5
/
tables.lasso
148 lines (121 loc) · 3.34 KB
/
tables.lasso
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
<?lassoscript
//-----------------------------------------------------------------------------------------
//
// base table — reduced functionality to a tree / map but better performance.
//
//-----------------------------------------------------------------------------------------
define table => type {
trait {
import trait_contractible, trait_searchable, trait_expandable, trait_keyed, trait_keyedforeach
}
data
private index = staticarray_join(256,void) // 256 table size
public insert(p::pair) => {
local(
key = #p->name,
i = .index(#key),
node = .'index'->get(#i) || .newnode
)
#node->insert(#p)
.'index'->get(#i) = #node
}
public get_index(key::any) => {
return .'index'->get(.index(#key))
}
public set_index(key::any,node) => {
.'index'->get(.index(#key->asstring)) = #node
}
public size => {
local(s = 0)
.'index'->foreach => {
#1 ? #s += #1->size
}
return #s
}
public keys => {
local(
keys = array
)
.foreachpair => {
#keys->insert(#1->name)
}
return #keys->asstaticarray
}
public get(key) => {
local(v) = .find(#key)
#v->isa(::void)
? fail(-1,'The specified key does not exist')
return #v
}
public find(key) => {
local(
node = .get_index(#key)
)
#node ? return #node->find(#key)
}
public remove(key) => {
local(
node = .get_index(#key)
)
#node ? return #node->remove(#key)
}
public removeall => {
local(i) = 1
.'index'->foreach => {
.'index'->get(#i) = void
#i++
}
}
// Value this should work off values instead of pairs
public foreach => {
local(gb) = givenblock
.'index'->foreach => {
#1 ? #1->foreach => #gb
}
}
public foreachkey => .keys->foreach => givenblock
public foreachpair => {
local(gb) = givenblock
.'index'->foreach => {
#1 ? #1->foreachpair => #gb
}
}
}
//-----------------------------------------------------------------------------------------
//
// hashtable — very fast for large number of keys (2 - 3x faster than map),
// slowish create time (16 micros vs 5 for map) namely due to index
//
//-----------------------------------------------------------------------------------------
define hashtable => type {
data
private index = staticarray_join(1024,void) // 1024 table size
parent table
public index(p::string) => #p->hash->abs % .'index'->size + 1
public index(p::integer) => #p % .'index'->size + 1
public index(p::bytes) => #p->crc % .'index'->size + 1
public index(p::any) => .index(bytes(#p))
public newnode => sequential
public oncreate(...) => {
params->foreach => {.insert(#1)}
}
}
//---------------------------------------------------------------------------------------
//
// indextable — indexes keys based soley on first character then straight scans
// extremely fast lookup outweighs collision issues, good for randomish
// keys < 100 typically faster than map, create time 8 micros or so.
//
//---------------------------------------------------------------------------------------
define indextable => type {
parent table
public index(p::string) => #p->integer % .'index'->size + 1
public index(p::integer) => #p % .'index'->size + 1
public index(p::bytes) => #p->crc % .'index'->size + 1
public index(p::any) => .index(#p->asstring)
public newnode => sequential
public oncreate(...) => {
params->foreach => {.insert(#1)}
}
}
?>