/
apertium-cat.cat.rlx
1409 lines (1164 loc) · 73.7 KB
/
apertium-cat.cat.rlx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# exemple ambigüitat fins i tot per a un parlant: "noble húngaro" (hungara nobelo / nobla hungaro), "viejos fanáticos" (maljunaj fanatikuloj / fanatikaj maljunuloj)
DELIMITERS = "<.>" "<!>" "<?>" "<...>" "<¶>" "<:>";
SOFT-DELIMITERS = "<,>" "<;>";
SUBREADINGS = LTR ; # Alternate, left-to-right (main reading on the left)
SETS
LIST >>> = >>> ;
LIST <<< = <<< ;
LIST N = (n) ;
LIST NP = (np) ;
LIST A = (adj) ;
LIST Pos = (pos) ;
LIST Ord = (ord) ;
LIST Det = (det) ;
LIST PreDet = (predet) ;
LIST Num = (num) ;
LIST Adv = (adv) ;
LIST PreAdv = (preadv) ;
LIST Vblex = (vblex) ;
LIST Vbmod = (vbmod) ;
LIST Vbhaver = (vbhaver) ;
LIST Copula = (vbser);
LIST Pron = (prn) ;
LIST Prep = (pr) ;
LIST CnjCoo = (cnjcoo) ;
LIST CnjSub = (cnjsub) ;
LIST CnjAdv = (cnjadv) ;
LIST Rel = (rel) ;
LIST Itg = (itg) ;
LIST Interj = (ij) ;
SET Lpar = (lpar) ;
SET Rpar = (rpar) ;
LIST unknown = ("\\*.*"r) ;
LIST unknownMajIni = ("\\*[A-ZÀÁÈÉíÒÓÚÜÇ].*"r) ;
LIST MajIni = ("<[A-ZÀÁÈÉíÒÓÚÜÇ].*>"r) ;
LIST MinIni = ("<[a-zàáèéìíòóùúçñ].*>"r) ;
LIST MajIni2 = ("<[A-ZÀÁÈÉÍÌÒÓÚÜÇ][a-zàáèéìíòóùúïüçñ·]+.*>"r) ;
LIST segles_num_romans = ("[IVX][IVX]*"r) ;
SET CM = (cm) OR (lpar) OR (rpar) OR ("<;>") ;
LIST Excl = "!" ;
SET Verb = Vblex OR Vbmod OR Vbhaver OR Copula ;
SET Cnj = CnjCoo OR CnjSub OR CnjAdv ;
SET V = Vblex + Vbmod + Vbhaver + Copula ;
SET Word = N + NP + A + Det + PreAdv + Adv + V + Pron + Prep + CnjCoo + CnjSub + CnjAdv + Rel + Interj ;
SET NP_Member = N + A + Det + PreAdv + Adv + Pron ; # Pron es distinto al resto...
#SET NOT_NP_Member = Word - NP_Member;
SET NOT_NP_Member = Vblex OR Vbmod OR Vbhaver OR Copula OR Prep OR CnjCoo OR CnjSub OR CnjAdv OR Rel OR Interj ;
LIST Imp = (imp) ;
LIST Inf = (inf) ;
LIST PP = (pp) ;
LIST PRS = (prs) ;
LIST PIS = (pis) ;
LIST IFI = (ifi) ;
LIST Ger = (ger) ;
LIST P1 = (p1) ;
LIST P2 = (p2) ;
LIST P3 = (p3) ;
LIST Def = (def) ;
LIST Enc = (enc) ;
LIST Masc = m mf ;
LIST Fem = f mf ;
# LIST Masc_strict = n ; no utilitzar: també agafa mf
# LIST Fem_strict = f ; no utilitzar: també agafa mf
LIST MF = mf ;
LIST Sg = sg sp ;
LIST Pl = pl sp ;
LIST Sg_strict = sg ;
LIST Pl_strict = pl ;
SET MascSg = (m sg) OR (m sp) OR (mf sg) OR (mf sp) ;
SET MascPl = (m pl) OR (m sp) OR (mf pl) OR (mf sp) ;
SET FemSg = (f sg) OR (f sp) OR (mf sg) OR (mf sp) ;
SET FemPl = (f pl) OR (f sp) OR (mf pl) OR (mf sp) ;
SET MascSg2 = (m sg) OR (m sp) OR (mf sg) OR (mf sp) ;
SET MascPl2 = (m pl) OR (m sp) OR (mf pl) OR (mf sp) ;
SET FemSg2 = (f sg) OR (f sp) OR (mf sg) OR (mf sp) ;
SET FemPl2 = (f pl) OR (f sp) OR (mf pl) OR (mf sp) ;
SET Pers = (p1) OR (p2) OR (p3) ;
SET Ref = (prn pro ref) ;
SET Pro = (prn pro) ;
SET Tn = (prn tn) ;
SET Tn_nt = (prn tn nt) ;
SET Ant = (np ant) ;
SET Cog = (np cog) ;
SET Ant_Cog = Ant OR Cog ;
SET Top = (np top) OR (np loc) ;
SET Al = (al) ;
SET DetDef = (det def) ;
SET DetInd = (det ind) ;
SET Noun_Adj = N OR A ;
SET Noun_Adj_PP = N OR A OR PP ;
SET Adj_PP = A OR PP ;
SET NO_Adj_PP = Word - Adj_PP ;
SET Adv_PreAdv = Adv OR PreAdv ;
SET Verb = Vblex OR Vbmod OR Vbhaver OR Copula ;
SET Verb_Prep = Verb OR Prep ;
SET Cnj_Rel = CnjCoo OR CnjSub OR CnjAdv OR Rel ;
SET Cnj_Rel_End = >>> OR CnjCoo OR CnjSub OR CnjAdv OR Rel OR Inf;
SET Trencat = ("terç") OR ("quart") OR ("cinquè") OR ("quint") OR ("sisè") OR ("setè") OR ("vuitè") OR ("novè") ;
SET Ordinal = ("primer") OR ("segon") OR ("tercer") OR ("quart") OR ("cinquè") OR ("quint") OR ("sisè") OR ("setè") OR ("vuitè") OR ("novè") OR ("últim") OR ("darrer") OR (Ord) ;
SET Llocs = ("riu") OR ("mar") OR ("oceà") OR ("muntanya") OR ("serra") OR ("serralada") OR ("cordillera") OR ("carena")
OR ("carrer") OR ("parc") OR ("plaça") OR ("avinguda") OR ("ciutat") OR ("vila") OR ("poble") OR ("capital") ;
SET Persones = ("pare") OR ("mare") OR ("avi") OR ("germà") OR ("fill") OR ("oncle") OR ("tia") OR ("sogre") OR ("cunyat")
OR ("marit") OR ("dona") OR ("muller") OR ("espòs") OR ("company") OR ("veí") OR ("cap") OR ("amic") OR ("conegut") ;
#SET Persones2 = ("pare") ("mare") ("avi") ;
SET Dignitat = ("president") OR ("governador") OR ("emperador") OR ("rei") OR ("príncep") OR ("comte") OR ("marquès") OR ("duc")
OR ("arxiduc") OR ("infant") OR ("bisbe") ;
SET DiaSetmana = ("dilluns") OR ("dimarts") OR ("dimecres") OR ("dijous") OR ("divendres") OR ("dissabte") OR ("diumenge");
# adj que són ambiguts amb el pp de verbs intransitius
SET PP_Intr_Adj = ("controvertit") ;
SET Barrera_Final_SN = <<< OR Prep OR Det OR CnjSub OR CnjAdv OR Verb OR Rel OR Pro ; # Verb és perillós per la ambigüitat, però en general, prolífic
SET Barrera_Final_Estrict_SN = <<< OR Prep OR Det OR CnjSub OR CnjAdv OR Rel OR Pro ;
SET Barrera_Inicial_SN = >>> OR Prep OR CnjSub OR CnjAdv OR Verb OR Rel ; # Verb és perillós per la ambigüitat, però en general, prolífic
SET Barrera_Inicial_Estrict_SN = >>> OR Prep OR CnjSub OR CnjAdv OR Rel ;
SET Limite_Barrera_Inicial_SN = ("ser") OR ("Ser") OR ("estar") OR ("Estar") OR ("semblar") OR ("Semblar") OR ("haver") OR ("Haver") ;
LIST Anar = "anar" ;
LIST Vanar = "vanar" ;
LIST Voler = "voler" ;
LIST Volar = "volar" ;
LIST Poder = "poder" ;
LIST Podar = "podar" ;
LIST Creure = "creure" ;
LIST Creuar = "creuar" ;
LIST Segons = "segons" ;
LIST Seriar = "seriar" ;
LIST Caldre = "caldre" ;
LIST Calar = "calar" ;
LIST Beure = "beure" ;
LIST Veure = "veure" ;
LIST Viure = "viure" ;
LIST Seure = "seure" ;
LIST Moure = "moure" ;
LIST So = "so" ;
LIST Son = "son" ;
LIST Fi = "fi" ;
LIST Fins = "fins" ;
LIST Fer = "fer" ;
LIST Faig = "faig" ;
LIST VSer = "ser" ;
LIST Pobla = "pobla" ;
LIST Poble = "poble" ;
LIST Tens = "tens" ;
LIST Tenir = "tenir" ;
LIST Turquesa = "turquesa" ;
LIST Turques = "turquès" ;
LIST Ponent = "ponent" ;
LIST Encara = "encara" ;
LIST Encarar = "encarar" ;
LIST Primer = "primer" ;
LIST Promes = "promès" ;
LIST Promesa = "promesa" ;
SET Ser = ("ser") OR ("Ser") ;
SET Estar = ("estar") OR ("Estar");
SET Haver = ("haver") OR ("Haver") ;
LIST Que = "que" ;
LIST Deu = "deu" ;
SET V_CI = ("telefonar") OR ("trucar") ; # verbs darrere els quals no pot anar un CD, sinó un CI
SET V_CD_CI = ("agafar") OR ("afegir") OR ("atorgar") OR ("atribuir")
OR ("comprar") OR ("comunicar") OR ("construir") OR ("contestar") OR ("cridar")
OR ("dar") OR ("demanar") OR ("demanar") OR ("deixar") OR ("dir") OR ("disparar") OR ("donar")
OR ("escriure") OR ("importar") OR ("lliurar") OR ("manllevar")
OR ("oferir") OR ("ofertar")
OR ("parlar") OR ("pegar") OR ("permetre") OR ("pispar") OR ("plaure") OR ("prendre")
OR ("reconèixer") OR ("regalar") OR ("replicar") OR ("repugnar") OR ("respondre") OR ("robar")
OR ("sobreviure") OR ("vendre") ; # verbs darrere els quals pot anar tant un CD com un CI
SET Com = ("com") OR ("Com") ;
LIST Li = "li" ;
# adjetivos ambíguos que sólo pueden anteceder el nombre ("gran" o "buen" no son ambiguos)
SET PreAdj = ("mal") OR ("força") ;
# adjetivos ambiguos que se anteponen a menudo
SET AdjPrefAmb = ("gran") OR ("petit") OR ("nou") OR ("antic") OR ("menor") OR ("major") OR ("doble") OR ("triple") OR ("possible") OR ("suposat") OR ("presumpte") OR ("altre") ;
# verbs Vblex que típicament impliquen subjuntiu
SET VerbSubj = ("voler") OR ("desitjar") OR ("proposar") OR ("agradar") OR ("plaure") OR ("exigir") OR ("reclamar") OR ("demanar") OR ("esperar") ;
# verbs Vblex que típicament impliquen indicatiu
SET VInd = ("considerar") OR ("creure") OR ("opinar") OR ("dir") OR ("sentir") OR ("trobar") OR ("continuar") OR ("mantenir") OR ("resultar") ;
# coincidències nom propi/comú
SET NomPropiComu = ("Sala") OR ("Guerra") OR ("Costa") OR ("Fons") OR ("Guàrdia");
###############################################################################
# Morphological disambiguation
#
SECTION
#
# Diacrítics de la nova ortografia IEC 2017
#
SELECT:dona_v Vblex IF (0 ("donar")) (-1 Pro) (-2 Pro) (NOT -2 ("<en>"i));
SELECT:dona_v Vblex IF (0 ("<dona>"i)) (-1 Pro) (NOT -1 ("<la>"i)) (NOT -1 ("<en>"i));
SELECT:dona_v Vblex IF (0 ("<dones>"i)) (-1 Pro) (NOT -1 ("<les>"i)) (NOT -1 ("<en>"i));
SELECT:dona_n N IF (0 ("dona")) (NOT -1 Cnj);
# feu/féu, veu/véu. Desambigua els casos clars: es feu>féu, t'ho feu>féu.
SELECT:feu (ifi) IF (0 (vblex ifi p3 sg)) (0 (vblex pri p2 pl)) (-1/* ("es") OR ("et"));
REMOVE:feu (ifi) IF (0 (vblex ifi p3 sg)) (0 (vblex pri p2 pl));
REMOVE:veu (ifi) IF (0 (vblex ifi p3 sg)) (0 (vblex pri p3 sg));
#bota/bóta: cal mirar el context
SELECT ("bóta") IF (0 ("bóta")) (0*/* ("vi"));
SELECT ("bota") IF (0 ("bota"));
#ós/os
SELECT ("ós") IF (0 ("ós")) (1 ("bru") OR ("gris") OR ("grizzly"));
SELECT ("ós") IF (0 ("ós")) (1 ("de")) (2 Det) (3 ("caverna"));
SELECT ("os") IF (0 ("os"));
#fora/fóra TODO: caldrà fer tota la desambiguació que es fa en castellà per a "fuera"
#Per a la traducció en castellà no és problema perquè en castellà també coincidex el verb i l'adverbi
#En altres idiomes sí que hi ha problemes si no es desambigua bé
SELECT (cni) IF (0 ("<fora>"i) OR ("<fóra>"i)) (1 A) (-1 >>>); #Fóra difícil=Seria difícil
REMOVE Ser IF (0 ("<fora>"i));
#molta/mòlta. Cal mirar el context. En principi s'ignora.
REMOVE ("mòlta") IF (0 ("molt"));
#molt/mòlt
SELECT PP IF (0 ("molt")) (-1 Vbhaver) (NOT -2 ("hi"));
REMOVE PP IF (0 ("molt"));
#mora/móra. Cal mirar el context. En principi s'ignora.
REMOVE ("móra") IF (0 ("mora"));
#véns,vénen/vens,venen
SELECT ("vendre") IF (0 ("vendre")) (1 Pos OR N);
SELECT ("vendre") IF (0 ("vendre")) (1 Det) (NOT 2 DiaSetmana);
SELECT ("venir") IF (0 ("venir")) (0 ("vendre"));
# revendre (més comú que revenir)
SELECT ("revendre") IF (0 ("revenir")) (0 ("revendre"));
#ves/vés
REMOVE ("anar") IF (0 ("<ves>"i)) (1 ("per")) (2 ("on"));
SELECT ("anar") IF (0 ("<ves>"i));
#res/rés. Dubtós: el res > rés ?
SELECT ("rés") IF (0 ("res")) (1/* ("de")) (2 Det) (3 ("hora") + FemPl);
SELECT ("rés") IF (0 ("res")) (1/* ("de")) (2* ("parenostre") OR ("avemaria") OR ("rosari") OR ("oració") OR ("pregària"));
SELECT ("res") IF (0 ("res"));
#seu/sèu.
SELECT ("sèu") IF (0 ("sèu") + MascSg) (-1 Prep) (-2* ("untar") OR ("candela"));
REMOVE ("sèu") IF (0 ("seu"));
#net/nét
REMOVE ("nét") IF (0 ("net")) (-1 ("<€>") OR ("mantener") OR ("IVA"));
REMOVE ("nét") IF (0 ("net")) (1 ("patrimonial") OR ("aigua") OR ("contribució") OR ("memòria"));
REMOVE ("nét") IF (0 ("net")) (1 ("de")) (2 ("cor"));
SELECT N IF (0 ("nét") + MascSg ) (-1 MascSg) (-1 Pos);
SELECT N IF (0 ("nét") + MascPl ) (-1 MascPl) (-1 Pos);
SELECT N IF (0 ("nét") + FemSg ) (-1 FemSg) (-1 Pos);
SELECT N IF (0 ("nét") + FemPl ) (-1 FemPl) (-1 Pos);
SELECT N IF (0 ("nét")) (-1 (ord) OR ("darrer") OR ("últim")) (-2 ("el"));
SELECT N IF (0 ("nét")) (-1 Num OR ("un") OR ("més") OR ("menys")) (-2 ("tenir"));
SELECT N IF (0 ("nét")) (-1 ("el")) (1 ("de"));
SELECT N IF (0 ("nét")) (1 ("de")) (2 MajIni2) (NOT -1 N) (NOT -1 ("més") OR ("menys"));
SELECT N IF (0 ("nét")) (-1 ("un") OR ("algun")) (1 ("de") OR (pos));
SELECT N IF (0 ("nét")) (-1 Copula) (1C ("de")) (2C ("el"));
SELECT N IF (0 ("nét")) (-1 Copula) (1/* ("de") + ("el"));
SELECT N IF (0 ("nét")) (-1 >>> OR CM) (1/* ("de") + ("el") + Sg);
SELECT N IF (0 ("nét")) (-1 >>> OR CM) (1 ("de")) (2 ("el") + Sg);
SELECT N IF (0 ("nét")) (-1 CnjCoo OR CM) (-2 ("fill") OR ("avi") OR ("pare") OR ("mare"));
SELECT N IF (0 ("nét")) (1 CnjCoo OR CM) (2 ("fill") OR ("avi") OR ("pare") OR ("mare"));
SELECT N IF (0 ("nét")) (-1/* ("de") + ("el")) (-2 ("un") OR ("algun"));
SELECT N IF (0 ("nét")) (-1 ("el")) (-2 ("de")) (-3 ("un") OR ("algun"));
SELECT N IF (0 ("nét")) (-1 ("algun de"));
REMOVE ("nét") IF (0 ("net")); #Al final, prioritat al sistema tradicional!
## FINAL Diacrítics nous
#SELECT:apellido0 (cog) IF (0 (cog)) (1 ("i"i)) (2 (cog)); # Navarro i García
#SELECT:apellido1 (cog) IF (0 (cog)) (-1 ("i"i)) (-2 (cog));
# Coincidència nom propi/comú. Ex. Fons Europeu, Guerra Civil...
REMOVE:nom_propicomu NP IF (0 NomPropiComu) (NOT -1C (ant) OR (cog) OR unknownMajIni);
REMOVE:marina NP IF (0 ("Marina")) (1 ("reial") OR ("mercant") OR ("britànic"));
REMOVE:costa NP IF (0 ("Costa")) (1 ("blau") OR ("brau") OR ("blanc"));
REMOVE:li_nonompropi NP IF (0 ("Li")) (1 Verb + Pers) (NOT -1 MinIni) (NOT -1 (ant) OR (cog) OR unknownMajIni);
# Per a evitar la traducció de cognoms
# Posa com a lema la forma de la paraula marcada amb *
# Amb els adjectius hi ha més risc d'error (!)
SUBSTITUTE:nom_propi1 (".*"r) ("\\*$1"v) TARGET ("<(.*)>"r) IF (-1C (ant) OR (cog)) (0C Verb OR N OR A) (0 MajIni) (NOT 0 segles_num_romans) (NOT -1 ("Al")) ;
REPLACE:nom_propi2 (np) Verb OR N OR A IF (-1C (ant) OR (cog)) (0C Verb OR N OR A) (0 MajIni) (NOT 0 segles_num_romans) (NOT -1 ("Al")); # Això no sé si és útil.
#amb sols
SELECT:sols Adv IF (0 ("sols"i)) (-1 Prep);
SELECT:seu N IF (0 ("<seu>"i)) (-1 Det + FemSg);
#molt
SELECT:molt_adv PreAdv IF (0 ("<molt>"i)) (1 A OR Adv OR PP) (NOT 1 Pron) (NOT 1 Rel) (NOT 1 Itg);
# prep + verb/nom > nom: (ej. dels centres ABC)
REMOVE:prep_VbN Verb + Pers IF (0 Verb + Pers) (-1C/* Prep) (NOT -1 ("fins"i)) (NOT -1C/* Rel);
REMOVE:prep_det_VbN Verb + Pers IF (0 Verb + Pers) (-2C Prep) (-1 Det + MascSg) (0 MascSg);
REMOVE:prep_det_VbN Verb + Pers IF (0 Verb + Pers) (-2C Prep) (-1 Det + MascPl) (0 MascPl);
REMOVE:prep_det_VbN Verb + Pers IF (0 Verb + Pers) (-2C Prep) (-1 Det + FemSg) (0 FemSg);
REMOVE:prep_det_VbN Verb + Pers IF (0 Verb + Pers) (-2C Prep) (-1 Det + FemPl) (0 FemPl);
REMOVE:verb_maj Vblex IF (NOT -1 >>>) (0 MajIni) (0 Verb + Pers) (0 N); #paraula en majúsucla: és més probablement nom. Gran Via Marqués del Túria.
SELECT:grau NP IF (0 ("Grau")) (-1/* NP OR unknownMajIni); #Grau nom comú / cognom
SELECT:grau NP IF (0 ("Grau")) (1/* NP OR unknownMajIni);
SELECT:grau NP IF (0 ("Grau")) (-1 ("de") OR ("i")) (-2/* NP OR unknownMajIni) (NOT -1/* Det);
SELECT:grau NP IF (0 ("Grau")) (-1 ("sant"));
REMOVE:grau NP IF (0 ("Grau"));
REMOVE Cog IF (-1 DetDef) (0 Cog) ;
REMOVE Cog IF (-1 DetInd) (0 Cog) ;
REMOVE Ant IF (-1 DetDef) (0 Ant) ;
REMOVE Ant IF (-1 DetInd) (0 Ant) ;
REMOVE Verb IF (0 ("IX")) ;
#acrónimos
LIST AllUpper = ("<[A-Z]+>"r) ;
SELECT:acronim (acr) IF (0 AllUpper);
SELECT Ant IF (0 Ant) (1C Ant) ;
# Rosa Maria
SELECT Ant IF (-1 ("sant")) (0 Ant) (0 Cog OR Top) ;
# sant Benet
SELECT Cog IF (0 Cog OR Ant) (-1C Ant) (NOT 1 segles_num_romans) (NOT 1 Cog) (NOT 1 ("de"));
# Josep Maria Carles
# Joan Carles I
SELECT Ant_Cog IF (0 Cog OR Ant) (1C Cog) ;
SELECT Top IF (-2 Ant) (-1 ("de")) (0 Ant OR Cog OR Top) ;
# Hiparc de Nicea
SELECT Top IF (-3 Ant) (-2 segles_num_romans) (-1 ("de")) (0 Ant OR Cog OR Top) ;
# Joan II de Castella
SELECT Top IF (-2 ("concili") OR ("parlament") OR ("estatut") OR ("constitució") OR ("tractat") OR ("declaració"))
(-1 ("de")) (0 Ant OR Cog OR Top) ;
# concili de Nicea
SELECT Top IF (-2 ("corona") OR ("regne") OR ("comtat") OR ("ducat")) (-1 ("de")) (0 Cog OR Top) ;
# regne de Castella
SELECT Top IF (-2 Dignitat) (-1 ("de")) (0 Ant OR Cog OR Top) ;
# príncep de Viana
SELECT Top IF (-2 ("anar") OR ("viatjar")) (-1 ("a")) (0 Ant OR Cog OR Top) ;
REMOVE Top IF (NOT -2 ("anar") OR ("viatjar")) (-1 ("a")) (0C Ant OR Cog OR Top) ;
SELECT Top IF (-3 ("anar") OR ("viatjar")) (-2 ("a")) (-1 Det + Def) (0 Ant OR Cog OR Top) ;
REMOVE Top IF (NOT -3 ("anar") OR ("viatjar")) (-2 ("a")) (-1 Det + Def) (0C Ant OR Cog OR Top) ;
SELECT Top IF (-2 NP) (-1 ("de")) (0 Ant OR Cog OR Top) ;
SELECT Top IF (-2C Top) (-1 CM OR CnjCoo) (0 Top) (0 Cog OR Ant);
SELECT Top IF (2 Top) (1 CM OR CnjCoo) (0 Top) (0 Cog OR Ant) (NOT -1 Cog OR Ant);
SELECT NP IF (0 NP LINK NOT 0 Prep OR Pron OR Det OR Num) (-1 >>>)
(NOT 0 ("just") OR ("fort") OR ("bon") OR ("ben") OR ("fidel") OR ("<Van>")
OR ("català") OR ("aragonès") OR ("espanyol") OR ("castellà")) ;
#SELECT NP IF (0 NP) (0 N OR A) (-1 >>>) (1C Verb) ; # Pujol diu
#SELECT NP IF (0 NP) (0 N OR A) (-1 >>>) (1 Adv) (2C Verb) ; # Pujol no diu
SELECT N IF (-1 ("<santes>")) (0 ("<creus>")) ;
SELECT N IF (-1 ("<Santes>")) (0 ("<Creus>")) ;
# santes creus
SELECT N IF (0 ("creure") OR ("creu")) (1 ("de")) ;
# creu de Sant Jordi
SELECT N IF (0 ("sant")) (1 NP) ;
SELECT NP IF (0 NP) (NOT -1 >>>) (NOT 0 ("I") OR ("Sol") OR ("Nadal") OR ("Parlament") OR ("Consell") OR ("Guerra") OR ("Civil") OR ("Reis")) ;
# Llevem paraules que, per una raó o altra, es posen en majúscules sense ser NP
SELECT:Consell_top Top IF (0 ("Consell")) (-2 ("ajuntament") OR ("alcalde") OR ("regidor") OR ("municipi") OR ("veí") OR ("batlle")) (-1 ("de"));
REMOVE:Consell_top Top IF (0 ("Consell"));
SELECT:Consell_n N IF (0 ("Consell")) (1 A + MascSg);
SELECT:Consell_n (np al) IF (0 ("Consell")) (0*/* ("Generalitat") OR ("la Generalitat"));
SELECT:Consell_n N IF (0 ("Consell"));
SELECT N IF (-1 ("<el>")) (0 ("<Sol>")) ; # el Sol
SELECT N IF (-1 ("<la>")) (0 ("<Guerra>")) ; # la Guerra (Mundial, d'Independència, etc.)
SELECT N IF (-2 ("<la>")) (-1 A) (0 ("<Guerra>")) ; # la Gran Guerra
SELECT A IF (-1 ("<Guerra>")) (0 ("<Civil>")) ; # la Guerra (Mundial, d'Independència, etc.)
SELECT A IF (-1 N + MascSg) (0 NP OR A) (0 ("català") OR ("aragonès") OR ("espanyol") OR ("castellà")) ;
SELECT A IF (-2 N + MascSg) (-1 A + MascSg) (0 NP OR A) (0 ("català") OR ("aragonès") OR ("espanyol") OR ("castellà")) ;
SELECT Ant IF (NOT -1 Det OR ("mar")) (0 ("Egeu") OR ("Egea")) ;
SELECT Top IF (-1 Det OR ("mar")) (0 ("Egeu")OR ("Egea")) ;
SELECT Rel (-1C N) (0 Que) (1 Verb + P3) ;
# la dona que estima les flors
SELECT Rel (-2C N) (-1 A) (0 Que) (1 Verb + P3) ;
# la dona gran que estima les flors
#REMOVE Rel (-2C Verb) (-1C Prep) (0 Rel OR Itg) ; # s'ha d'estudiar millor
# sap de què parla
SELECT Verb (-1 Rel OR CnjSub) (0C Verb OR N) (1C N) ;
SELECT Verb (-1 Rel OR CnjSub) (0C Verb OR N) (1 Det) (2C N) ;
SELECT Verb (-1 Rel OR CnjSub) (0C Verb OR N) (1 Det) (2 A) (3C N) ;
SELECT Verb (-1 Rel OR CnjSub) (0C Verb OR N) (1 Det) (2A A) (3 N) ;
# la dona que estima les flors
REMOVE N (-1 ("anar")) (0 N) (0 Ser) (1 PP) ;
# va ser entregat
REMOVE N (-1C ("anar")) (0 N) (0 Ser) ;
# va ser
SELECT Vbhaver (-1 ("hi")) (0 Vbhaver) (NOT 1 PP) ;
# Tio estas ligita al la (mis)difinoj de accionista__n, albañil__n, gilipollas__n kaj reh/én__n
#SELECT Masc IF (0C N LINK NOT 0 Defensa) (-1C Vblex OR Prep OR ("com")) (NOT -1 PP) (1 <<< OR Prep) ;
## cogieron rehenes.
#SELECT Masc IF (0C N LINK NOT 0 Defensa) (-1C Num) (-2C Vblex OR Prep OR ("com")) (NOT -2 PP) (1 <<< OR Prep) ;
## cogieron tres rehenes.
# se referirán, desde entonces, a los indígenas del Magreb como pueblos líbicos, aunque
#REMOVE Vblex (0 Vblex + Pers) (*1C Vblex + Pers BARRIER Cnj_Rel) ;
# no funciona: quan va venir, ho van veure
# SELECT Vblex (0 Vblex + Pers) (-1C Pro) ; No: podría recurrir a ellas para hacer
SELECT CnjSub (0 ("que")) (-1C Inf OR Enc) ;
SELECT CnjSub (0 ("que")) (-1C Vblex LINK NOT 0 PP) ;
SELECT CnjSub (0 ("que")) (-2C Vblex LINK NOT 0 PP) (-1C Adv);
SELECT CnjSub (0 ("que")) (-2C Vblex LINK NOT 0 PP) (-1 ("entonces")) ;
SELECT CnjSub (0 ("que")) (-1C PP) (-2C ("haver") OR ("Haver") OR ("ser") OR ("Ser") OR ("estar") OR ("Estar")) ;
SELECT CnjSub (0 ("que")) (-2 ("tan") OR ("Tan")) (-1 A OR Adv) ;
SELECT CnjSub (0 ("que")) (-2 ("més") OR ("més")) (-1 A OR Adv) (NOT 1 Verb OR Pron) ;
SELECT CnjSub (0 ("que")) (-2 ("menys") OR ("menys")) (-1 A OR Adv) (NOT 1 Verb OR Pron) ;
REMOVE Adv (0 Adv) (-1C N) (1C N) ;
# manifestantes bajo jurisdicción
REMOVE N (-1C Pro) (0 N LINK 0 Verb) (1 ("que")) ;
REMOVE N (NOT -2 Verb) (NOT -2 Prep) (-1C Pro) (0 N LINK 0 Verb) ;
#REMOVE N (NOT *-1 Verb BARRIER <<< OR CnjSub OR CnjAdv OR Rel) (0 N LINK 0 Verb) (NOT *1 Verb BARRIER >>> OR CnjSub OR CnjAdv OR Rel);
#SELECT V (NOT *-1 Verb BARRIER <<< OR CnjSub OR CnjAdv OR Rel) (0 Verb) (NOT *1 Verb BARRIER >>> OR CnjSub OR CnjAdv OR Rel);
# se estima que
# le cuenta que
# NO: que ayuda en muchos aspectos
REMOVE A (0 ("tant") OR ("Tant")) (*1 ("com") BARRIER CnjSub) ;
REMOVE Verb (-1* ("tant") OR ("Tant") BARRIER CnjSub) (0 ("com")) ;
REMOVE Adv (-1 Copula) (0 A LINK 0 Adv) (NOT 1 A) ;
REMOVE Adv (-1C N) (0 A LINK 0 Adv) (NOT 1 A) (NOT 1 Verb) (NOT 1 Prep) ;
REMOVE Adv (-1C A) (0 A LINK 0 Adv) (NOT 1 Verb) (NOT 0 ("prou")) ;
REMOVE A (-1C N + MascSg) (0 A LINK 0 Adv) (1C A + MascSg) ;
REMOVE A (-1C N + FemSg) (0 A LINK 0 Adv) (1C A + FemSg) ;
REMOVE A (-1C N + MascPl) (0 A LINK 0 Adv) (1C A + MascPl) ;
REMOVE A (-1C N + FemPl) (0 A LINK 0 Adv) (1C A + FemPl) ;
SELECT Adv (-1C N + MascSg) (0 ("poc")) (1 A + MascSg) ;
SELECT Adv (-1C N + FemSg) (0 ("poc")) (1 A + FemSg) ;
SELECT Adv (-1C N + MascPl) (0 ("poc")) (1 A + MascPl) ;
SELECT Adv (-1C N + FemPl) (0 ("poc")) (1 A + FemPl) ;
SELECT A (-2C N + MascSg) (-1C Adv) (0 A + MascSg) (NOT 0 ("va")) ;
SELECT A (-2C N + FemSg) (-1C Adv) (0 A + FemSg) (NOT 0 ("va")) ;
SELECT A (-2C N + MascPl) (-1C Adv) (0 A + MascPl) (NOT 0 ("va")) ;
SELECT A (-2C N + FemPl) (-1C Adv) (0 A + FemPl) (NOT 0 ("va")) ;
#REMOVE A IF (0 NP LINK 0 (adj m sg)) (-1 Prep) (1C N) (NOT 1 MascSg) ;
#REMOVE A IF (0 NP LINK 0 (adj f sg)) (-1 Prep) (1C N) (NOT 1 FemSg) ;
#REMOVE A IF (0 NP LINK 0 (adj m pl)) (-1 Prep) (1C N) (NOT 1 MascPl) ;
#REMOVE A IF (0 NP LINK 0 (adj f pl)) (-1 Prep) (1C N) (NOT 1 FemPl) ;
# asignaba a Armenia territorios
REMOVE Imp IF (NOT 1* Excl) ;
# elección de subjuntivo después de "que"
SELECT PRS (*-1 Que BARRIER Cnj_Rel_End) (*-1 VerbSubj LINK NOT 1 Inf) (0C Verb) (NOT 0 ("<poden>")) ;
# Compte: quiero decirle que me parece muy bien
#REMOVE PRS (*-1 >>> BARRIER CnjAdv OR CnjSub OR Rel) (NOT -1 ("no") OR ("No") OR ("nunca") OR ("Nunca")) (0C Verb) ;
SELECT PRS (*-1 ("ser# .*"r) LINK 1 ("que")) (0C Verb) (NOT 0 ("<poden>")) ;
SELECT PRS (*-1 ("ser") LINK 1 A LINK 1 ("que")) (0C Verb) (NOT 0 ("<poden>")) ;
SELECT PRS (*-1 ("ser") LINK 1 Adv_PreAdv LINK 1 A LINK 1 ("que")) (0C Verb) (NOT 0 ("<poden>")) ;
# es común que la persona sienta la certeza
# es posible que vengas.
# es bueno que vengas
# però: són tan variades que en cadascuna d'elles es poden observar patrons
REMOVE PIS (0 ("<foren>")) (1 PP) ;
# que foren capturats
SELECT IFI (0 ("<Foren>")) (-1 >>>) ;
# adjectiu/nom i gerundi (filtrant, comptant, alternant, impugnant, cantant...)
# Desactivat perquè és molt més complicat.
#REMOVE:adj_ger A IF (0 A) (0 Ger) (NOT -1/* Det OR Prep);
#REMOVE:nom_ger N IF (0 N) (0 Ger) (NOT -1/* Det OR Prep);
# pronom + verb (És estrany que falli el tagger!)
SELECT:pronom_verb Verb IF (-1 ("es"i)) (-1 (prn pro)) (0 (vblex p3)); #s'arreplega
# 3a persona, no 1a
SELECT:pronom_verb (p3) IF (-1 ("es"i)) (-1 (prn pro)) (0 (vblex p3)); #s'implante
# deure
REMOVE:deure_vbmod Vbmod IF (0 ("deure")) (NOT 1 Inf);
# arreplega V/N: TODO: generalitzar
SELECT:arreplega Verb IF (0 ("entrega") OR ("arreplega")) (1 Det OR ("que"));
#
# comparaciones
#
#SELECT Adv IF (0 ("tant")) (1C N) (2 ("com")) ;
SELECT PP IF (-1 ("haver") OR ("Haver")) (0 PP) ;
SELECT PP IF (-1 ("ser") OR ("ser")) (0 PP) (*1 ("por") BARRIER (Cnj_Rel_End)) ;
# seguir, estar + ger
SELECT:ger Ger IF (-1 ("estar"i) OR ("seguir"i) OR ("continuar"i) OR ("acabar"i)) (0 Ger) ;
#
# PALABRAS PARTICULARES
#
SELECT Vblex IF (0 ("mancar")) (1 CnjSub OR CnjAdv OR Rel);
SELECT ("a fi de") IF (0 ("a fi de")) (1 Inf);
REMOVE ("a fi de") IF (0 ("a fi de")) (NOT 1 Inf);
#animal
REMOVE A IF (-1 Copula + P3 + Pl) (0 ("animal") + Pl);
#recolzada
REMOVE:recolzada N IF (0 ("recolzada")) (NOT -1 Det + Fem);
REMOVE:recolzada N IF (0 ("recolzada")) (1 ("per"));
#estret, assedegat (no participi)
REMOVE:estret PP IF (0 ("estret") OR ("assedegat")) (NOT -1 Vbhaver);
#tractat (no participi)
#REMOVE:tractat PP IF (0 ("estret") OR ("tractat") OR ("assedegat")) (NOT -1 Vbhaver);
# no funciona: bits de manera simultània
REMOVE PP IF (0 ("tractat")) (1 ("de")) (2 ("pau") OR ("amistat") OR NP OR unknownMajIni) (NOT -1 Vbhaver);
SELECT N IF (-2 ("tractat")) (-1 ("de")) (0 ("pau"));
#el vals (per què falla el tagger?)
REMOVE:n_sg_pl (n pl) IF (0 N + Pl) (0 N + Sg) (-1 Det + Sg);
#seguit
SELECT:seguit_n N IF (0 ("seguit")) (-1 Det + MascSg) (1 ("de")) (2 N + Pl);
REMOVE:seguit_n N IF (0 ("seguit"));
SELECT:escaient A IF (0 ("escaient"));
REMOVE:compondre ("compostar") IF (0 ("compostar")) (0 ("compondre"));
SELECT:nus A IF (0 ("<nus>"i)) (-2 ("model")) (-1 ("de")) (NOT 1 A + MascSg);
REMOVE:nus A IF (0 ("<nus>"i)) (1 N + Fem OR N + Sg); #noms de lletres: nus B-10, més casos?
SELECT:que PreAdv IF (0 ("que")) (1C A) (NOT 2 N OR A) (NOT 1 ("junt")) (-1 >>>); #(NOT -1 ("més") OR ("menys") OR ("manco"));
REMOVE:que PreAdv IF (0 ("que")); #(Excepcions?)
SELECT:pols1 MascSg IF (0 ("<pols>"i)) (-1 MascSg);
SELECT:pols2 MascSg IF (0 ("<pols>"i)) (1 MascSg);
SELECT:pols3 MascPl IF (0 ("<pols>"i)) (-1 MascPl);
SELECT:pols4 MascPl IF (0 ("<pols>"i)) (1 MascPl);
SELECT:pols0 FemSg IF (0 ("<pols>"i)); # per defecte
REMOVE:concorda_num (f) IF (-2 (det m)) (-1 (num)) (0 (m)) (0 (f)); # els/les tres regnes
REMOVE:concorda_num (m) IF (-2 (det f)) (-1 (num)) (0 (m)) (0 (f));
SELECT:apartat N IF (0 ("apartat"i)) (1 ("<[a-hj-zA-Z]>"r));
REMOVE:càmera (m) IF (0 ("càmera"i)) (NOT -1 (det m)) (NOT -1 (adj m)) (NOT 1 (adj m)); #si no està determinat és femení
REMOVE:contractes (f) IF (0 ("<contractes>"i)) (NOT -1 (det f)) (NOT -1 (adj f)) (NOT 1 (adj f)) (NOT 1 (vblex pp f)); #si no està determinat és masculí
REMOVE:quadres (f) IF (0 ("<quadres>"i)) (NOT -1 (det f)) (NOT -1 (adj f)) (NOT 1 (adj f)) (NOT 1 (vblex pp f)); #si no està determinat és masculí
#ordinales (el tagger no detecta els ordinals)
SELECT:ordinal A IF (0 (ord) + MascSg) (1 N + MascSg);
SELECT:ordinal A IF (0 (ord) + MascPl) (1 N + MascPl) (NOT 0 ("segons"i));
SELECT:ordinal A IF (0 (ord) + FemSg) (1 N + FemSg);
SELECT:ordinal A IF (0 (ord) + FemPl) (1 N + FemPl);
SELECT:ordinal Det IF (0 Det + MascSg) (1 (ord) + MascSg) (2 N + MascSg); #el quart àlbum >*lo cuarto
SELECT N IF (-1 Det + Masc) (0 ("estat") OR ("Estat")) ;
SELECT PP IF (-1 Vbhaver) (0 ("estat")) (1 PP) ;
SELECT N IF (-1 ("[a-záéíóúñ].*"r)) (0 ("Estat")) ; # "Estat" (con mayúscula) va precedido de una palabra con minúscula inicial
SELECT N IF (-1 ("ciutat")) (0 ("estat")) ; # ciutat estat
#SELECT Anar IF (0 ("anar") OR ("va")) (0 P3) (1 Inf) ;
SELECT Anar IF (0 ("anar") OR ("va")) (0 P3) (1/* Inf) ;
# Boas va anar ("Boas" = paraula desconeguda, tria l'adjectiu "va")
# una data festiva alternativa va produir-se, entre altres coses (per alguna raó desconeguda, (1 Inf) no funciona amb cat-tagger)
SELECT Anar IF (0 ("anar") OR ("va")) (0 P3) (1 Adv) ;
# Va més ràpidament
SELECT Anar IF (0 ("anar") OR ("va")) (0 P3) (1C PP) ;
# L'escultura del Renaixement a la Corona d'Aragó va lligada a la cultura humanista
# "van" en balear pot ser vanar<vblex><pri><p1><sg> (el verb, però, és vanar-se)
# desfem l'ambigüitat amb anar<vblex><pri><p3><pl>
SELECT Anar IF (0 ("vanar") OR ("anar")) (0 P1) (NOT -1 ("em")) ;
# si no va precedit per "em" triem "anar"
SELECT Vanar IF (0 ("vanar") OR ("anar")) (0 P1) (-1 ("em")) ;
# si va precedit per "em" triem "vanar"
# voler i volar (p.ex. volen)
SELECT Voler IF (0 ("voler") OR ("volar")) (1/* Inf) ;
SELECT Voler IF (0 ("voler") OR ("volar")) (1 Inf) ;
SELECT Volar IF (0 ("voler") OR ("volar")) (1 ("a") OR ("cap") OR ("cap a")) ;
SELECT Volar IF (0 ("voler") OR ("volar")) (1 Adv) (2 ("a") OR ("cap") OR ("cap a")) ;
SELECT Voler IF (0 ("voler") OR ("volar")) (1 ("que")) ;
SELECT Voler IF (0 ("voler") OR ("volar")) (1 Adv) (2 ("que")) ;
# No volen pas que, volen sovint que
# poder i podar (p.ex. poden)
SELECT Poder IF (0 ("poder") OR ("podar")) (1/* Inf) ;
SELECT Poder IF (0 ("poder") OR ("podar")) (1 Inf) ;
# creure i creuar (p.ex. creuen)
SELECT Creure IF (0 ("creure") OR ("creuar")) (1/* Inf) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Inf) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 ("que")) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Adv) (2 ("que")) ;
# No creuen pas que, creuen sovint que
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 ("a")) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Adv) (2 ("a")) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 ("algú")) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 ("en")) (2 N) (NOT 2 ("déu"));
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 ("en")) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Adv) (2 ("en")) (3 N) (NOT 3 ("déu"));
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Adv) (2 ("en")) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Top) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Adv) (2 Top) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Det) (2 Top) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Adv) (2 Det) (3 Top) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Ant) (NOT 1 ("<Creus")) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Adv) (2 Ant) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Det) (2 Llocs) ;
SELECT Creuar IF (0 ("creure") OR ("creuar")) (1 Adv) (2 Det) (3 Llocs) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Det) (2 Persones) ;
SELECT Creure IF (0 ("creure") OR ("creuar")) (1 Adv) (2 Det) (3 Persones) ;
# ser i seriar (p.ex. seria)
REMOVE Seriar IF (0C ("ser") OR ("seriar")) (1 PP) ;
REMOVE Seriar IF (0C ("ser") OR ("seriar")) (1 A OR N OR Det) ;
REMOVE Seriar IF (0C ("ser") OR ("seriar")) (1 Adv OR PreAdv) (2 A OR N) ;
# ser i estat (p.ex. estat)
SELECT VSer IF (-1 Vbhaver) (0 ("ser") OR ("estar")) (1 PP) ;
SELECT VSer IF (-1 Vbhaver) (0 ("<estat>")) (1 Det) ;
# han estat les de marxa atlètica
# caldre i calar (p.ex. calen)
SELECT Calar IF (-1 Pro) (0C ("caldre") OR ("calar")) ;
REMOVE Calar IF (NOT -1 Pro) (0C ("caldre") OR ("calar")) ;
# veure i viure (p.ex. viu)
SELECT Viure IF (NOT -1 ("jo")) (0 ("<viu>")) ;
# jo bec
SELECT Beure IF (-1 ("jo")) (0 ("<bec>")) ;
# jo moc
SELECT Moure IF (-1 ("jo")) (0 ("<moc>")) ;
# jo sec
SELECT Seure IF (-1 ("jo")) (0 ("<sec>")) ;
SELECT Seure IF (-1 >>>) (0 ("<Sec>")) ;
SELECT Vblex IF (0 ("<sol>")) (1 Inf) ;
# L'agnòstic sol separar les posicions
SELECT So IF (0 So OR Son + Pl) ;
SELECT Fins IF (0 Fins OR Fi + Pl) (1 ("fer")) ;
REMOVE:empresa_n PP IF (0 ("empresa")) (-1 Prep);
SELECT Pobla IF (0 Poble OR Pobla + Pl) (-1 Fem LINK NOT 0 MF) ;
SELECT Pobla IF (0 Poble OR Pobla + Pl) (1 Fem LINK NOT 0 MF) ;
SELECT Poble IF (0 Poble OR Pobla + Pl) (NOT -1 Fem LINK NOT 0 MF) (NOT 1 Fem LINK NOT 0 MF);
SELECT Poble IF (0 Poble OR Pobla + Pl) (-1 ("<els>") OR ("<Els>")) ;
SELECT Turques IF (0 Turques OR Turquesa) (-1 ("llengua")) ;
SELECT Promes IF (0 Promes OR Promes) (-1 Pos) ;
SELECT Promesa IF (0 Promes OR Promes) (NOT -1 Pos) ;
SELECT Tenir IF (0 Tens OR Tenir) (NOT -1 Det) (1 N) ;
SELECT Tenir IF (0 Tens OR Tenir) (-1 Fem OR MascPl) ;
SELECT Encara IF (-1 Vbhaver) (0 Encara OR Encarar) ;
# hi ha encara alguns antics alumnes
SELECT Encara IF (0 Encara OR Encarar) (1 Verb LINK 0 Pers) ;
SELECT Encara IF (0 Encara OR Encarar) (1 Adv) (2 Verb LINK 0 Pers) ;
SELECT Encara IF (0 Encara OR Encarar) (1 Adv) (2 Adv) (3 Verb LINK 0 Pers) ;
# perquè encara conserva
# un article que encara no exiteix
SELECT Encara IF (0 Encara OR Encarar) (1 Pron) (2 Verb LINK 0 Pers) ;
SELECT Encara IF (0 Encara OR Encarar) (1 Adv) (2 Pron) (3 Verb LINK 0 Pers) ;
SELECT Encara IF (0 Encara OR Encarar) (1 Adv) (2 Adv) (3 Pron) (4 Verb LINK 0 Pers) ;
# encara no es coneix
SELECT Encara IF (0 Encara OR Encarar) (1C A OR PP) ;
SELECT Encara IF (0 Encara OR Encarar) (1 PreAdv) (2C A OR PP) ;
# encara molt imprecís
SELECT Encara IF (0 Encara OR Encarar) (1 ("més") OR ("menys")) ;
# encara menys
SELECT Encara IF (-2 ("més") OR ("menys")) (-1 A OR PP) (0 Encara OR Encarar) ;
# més pròxim encara
SELECT Interj IF (0 ("adéu")) (NOT -1 Det OR A);
SELECT Cog IF (-2 Ant) (-1 ("de")) (0 ("Orange")) ;
SELECT Cog IF (-3 Ant) (-2 Num) (-1 ("de")) (0 ("Orange")) ;
SELECT Al IF (0 ("Orange")) (1 ("S.A.") OR Top) ;
SELECT A IF (-1 ("observació")) (0 ("participant")) ;
SELECT MF IF (-1 Det) (0 Ponent) ;
SELECT MF IF (-2 Det) (-1 A) (0 Ponent) ;
SELECT MF IF (-3 Det) (-2 Adv_PreAdv) (-1 A) (0 Ponent) ;
REMOVE MF IF (-1C Prep) (0 Ponent) ;
REMOVE Ger IF (-1C Rel) (0 Ger LINK 0 Pers) ;
REMOVE Ger IF (-2C Rel) (-1 Adv) (0 Ger LINK 0 Pers) ;
# que sent
REMOVE N IF (-1 DetDef + Sg_strict) (0C N + Pl_strict OR Verb) ;
REMOVE N IF (-1 DetDef + Pl_strict) (0C N + Sg_strict OR Verb) ;
# els reis catalans els faig a partir de
REMOVE Copula IF (0 Copula) (1C V + P1 OR P2 OR P3) ;
# de la nostra era queda
SELECT Num IF (0 Deu) (1 N) (2 ("abans") OR ("després")) ;
# Deu anys després
SELECT Num IF (0 Deu) (1 A) (2 N) (3 ("abans") OR ("després")) ;
SELECT Num IF (0 Deu) (1 N) (2 A) (3 ("abans") OR ("després")) ;
SELECT Num IF (0 ("<I>")) (1 ("república") OR ("congrés") OR ("conferència")) ;
SELECT Num IF (0 ("<V>")) (1 ("república") OR ("congrés") OR ("conferència")) ;
SELECT Num IF (0 ("<X>")) (1 ("república") OR ("congrés") OR ("conferència")) ;
SELECT CnjCoo IF (-1 >>>) (0 ("<I>")) (NOT 1 Rpar OR <<<) ;
SELECT Num IF (-1 >>>) (0 ("<I>")) (1 Rpar OR <<<) ;
SELECT Vblex IF (-1 Tn_nt) (0 N OR Vblex) (0 P3) ;
# això comporta
SELECT Vblex IF (-1C Adv) (0C N OR Vblex) (1 Det) (2C N) ;
SELECT Vblex IF (0C N OR Vblex) (0 ("posar")) (1 Det) (2 N) ;
# finalment posa l'esquena completament recta
SELECT N IF (-2 Prep) (-1 Det) (0 N OR Vblex) (1 A) ;
SELECT N IF (-2C Prep) (-1 Det) (0C N OR Vblex) ;
# que corre paral·lela a la costa sud-americana del Pacífic
SELECT N IF (-2 Prep) (-1 Pos) (0 N OR Vblex) (1 A) ;
SELECT N IF (-2C Prep) (-1 Pos) (0C N OR Vblex) ;
# juntament amb la seva guarda personal
REMOVE Itg IF (0 Com) (1 (":")) ;
# paraules com:
REMOVE Itg IF (NOT -2 V LINK -1 Adv) (0 Com) ;
# no sé com
REMOVE Itg IF (NOT -1 >>>) (NOT -1 Verb) (NOT -1 Adv) (NOT -1 Prep) (0 Com) ;
REMOVE Itg IF (-1 >>>) (0 Com) (NOT 1 Verb) (NOT 1 Pron) ;
# not: com fas? com tu fas? com li fas?
REMOVE N + Fem IF (0 ("u"i)) (NOT -1 Det + (f)) (NOT -1 ("lletra"i)); # l'u (no és nom de lletra u femení)
# set per cent
SELECT (num) IF (0 (num)) (1 ("per")) (2 ("cent"));
#
# Desambiguació "los" enc / els "pro"
#
#"<donant-los>"
# "donar" vblex ger
# "el" prn enc p3 m pl
# "donar" vblex ger
# "li" prn enc p3 mf pl
SELECT Li IF (0 ("<els>")) (1C V_CI) ;
SELECT Li IF (0 ("<els>")) (1C V) (1 ("parlar")) ; # purament per freqüències en què "els parlo" es refereix a idiomes i no a persones.
SELECT Li IF (0 ("<els>")) (1 V_CD_CI) (2 Det) ;
SELECT SUB:1 Li IF (0/* V_CI) ;
SELECT SUB:1 Li IF (0/* ("parlar")) ; # purament per freqüències en què "els parlo" es refereix a idiomes i no a persones.
SELECT SUB:1 Li IF (0/* V_CD_CI) (1 Det) ;
# donant-los una cosa
#
# Desambiguación ADJ (+PP) - NOMBRE
#
REMOVE PP IF (-1 VSer) (0 PP_Intr_Adj) ;
# el judici fou controvertit
REMOVE Pron IF (0 ("pocs") + Masc + Pl) (1 N + Masc + Pl) ;
REMOVE Pron IF (0 ("pocs") + Fem + Pl) (1 N + Fem + Pl) ;
REMOVE Pron IF (0 ("molts") + Masc + Pl) (1 N + Masc + Pl) ;
REMOVE Pron IF (0 ("molts") + Fem + Pl) (1 N + Fem + Pl) ;
# noltes arts japoneses
REMOVE Pron IF (0 ("molts") + Masc + Pl) (1 A + Masc + Pl) (2 N + Masc + Pl) ;
REMOVE Pron IF (0 ("molts") + Fem + Pl) (1 A + Fem + Pl) (2 N + Fem + Pl) ;
REMOVE Pron IF (0 ("molts") + Masc + Pl) (1 Adv OR PreAdv) (2 A + Masc + Pl) (3 N + Masc + Pl) ;
REMOVE Pron IF (0 ("molts") + Fem + Pl) (1 Adv OR PreAdv) (2 A + Fem + Pl) (3 N + Fem + Pl) ;
REMOVE Pron IF (0 ("pocs") + Masc + Pl) (1 A + Masc + Pl) (2 N + Masc + Pl) ;
REMOVE Pron IF (0 ("pocs") + Fem + Pl) (1 A + Fem + Pl) (2 N + Fem + Pl) ;
REMOVE Pron IF (0 ("pocs") + Masc + Pl) (1 Adv OR PreAdv) (2 A + Masc + Pl) (3 N + Masc + Pl) ;
REMOVE Pron IF (0 ("pocs") + Fem + Pl) (1 Adv OR PreAdv) (2 A + Fem + Pl) (3 N + Fem + Pl) ;
# NOM / ADJ
REMOVE N IF (-1 Estar LINK NOT 0 VSer) (0 Noun_Adj_PP) ;
# estan retallades
REMOVE P1 OR P2 OR P3 (-1C Estar) (0 N OR A OR Ger LINK 0 Pers) ;
# està subjecte a
REMOVE A OR PP IF (-1 Prep) (0 Noun_Adj_PP LINK 0 N OR NP) (NOT 0 Num OR ("passat") OR ("passada")) (1 <<< OR Prep OR Det OR CnjSub) ;
REMOVE A OR PP IF (-1/* Prep) (0 Noun_Adj_PP LINK 0 N OR NP) (NOT 0 Num OR ("passat") OR ("passada")) (1 <<< OR Prep OR Det OR CnjSub) ;
REMOVE A OR PP IF (-1 Prep) (0 Noun_Adj_PP LINK 0 N OR NP) (NOT 0 Num OR ("passat") OR ("passada")) (1 CM) (2 Prep OR Det OR CnjSub OR CnjCoo) ;
REMOVE A OR PP IF (-1/* Prep) (0 Noun_Adj_PP LINK 0 N OR NP) (NOT 0 Num OR ("passat") OR ("passada")) (1 CM) (2 Prep OR Det OR CnjSub OR CnjCoo) ;
# eren semblants al Sol, però [VERIFY: funciona amb cat-disam, però no amb cat-tagger]
REMOVE A OR PP IF (-1 Prep) (0 Noun_Adj_PP LINK 0 N OR NP) (1 CM OR CnjCoo) (2 CnjSub) ;
REMOVE A OR PP IF (NOT -2 Com OR Ant) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) ;
REMOVE A OR PP IF (NOT -2 Com OR Ant) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) ;
REMOVE N IF (-2 Ant) (-1 Def + MascSg) (0 Noun_Adj_PP + MascSg) ;
REMOVE N IF (-2 Ant) (-1 Def + FemSg) (0 Noun_Adj_PP + FemSg) ;
# Martí l'Humà
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1C Verb) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1C Verb) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1C Verb) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1C Verb) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Copula) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Copula) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Copula) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Copula) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (NOT -2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN OR Ant_Cog) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1C Verb) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1C Verb) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1C Verb) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1C Verb) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Copula) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Copula) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Copula) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Copula) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) (NOT -1 DetDef) ;
REMOVE A OR PP IF (-2 Com) (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 CM OR CnjCoo) (2 Barrera_Final_Estrict_SN) (NOT -1 DetDef) ;
SELECT N IF (-1 Det + MascSg) (0 Noun_Adj_PP + MascSg LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
SELECT N IF (-1 Det + FemSg) (0 Noun_Adj_PP + FemSg LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
SELECT N IF (-1 Det + MascPl) (0 Noun_Adj_PP + MascPl LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
SELECT N IF (-1 Det + FemPl) (0 Noun_Adj_PP + FemPl LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
# la ofensiva de pascua
# la política del gobierno (per error, es veu Det i no Prep)
REMOVE N IF (-2 Det + Def + MascSg) (-1 ("més") OR ("menys")) (0 Noun_Adj_PP + MascSg LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
REMOVE N IF (-2 Det + Def + FemSg) (-1 ("més") OR ("menys")) (0 Noun_Adj_PP + FemSg LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
REMOVE N IF (-2 Det + Def + MascPl) (-1 ("més") OR ("menys")) (0 Noun_Adj_PP + MascPl LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
REMOVE N IF (-2 Det + Def + FemPl) (-1 ("més") OR ("menys")) (0 Noun_Adj_PP + FemPl LINK NOT 0 NP) (1 <<< OR Prep OR Det) ;
# el més extemista de tots
# és la més comuna.
SELECT A IF (-3 N + MascSg) (-2 A + MascSg) (-1 ("més") OR ("menys")) (0 A + MascSg LINK NOT 0 NP) ;
SELECT A IF (-3 N + FemSg) (-2 A + FemSg) (-1 ("més") OR ("menys")) (0 A + FemSg LINK NOT 0 NP) ;
SELECT A IF (-3 N + MascPl) (-2 A + MascPl) (-1 ("més") OR ("menys")) (0 A + MascPl LINK NOT 0 NP) ;
SELECT A IF (-3 N + FemPl) (-2 A + FemPl) (-1 ("més") OR ("menys")) (0 A + FemPl LINK NOT 0 NP) ;
# l'activitat industrial més activa
# les llengües internacionales més esteses
REMOVE N IF (-1C N + MascSg) (0 N OR A + MascSg) (1 (",")) (2 A + MascSg) (3 ("i")) (4 A + MascSg) ;
REMOVE N IF (-1C N + FemSg) (0 N OR A + FemSg) (1 (",")) (2 A + FemSg) (3 ("i")) (4 A + FemSg) ;
REMOVE N IF (-1C N + MascPl) (0 N OR A + MascPl) (1 (",")) (2 A + MascPl) (3 ("i")) (4 A + MascPl) ;
REMOVE N IF (-1C N + FemPl) (0 N OR A + FemPl) (1 (",")) (2 A + FemPl) (3 ("i")) (4 A + FemPl) ;
# ortografia francesa, llatina i grega
REMOVE N IF (-3 N + MascSg) (-2 A + MascSg) (-1 ("i")) (0 A + MascSg) (0 N) ;
REMOVE N IF (-3 N + FemSg) (-2 A + FemSg) (-1 ("i")) (0 A + FemSg) (0 N) ;
REMOVE N IF (-3 N + MascPl) (-2 A + MascPl) (-1 ("i")) (0 A + MascPl) (0 N) ;
REMOVE N IF (-3 N + FemPl) (-2 A + FemPl) (-1 ("i")) (0 A + FemPl) (0 N) ;
# el seu caràcter màgic i religiós
SELECT N IF (0 Noun_Adj_PP LINK NOT 0 Adv OR PP OR Ger OR Inf OR NP OR Prep OR ("ser") OR ("sinó")) (NOT 0 ("cap")) (-1C Vblex) (NOT -1 PP OR ("parlar") OR VInd) (1 Barrera_Final_Estrict_SN) ;
# detonar explosivos.
# nos vino impuesto.
SELECT N IF (0 Noun_Adj_PP LINK NOT 0 Adv OR PP OR Ger OR Inf OR NP OR Prep OR ("ser") OR ("sinó")) (-1C Vblex) (NOT -1 PP OR ("parlar") OR VInd) (1 CnjCoo) (2 Barrera_Final_Estrict_SN) ;
# detonando explosivos y derrumbando
SELECT N IF (0 Noun_Adj_PP LINK NOT 0 NP OR ("ser") OR Prep) (-1C Det) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (0 Noun_Adj_PP LINK NOT 0 NP OR ("ser") OR Prep) (-1C Det) (1 CM OR CnjCoo) (1 Barrera_Final_Estrict_SN) ;
# detonar los explosivos.
# PERO: Las clasificaciones más reconocidas internacionalmente son la francesa y la estadounidense.
# PERO: muy poco conocida.
REMOVE A OR PP IF (NOT -2 Verb) (-1 Prep LINK NOT 0 Com) (0 N LINK NOT 0 NP LINK NOT 0 Copula) (NOT 0 ("passat") OR ("passada")) (1 Barrera_Final_SN LINK NOT 0 PP LINK NOT 0 N) ;
SELECT N IF (NOT -2 Verb) (-1 Prep LINK NOT 0 Com) (0 N LINK NOT 0 NP LINK NOT 0 Copula LINK NOT 0 PreDet LINK NOT 0 Pron OR Num) (NOT 0 ("passat") OR ("passada")) (1 Barrera_Final_Estrict_SN LINK NOT 0 PP LINK NOT 0 N) ;
SELECT N IF (NOT -2 Verb) (-1 Prep LINK NOT 0 Com) (0 N LINK NOT 0 NP LINK NOT 0 Copula) (NOT 0 ("gra")) (1 CM OR CnjCoo) (2 Barrera_Final_SN LINK NOT 0 PP) ;
SELECT N IF (-2 PP) (-1 ("por")) (0 N LINK NOT 0 NP LINK NOT 0 Copula) (1 Barrera_Final_SN LINK NOT 0 PP LINK NOT 0 N) ;
SELECT N IF (-2 PP) (-1 ("por")) (0 N LINK NOT 0 NP LINK NOT 0 Copula) (1 CM OR CnjCoo) (2 Barrera_Final_SN LINK NOT 0 PP) ;
SELECT Num (0 ("nou")) (1 AdjPrefAmb + Pl) ;
SELECT A (0 ("gran") + Pl) (1 N + Pl) ;
## grans matemàtics
SELECT A (0 ("gran") + Pl) (1 CnjCoo) (2 ("petit") + Pl) ;
SELECT A (0 ("gran") + Pl) (-1 CnjCoo) (-2 ("petit") + Pl) ;
SELECT A (0 ("gran") + Pl) (1 CnjCoo) (2 Det + Pl) (3 ("petit") + Pl) ;
SELECT A (-1 Det + Pl) (0 ("gran") + Pl) (-2 CnjCoo) (-3 ("petit") + Pl) ;
SELECT A (0 ("gran") + Pl) (1 CnjCoo) (2 Prep) (3 Det + Pl) (4 ("petit") + Pl) ;
SELECT A (0 ("gran") + Pl) (1 CnjCoo) (2 ("<dels>")) (3 ("petit") + Pl) ;
SELECT A (-2 Prep) (-1 Det + Pl) (0 ("gran") + Pl) (-3 CnjCoo) (-4 ("petit") + Pl) ;
SELECT A (-1 ("<dels>")) (0 ("gran") + Pl) (-2 CnjCoo) (-3 ("petit") + Pl) ;
## grans i petits, petits i grans, etc.
# NP / ADJ
SELECT NP IF (-1 Det + Fem) (0 ("Argentina") OR ("India") OR ("Filipines") OR ("Balears") OR ("Canàries") OR ("Polinèsia")) (1 <<< OR Prep OR Det OR CM) ;
SELECT NP IF (-1 Det + Masc) (0 ("Mediterrani") OR ("Atlàntic") OR ("Cantàbric") OR ("Pacífic") OR ("Índic") OR ("Àrtic")) (1 <<< OR Prep OR Det OR CM) ;
# NP / N
REMOVE Noun_Adj_PP IF (-1 Det + MascSg) (0 NP + MascSg) (1 Adj_PP + MascSg) ;
REMOVE Noun_Adj_PP IF (-1 Det + MascPl) (0 NP + MascPl) (1 Adj_PP + MascPl) ;
REMOVE Noun_Adj_PP IF (-1 Det + FemSg) (0 NP + FemSg) (1 Adj_PP + FemSg) ;
REMOVE Noun_Adj_PP IF (-1 Det + FemPl) (0 NP + FemPl) (1 Adj_PP + FemPl) ;
# la Indochina francesa (cal treure Indochina n)
# ADJ NOM
# elimina la opción "adjetivo" de aquellos adjetivos que sólo pueden anteceder un nombre ("buen", "mal", etc.) y no están delante de uno
REMOVE A IF (0 PreAdj) (NOT 1 N) ;
REMOVE A OR PP IF (-2 Det + MascSg) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_SN OR Ant_Cog) ;
REMOVE A OR PP IF (-2 Det + FemSg) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_SN OR Ant_Cog) ;
REMOVE A OR PP IF (-2 Det + MascPl) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_SN OR Ant_Cog) ;
REMOVE A OR PP IF (-2 Det + FemPl) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_SN OR Ant_Cog) ;
## PERO: una densa doble capa de pelo
REMOVE A OR PP IF (-2 Det + MascSg) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2 Det + FemSg) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2 Det + MascPl) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2 Det + FemPl) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
REMOVE A OR PP IF (-2C Verb) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 CM) (2 Barrera_Final_Estrict_SN) ;
SELECT N IF (-2 Barrera_Inicial_SN LINK NOT 0 Verb) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-2 Barrera_Inicial_SN LINK NOT 0 Verb) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-2 Barrera_Inicial_SN LINK NOT 0 Verb) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-2 Barrera_Inicial_SN LINK NOT 0 Verb) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-3 Barrera_Inicial_SN LINK NOT 0 Verb) (-2C Det + MascSg) (-1C A + MascSg) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-3 Barrera_Inicial_SN LINK NOT 0 Verb) (-2C Det + FemSg) (-1C A + FemSg) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-3 Barrera_Inicial_SN LINK NOT 0 Verb) (-2C Det + MascPl) (-1C A + MascPl) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
SELECT N IF (-3 Barrera_Inicial_SN LINK NOT 0 Verb) (-2C Det + FemPl) (-1C A + FemPl) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Barrera_Final_Estrict_SN) ;
# NOM ADJ
REMOVE A OR PP IF (-1 Barrera_Inicial_Estrict_SN) (0 Noun_Adj_PP + MascSg LINK 0 N OR NP) (1 Adj_PP + MascSg) (NOT 0 ("nou") OR ("sol")) ;
REMOVE A OR PP IF (-1 Barrera_Inicial_Estrict_SN) (0 Noun_Adj_PP + MascPl LINK 0 N OR NP) (1 Adj_PP + MascPl) (NOT 0 ("nou") OR ("sol")) ;
REMOVE A OR PP IF (-1 Barrera_Inicial_Estrict_SN) (0 Noun_Adj_PP + FemSg LINK 0 N OR NP) (1 Adj_PP + FemSg) (NOT 0 ("nou") OR ("sol")) ;
REMOVE A OR PP IF (-1 Barrera_Inicial_Estrict_SN) (0 Noun_Adj_PP + FemPl LINK 0 N OR NP) (1 Adj_PP + FemPl) (NOT 0 ("nou") OR ("sol")) ;
## jóvenes inteligentes (jóvenes > n)
## jóvenes encapuchadas (jóvenes > n)
## abisenios inteligentes (jóvenes > n)
## escrito largo (escrito > n)
## nous materials
## pels sols fets de
REMOVE A OR PP IF (NOT -1 N OR A OR PP OR ("ser") OR ("estar")) (0 Noun_Adj + MascSg LINK 0 N OR NP) (NOT 0 Trencat) (NOT 0 ("nou") OR ("força") OR ("sol") OR ("bo")) (1 Adj_PP + MascSg) ;
REMOVE A OR PP IF (NOT -1 N OR A OR PP OR ("ser") OR ("estar")) (0 Noun_Adj + MascPl LINK 0 N OR NP) (NOT 0 Trencat) (NOT 0 ("nou") OR ("força") OR ("sol") OR ("bo") OR ("gran")) (1 Adj_PP + MascPl) ;
REMOVE A OR PP IF (NOT -1 N OR A OR PP OR ("ser") OR ("estar")) (0 Noun_Adj + FemSg LINK 0 N OR NP) (NOT 0 ("nou") OR ("força") OR ("sol") OR ("bo")) (1 Adj_PP + FemSg) ;
REMOVE A OR PP IF (NOT -1 N OR A OR PP OR ("ser") OR ("estar")) (0 Noun_Adj + FemPl LINK 0 N OR NP) (NOT 0 ("nou") OR ("força") OR ("sol") OR ("bo") OR ("gran")) (1 Adj_PP + FemPl) ;
REMOVE PP IF (NOT -1 N OR Vbhaver OR ("ser") OR ("estar")) (0 PP + MascSg LINK 0 N OR NP) (1 Adj_PP + MascSg) ;
REMOVE PP IF (NOT -1 N OR Vbhaver OR ("ser") OR ("estar")) (0 PP + MascPl LINK 0 N OR NP) (1 Adj_PP + MascPl) ;