Added ps3mediaserver 1.50 beta

net-misc/ps3mediaserver/Manifest

@@ -0,0 +1 @@
+DIST pms-generic-linux-unix-1.50.0-b1.tgz 12324560 RMD160 03570aa2275f4f3ccb38847770052bfcd4d55e6d SHA1 602622ab7c98c5f24496697cc7a276e5b926b2b0 SHA256 3181ce04134a9aa83ded7bb9dd435d93c4d7e75236c6b6cfcdf07872c4d25a17

net-misc/ps3mediaserver/ps3mediaserver-1.50.0_beta1.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.20.412-r1.ebuild,v 1.1 2011/01/07 17:03:11 vapier Exp $
+
+EAPI="2"
+
+MY_PV="1.50.0-b1"
+
+DESCRIPTION="DLNA compliant UPNP server for streaming media to Playstation 3"
+HOMEPAGE="http://code.google.com/p/ps3mediaserver"
+SRC_URI="http://ps3mediaserver.googlecode.com/files/pms-generic-linux-unix-${MY_PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+transcode tsmuxer"
+
+DEPEND=""
+RDEPEND=">=virtual/jre-1.6.0
+	tsmuxer? ( media-video/tsmuxer )
+	transcode? ( media-video/mplayer[encode] )"
+
+S=${WORKDIR}/pms-linux-${MY_PV}
+
+src_prepare() {
+	rm linux/tsMuxeR* || die
+	cat <<-EOF > ${PN}
+	#!/bin/sh
+	echo "Setting up ~/.${PN} based on /usr/share/${PN}/"
+	if [ ! -e ~/.${PN} ] ; then
+		mkdir -p ~/.${PN}
+		cp -pPR /usr/share/${PN}/* ~/.${PN}/
+	fi
+	cd ~/.${PN}
+	PMS_HOME=\$PWD
+	EOF
+	cat PMS.sh >> ${PN}
+}
+
+src_install() {
+	dobin ${PN} || die
+	insinto /usr/share/${PN}
+	doins -r pms.jar *.conf linux plugins renderers || die
+	use tsmuxer && { dosym /opt/bin/tsMuxeR /usr/share/${PN}/linux/ || die ; }
+	dodoc CHANGELOG FAQ README
+}
+
+pkg_postinst() {
+	ewarn "Don't forget to disable transcoding engines for software"
+	ewarn "that you don't have installed (such as having the VLC"
+	ewarn "transcoding engine enabled when you only have mencoder)."
+}