-
Notifications
You must be signed in to change notification settings - Fork 0
/
core.clj
288 lines (231 loc) · 6.75 KB
/
core.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
(ns neo4j-clj.core
(:use clojure.core)
(:import [org.neo4j.kernel EmbeddedGraphDatabase]
[org.neo4j.graphdb Direction NotFoundException RelationshipType]
[org.neo4j.cypher.javacompat ExecutionEngine CypherParser]))
;;; --------------------------------------------------------------------------------
(def ^:dynamic *db* nil)
(defn make-embedded-db
[path]
(EmbeddedGraphDatabase. path))
(defn set-db!
[db]
(alter-var-root #'*db* (constantly db)))
(defn shutdown
([]
(.shutdown *db*))
([db]
(.shutdown db)))
(defn reference-node
([]
(reference-node *db*))
([db]
(.getReferenceNode db)))
(defn get-all-nodes
([]
(get-all-nodes *db*))
([db]
(.getAllNodes db)))
(defn get-node-by-id
([node-id]
(get-node-by-id *db* node-id))
([db node-id]
(.getNodeById db node-id)))
(defn get-id
[node-or-relationship]
(.getId node-or-relationship))
(defn ^RelationshipType as-relationship
"Creates a Neo4j relationship type object from a keyword.
Copied from borneo hence same caveats apply: should we cache these?
"
[k]
(reify RelationshipType
(^String name [this] (name k))))
(defmacro with-connection [db & body]
`(binding [*db* ~db]
~@body))
(defmacro with-transaction
[& body]
`(let [transaction# (.beginTx *db*)]
(try
(let [val# (do ~@body)]
(.success transaction#)
val#)
(finally (.finish transaction#)))))
(defmacro with-transaction*
[db & body]
`(with-connection ~db
(with-transaction
~@body)))
;;; --------------------------------------------------------------------------------
;; Property Containers
(defn associate
([container key val]
(.setProperty container (name key) val)
container)
([container m]
(doseq [[k v] m]
(associate container k v))
container))
(defn disassociate
([container k-or-ks]
(if (keyword? k-or-ks)
(.removeProperty container (name k-or-ks))
(doseq [k k-or-ks]
(disassociate container k)))
container))
(defn property
[container k]
(try
(.getProperty container (name k))
(catch NotFoundException e
nil)))
(defn properties
([container]
(properties container (.getPropertyKeys container)))
([container ks]
(doall
(reduce (fn [m k]
(assoc m (keyword k) (property container k)))
{}
ks))))
;;; --------------------------------------------------------------------------------
;; Relationships
(defn ^Direction as-direction
"Translates keyword to the respective relationship direction.
Valid values are :out :in and :both.
See javadoc for Direction for more info on directions."
[k]
(case k
:out Direction/OUTGOING
:in Direction/INCOMING
:both Direction/BOTH))
(defn relate
([n1 n2 via]
(.createRelationshipTo n1 n2 (as-relationship via)))
([n1 n2 via m]
(doto (.createRelationshipTo n1 n2 (as-relationship via))
(associate m))))
(defn relationship-type
[rel]
(keyword (.. rel getType name)))
(defn relationship-type?
[rel type]
(= (relationship-type rel) type))
(defn start-node
[rel]
(.getStartNode rel))
(defn end-node
[rel]
(.getEndNode rel))
(defn other-node
[rel node]
(.getOtherNode rel node))
(defn nodes
[rel]
(seq (.getNodes rel)))
(defn delete
[rel]
(.delete rel))
;;; --------------------------------------------------------------------------------
;; Nodes
(defn create-node
([]
(.createNode *db*))
([m]
(doto (.createNode *db*)
(associate m))))
(defn relationships
([node]
(.getRelationships node))
([node direction]
(.getRelationships node (as-direction direction))))
(defn relationship
([node kind]
(relationship node kind :both))
([node kind direction]
(.getSingleRelationship node (as-relationship kind) (as-direction direction))))
(defn relationship?
([node]
(.hasRelationship node))
([node direction]
(.hasRelationship node (as-direction direction)))
([node direction kind-or-kinds]
(if (keyword? kind-or-kinds)
(.hasRelationship node (as-relationship kind-or-kinds) (as-direction direction))
(.hasRelationship node
(as-direction direction)
(into-array RelationshipType (map as-relationship kind-or-kinds))))))
;;; --------------------------------------------------------------------------------
;; Indexes
(defn create-node-index
[index-name]
(let [index-manager (.index *db*)]
(.forNodes index-manager (name index-name))))
(defn create-relationship-index
[index-name]
(let [index-manager (.index *db*)]
(.forRelationships index-manager (name index-name))))
(defn add-to-index
[index node k v]
(.add index node (name k) v)
node)
(defn get-hit
[index k v]
(.. index
(get (name k) v)
getSingle))
(defn get-hits
[index k v]
(seq (.. index
(get (name k) v))))
;;; --------------------------------------------------------------------------------
;; Cypher Interface
;; db = new ImpermanentGraphDatabase();
;; CypherParser parser = new CypherParser();
;; ExecutionEngine engine = new ExecutionEngine(db);
;; Query query = parser.parse( "start n=(0) where 1=1 return n" );
;; ExecutionResult result = engine.execute( query );
;; assertThat( result.columns(), hasItem( "n" ) );
;; Iterator<Node> n_column = result.columnAs( "n" );
;; assertThat( asIterable( n_column ), hasItem(db.getNodeById(0)) );
;; assertThat( result.toString(), containsString("Node[0]"
(defn cypher-query
([query]
(cypher-query *db* query))
([db query]
(let [engine (ExecutionEngine. db)
parser (CypherParser.)]
(.parse parser query)
(let [result (.execute engine (.parse parser query))]
(with-meta
(seq result)
{:columns (.columns result)})))))
(defn result-columns
[r]
(:columns (meta r)))
(defn cypher-result-as-rows
[results]
(let [cols (result-columns results)]
(with-meta
(map (fn [row]
(map #(.get row %) cols))
results)
(meta results))))
(defn cypher-result-as-nodes
"Lots of queries return a single column in the result set, in that
case it is a pain to deal with a seq of seqs of only one item.
This flattens out the results to give you just a seq of nodes.
If the result has more than one column the rest are silently ignored."
[result]
(let [col (first (result-columns result))]
(with-meta
(map (fn [row] (.get row col))
result)
{:columns [col]})))
;;; --------------------------------------------------------------------------------
;; Some nice to have utilities
(defn follow
[node relationship-type]
(let [rel (relationship node relationship-type)]
(.getOtherNode rel node)))