-
Notifications
You must be signed in to change notification settings - Fork 2
/
anfout.mac
708 lines (708 loc) · 17.3 KB
/
anfout.mac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
!-----------------------------------------------------!
! !
! Macro that traverses the solid model and writes an !
! anf file !
! !
! Provided by John Swanson
! USE AT YOUR OWN RISK
! NO SUPPORT IS AVAILABLE FOR THIS MACRO
!
! Posted by Eric Miller, PADT
!-----------------------------------------------------!
!
/nopr
! 1st define components of the present selected entities
cm,vol,volu
cm,ar,area
cm,ls,line
cm,kpt,kp
! 2nd see what entities are selected/defined
*get,vtot,volu,,count
*get,atot,area,,count
*get,ltot,line,,count
*get,ktot,kp,,count
! 3rd decide what entities need to be processed
proc=0
*if,vtot,gt,0,then
proc=4
lab='volu'
*elseif,atot,gt,0,then
proc=3
lab='area'
*elseif,ltot,gt,0,then
proc=2
lab='line'
*elseif,ktot,gt,0,then
proc=1
lab = 'kp'
*endif
vtot=
atot=
ltot=
ktot=
! 4th temparily select all entities below the highest selected entity
allsel,below,lab
lab=
! 5th define global arrays used in all entities
*dim,val,array,1
*dim,coord,array,3
!
! 6th get the current jobname
*get,jobn1,active,,jobnam,,start,1
*get,jobn2,active,,jobnam,,start,9
*get,jobn3,active,,jobnam,,start,17
*get,jobn4,active,,jobnam,,start,25
!
! 7th Delete old anf file
/delete,%jobn1%%jobn2%%jobn3%%jobn4%,anf
!
! 8th open anf file
*cfopen,%jobn1%%jobn2%%jobn3%%jobn4%,anf
!
!
! 9th Check to see if lines are concatenated
*dim,valu,array,1000
*if,proc,ge,3,then
conc=0
*get,tot,line,,count ! get the number of lines
num=0
*DO,i,1,tot ! loop thru lines
num=lsnext(num) ! get next line number
*vget,valu(1),40,num,15,1,,,4 ! get the list of sublines
*vscfun,nsub,last,valu(1) ! how many sublines are there
*if,nsub,gt,1,then ! concatenation detected
conc=1
*msg,warn
Concatenation Encountered in a line - anf file not written
*exit
*endif
*ENDDO ! end of *do,i (lines) loop
*endif ! end of if processing areas and/or volumes
!
! Check to see if areas are concatenated - if lines are not concatenated
*if,conc,eq,0,then ! no concatenation found - continue
*if,proc,eq,4,then
*get,tot,area,,count ! get the number of areas
num=0
*DO,i,1,tot ! loop thru area
num=arnext(num) ! get next area number
*vget,valu(1),60,num,14,1,,,4 ! get the list of subareas
*vscfun,nsub,last,valu(1) ! how many subareas are there
*if,nsub,gt,1,then ! concatenation detected
conc=1
*msg,warn
Concatenation Encountered in an area - anf file not written
*exit
*endif
*ENDDO ! end of *do,i (areas) loop
*endif ! end of if processing volumes
*endif ! end of if no concatenation
nsub=
!
!
*if,conc,eq,0,then ! no concatenation found - continue
*cfwrit, /out,anf,lst
*cfwrit,/AUX15
!
!
! Process the keypoints
*if,proc,ge,1,then
*get,tot,kp,,count ! get the number of keypoints
num=0
*DO,i,1,tot ! loop thru keypoints
num=kpnext(num) ! get next keypoint number
*vget,val(1),20,num,1,5 ! get point associated w/ kp
*vlen,3
*vget,coord(1),22,val(1),2,1,,,4 ! get the coord's
*cfwrit,kpt,num,coord(1),coord(2),coord(3)
chr=chrval(num)
*vwrit,chr
(a8)
*ENDDO ! end of *do,i (keypoints) loop
*endif ! end of if processing keypoints
!
!
! Process the lines
*if,proc,ge,2,then
*get,tot,line,,num,max ! get the max line id number
*dim,ldir_,array,tot
*get,tot,line,,count ! get the number of lines
num=0
*DO,i,1,tot ! loop thru lines
num=lsnext(num) ! get next line number
*vget,val(1),40,num,15,1 ! get line's subline number
*if,val(1),lt,0,then
ldir_(num)=1
*endif
snum=abs(val(1))
*vget,val(1),40,num,1,9 ! get 1st keypt
kp1=val(1)
*vget,val(1),40,num,1,10 ! get 2nd keypt
kp2=val(1)
*vlen,2
*vget,coord(1),42,snum,6,1,,,4 ! get the min/max parm values
*if,ldir_(num),eq,1,then
*cfwrit,lcurv,num,1,kp2,kp1,coord(1),coord(2)
*else
*cfwrit,lcurv,num,1,kp1,kp2,coord(1),coord(2)
*endif
chr=chrval(num)
*vwrit,chr
(a8)
*vget,val(1),42,snum,3,2 ! get subline's curve number
cnum=abs(val(1))
*vget,val(1),44,cnum,1,5
form=chrval(val(1)) ! form number
*vget,val(1),44,cnum,1,2
ordrx=chrval(val(1)) ! nurb order
*vget,val(1),44,cnum,1,9
ndim=val(1) ! dimensionality
*if,ndim,eq,3,then ! rational?
irat = 0
rat=chrval(0)
*else
irat=1
rat=chrval(1)
*endif
*vget,val(1),44,cnum,1,3
nkntx = val(1)
kntx=chrval(val(1)) ! numb of knots
*vget,val(1),44,cnum,1,8
ncntl=val(1)
cntlx=chrval(val(1)) ! numb of control pts
*vwrite,form,ordrx,rat,kntx,cntlx ! write the nurb int data
(5a8)
*dim,arr,array,nkntx
*vlen,nkntx
*vget,arr(1),44,cnum,6,1,,,4 ! get the knots
itime=nint(nkntx/4)+1 ! print the knots
n2=0
*do,j,1,itime
n1=n2+1
n2=n1+3
*if,n1,le,nkntx,then
a1=arr(n1)
*endif
*if,n1+1,le,nkntx,then
a2=arr(n1+1)
*endif
*if,n1+2,le,nkntx,then
a3=arr(n1+2)
*endif
*if,n1+3,le,nkntx,then
a4=arr(n1+3)
*endif
*if,n1+3,le,nkntx,then
*vwrite,a1,a2,a3,a4
(4g20.12)
*elseif,n1+2,le,nkntx,then
*vwrite,a1,a2,a3,
(3g20.12)
*elseif,n1+1,le,nkntx,then
*vwrite,a1,a2,
(2g20.12)
*elseif,n1,le,nkntx,then
*vwrite,a1
(g20.12)
*endif
*enddo ! end of *do,j (knots) loop
*del,arr
nmbr=ncntl*ndim
*dim,arr,array,nmbr
*vlen,nmbr
*vget,arr(1),44,cnum,6,nkntx+1,,,4 ! get the control pts/weights
n2=0
*do,j,1,ncntl
n1=n2+1
n2=n1+ndim-1
a1=arr(n1)
a2=arr(n1+1)
a3=arr(n1+2)
*if,irat,eq,1,then ! if rational, divide cntl pts by weight
a4=arr(n1+3)
*vwrite,a1/a4,a2/a4,a3/a4
(3g20.12)
*else ! not rational, write out cntl pts
*vwrite,a1,a2,a3
(3g20.12)
*endif
*enddo ! end of *do,j (cntl pts) loop
*if,irat,eq,1,then
itime=nint(ncntl/4)+1 ! print the weights (if applicable)
n2=3
*do,j,1,itime
n1=n2+1
n2=n1+15
*if,n1,le,nmbr,then
a1=arr(n1)
*endif
*if,n1+4,le,nmbr,then
a2=arr(n1+4)
*endif
*if,n1+8,le,nmbr,then
a3=arr(n1+8)
*endif
*if,n1+12,le,nmbr,then
a4=arr(n1+12)
*endif
*if,n1+12,le,nmbr,then
*vwrite,a1,a2,a3,a4
(4g20.12)
*elseif,n1+8,le,nmbr,then
*vwrite,a1,a2,a3,
(3g20.12)
*elseif,n1+4,le,nmbr,then
*vwrite,a1,a2,
(2g20.12)
*elseif,n1,le,nmbr,then
*vwrite,a1
(g20.12)
*endif
*enddo ! end of *do,j (weights) loop
*endif ! end of if rational
*del,arr
*ENDDO ! end of *do,i (lines) loop
*endif ! end of if processing lines
!
!
! Process the area
*if,proc,ge,3,then
*get,tot,area,,count ! get the number of areas
num=0
*DO,i,1,tot ! loop thru area
num=arnext(num) ! get next area number
*vget,valu(1),60,num,12,1,,,4 ! get list of loops
*vscfun,nloop,last,valu(1) ! get the number of loops
maxnum = 0 ! max nmbr of lines in a loop
*do,j,1,nloop ! loop thru loops and get max nmbr of lines
*vget,valu(1),60,num,12,j,1,,5 ! get the list of lines for this loop
*vscfun,nlin,last,valu(1) ! get the number of lines for this loop
*if,nlin,gt,maxnum,then
maxnum=nlin
*endif
*enddo ! end of *do,j (loops) loop
*vget,val(1),60,num,14,1 ! get area's subarea number
snum=abs(val(1))
*vget,val(1),62,snum,1,1 ! get the subarea's surface number
cnum=abs(val(1))
*vget,val(1),64,cnum,1,11 ! get number of knots in x direction
nkntx=val(1)
kntx=chrval(nkntx)
*vget,val(1),64,cnum,1,12 ! get number of knots in y direction
nknty=val(1)
knty=chrval(nknty)
nmbr=nkntx+nknty
*dim,arr,array,nmbr
*vlen,nmbr
*vget,arr(1),64,cnum,6,1,,,4 ! get the knots
*cfwrit,asurf,num,1,nloop,maxnum,arr(1),arr(nkntx),arr(nkntx+1),arr(nmbr)
chr=chrval(num)
*vwrit,chr
(a8)
*do,j,1,nloop ! loop thru loops and get list of lines
*vger,valu(1),60,num,12,j,1,,5 ! get the list of lines for this loop
*vscfun,nlin,last,valu(1) ! get the number of lines for this loop
*if,j,eq,1,then
chr=chrval(0)
*else
chr=chrval(1)
*endif
cntlx=chrval(nlin)
*vwrite,chr,cntlx ! write the nmbr of lines for this loop
(2a8)
*do,k,1,nlin ! loop thru lines and check direction
n1 = abs(valu(k))
*if,ldir_(n1),eq,1,then
valu(k)=-1*valu(k) ! line direction was switched
*endif
*enddo ! end of do,k line loop
itime=nint(nlin/10)+1
n2=0
*do,k,1,itime
n1=n2+1
n2=n1+9
*if,n1,le,nlin,then
i1=chrval(valu(n1))
*endif
*if,n1+1,le,nlin,then
i2=chrval(valu(n1+1))
*endif
*if,n1+2,le,nlin,then
i3=chrval(valu(n1+2))
*endif
*if,n1+3,le,nlin,then
i4=chrval(valu(n1+3))
*endif
*if,n1+4,le,nlin,then
i5=chrval(valu(n1+4))
*endif
*if,n1+5,le,nlin,then
i6=chrval(valu(n1+5))
*endif
*if,n1+6,le,nlin,then
i7=chrval(valu(n1+6))
*endif
*if,n1+7,le,nlin,then
i8=chrval(valu(n1+7))
*endif
*if,n1+8,le,nlin,then
i9=chrval(valu(n1+8))
*endif
*if,n1+9,le,nlin,then
i10=chrval(valu(n1+9))
*endif
*if,n1+9,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8,i9,i10
(10a8)
*elseif,n1+8,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8,i9
(9a8)
*elseif,n1+7,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8
(8a8)
*elseif,n1+6,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7
(7a8)
*elseif,n1+5,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6
(6a8)
*elseif,n1+4,le,nlin,then
*vwrite,i1,i2,i3,i4,i5
(5a8)
*elseif,n1+3,le,nlin,then
*vwrite,i1,i2,i3,i4
(4a8)
*elseif,n1+2,le,nlin,then
*vwrite,i1,i2,i3
(3a8)
*elseif,n1+1,le,nlin,then
*vwrite,i1,i2
(2a8)
*elseif,n1,le,nlin,then
*vwrite,i1
(a8)
*endif
*enddo ! end of *do,k loop
*enddo ! end of *do,j (loops) loop
*vget,val(1),64,cnum,1,4 ! form number
form=chrval(val(1))
*vget,val(1),64,cnum,1,13 ! nurb order in x direction
ordrx=chrval(val(1))
*vget,val(1),64,cnum,1,14 ! nurb order in y direction
ordry=chrval(val(1))
*vget,val(1),64,cnum,1,9
ndim=val(1) ! dimensionality
*if,ndim,eq,3,then ! rational?
irat = 0
rat=chrval(0)
*else
irat=1
rat=chrval(1)
*endif
*vget,val(1),64,cnum,1,2 ! get number of cntl pts in x direction
cntlx=chrval(val(1))
ncntl=val(1)
*vget,val(1),64,cnum,1,3 ! get number of cntl pts in y direction
ncntl=ncntl*val(1) ! get the total nmbr of cntl pts
cntly=chrval(val(1))
*vwrite,form,ordrx,ordry,rat,kntx,knty,cntlx,cntly ! print the nurb int data
(8a8)
*vlen,nkntx
itime=nint(nkntx/4)+1 ! print the x-knots
n2=0
*do,j,1,itime
n1=n2+1
n2=n1+3
*if,n1,le,nkntx,then
a1=arr(n1)
*endif
*if,n1+1,le,nkntx,then
a2=arr(n1+1)
*endif
*if,n1+2,le,nkntx,then
a3=arr(n1+2)
*endif
*if,n1+3,le,nkntx,then
a4=arr(n1+3)
*endif
*if,n1+3,le,nkntx,then
*vwrite,a1,a2,a3,a4
(4g20.12)
*elseif,n1+2,le,nkntx,then
*vwrite,a1,a2,a3,
(3g20.12)
*elseif,n1+1,le,nkntx,then
*vwrite,a1,a2,
(2g20.12)
*elseif,n1,le,nkntx,then
*vwrite,a1
(g20.12)
*endif
*enddo ! end of *do,j (x-knots) loop
*vlen,nkntx
itime=nint(nknty/4)+1 ! print the y-knots
n2=nkntx
*do,j,1,itime
n1=n2+1
n2=n1+3
*if,n1,le,nkntx+nknty,then
a1=arr(n1)
*endif
*if,n1+1,le,nkntx+nknty,then
a2=arr(n1+1)
*endif
*if,n1+2,le,nkntx+nknty,then
a3=arr(n1+2)
*endif
*if,n1+3,le,nkntx+nknty,then
a4=arr(n1+3)
*endif
*if,n1+3,le,nkntx+nknty,then
*vwrite,a1,a2,a3,a4
(4g20.12)
*elseif,n1+2,le,nkntx+nknty,then
*vwrite,a1,a2,a3,
(3g20.12)
*elseif,n1+1,le,nkntx+nknty,then
*vwrite,a1,a2,
(2g20.12)
*elseif,n1,le,nkntx+nknty,then
*vwrite,a1
(g20.12)
*endif
*enddo ! end of *do,j (y-knots) loop
*del,arr
nmbr=ncntl*ndim
*dim,arr,array,nmbr
*vlen,nmbr
*vget,arr(1),64,cnum,6,nkntx+nknty+1,,,4 ! get the control pts/weights
n2=0
*do,j,1,ncntl
n1=n2+1
n2=n1+ndim-1
a1=arr(n1)
a2=arr(n1+1)
a3=arr(n1+2)
*if,irat,eq,1,then ! if rational, divide cntl pts by weight
a4=arr(n1+3)
*vwrite,a1/a4,a2/a4,a3/a4
(3g20.12)
*else ! not rational, write out cntl pts
*vwrite,a1,a2,a3
(3g20.12)
*endif
*enddo ! end of *do,j (cntl pts) loop
*if,irat,eq,1,then
itime=nint(ncntl/4)+1 ! print the weights (if applicable)
n2=3
*do,j,1,itime
n1=n2+1
n2=n1+15
*if,n1,le,nmbr,then
a1=arr(n1)
*endif
*if,n1+4,le,nmbr,then
a2=arr(n1+4)
*endif
*if,n1+8,le,nmbr,then
a3=arr(n1+8)
*endif
*if,n1+12,le,nmbr,then
a4=arr(n1+12)
*endif
*if,n1+12,le,nmbr,then
*vwrite,a1,a2,a3,a4
(4g20.12)
*elseif,n1+8,le,nmbr,then
*vwrite,a1,a2,a3,
(3g20.12)
*elseif,n1+4,le,nmbr,then
*vwrite,a1,a2,
(2g20.12)
*elseif,n1,le,nmbr,then
*vwrite,a1
(g20.12)
*endif
*enddo ! end of *do,j (weights) loop
*endif ! end of if rational
*del,arr
*ENDDO ! end of *do,i (areas) loop
*del,ldir_
*endif ! end of if processing areas
!
!
! Process the volumes
*if,proc,eq,4,then
*get,tot,volu,,count ! get the number of volumes
num=0
*DO,i,1,tot ! loop thru volumes
num=vlnext(num) ! get next volume number
*vget,valu(1),80,num,12,1,,,4 ! get list of shells
*vscfun,nloop,last,valu(1) ! get the number of shells
maxnum = 0 ! max nmbr of areas in an volume
*do,j,1,nloop ! loop thru shells and get max nmbr of areas
*vget,valu(1),80,num,12,j,1,,5 ! get the list of area for this shell
*vscfun,nlin,last,valu(1) ! get the number of areas for this shell
*if,nlin,gt,maxnum,then
maxnum=nlin
*endif
*enddo
*cfwrit,vbody,num,nloop,maxnum
chr=chrval(num)
*vwrit,chr
(a8)
*do,j,1,nloop ! loop thru shells and get list of areas
*vget,valu(1),80,num,12,j,1,,5 ! get the list of areas for this loop
*vscfun,nlin,last,valu(1) ! get the number of areas for this loop
*if,j,eq,1,then
chr=chrval(0)
*else
chr=chrval(1)
*endif
cntlx=chrval(nlin)
*vwrite,chr,cntlx ! write the nmbr of areas for this shell
(2a8)
itime=nint(nlin/10)+1
n2=0
*do,k,1,itime
n1=n2+1
n2=n1+9
*if,n1,le,nlin,then
i1=chrval(valu(n1))
*endif
*if,n1+1,le,nlin,then
i2=chrval(valu(n1+1))
*endif
*if,n1+2,le,nlin,then
i3=chrval(valu(n1+2))
*endif
*if,n1+3,le,nlin,then
i4=chrval(valu(n1+3))
*endif
*if,n1+4,le,nlin,then
i5=chrval(valu(n1+4))
*endif
*if,n1+5,le,nlin,then
i6=chrval(valu(n1+5))
*endif
*if,n1+6,le,nlin,then
i7=chrval(valu(n1+6))
*endif
*if,n1+7,le,nlin,then
i8=chrval(valu(n1+7))
*endif
*if,n1+8,le,nlin,then
i9=chrval(valu(n1+8))
*endif
*if,n1+9,le,nlin,then
i10=chrval(valu(n1+9))
*endif
*if,n1+9,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8,i9,i10
(10a8)
*elseif,n1+8,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8,i9
(9a8)
*elseif,n1+7,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7,i8
(8a8)
*elseif,n1+6,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6,i7
(7a8)
*elseif,n1+5,le,nlin,then
*vwrite,i1,i2,i3,i4,i5,i6
(6a8)
*elseif,n1+4,le,nlin,then
*vwrite,i1,i2,i3,i4,i5
(5a8)
*elseif,n1+3,le,nlin,then
*vwrite,i1,i2,i3,i4
(4a8)
*elseif,n1+2,le,nlin,then
*vwrite,i1,i2,i3
(3a8)
*elseif,n1+1,le,nlin,then
*vwrite,i1,i2
(2a8)
*elseif,n1,le,nlin,then
*vwrite,i1
(a8)
*endif
*enddo ! end of *do,k loop
*enddo ! end of *do,j (shells) loop
*ENDDO ! end of *do,i (volumes) loop
*endif ! end of if processing vl
!
*endif ! end of if no concatenation
*cfwrit, /out
!
! restore original selected sets of entities
cmsel,,vol
cmsel,,ar
cmsel,,ls
cmsel,,kpt
!
! close anf file
*cfclose
!
! clean up
!
i=
j=
k=
conc=
jobn1=
jobn2=
jobn3=
jobn4=
tot=
num=
nmbr=
kp1=
kp2=
snum=
cnum=
nkntx=
nknty=
kntx=
knty=
ncntl=
cntlx=
cntly=
ndim=
form=
ordrx=
ordry=
irat=
rat=
itime=
a1=
a2=
a3=
a4=
n1=
n2=
i1=
i2=
i3=
i4=
i5=
i6=
i7=
i8=
i9=
i10=
hr=
nloop=
nlin=
maxnum=
chr=
proc=
cmdel,vol
cmdel,ar
cmdel,ls
cmdel,kpt
*del,val
*del,coord
*del,valu
/gopr