-
Notifications
You must be signed in to change notification settings - Fork 8
/
vcfnp.pyx
1849 lines (1587 loc) · 65.9 KB
/
vcfnp.pyx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# cython: profile = False
# cython: boundscheck = False
# cython: wraparound = False
# cython: embedsignature = True
"""
Utility functions to extract data from a VCF file and load into a numpy array.
"""
__version__ = '1.9'
import sys
import re
from itertools import chain
import numpy as np
cimport numpy as np
from vcflib cimport (PyVariantCallFile, VariantCallFile, Variant,
VariantFieldType, FIELD_FLOAT, FIELD_INTEGER,
FIELD_STRING, FIELD_BOOL, FIELD_UNKNOWN,
ALLELE_NUMBER, GENOTYPE_NUMBER)
from libcpp cimport bool
from libcpp.string cimport string
from libcpp.vector cimport vector
from libcpp.map cimport map
from libc.stdlib cimport atoi, atol, atof
from cython.operator cimport dereference as deref
import time
from itertools import islice
import os
from datetime import datetime
cdef size_t npos = -1
cdef extern from "split.h":
# split a string on a single delimiter character (delim)
vector[string]& split(const string &s, char delim, vector[string] &elems)
vector[string] split(const string &s, char delim)
# split a string on any character found in the string of delimiters (delims)
vector[string]& split(const string &s, const string& delims, vector[string] &elems)
vector[string] split(const string &s, const string& delims)
TYPESTRING2KEY = {
'Float': FIELD_FLOAT,
'Integer': FIELD_INTEGER,
'String': FIELD_STRING,
'Flag': FIELD_BOOL,
}
# these are the possible fields in the variants array
STANDARD_VARIANT_FIELDS = (
'CHROM', 'POS', 'ID', 'REF', 'ALT', 'QUAL', 'FILTER',
'num_alleles', 'is_snp', 'svlen'
)
# default dtypes for the variants array fields
DEFAULT_VARIANT_DTYPE = {
'CHROM': 'a12',
'POS': 'i4',
'ID': 'a12',
'REF': 'a12',
'ALT': 'a12',
'QUAL': 'f4',
'num_alleles': 'u1',
'is_snp': 'b1',
'svlen': 'i4',
}
# default arities for the variants array fields
DEFAULT_VARIANT_ARITY = {
'CHROM': 1,
'POS': 1,
'ID': 1,
'REF': 1,
'ALT': 1, # default assume biallelic (1 alt allele)
'QUAL': 1,
'num_alleles': 1,
'is_snp': 1,
'svlen': 1, # default assume biallelic
}
# default fill values for the variants fields if values are missing
DEFAULT_VARIANT_FILL = {
'CHROM': '',
'POS': 0,
'ID': '',
'REF': '',
'ALT': '',
'QUAL': 0,
'num_alleles': 0,
'is_snp': False,
'svlen': 0,
}
# default mapping from VCF field types to numpy dtypes
DEFAULT_TYPE_MAP = {
FIELD_FLOAT: 'f4',
FIELD_INTEGER: 'i4',
FIELD_STRING: 'a12',
FIELD_BOOL: 'b1',
FIELD_UNKNOWN: 'a12' # leave as string
}
# default mapping from VCF field types to fill values for missing values
DEFAULT_FILL_MAP = {
FIELD_FLOAT: 0.,
FIELD_INTEGER: 0,
FIELD_STRING: '',
FIELD_BOOL: False,
FIELD_UNKNOWN: ''
}
# default dtypes for some known INFO fields where lower precision is acceptable in most cases
DEFAULT_INFO_DTYPE = {
'ABHet': 'f2',
'ABHom': 'f2',
'AC': 'u2',
'AF': 'f2',
'AN': 'u2',
'BaseQRankSum': 'f2',
'ClippingRankSum': 'f2',
'Dels': 'f2',
'FS': 'f2',
'HRun': 'u1',
'HaplotypeScore': 'f2',
'InbreedingCoeff': 'f2',
'VariantType': 'a12',
'MLEAC': 'u2',
'MLEAF': 'f2',
'MQ': 'f2',
'MQ0Fraction': 'f2',
'MQRankSum': 'f2',
'OND': 'f2',
'QD': 'f2',
'RPA': 'u2',
'RU': 'a12',
'ReadPosRankSum': 'f2',
}
STANDARD_CALLDATA_FIELDS = ('is_called', 'is_phased', 'genotype')
DEFAULT_CALLDATA_DTYPE = {
'is_called': 'b1',
'is_phased': 'b1',
'genotype': 'i1',
# set some lower precision defaults for known FORMAT fields
'AD': 'u2',
'DP': 'u2',
'GQ': 'u1',
'MLPSAC': 'u1',
'MLPSAF': 'f2',
'MQ0': 'u2',
'PL': 'u2',
}
DEFAULT_CALLDATA_FILL = {
'is_called': False,
'is_phased': False,
'genotype': -1,
}
DEFAULT_CALLDATA_ARITY = {
'is_called': 1,
'is_phased': 1,
# N.B., set genotype arity to ploidy
'AD': 2, # default to biallelic
}
cdef char SEMICOLON = ';'
cdef string DOT = '.'
cdef string GT_DELIMS = '/|'
cdef string FIELD_NAME_CHROM = 'CHROM'
cdef string FIELD_NAME_POS = 'POS'
cdef string FIELD_NAME_ID = 'ID'
cdef string FIELD_NAME_REF = 'REF'
cdef string FIELD_NAME_ALT = 'ALT'
cdef string FIELD_NAME_QUAL = 'QUAL'
cdef string FIELD_NAME_FILTER = 'FILTER'
cdef string FIELD_NAME_INFO = 'INFO'
cdef string FIELD_NAME_NUM_ALLELES = 'num_alleles'
cdef string FIELD_NAME_IS_SNP = 'is_snp'
cdef string FIELD_NAME_SVLEN = 'svlen'
cdef string FIELD_NAME_IS_CALLED = 'is_called'
cdef string FIELD_NAME_IS_PHASED = 'is_phased'
cdef string FIELD_NAME_GENOTYPE = 'genotype'
cdef string FIELD_NAME_GT = 'GT'
def _variants_fields(fields, exclude_fields, infoIds):
if fields is None:
fields = STANDARD_VARIANT_FIELDS + infoIds
else:
for f in fields:
if f not in STANDARD_VARIANT_FIELDS and f not in infoIds:
# support extracting INFO even if not declared in header, but warn...
print >>sys.stderr, 'WARNING: no INFO definition found for field %s' % f
if exclude_fields is not None:
fields = [f for f in fields if f not in exclude_fields]
return tuple(fields)
def _variants_arities(fields, arities, infoCounts):
if arities is None:
arities = dict()
for f, vcf_count in zip(fields, infoCounts):
if f == 'FILTER':
arities[f] = 1 # one value
elif f not in arities:
if f in STANDARD_VARIANT_FIELDS:
arities[f] = DEFAULT_VARIANT_ARITY[f]
elif vcf_count == ALLELE_NUMBER:
# default to 1 (biallelic)
arities[f] = 1
elif vcf_count <= 0:
# catch any other cases of non-specific arity
arities[f] = 1
else:
arities[f] = vcf_count
arities = tuple(arities[f] for f in fields)
return arities
def _variants_fills(fields, fills, infoTypes):
if fills is None:
fills = dict()
for f, vcf_type in zip(fields, infoTypes):
if f == 'FILTER':
fills[f] = False
elif f not in fills:
if f in STANDARD_VARIANT_FIELDS:
fills[f] = DEFAULT_VARIANT_FILL[f]
else:
fills[f] = DEFAULT_FILL_MAP[vcf_type]
fills = tuple(fills[f] for f in fields)
return fills
def _info_transformers(fields, transformers):
if transformers is None:
transformers = dict()
for f in fields:
if f not in transformers:
transformers[f] = None
return tuple(transformers[f] for f in fields)
def _variants_dtype(fields, dtypes, arities, filterIds, flatten_filter, infoTypes):
dtype = list()
for f, n, vcf_type in zip(fields, arities, infoTypes):
if f == 'FILTER' and flatten_filter:
# represent FILTER as multiple boolean fields
for flt in filterIds:
nm = 'FILTER_' + flt
dtype.append((nm, 'b1'))
elif f == 'FILTER' and not flatten_filter:
# represent FILTER as a structured datatype
t = [(flt, 'b1') for flt in filterIds]
dtype.append((f, t))
else:
if dtypes is not None and f in dtypes:
# user overrides default dtype
t = dtypes[f]
elif f in STANDARD_VARIANT_FIELDS:
t = DEFAULT_VARIANT_DTYPE[f]
elif f in DEFAULT_INFO_DTYPE:
# known INFO field
t = DEFAULT_INFO_DTYPE[f]
else:
t = DEFAULT_TYPE_MAP[vcf_type]
if n == 1:
dtype.append((f, t))
else:
dtype.append((f, t, (n,)))
return dtype
def _filenames_from_arg(filename):
if isinstance(filename, basestring):
filenames = [filename]
elif isinstance(filename, (list, tuple)):
filenames = filename
else:
raise Exception('filename argument must be basestring, list or tuple')
for fn in filenames:
if not os.path.exists(fn):
raise Exception('file not found: %s' % fn)
return filenames
def _setup_variants(filename,
region,
fields,
exclude_fields,
arities,
fills,
transformers,
vcf_types,
flatten_filter):
filenames = _filenames_from_arg(filename)
# extract definitions from VCF header
vcf = PyVariantCallFile(filenames[0])
# FILTER definitions
filterIds = vcf.filterIds
_warn_duplicates(filterIds)
filterIds = sorted(set(filterIds))
if 'PASS' not in filterIds:
filterIds.append('PASS')
filterIds = tuple(filterIds)
# INFO definitions
_warn_duplicates(vcf.infoIds)
infoIds = tuple(sorted(set(vcf.infoIds)))
infoTypes = vcf.infoTypes
infoCounts = vcf.infoCounts
# determine fields to extract
fields = _variants_fields(fields, exclude_fields, infoIds)
# determine if we need to parse the INFO field
parseInfo = any([f not in STANDARD_VARIANT_FIELDS for f in fields])
# support for working around VCFs with bad INFO headers
for f in fields:
if f not in STANDARD_VARIANT_FIELDS and f not in infoIds:
# fall back to unary string; can be overridden with vcf_types, dtypes and arities args
infoTypes[f] = FIELD_STRING
infoCounts[f] = 1
if vcf_types is not None and f in vcf_types:
# override type declared in VCF header
infoTypes[f] = TYPESTRING2KEY[vcf_types[f]]
infoTypes = tuple(infoTypes[f] if f in infoTypes else -1 for f in fields)
infoCounts = tuple(infoCounts[f] if f in infoCounts else -1 for f in fields)
# determine expected number of values for each field
arities = _variants_arities(fields, arities, infoCounts)
# determine fill values to use where number of values is less than expectation
fills = _variants_fills(fields, fills, infoTypes)
# initialise INFO field transformers
transformers = _info_transformers(fields, transformers)
return filenames, region, fields, arities, fills, infoTypes, transformers, parseInfo, filterIds, flatten_filter
def log(logstream, *msg):
print >>logstream, '[vcfnp] ' + str(datetime.now()) + ' :: ' + ' '.join([str(m) for m in msg])
sys.stderr.flush()
def variants(filename,
region=None,
fields=None,
exclude_fields=None,
dtypes=None,
arities=None,
fills=None,
transformers=None,
vcf_types=None,
count=None,
progress=0,
logstream=sys.stderr,
condition=None,
slice=None,
flatten_filter=False,
verbose=False,
cache=False,
cachedir=None,
skip_cached=False,
):
"""
Load an numpy structured array with data from the fixed fields of a VCF file
(including INFO).
Parameters
----------
filename: string or list
Name of the VCF file or list of file names
region: string
Region to extract, e.g., 'chr1' or 'chr1:0-100000'
fields: list or array-like
List of fields to extract from the VCF
exclude_fields: list or array-like
Fields to exclude from extraction
dtypes: dict or dict-like
Dictionary cotaining dtypes to use instead of the default inferred ones
arities: dict or dict-like
Dictinoary containing field:integer mappings used to override the number
of values to expect
fills: dict or dict-like
Dictionary containing field:fillvalue mappings used to override the
defaults used for missing values
transformers: dict or dict-like
Dictionary containing field:function mappings used to preprocess
any values prior to loading into array
vcf_types: dict or dict-like
Dictionary containing field:string mappings used to override any
bogus type declarations in the VCF header (e.g., MQ0Fraction declared
as Integer)
count: int
Attempt to extract a specific number of records
progress: int
If greater than 0, log parsing progress
logstream: file or file-like object
Stream to use for logging progress
condition: array
Boolean array defining which rows to load
slice: tuple or list
Slice of the underlying iterator, e.g., (0, 1000, 10) takes every 10th row from the first 1000
flatten_filter: bool
Return FILTER as multiple boolean fields, e.g., FILTER_PASS, FILTER_LowQuality, etc.
verbose: bool
Log more messages.
cache: bool
If True, save the resulting numpy array to disk, and load from the cache if present rather than rebuilding
from the VCF.
cachedir: string
Manually specify the directory to use to store cache files.
skip_cached: bool
If True and cache file is fresh, do not load and return None.
Examples
--------
>>> from vcfnp import variants
>>> V = variants('fixture/sample.vcf')
>>> V
array([ ('19', 111, '.', 'A', 'C', 9.600000381469727, (False, False, False), 2, True, 0, '.', 0, 0.0, 0, False, 0, False, 0),
('19', 112, '.', 'A', 'G', 10.0, (False, False, False), 2, True, 0, '.', 0, 0.0, 0, False, 0, False, 0),
('20', 14370, 'rs6054257', 'G', 'A', 29.0, (False, False, True), 2, True, 0, '.', 0, 0.5, 0, True, 14, True, 3),
('20', 17330, '.', 'T', 'A', 3.0, (True, False, False), 2, True, 0, '.', 0, 0.017000000923871994, 0, False, 11, False, 3),
('20', 1110696, 'rs6040355', 'A', 'G', 67.0, (False, False, True), 3, True, 0, 'T', 0, 0.3330000042915344, 0, True, 10, False, 2),
('20', 1230237, '.', 'T', '.', 47.0, (False, False, True), 2, False, 0, 'T', 0, 0.0, 0, False, 13, False, 3),
('20', 1234567, 'microsat1', 'G', 'GA', 50.0, (False, False, True), 3, False, 1, 'G', 3, 0.0, 6, False, 9, False, 3),
('20', 1235237, '.', 'T', '.', 0.0, (False, False, False), 2, False, 0, '.', 0, 0.0, 0, False, 0, False, 0),
('X', 10, 'rsTest', 'AC', 'A', 10.0, (False, False, True), 3, False, -1, '.', 0, 0.0, 0, False, 0, False, 0)],
dtype=[('CHROM', 'S12'), ('POS', '<i4'), ('ID', 'S12'), ('REF', 'S12'), ('ALT', 'S12'), ('QUAL', '<f4'), ('FILTER', [('q10', '?'), ('s50', '?'), ('PASS', '?')]), ('num_alleles', 'u1'), ('is_snp', '?'), ('svlen', '<i4'), ('AA', 'S12'), ('AC', '<u2'), ('AF', '<f4'), ('AN', '<u2'), ('DB', '?'), ('DP', '<i4'), ('H2', '?'), ('NS', '<i4')])
>>> V['QUAL']
array([ 9.60000038, 10. , 29. , 3. ,
67. , 47. , 50. , 0. , 10. ], dtype=float32)
>>> V['FILTER']['PASS']
array([False, False, True, False, True, True, True, False, True], dtype=bool)
>>> V['AF']
array([ 0. , 0. , 0.5 , 0.017, 0.333, 0. , 0. , 0. , 0. ], dtype=float32)
"""
if cache:
if isinstance(filename, (list, tuple)):
raise Exception('caching only supported when loading from a single VCF file')
cache_fn = _mk_cache_fn(filename, type='variants', region=region, cachedir=cachedir)
if not os.path.exists(cache_fn) or os.path.getmtime(filename) > os.path.getmtime(cache_fn):
if verbose:
log(logstream, 'no cache file found or cache out of date')
A = _build_variants(filename,
region=region,
fields=fields,
exclude_fields=exclude_fields,
dtypes=dtypes,
arities=arities,
fills=fills,
transformers=transformers,
vcf_types=vcf_types,
count=count,
progress=progress,
logstream=logstream,
condition=condition,
slice=slice,
flatten_filter=flatten_filter,
verbose=verbose)
if verbose:
log(logstream, 'saving to cache', cache_fn)
np.save(cache_fn, A)
return A
else:
if skip_cached:
if verbose:
log(logstream, 'skipping from cache', cache_fn)
return None
else:
if verbose:
log(logstream, 'loading from cache', cache_fn)
A = np.load(cache_fn)
return A
else:
A = _build_variants(filename,
region=region,
fields=fields,
exclude_fields=exclude_fields,
dtypes=dtypes,
arities=arities,
fills=fills,
transformers=transformers,
vcf_types=vcf_types,
count=count,
progress=progress,
logstream=logstream,
condition=condition,
slice=slice,
flatten_filter=flatten_filter,
verbose=verbose)
return A
cachedir_suffix = '.vcfnp_cache'
def _mk_cache_fn(vcf_fn, type, region=None, cachedir=None):
if cachedir is None:
cachedir = vcf_fn + cachedir_suffix
if not os.path.exists(cachedir):
os.makedirs(cachedir)
else:
assert os.path.isdir(cachedir), 'unexpected error, cache directory is not a directory: %s' % cachedir
if region is None:
cache_fn = os.path.join(cachedir, '%s.npy' % type)
else:
region = region.replace(':', '_').replace('-', '_')
cache_fn = os.path.join(cachedir, '%s.%s.npy' % (type, region))
return cache_fn
def _build_variants(filename,
region=None,
fields=None,
exclude_fields=None,
dtypes=None,
arities=None,
fills=None,
transformers=None,
vcf_types=None,
count=None,
progress=0,
logstream=sys.stderr,
condition=None,
slice=None,
flatten_filter=False,
verbose=False,
cache=False,
):
if verbose:
log(logstream, 'loading variants from', filename)
filenames, region, fields, arities, fills, infoTypes, transformers, parseInfo, filterIds, flatten_filter = _setup_variants(filename,
region,
fields,
exclude_fields,
arities,
fills,
transformers,
vcf_types,
flatten_filter)
# zip up field parameters
fieldspec = zip(fields, arities, fills, infoTypes, transformers)
# create a numpy dtype
dtype = _variants_dtype(fields, dtypes, arities, filterIds, flatten_filter, infoTypes)
# set up iterator
if condition is not None:
it = itervariants_with_condition(filenames, region, fieldspec, filterIds, flatten_filter, parseInfo, condition)
else:
it = itervariants(filenames, region, fieldspec, filterIds, flatten_filter, parseInfo)
# slice?
if slice:
it = islice(it, *slice)
# build an array from the iterator
return _fromiter(it, dtype, count, progress, logstream)
def _fromiter(it, dtype, count, long progress=0, logstream=sys.stderr):
if progress > 0:
it = _iter_withprogress(it, progress, logstream)
if count is not None:
a = np.fromiter(it, dtype=dtype, count=count)
else:
a = np.fromiter(it, dtype=dtype)
return a
def _iter_withprogress(iterable, long progress, logstream):
cdef long i, n
before_all = time.time()
before = before_all
for i, o in enumerate(iterable):
yield o
n = i+1
if n % progress == 0:
after = time.time()
log(logstream, '%s rows in %.2fs; batch in %.2fs (%d rows/s)' % (n, after-before_all, after-before, progress/(after-before)))
before = after
after_all = time.time()
log(logstream, '%s rows in %.2fs (%d rows/s)' % (n, after_all-before_all, n/(after_all-before_all)))
def itervariants(filenames,
region,
list fieldspec,
tuple filterIds,
bint flatten_filter,
parseInfo):
cdef VariantCallFile *variantFile
cdef Variant *var
for current_filename in filenames:
variantFile = new VariantCallFile()
variantFile.open(current_filename)
variantFile.parseInfo = parseInfo
variantFile.parseSamples = False
if region is not None:
region_set = variantFile.setRegion(region)
if not region_set:
raise StopIteration
var = new Variant(deref(variantFile))
while _get_next_variant(variantFile, var):
yield _mkvrow(var, fieldspec, filterIds, flatten_filter)
del variantFile
del var
def itervariants_with_condition(filenames,
region,
list fieldspec,
tuple filterIds,
bint flatten_filter,
parseInfo,
condition,
):
cdef VariantCallFile *variantFile
cdef Variant *var
cdef long i = 0
cdef long n = len(condition)
for current_filename in filenames:
variantFile = new VariantCallFile()
variantFile.open(current_filename)
variantFile.parseInfo = parseInfo
variantFile.parseSamples = False
if region is not None:
region_set = variantFile.setRegion(region)
if not region_set:
raise StopIteration
var = new Variant(deref(variantFile))
while i < n and _get_next_variant(variantFile, var):
if condition[i]:
yield _mkvrow(var, fieldspec, filterIds, flatten_filter)
i += 1
del variantFile
del var
cdef inline bool _get_next_variant(VariantCallFile *variantFile, Variant *var):
# break this out into a separate function so we can profile it
return variantFile.getNextVariant(deref(var))
cdef inline object _mkvrow(Variant *var,
list fieldspec,
tuple filterIds,
bint flatten_filter):
out = list()
for f, arity, fill, vcf_type, transformer in fieldspec:
val = _mkvval(var, f, arity, fill, vcf_type, transformer, filterIds)
if f == 'FILTER' and flatten_filter:
out.extend(val)
else:
out.append(val)
return tuple(out)
cdef inline object _mkvval(Variant *var, string field, int arity, object fill, int vcf_type, transformer, tuple filterIds):
if field == FIELD_NAME_CHROM:
out = var.sequenceName
elif field == FIELD_NAME_POS:
out = var.position
elif field == FIELD_NAME_ID:
out = var.id
elif field == FIELD_NAME_REF:
out = var.ref
elif field == FIELD_NAME_ALT:
out = _mkaltval(var, arity, fill)
elif field == FIELD_NAME_QUAL:
out = var.quality
elif field == FIELD_NAME_FILTER:
out = _mkfilterval(var, filterIds)
elif field == FIELD_NAME_NUM_ALLELES:
out = <int>(var.alt.size() + 1)
elif field == FIELD_NAME_IS_SNP:
out = _is_snp(var)
elif field == FIELD_NAME_SVLEN:
out = _svlen(var, arity, fill)
elif transformer is not None:
out = transformer(var.info[field])
elif vcf_type == FIELD_BOOL:
# ignore arity, this is a flag
out = (var.infoFlags.count(field) > 0)
else:
out = _mkval(var.info[field], arity, fill, vcf_type)
return out
cdef inline object _mkaltval(Variant *var, int arity, object fill):
if arity == 1:
if var.alt.size() == 0:
out = fill
else:
out = var.alt.at(0)
elif var.alt.size() == arity:
out = var.alt
out = tuple(out)
elif var.alt.size() > arity:
out = var.alt
out = tuple(out[:arity])
else:
out = var.alt
out += [fill] * (arity-var.alt.size())
out = tuple(out)
return out
cdef inline object _mkfilterval(Variant *var, tuple filterIds):
filters = <list>split(var.filter, SEMICOLON)
out = [(id in filters) for id in filterIds]
out = tuple(out)
return out
cdef inline object _is_snp(Variant *var):
cdef int i
cdef bytes alt
if var.ref.size() > 1:
return False
for i in range(var.alt.size()):
alt = var.alt.at(i)
if alt not in {'A', 'C', 'G', 'T'}:
return False
return True
cdef inline object _svlen(Variant *var, int arity, object fill):
if arity == 1:
return _svlen_single(var.ref, var.alt, fill)
else:
return _svlen_multi(var.ref, var.alt, arity, fill)
cdef inline object _svlen_single(string ref, vector[string]& alt, object fill):
if alt.size() > 0:
return <int>(alt.at(0).size() - ref.size())
return fill
cdef inline object _svlen_multi(string ref, vector[string]& alt, int arity, object fill):
cdef int i
out = list()
for i in range(arity):
if i < alt.size():
out.append(<int>(alt.at(i).size() - ref.size()))
else:
out.append(fill)
return out
def _warn_duplicates(fields):
visited = set()
for f in fields:
if f in visited:
print >>sys.stderr, 'WARNING: duplicate definition in header: %s' % f
visited.add(f)
cdef inline object _mkval(vector[string]& string_vals, int arity, object fill, int vcf_type):
if vcf_type == FIELD_FLOAT:
out = _mkval_double(string_vals, arity, fill)
elif vcf_type == FIELD_INTEGER:
out = _mkval_long(string_vals, arity, fill)
else:
# make strings by default
out = _mkval_string(string_vals, arity, fill)
return out
cdef inline object _mkval_string(vector[string]& string_vals, int arity, object fill):
if arity == 1:
if string_vals.size() > 0:
return string_vals.at(0)
else:
return fill
else:
return _mkval_string_multi(string_vals, arity, fill)
cdef inline object _mkval_string_multi(vector[string]& string_vals, int arity, object fill):
cdef int i
out = list()
for i in range(arity):
if i < string_vals.size():
out.append(string_vals.at(i))
else:
out.append(fill)
return out
cdef inline object _mkval_double(vector[string]& string_vals, int arity, object fill):
if arity == 1:
out = _mkval_double_single(string_vals, fill)
else:
out = _mkval_double_multi(string_vals, arity, fill)
return out
cdef inline object _mkval_double_single(vector[string]& string_vals, object fill):
cdef double v
if string_vals.size() > 0:
return atof(string_vals.at(0).c_str())
return fill
cdef inline object _mkval_double_multi(vector[string]& string_vals, int arity, object fill):
cdef int i
out = list()
for i in range(arity):
if i < string_vals.size():
out.append(atof(string_vals.at(i).c_str()))
else:
out.append(fill)
return out
cdef inline object _mkval_long(vector[string]& string_vals, int arity, object fill):
if arity == 1:
out = _mkval_long_single(string_vals, fill)
else:
out = _mkval_long_multi(string_vals, arity, fill)
return out
cdef inline object _mkval_long_single(vector[string]& string_vals, object fill):
if string_vals.size() > 0:
return atol(string_vals.at(0).c_str())
return fill
cdef inline object _mkval_long_multi(vector[string]& string_vals, int arity, object fill):
cdef int i
out = list()
for i in range(arity):
if i < string_vals.size():
out.append(atol(string_vals.at(i).c_str()))
else:
out.append(fill)
return out
def _calldata_fields(fields, exclude_fields, formatIds):
if fields is None:
fields = STANDARD_CALLDATA_FIELDS + formatIds
else:
for f in fields:
if f not in STANDARD_CALLDATA_FIELDS and f not in formatIds:
# support extracting FORMAT even if not declared in header, but warn...
print >>sys.stderr, 'WARNING: no definition found for field %s' % f
if exclude_fields is not None:
fields = [f for f in fields if f not in exclude_fields]
return tuple(fields)
def _calldata_arities(fields, arities, formatCounts, ploidy):
if arities is None:
arities = dict()
for f, vcf_count in zip(fields, formatCounts):
if f not in arities:
if f == 'genotype':
arities[f] = ploidy
elif f in DEFAULT_CALLDATA_ARITY:
arities[f] = DEFAULT_CALLDATA_ARITY[f]
elif vcf_count == ALLELE_NUMBER:
# default to 2 (biallelic)
arities[f] = 2
elif vcf_count == GENOTYPE_NUMBER:
# arity = (n + p - 1) choose p (n is number of alleles; p is ploidy)
# default to biallelic (n = 2)
arities[f] = ploidy + 1
elif vcf_count <= 0:
# catch any other cases of non-specific arity
arities[f] = 1
else:
arities[f] = vcf_count
return tuple(arities[f] for f in fields)
def _calldata_fills(fields, fills, formatTypes, ploidy):
if fills is None:
fills = dict()
for f, vcf_type in zip(fields, formatTypes):
if f not in fills:
if f == 'GT':
fills[f] = '/'.join(['.'] * ploidy)
elif f in DEFAULT_CALLDATA_FILL:
fills[f] = DEFAULT_CALLDATA_FILL[f]
else:
fills[f] = DEFAULT_FILL_MAP[vcf_type]
return tuple(fills[f] for f in fields)
def _calldata_dtype(fields, dtypes, formatTypes, arities, samples, ploidy):
# construct a numpy dtype for structured array cells
cell_dtype = list()
for f, vcf_type, n in zip(fields, formatTypes, arities):
if dtypes is not None and f in dtypes:
t = dtypes[f]
elif f == 'GT':
t = 'a%d' % ((ploidy*2)-1)
elif f in DEFAULT_CALLDATA_DTYPE:
# known field
t = DEFAULT_CALLDATA_DTYPE[f]
else:
t = DEFAULT_TYPE_MAP[vcf_type]
if n == 1:
cell_dtype.append((f, t))
else:
cell_dtype.append((f, t, (n,)))
# construct a numpy dtype for structured array
dtype = [(s, cell_dtype) for s in samples]
return dtype
def calldata(filename,
region=None,
samples=None,
ploidy=2,
fields=None,
exclude_fields=None,
dtypes=None,
arities=None,
fills=None,
vcf_types=None,
count=None,
progress=0,
logstream=sys.stderr,
condition=None,
slice=None,
verbose=False,
cache=False,
cachedir=None,
skip_cached=False,
):
"""
Load a numpy 1-dimensional structured array with data from the sample columns of a VCF
file.
Parameters
----------
filename: string or list
Name of the VCF file or list of file names
region: string
Region to extract, e.g., 'chr1' or 'chr1:0-100000'
fields: list or array-like
List of fields to extract from the VCF
exclude_fields: list or array-like
Fields to exclude from extraction
dtypes: dict or dict-like
Dictionary cotaining dtypes to use instead of the default inferred ones