-
Notifications
You must be signed in to change notification settings - Fork 0
/
types.lisp
164 lines (130 loc) · 5.18 KB
/
types.lisp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
;;; types.lisp --- cffi types for the horde3d lisp bindings
;;; _
;;; | |_ _ _ _ __ ___ ___
;;; | __| | | | '_ \ / _ \/ __|
;;; | |_| |_| | |_) | __/\__ \
;;; \__|\__, | .__/ \___||___/
;;; |___/|_|
;;;
;;; Copyright (C) 2009 Ole Arndt <anwyn@sugarshark.com>
;;;
(in-package :horde3d-cffi)
;;;; CFFI types
(define-foreign-type ensure-integer ()
()
(:actual-type :int)
(:simple-parser ensure-integer))
(defmethod translate-to-foreign (value (type ensure-integer))
(truncate value))
(defmethod expand-to-foreign (value (type ensure-integer))
(if (constantp value)
(truncate (eval value))
`(truncate ,value)))
(define-foreign-type ensure-float ()
()
(:actual-type :float)
(:simple-parser ensure-float))
(defmethod translate-to-foreign (value (type ensure-float))
(cl:float value 1.0))
(defmethod expand-to-foreign (value (type ensure-float))
(if (constantp value)
(cl:float (eval value) 1.0)
`(cl:float ,value 1.0)))
(define-foreign-type ensure-double ()
()
(:actual-type :double)
(:simple-parser ensure-double))
(defmethod translate-to-foreign (value (type ensure-double))
(cl:float value 1.0d0))
(defmethod expand-to-foreign (value (type ensure-double))
(if (constantp value)
(cl:float (eval value) 1.0d0)
`(cl:float ,value 1.0d0)))
;;;; C types
(defctype boolean (:boolean :unsigned-char))
(defctype int ensure-integer)
(defctype sizei ensure-integer)
(defctype void :void)
(defctype string :string)
(defctype float ensure-float)
(defctype double ensure-double)
;;;; Enums
(define-foreign-type multi-enum ()
((enums :accessor enums :initarg :enums :initform nil))
(:actual-type :int)
(:simple-parser multi-enum))
(defmethod translate-to-foreign (value (type multi-enum))
(or (some (lambda (enum)
(foreign-enum-value enum value :errorp nil)) (enums type))
(error "~S is not defined as a value for multi enum type ~S."
value type)))
(defmethod translate-from-foreign (value (type multi-enum))
(or (some (lambda (enum)
(foreign-enum-keyword enum value :errorp nil)) (enums type))
(error "~S is not defined as a keyword for multi enum type ~S."
value type)))
(defmethod expand-to-foreign (value (type multi-enum))
(if (constantp value)
(or (some (lambda (enum)
(foreign-enum-value enum (eval value) :errorp nil)) (enums type))
(error "~S is not defined as a value for multi enum type ~S."
value type))
`(or (some (lambda (enum)
(foreign-enum-value enum ,value :errorp nil)) ',(enums type))
(error "~S is not defined as a value for multi enum type ~S."
,value ,type))))
(defmethod expand-from-foreign (value (type multi-enum))
(if (constantp value)
(or (some (lambda (enum)
(foreign-enum-keyword enum (eval value) :errorp nil)) (enums type))
(error "~S is not defined as a keyword for multi enum type ~S."
value type))
`(or (some (lambda (enum)
(foreign-enum-keyword enum ,value :errorp nil)) ',(enums type))
(error "~S is not defined as a keyword for multi enum type ~S."
,value ,type))))
;;;; Group: Typedefs and constants
(defctype resource ensure-integer
"Handle to a resource (int).")
(defctype node ensure-integer
"Handle to a scene node (int).")
;;;; Macros
(eval-when (:compile-toplevel :load-toplevel :execute)
(let ((enum-types (make-hash-table)))
(defun enum-type (keyword)
(gethash keyword enum-types))
(defun notice-enum-type (keyword type)
(setf (gethash keyword enum-types) type)))
(defun emit-typed-enum-form (name enums)
(let ((e-values (loop for enum in enums by #'cddr collect enum))
(e-types (loop for (enum . rest) on enums by #'cddr
collect (cons (if (listp enum)
(car enum)
enum)
(car rest))))
(i (gensym)))
`(progn
(eval-when (:compile-toplevel :load-toplevel :execute)
(dolist (,i ',e-types)
(notice-enum-type (car ,i) (cdr ,i))))
(defcenum ,name ,@e-values)))))
(defmacro deftypedenum (name &body enum-values)
(when (and (stringp (car enum-values)) (cdr enum-values))
(pop enum-values))
(emit-typed-enum-form name enum-values))
(define-condition no-such-enum-type (simple-error)
((enum :initarg :enum :reader enum))
(:report (lambda (condition stream)
(format stream "There is no enum type associated with keyword ~A."
(enum condition)))))
;;; Helper macro to define a horde3d API function and declare it inline.
(defmacro defh3fun ((cname lname) result-type &body body)
`(progn
(declaim (inline ,lname))
(defcfun (,cname ,lname :library horde3d) ,result-type ,@body)))
;;; Helper macro to define a horde3d utils API function and declare it inline.
(defmacro defh3ufun ((cname lname) result-type &body body)
`(progn
(declaim (inline ,lname))
(defcfun (,cname ,lname :library horde3d-utils) ,result-type ,@body)))
;;; types.lisp ends here