This repository has been archived by the owner on May 20, 2023. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 298
/
PKGBUILD
84 lines (68 loc) · 2.27 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
pkgname=haproxy
pkgver=2.7.8
pkgrel=1
pkgdesc='Reliable, high performance TCP/HTTP load balancer'
url='https://www.haproxy.org/'
arch=('x86_64')
license=('GPL')
depends=('openssl' 'pcre2' 'zlib' 'libxcrypt' 'libcrypt.so' 'lua' 'systemd-libs')
makedepends=('systemd')
backup=('etc/haproxy/haproxy.cfg')
install=haproxy.install
source=(https://www.haproxy.org/download/${pkgver%.*}/src/haproxy-$pkgver.tar.gz
haproxy.cfg
haproxy.sysusers
0001-Use-CFLAGS-and-LDFLAGS-when-building-admin.patch)
sha256sums=('15f2276971bbba8c47d86cc82ebfc6ec33e3aef2e4565058b2e4950c07b8e75c'
'f6babef513b99a3fa0e50f2b144c73c980f1b78b119874ffa2580af1e651e7a9'
'b02b4088205039f0979aef0ef3e22957f493dd54eabefaee7011f2d795303b3e'
'a1e3a1c2923465081383eb431bae55ff9841d89909469311cdba4b394ec4a998')
prepare() {
cd haproxy-$pkgver
patch -p1 <"$srcdir"/0001-Use-CFLAGS-and-LDFLAGS-when-building-admin.patch
}
build() {
cd haproxy-$pkgver
export CFLAGS="$CFLAGS -fwrapv"
make \
CFLAGS="$CFLAGS" \
LDFLAGS="$LDFLAGS" \
CPU=generic \
TARGET=linux-glibc \
USE_GETADDRINFO=1 \
USE_LUA=1 \
USE_OPENSSL=1 \
USE_PCRE2=1 USE_PCRE2_JIT=1 \
USE_PROMEX=1 \
USE_SYSTEMD=1 \
USE_ZLIB=1
make \
SBINDIR=/usr/bin \
OPTIMIZE= \
CFLAGS="$CFLAGS" \
LDFLAGS="$LDFLAGS" \
admin/{halog/halog,iprange/ip{,6}range}
make \
SBINDIR=/usr/bin \
-C admin/systemd/
}
package() {
cd haproxy-$pkgver
make \
PREFIX="$pkgdir"/usr \
SBINDIR="$pkgdir"/usr/bin \
DOCDIR="$pkgdir"/usr/share/$pkgname \
install
for admin in admin/{halog/halog,iprange/ip{,6}range}; do
install -D -m0755 $admin "$pkgdir"/usr/bin/$(basename $admin)
done
install -D -m0644 ../haproxy.sysusers "$pkgdir"/usr/lib/sysusers.d/haproxy.conf
install -D -m0644 ../haproxy.cfg "$pkgdir"/etc/haproxy/haproxy.cfg
install -D -m0644 admin/systemd/haproxy.service \
"$pkgdir"/usr/lib/systemd/system/haproxy.service
install -D -m0644 admin/syntax-highlight/haproxy.vim \
"$pkgdir"/usr/share/nvim/runtime/syntax/haproxy.vim
cp -r examples "$pkgdir"/usr/share/haproxy/examples
}