forked from PerlRedis/perl-redis
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Redis.pm
995 lines (669 loc) · 21 KB
/
Redis.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
package Redis;
use warnings;
use strict;
use IO::Socket::INET;
use IO::Socket::UNIX;
use IO::Select;
use IO::Handle;
use Fcntl qw( O_NONBLOCK F_SETFL );
use Data::Dumper;
use Carp qw/confess/;
use Encode;
use Try::Tiny;
use Scalar::Util ();
=head1 NAME
Redis - perl binding for Redis database
=cut
our $VERSION = '1.926';
=head1 SYNOPSIS
## Defaults to $ENV{REDIS_SERVER} or 127.0.0.1:6379
my $redis = Redis->new;
my $redis = Redis->new(server => 'redis.example.com:8080');
## Use UNIX domain socket
my $redis = Redis->new(sock => '/path/to/socket');
## Enable auto-reconnect
## Try to reconnect every 500ms up to 60 seconds until success
## Die if you can't after that
my $redis = Redis->new(reconnect => 60);
## Try each 100ms upto 2 seconds (every is in milisecs)
my $redis = Redis->new(reconnect => 2, every => 100);
## Disable the automatic utf8 encoding => much more performance
my $redis = Redis->new(encoding => undef);
## Use all the regular Redis commands, they all accept a list of
## arguments
## See http://redis.io/commands for full list
$redis->get('key');
$redis->set('key' => 'value');
$redis->sort('list', 'DESC');
$redis->sort(qw{list LIMIT 0 5 ALPHA DESC});
## Publish/Subscribe
$redis->subscribe(
'topic_1',
'topic_2',
sub {
my ($message, $topic, $subscribed_topic) = @_
## $subscribed_topic can be different from topic if
## you use psubscribe() with wildcards
}
);
$redis->psubscribe('nasdaq.*', sub {...});
## Blocks and waits for messages, calls subscribe() callbacks
## ... forever
$redis->wait_for_messages($timeout) while 1;
## ... until some condition
$redis->wait_for_messages($timeout) while $keep_going;
$redis->publish('topic_1', 'message');
=head1 DESCRIPTION
Pure perl bindings for L<http://redis.io/>
This version supports protocol 2.x (multi-bulk) or later of Redis
available at L<https://github.com/antirez/redis/>.
This documentation lists commands which are exercised in test suite, but
additional commands will work correctly since protocol specifies enough
information to support almost all commands with same piece of code with
a little help of C<AUTOLOAD>.
=head1 METHODS
=head2 new
my $r = Redis->new; # $ENV{REDIS_SERVER} or 127.0.0.1:6379
my $r = Redis->new( server => '192.168.0.1:6379', debug => 0 );
my $r = Redis->new( server => '192.168.0.1:6379', encoding => undef );
my $r = Redis->new( sock => '/path/to/sock' );
my $r = Redis->new( reconnect => 60, every => 5000 );
The C<< server >> parameter specifies the Redis server we should connect
to, via TCP. Use the 'IP:PORT' format. If no C<< server >> option is
present, we will attempt to use the C<< REDIS_SERVER >> environment
variable. If neither of those options are present, it defaults to
'127.0.0.1:6379'.
Alternatively you can use the C<< sock >> parameter to specify the path
of the UNIX domain socket where the Redis server is listening.
The C<< REDIS_SERVER >> can be used for UNIX domain sockets too. The following formats are supported:
=over 4
=item /path/to/sock
=item unix:/path/to/sock
=item 127.0.0.1:11011
=item tcp:127.0.0.1:11011
=back
The C<< encoding >> parameter speficies the encoding we will use to
decode all the data we receive and encode all the data sent to the redis
server. Due to backwards-compatibility we default to C<< utf8 >>. To
disable all this encoding/decoding, you must use C<<encoding => undef>>.
B<< This is the recommended option >>.
B<< Warning >>: this option has several problems and it is
B<deprecated>. A future version will add a safer option.
The C<< reconnect >> option enables auto-reconnection mode. If we cannot
connect to the Redis server, or if a network write fails, we enter retry
mode. We will try a new connection every C<< every >> miliseconds
(1000ms by default), up-to C<< reconnect >> seconds.
Be aware that read errors will always thrown an exception, and will not
trigger a retry until the new command is sent.
If we cannot re-establish a connection after C<< reconnect >> seconds,
an exception will be thrown.
The C<< debug >> parameter enables debug information to STDERR,
including all interactions with the server. You can also enable debug
with the C<REDIS_DEBUG> environment variable.
=cut
sub new {
my $class = shift;
my %args = @_;
my $self = bless {}, $class;
$self->{debug} = $args{debug} || $ENV{REDIS_DEBUG};
## default to lax utf8
$self->{encoding} = exists $args{encoding}? $args{encoding} : 'utf8';
## Deal with REDIS_SERVER ENV
if ($ENV{REDIS_SERVER} && !$args{sock} && !$args{server}) {
if ($ENV{REDIS_SERVER} =~ m!^/!) {
$args{sock} = $ENV{REDIS_SERVER};
}
elsif ($ENV{REDIS_SERVER} =~ m!^unix:(.+)!) {
$args{sock} = $1;
}
elsif ($ENV{REDIS_SERVER} =~ m!^(tcp:)?(.+)!) {
$args{server} = $2;
}
}
if ($args{sock}) {
$self->{server} = $args{sock};
$self->{builder} = sub { IO::Socket::UNIX->new($_[0]->{server}) };
}
else {
$self->{server} = $args{server} || '127.0.0.1:6379';
$self->{builder} = sub {
IO::Socket::INET->new(
PeerAddr => $_[0]->{server},
Proto => 'tcp',
);
};
}
$self->{is_subscriber} = 0;
$self->{subscribers} = {};
$self->{reconnect} = $args{reconnect} || 0;
$self->{every} = $args{every} || 1000;
$self->__connect;
return $self;
}
sub is_subscriber { $_[0]{is_subscriber} }
### we don't want DESTROY to fallback into AUTOLOAD
sub DESTROY { }
### Deal with common, general case, Redis commands
our $AUTOLOAD;
sub AUTOLOAD {
my $command = $AUTOLOAD;
$command =~ s/.*://;
my $method = sub { shift->__std_cmd($command, @_) };
# Save this method for future calls
no strict 'refs';
*$AUTOLOAD = $method;
goto $method;
}
sub __std_cmd {
my $self = shift;
my $command = shift;
$self->__is_valid_command($command);
my @cmd_args = @_;
return $self->__with_reconnect(sub {
$self->__run_cmd($command, @cmd_args);
});
}
sub __with_reconnect {
my ($self, $cb) = @_;
## Fast path, no reconnect
return $cb->() unless $self->{reconnect};
return try {
$cb->();
}
catch {
die $_ unless ref($_) eq 'Redis::X::Reconnect';
$self->__connect;
$cb->();
};
}
sub __run_cmd {
my $self = shift;
my $command = shift;
$self->__send_command($command, @_);
return $self->__read_response($command);
}
### Commands with extra logic
sub quit {
my ($self) = @_;
return unless $self->{sock};
$self->__send_command('QUIT');
close(delete $self->{sock}) || confess("Can't close socket: $!");
return 1;
}
sub shutdown {
my ($self) = @_;
$self->__is_valid_command('SHUTDOWN');
return unless $self->{sock};
$self->__send_command('SHUTDOWN');
close(delete $self->{sock}) || confess("Can't close socket: $!");
return 1;
}
sub ping {
my ($self) = @_;
$self->__is_valid_command('PING');
return unless exists $self->{sock};
return scalar try {
$self->__run_cmd('PING');
}
catch {
close(delete $self->{sock});
return;
};
}
sub info {
my ($self) = @_;
$self->__is_valid_command('INFO');
$self->__with_reconnect(sub {
my $info = $self->__run_cmd('INFO');
return {map { split(/:/, $_, 2) } split(/\r\n/, $info)};
});
}
sub keys {
my $self = shift;
$self->__is_valid_command('KEYS');
my @cmd_args = @_;
$self->__with_reconnect(sub {
my $keys = $self->__run_cmd('KEYS', @cmd_args);
## Support redis > 1.26
return @$keys if ref $keys eq 'ARRAY';
## Support redis <= 1.2.6
return split(/\s/, $keys) if $keys;
return;
});
}
### PubSub
sub wait_for_messages {
my ($self, $timeout) = @_;
my $sock = $self->{sock};
my $s = IO::Select->new;
$s->add($sock);
my $count = 0;
while ($s->can_read($timeout)) {
while (__try_read_sock($sock)) {
my @m = $self->__read_response('WAIT_FOR_MESSAGES');
$self->__process_pubsub_msg(\@m);
$count++;
}
}
return $count;
}
sub __subscription_cmd {
my $self = shift;
my $pr = shift;
my $unsub = shift;
my $command = shift;
my $cb = pop;
confess("Missing required callback in call to $command(), ")
unless ref($cb) eq 'CODE';
my @subs = @_;
$self->__with_reconnect(sub {
$self->__throw_reconnect('Not connected to any server')
unless $self->{sock};
@subs = $self->__process_unsubscribe_requests($cb, $pr, @subs)
if $unsub;
return unless @subs;
$self->__send_command($command, @subs);
my %cbs = map { ("${pr}message:$_" => $cb) } @subs;
return $self->__process_subscription_changes($command, \%cbs);
});
}
sub subscribe { shift->__subscription_cmd('', 0, subscribe => @_) }
sub psubscribe { shift->__subscription_cmd('p', 0, psubscribe => @_) }
sub unsubscribe { shift->__subscription_cmd('', 1, unsubscribe => @_) }
sub punsubscribe { shift->__subscription_cmd('p', 1, punsubscribe => @_) }
sub __process_unsubscribe_requests {
my ($self, $cb, $pr, @unsubs) = @_;
my $subs = $self->{subscribers};
my @subs_to_unsubscribe;
for my $sub (@unsubs) {
my $key = "${pr}message:$sub";
my $cbs = $subs->{$key} = [grep { $_ ne $cb } @{$subs->{$key}}];
next if @$cbs;
delete $subs->{$key};
push @subs_to_unsubscribe, $sub;
}
return @subs_to_unsubscribe;
}
sub __process_subscription_changes {
my ($self, $cmd, $expected) = @_;
my $subs = $self->{subscribers};
while (%$expected) {
my @m = $self->__read_response($cmd);
## Deal with pending PUBLISH'ed messages
if ($m[0] =~ /^p?message$/) {
$self->__process_pubsub_msg(\@m);
next;
}
my ($key, $unsub) = $m[0] =~ m/^(p)?(un)?subscribe$/;
$key .= "message:$m[1]";
my $cb = delete $expected->{$key};
push @{$subs->{$key}}, $cb unless $unsub;
$self->{is_subscriber} = $m[2];
}
}
sub __process_pubsub_msg {
my ($self, $m) = @_;
my $subs = $self->{subscribers};
my $sub = $m->[1];
my $cbid = "$m->[0]:$sub";
my $data = pop @$m;
my $topic = $m->[2] || $sub;
if (!exists $subs->{$cbid}) {
warn "Message for topic '$topic' ($cbid) without expected callback, ";
return;
}
$_->($data, $topic, $sub) for @{$subs->{$cbid}};
return 1;
}
### Mode validation
sub __is_valid_command {
my ($self, $cmd) = @_;
confess("Cannot use command '$cmd' while in SUBSCRIBE mode, ")
if $self->{is_subscriber};
}
### Socket operations
sub __connect {
my ($self) = @_;
delete $self->{sock};
## Fast path, no reconnect
return $self->__build_sock() unless $self->{reconnect};
## Use precise timers on reconnections
require Time::HiRes;
my $t0 = [Time::HiRes::gettimeofday()];
## Reconnect...
while (1) {
eval { $self->__build_sock };
last unless $@; ## Connected!
die if Time::HiRes::tv_interval($t0) > $self->{reconnect}; ## Timeout
Time::HiRes::usleep($self->{every}); ## Retry in...
}
return;
}
sub __build_sock {
my ($self) = @_;
$self->{sock} = $self->{builder}->($self)
|| confess("Could not connect to Redis server at $self->{server}: $!");
return;
}
sub __send_command {
my $self = shift;
my $cmd = uc(shift);
my $enc = $self->{encoding};
my $deb = $self->{debug};
my $sock = $self->{sock}
|| $self->__throw_reconnect('Not connected to any server');
warn "[SEND] $cmd ", Dumper([@_]) if $deb;
## Encode command using multi-bulk format
my $n_elems = scalar(@_) + 1;
my $buf = "\*$n_elems\r\n";
for my $elem ($cmd, @_) {
my $bin = $enc ? encode($enc, $elem) : $elem;
$buf .= defined($bin) ? '$' . length($bin) . "\r\n$bin\r\n" : "\$-1\r\n";
}
## Check to see if socket was closed: reconnect on EOF
my $status = __try_read_sock($sock);
$self->__throw_reconnect('Not connected to any server')
if defined $status && $status == 0;
## Send command, take care for partial writes
warn "[SEND RAW] $buf" if $deb;
while ($buf) {
my $len = syswrite $sock, $buf, length $buf;
$self->__throw_reconnect("Could not write to Redis server: $!")
unless $len;
substr $buf, 0, $len, "";
}
return;
}
sub __read_response {
my ($self, $cmd) = @_;
confess("Not connected to any server") unless $self->{sock};
local $/ = "\r\n";
## no debug => fast path
return __read_response_r(@_) unless $self->{debug};
if (wantarray) {
my @r = __read_response_r(@_);
warn "[RECV] $cmd ", Dumper(\@r);
return @r;
}
else {
my $r = __read_response_r(@_);
warn "[RECV] $cmd ", Dumper($r);
return $r;
}
}
sub __read_response_r {
my ($self, $command) = @_;
my ($type, $result) = $self->__read_line;
if ($type eq '-') {
confess "[$command] $result, ";
}
elsif ($type eq '+') {
return $result;
}
elsif ($type eq '$') {
return if $result < 0;
return $self->__read_len($result + 2);
}
elsif ($type eq '*') {
return if $result < 0;
my @list;
while ($result--) {
push @list, scalar($self->__read_response_r($command));
}
return @list if wantarray;
return \@list;
}
elsif ($type eq ':') {
return $result;
}
else {
confess "unknown answer type: $type ($result), ";
}
}
sub __read_line {
my $self = $_[0];
my $sock = $self->{sock};
my $data = <$sock>;
confess("Error while reading from Redis server: $!")
unless defined $data;
chomp $data;
warn "[RECV RAW] '$data'" if $self->{debug};
my $type = substr($data, 0, 1, '');
return ($type, $data) unless $self->{encoding};
return ($type, decode($self->{encoding}, $data));
}
sub __read_len {
my ($self, $len) = @_;
my $data = '';
my $offset = 0;
while ($len) {
my $bytes = read $self->{sock}, $data, $len, $offset;
confess("Error while reading from Redis server: $!")
unless defined $bytes;
confess("Redis server closed connection") unless $bytes;
$offset += $bytes;
$len -= $bytes;
}
chomp $data;
warn "[RECV RAW] '$data'" if $self->{debug};
return $data unless $self->{encoding};
return decode($self->{encoding}, $data);
}
#
# The reason for this code:
#
# IO::Select and buffered reads like <$sock> and read() dont mix
# For example, if I receive two MESSAGE messages (from Redis PubSub),
# the first read for the first message will probably empty to socket
# buffer and move the data to the perl IO buffer.
#
# This means that IO::Select->can_read will return false (after all
# the socket buffer is empty) but from the application point of view
# there is still data to be read and process
#
# Hence this code. We try to do a non-blocking read() of 1 byte, and if
# we succeed, we put it back and signal "yes, Virginia, there is still
# stuff out there"
#
# We could just use sysread and leave the socket buffer with the second
# message, and then use IO::Select as intended, and previous versions of
# this code did that (check the git history for this file), but
# performance suffers, about 20/30% slower, mostly because we do a lot
# of "read one line", where <$sock> beats the crap of anything you can
# write on Perl-land.
#
sub __try_read_sock {
my $sock = shift;
my $data = '';
__fh_nonblocking($sock, 1);
my $result = read($sock, $data, 1);
my $err = 0 + $!;
__fh_nonblocking($sock, 0);
## No errno?? This happens sometimes on my tests when the server
## timesout the client. I traced the system calls and I see the read()
## system call return 0 for EOF, but on this side of perl, we get
## undef...
return 0 if !defined($result) && $err == 0;
return $result unless $result;
$sock->ungetc(ord($data));
return 1;
}
### Copied from AnyEvent::Util
BEGIN {
*__fh_nonblocking = ($^O eq 'MSWin32')
? sub($$) { ioctl $_[0], 0x8004667e, pack "L", $_[1]; } # FIONBIO
: sub($$) { fcntl $_[0], F_SETFL, $_[1] ? O_NONBLOCK : 0; };
}
##########################
# I take exception to that
sub __throw_reconnect {
my ($self, $m) = @_;
die bless(\$m, 'Redis::X::Reconnect') if $self->{reconnect};
die $m;
}
1;
__END__
=head1 Connection Handling
=head2 quit
$r->quit;
=head2 ping
$r->ping || die "no server?";
=head1 Commands operating on string values
=head2 set
$r->set( foo => 'bar' );
$r->setnx( foo => 42 );
=head2 get
my $value = $r->get( 'foo' );
=head2 mget
my @values = $r->mget( 'foo', 'bar', 'baz' );
=head2 incr
$r->incr('counter');
$r->incrby('tripplets', 3);
=head2 decr
$r->decr('counter');
$r->decrby('tripplets', 3);
=head2 exists
$r->exists( 'key' ) && print "got key!";
=head2 del
$r->del( 'key' ) || warn "key doesn't exist";
=head2 type
$r->type( 'key' ); # = string
=head1 Commands operating on the key space
=head2 keys
my @keys = $r->keys( '*glob_pattern*' );
my $keys = $r->keys( '*glob_pattern*' ); # count of matching keys
=head2 randomkey
my $key = $r->randomkey;
=head2 rename
my $ok = $r->rename( 'old-key', 'new-key', $new );
=head2 dbsize
my $nr_keys = $r->dbsize;
=head1 Commands operating on lists
See also L<Redis::List> for tie interface.
=head2 rpush
$r->rpush( $key, $value );
=head2 lpush
$r->lpush( $key, $value );
=head2 llen
$r->llen( $key );
=head2 lrange
my @list = $r->lrange( $key, $start, $end );
=head2 ltrim
my $ok = $r->ltrim( $key, $start, $end );
=head2 lindex
$r->lindex( $key, $index );
=head2 lset
$r->lset( $key, $index, $value );
=head2 lrem
my $modified_count = $r->lrem( $key, $count, $value );
=head2 lpop
my $value = $r->lpop( $key );
=head2 rpop
my $value = $r->rpop( $key );
=head1 Commands operating on sets
=head2 sadd
my $ok = $r->sadd( $key, $member );
=head2 scard
my $n_elements = $r->scard( $key );
=head2 sdiff
my @elements = $r->sdiff( $key1, $key2, ... );
my $elements = $r->sdiff( $key1, $key2, ... ); # ARRAY ref
=head2 sdiffstore
my $ok = $r->sdiffstore( $dstkey, $key1, $key2, ... );
=head2 sinter
my @elements = $r->sinter( $key1, $key2, ... );
my $elements = $r->sinter( $key1, $key2, ... ); # ARRAY ref
=head2 sinterstore
my $ok = $r->sinterstore( $dstkey, $key1, $key2, ... );
=head2 sismember
my $bool = $r->sismember( $key, $member );
=head2 smembers
my @elements = $r->smembers( $key );
my $elements = $r->smembers( $key ); # ARRAY ref
=head2 smove
my $ok = $r->smove( $srckey, $dstkey, $element );
=head2 spop
my $element = $r->spop( $key );
=head2 spop
my $element = $r->srandmember( $key );
=head2 srem
$r->srem( $key, $member );
=head2 sunion
my @elements = $r->sunion( $key1, $key2, ... );
my $elements = $r->sunion( $key1, $key2, ... ); # ARRAY ref
=head2 sunionstore
my $ok = $r->sunionstore( $dstkey, $key1, $key2, ... );
=head1 Multiple databases handling commands
=head2 select
$r->select( $dbindex ); # 0 for new clients
=head2 move
$r->move( $key, $dbindex );
=head2 flushdb
$r->flushdb;
=head2 flushall
$r->flushall;
=head1 Sorting
=head2 sort
$r->sort("key BY pattern LIMIT start end GET pattern ASC|DESC ALPHA');
=head1 Persistence control commands
=head2 save
$r->save;
=head2 bgsave
$r->bgsave;
=head2 lastsave
$r->lastsave;
=head2 shutdown
$r->shutdown;
=head1 Remote server control commands
=head2 info
my $info_hash = $r->info;
=head1 ENCODING
Since Redis knows nothing about encoding, we are forcing utf-8 flag on
all data received from Redis. This change is introduced in 1.2001
version. B<Please note> that this encoding option severely degrades
performance
You can disable this automatic encoding by passing an option to
new: C<< encoding => undef >>.
This allows us to round-trip utf-8 encoded characters correctly, but
might be problem if you push binary junk into Redis and expect to get it
back without utf-8 flag turned on.
=head1 AUTHORS
Pedro Melo, C<< <melo@cpan.org> >>
Original author and maintainer: Dobrica Pavlinusic, C<< <dpavlin at rot13.org> >>
=head1 BUGS
Please report any bugs or feature requests to C<bug-redis at rt.cpan.org>, or through
the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Redis>. I will be notified, and then you'll
automatically be notified of progress on your bug as I make changes.
=head1 SUPPORT
You can find documentation for this module with the perldoc command.
perldoc Redis
perldoc Redis::List
perldoc Redis::Hash
You can also look for information at:
=over 4
=item * RT: CPAN's request tracker
L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Redis>
=item * AnnoCPAN: Annotated CPAN documentation
L<http://annocpan.org/dist/Redis>
=item * CPAN Ratings
L<http://cpanratings.perl.org/d/Redis>
=item * Search CPAN
L<http://search.cpan.org/dist/Redis>
=back
=head1 ACKNOWLEDGEMENTS
The following persons contributed to this project (alphabetical order):
=over 4
=item Dirk Vleugels
=item Flavio Poletti
=item Jeremy Zawodny
=item sunnavy at bestpractical.com
=item Thiago Berlitz Rondon
=item Ulrich Habel
=back
=head1 COPYRIGHT & LICENSE
Copyright 2009-2010 Dobrica Pavlinusic, all rights reserved.
Copyright 2011-2012 Pedro Melo, all rights reserved
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.
=cut
1; # End of Redis