HAVING and ORDER BY broken on COUNT() columns

[niklas88]

This issue was found by @hannahbast with the HAVING clause of the following average height by profession query:

PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX psv: <http://www.wikidata.org/prop/statement/value/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?occupation ?gender (AVG(?height) AS ?average_height) (COUNT(?height) AS ?count) WHERE {
  ?x wdt:P31 wd:Q5 .
  ?x p:P2048 ?statement .
  ?x wdt:P21 ?gender_id .
  ?gender_id rdfs:label ?gender .
  FILTER langMatches(lang(?gender), "en") .
  ?statement psv:P2048 ?value .
  ?value wikibase:quantityNormalized ?quantity .
  ?quantity wikibase:quantityUnit wd:Q11573 .
  ?quantity wikibase:quantityAmount ?height .
  ?x wdt:P106 ?occupation_id .
  ?occupation_id rdfs:label ?occupation .
  FILTER langMatches(lang(?occupation), "en") .
  FILTER (?height < 3)
}
GROUP BY ?occupation ?gender
HAVING (?count > 100)
ORDER BY DESC(?average_height)

It turns out this also affects ORDER BY, but works fine when the GROUP BY is implemented by CountAvailablePredicates.

A simple reproducer on the scientists collection is as follows

SELECT ?place (COUNT(?person) AS ?count) WHERE {
   ?person <is-a> <Person> .
   ?person <Place_of_birth> ?place
}
GROUP BY ?place
HAVING (?count > 5)
ORDER BY ASC(?count)

Where both the HAVING and the ORDER BY are broken on current master