-
Notifications
You must be signed in to change notification settings - Fork 2
/
binary_file_response.cr
212 lines (175 loc) · 7.4 KB
/
binary_file_response.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
require "./response"
require "digest/sha256"
require "mime"
# Represents a static file that should be returned the client; includes various options to enhance the response headers. See `.new` for details.
#
# This response supports [Range](https://developer.mozilla.org/en-US/docs/Web/HTTP/Range_requests) requests
# and [Conditional](https://developer.mozilla.org/en-US/docs/Web/HTTP/Conditional_requests) requests via the
# [If-None-Match](https://developer.mozilla.org/en-US/docs/Web/HTTP/Headers/If-None-Match),
# [If-Modified-Since](https://developer.mozilla.org/en-US/docs/Web/HTTP/Headers/If-Modified-Since),
# and [If-Range](https://developer.mozilla.org/en-US/docs/Web/HTTP/Headers/If-Range) headers.
#
# See `ATH::HeaderUtils.make_disposition` for an example of handling dynamic files.
class Athena::Framework::BinaryFileResponse < Athena::Framework::Response
# Returns a `Path` instance representing the file that will be sent to the client.
getter file_path : Path
# Determines if the file should be deleted after being sent to the client.
setter delete_file_after_send : Bool = false
@offset : Int64 = 0
@max_length : Int64? = nil
# Represents the possible [content-disposition](https://developer.mozilla.org/en-US/docs/Web/HTTP/Headers/Content-Disposition) header values.
enum ContentDisposition
# Indicates that the file should be downloaded.
Attachment
# Indicates that the browser should display the file inside the Web page, or as the Web page.
Inline
# :inherit:
def to_s(io : IO) : Nil
case self
in .attachment? then io << "attachment"
in .inline? then io << "inline"
end
end
end
# Instantiates `self` wrapping the file at the provided *file_path*, optionally with the provided *status*, and *headers*.
#
# By default the response is `ATH::Response#set_public` and includes a `last-modified` header,
# but these can be controlled via the *public* and *auto_last_modified* arguments respectively.
#
# The *content_disposition* argument can be used to set the `content-disposition` header on `self` if it should be downloadable.
#
# The *auto_etag* argument can be used to automatically set `ETag` header based on a `SHA256` hash of the file.
def initialize(
file_path : String | Path,
status : HTTP::Status | Int32 = HTTP::Status::OK,
headers : HTTP::Headers | ATH::Response::Headers = ATH::Response::Headers.new,
public : Bool = true,
content_disposition : ATH::BinaryFileResponse::ContentDisposition? = nil,
auto_etag : Bool = false,
auto_last_modified : Bool = true
)
super nil, status, headers
raise File::Error.new("File '#{file_path}' must be readable.", file: file_path) unless File.readable? file_path
@file_path = Path.new(file_path).expand
self.set_public if public
self.set_auto_etag if auto_etag
self.auto_last_modified if auto_last_modified
self.set_content_disposition content_disposition if content_disposition
end
# CAUTION: Cannot set the response content via this method on `self`.
def content=(data) : Nil
raise "The content cannot be set on a BinaryFileResponse instance." unless data.nil?
end
# CAUTION: Cannot get the response content via this method on `self`.
def content : String
""
end
# Sets the `content-disposition` header on `self` to the provided *disposition*.
# *filename* defaults to the basename of `#file_path`.
#
# See `ATH::HeaderUtils.make_disposition`.
def set_content_disposition(disposition : ATH::BinaryFileResponse::ContentDisposition, filename : String? = nil, fallback_filename : String? = nil)
if filename.nil?
filename = @file_path.basename
end
@headers["content-disposition"] = ATH::HeaderUtils.make_disposition disposition, filename, fallback_filename
end
# Sets the `etag` header on `self` based on a `SHA256` hash of the file.
def set_auto_etag : Nil
self.set_etag Digest::SHA256.base64digest &.file(@file_path)
end
# Sets the `last-modified` header on `self` based on the modification time of the file.
def auto_last_modified : Nil
self.last_modified = File.info(@file_path).modification_time
end
# TODO: Support multiple ranges.
# TODO: Support `X-Sendfile`.
#
# OPTIMIZE: Make this less complex.
#
# ameba:disable Metrics/CyclomaticComplexity
protected def prepare(request : ATH::Request) : Nil
if self.cache_request?(request)
self.status = :not_modified
return super
end
unless @headers.has_key? "content-type"
@headers["content-type"] = MIME.from_filename(@file_path, "application/octet-stream")
end
file_size = File.info(@file_path).size
@headers["content-length"] = file_size.to_s
unless @headers.has_key? "accept-ranges"
@headers["accept-ranges"] = request.safe? ? "bytes" : "none"
end
if request.headers.has_key?("range") && "GET" == request.method
if !request.headers.has_key?("if-range") || self.valid_if_range_header?(request.headers["if-range"]?)
if range = request.headers["range"].lchop? "bytes="
s, e = range.split '-', 2
e = e.empty? ? file_size - 1 : e.to_i64
if s.empty?
s = file_size - e
e = file_size - 1
else
s = s.to_i64
end
if s <= e
e = Math.min e, file_size - 1
if s < 0 || s > e
self.status = :range_not_satisfiable
@headers["content-range"] = "bytes */#{file_size}"
elsif e - s < file_size - 1
@max_length = e < file_size ? (e - s + 1).to_i64 : nil
@offset = s.to_i64
self.status = :partial_content
@headers["content-range"] = "bytes #{s}-#{e}/#{file_size}"
@headers["content-length"] = "#{e - s + 1}"
end
end
end
end
end
end
protected def write(output : IO) : Nil
unless @status.success?
return super output
end
if @max_length.try &.zero?
return
end
@writer.write(output) do |writer_io|
File.open(@file_path, "rb") do |file|
file.skip @offset
if limit = @max_length
IO.copy file, writer_io, limit
else
IO.copy file, writer_io
end
end
end
if @delete_file_after_send && File.file?(@file_path)
File.delete @file_path
end
end
private def cache_request?(request : ATH::Request) : Bool
# According to RFC 7232:
# A recipient must ignore If-Modified-Since if the request contains an If-None-Match header field
if (if_none_match = request.if_none_match) && (etag = self.etag)
match = {"*", etag}
if_none_match.any? { |et| match.includes? et }
elsif if_modified_since = request.headers["if-modified-since"]?
header_time = HTTP.parse_time if_modified_since
last_modified = self.last_modified || File.info(@file_path).modification_time
# File mtime probably has a higher resolution than the header value.
# An exact comparison might be slightly off, so we add 1s padding.
# Static files should generally not be modified in subsecond intervals, so this is perfectly safe.
!!(header_time && last_modified <= header_time + 1.second)
else
false
end
end
private def valid_if_range_header?(header : String?) : Bool
return true if self.etag == header
return false unless last_modified = self.last_modified
HTTP.format_time(last_modified) == header
end
end