-
Notifications
You must be signed in to change notification settings - Fork 0
/
ExpandEnv.n
143 lines (125 loc) · 3.83 KB
/
ExpandEnv.n
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
using System;
using System.IO;
using System.Collections.Generic;
using System.Linq.Enumerable;
using Nemerle.Collections;
using Nemerle.Compiler.NemerleAttributes;
using Nemerle.Compiler.Parsetree;
using Nemerle.Compiler;
using Nemerle.Macros;
using Nemerle.Utility;
using Nemerle;
using System.Diagnostics.Trace;
using System.Reflection;
using System.Text.RegularExpressions;
using TT = Nemerle.Compiler.Typedtree;
namespace GitVersion
{
[Nemerle.MacroUsage (Nemerle.MacroPhase.BeforeInheritance,
Nemerle.MacroTargets.Assembly)]
macro GeneratedAssemblyVersion(str, defaults = null)
{
def version = ExpandEnvHelper.Expand(str, defaults);
Manager().Hierarchy.AddAssemblyAttribute(Manager().CoreEnv,
<[ System.Reflection.AssemblyVersion($(version : string)) ]>);
}
macro ExpandEnv(str, defaults = null)
{
def version = ExpandEnvHelper.Expand(str, defaults);
<[ $(version : string) ]>;
}
module ExpandEnvHelper
{
VarRegex : Regex = Regex(@"\$([\w_][\w\d_]*)");
public Expand(strExpr : PExpr, defaults: PExpr) : string
{
def str = match (strExpr)
{
| Literal(Literal.String(s)) => s
| _ => Message.FatalError(strExpr.Location, "Expected string literal.")
}
mutable vars = Set();
foreach (m is Match in VarRegex.Matches(str))
{
vars = vars.Add(m.Groups[1].Value);
}
def defaultValues = Dictionary();
match (defaults)
{
| null => ()
| <[ Defaults(..$parms) ]> =>
foreach (d in parms)
{
| <[ $var = $value ]> =>
def varName = var.ToString();
def value = match (value)
{
| Literal(Literal.String(s)) => s
| _ => Message.Error(value.Location, "Default value must be a string."); ""
}
unless (vars.Contains(varName))
Message.Error(var.Location, $"$('$')$varName not found in the template.");
when (defaultValues.ContainsKey(varName))
Message.Error(var.Location, $"Duplicate $varName.");
defaultValues[varName] = value;
| _ =>
Message.Error(d.Location, "Default value expression must have 'x = \"y\"' format.");
()
}
| _ =>
Message.FatalError(defaults.Location, "Defaults expression must have Defaults(x = \"y\", x1 = \"y1\",...)' format.");
}
def path = lazy({
def loc = strExpr.Location;
if (loc.IsSourceFileAvailable)
Path.GetDirectoryName(Path.GetFullPath(loc.File))
else
Directory.GetCurrentDirectory();
});
//System.Diagnostics.Debugger.Launch();
def evaluateVar(var)
{
def getSpecial()
{
match (var)
{
| "GitTag" =>
Console.Error.WriteLine("Tag");
match (GitRevisionHelper.GetRevisionGeneric(path))
{
| Some( (tag, _rev, _commit) ) => tag
| None() => null
}
| "GitRevision" =>
match (GitRevisionHelper.GetRevisionGeneric(path))
{
| Some( (_tag, rev, _commit) ) => rev
| None() => null
}
| _ => null
}
}
def getEnvironment()
{
Environment.GetEnvironmentVariable(var)
}
def getDefault()
{
match (defaultValues.ContainsKey(var))
{
| true =>
defaultValues[var]
| false =>
Message.Error(strExpr.Location, $"$var is not defined and have not default value.");
""
}
}
getEnvironment() ?? getSpecial() ?? getDefault()
}
VarRegex.Replace(str, MatchEvaluator(m => {
def varName = m.Groups[1].Value;
evaluateVar(varName)
}));
}
}
}