/
curve25519_x25519.S
2179 lines (2083 loc) · 66.6 KB
/
curve25519_x25519.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// Copyright Amazon.com, Inc. or its affiliates. All Rights Reserved.
// SPDX-License-Identifier: Apache-2.0 OR ISC OR MIT-0
// ----------------------------------------------------------------------------
// The x25519 function for curve25519
// Inputs scalar[4], point[4]; output res[4]
//
// extern void curve25519_x25519
// (uint64_t res[static 4],uint64_t scalar[static 4],uint64_t point[static 4])
//
// The function has a second prototype considering the arguments as arrays
// of bytes rather than 64-bit words. The underlying code is the same, since
// the x86 platform is little-endian.
//
// extern void curve25519_x25519_byte
// (uint8_t res[static 32],uint8_t scalar[static 32],uint8_t point[static 32])
//
// Given a scalar n and the X coordinate of an input point P = (X,Y) on
// curve25519 (Y can live in any extension field of characteristic 2^255-19),
// this returns the X coordinate of n * P = (X, Y), or 0 when n * P is the
// point at infinity. Both n and X inputs are first slightly modified/mangled
// as specified in the relevant RFC (https://www.rfc-editor.org/rfc/rfc7748);
// in particular the lower three bits of n are set to zero. Does not implement
// the zero-check specified in Section 6.1.
//
// Standard x86-64 ABI: RDI = res, RSI = scalar, RDX = point
// Microsoft x64 ABI: RCX = res, RDX = scalar, R8 = point
// ----------------------------------------------------------------------------
#include "_internal_s2n_bignum.h"
.intel_syntax noprefix
S2N_BN_SYM_VISIBILITY_DIRECTIVE(curve25519_x25519)
S2N_BN_SYM_PRIVACY_DIRECTIVE(curve25519_x25519)
S2N_BN_SYM_VISIBILITY_DIRECTIVE(curve25519_x25519_byte)
S2N_BN_SYM_PRIVACY_DIRECTIVE(curve25519_x25519_byte)
.text
// Size of individual field elements
#define NUMSIZE 32
// Stable homes for the input result argument during the whole body
// and other variables that are only needed prior to the modular inverse.
#define res QWORD PTR [rsp+12*NUMSIZE]
#define i QWORD PTR [rsp+12*NUMSIZE+8]
#define swap QWORD PTR [rsp+12*NUMSIZE+16]
// Pointers to result x coord to be written, assuming the base "res"
// has been loaded into rbp
#define resx rbp+0
// Pointer-offset pairs for temporaries on stack with some aliasing.
// Both dmsn and dnsm need space for >= 5 digits, and we allocate 8
#define scalar rsp+(0*NUMSIZE)
#define pointx rsp+(1*NUMSIZE)
#define dm rsp+(2*NUMSIZE)
#define zm rsp+(3*NUMSIZE)
#define sm rsp+(3*NUMSIZE)
#define dpro rsp+(3*NUMSIZE)
#define sn rsp+(4*NUMSIZE)
#define dn rsp+(5*NUMSIZE)
#define e rsp+(5*NUMSIZE)
#define dmsn rsp+(6*NUMSIZE)
#define p rsp+(6*NUMSIZE)
#define zn rsp+(7*NUMSIZE)
#define xm rsp+(8*NUMSIZE)
#define dnsm rsp+(8*NUMSIZE)
#define spro rsp+(8*NUMSIZE)
#define xn rsp+(10*NUMSIZE)
#define s rsp+(10*NUMSIZE)
#define d rsp+(11*NUMSIZE)
// Total size to reserve on the stack
// This includes space for the 3 other variables above
// and rounds up to a multiple of 32
#define NSPACE (13*NUMSIZE)
// Macro wrapping up the basic field operation bignum_mul_p25519, only
// trivially different from a pure function call to that subroutine.
#define mul_p25519(P0,P1,P2) \
xor edi, edi; \
mov rdx, [P2]; \
mulx r9, r8, [P1]; \
mulx r10, rax, [P1+0x8]; \
add r9, rax; \
mulx r11, rax, [P1+0x10]; \
adc r10, rax; \
mulx r12, rax, [P1+0x18]; \
adc r11, rax; \
adc r12, rdi; \
xor edi, edi; \
mov rdx, [P2+0x8]; \
mulx rbx, rax, [P1]; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r11, rax; \
adox r12, rbx; \
mulx r13, rax, [P1+0x18]; \
adcx r12, rax; \
adox r13, rdi; \
adcx r13, rdi; \
xor edi, edi; \
mov rdx, [P2+0x10]; \
mulx rbx, rax, [P1]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r12, rax; \
adox r13, rbx; \
mulx r14, rax, [P1+0x18]; \
adcx r13, rax; \
adox r14, rdi; \
adcx r14, rdi; \
xor edi, edi; \
mov rdx, [P2+0x18]; \
mulx rbx, rax, [P1]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r12, rax; \
adox r13, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r13, rax; \
adox r14, rbx; \
mulx r15, rax, [P1+0x18]; \
adcx r14, rax; \
adox r15, rdi; \
adcx r15, rdi; \
mov edx, 0x26; \
xor edi, edi; \
mulx rbx, rax, r12; \
adcx r8, rax; \
adox r9, rbx; \
mulx rbx, rax, r13; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, r14; \
adcx r10, rax; \
adox r11, rbx; \
mulx r12, rax, r15; \
adcx r11, rax; \
adox r12, rdi; \
adcx r12, rdi; \
shld r12, r11, 0x1; \
mov edx, 0x13; \
inc r12; \
bts r11, 63; \
mulx rbx, rax, r12; \
add r8, rax; \
adc r9, rbx; \
adc r10, rdi; \
adc r11, rdi; \
sbb rax, rax; \
not rax; \
and rax, rdx; \
sub r8, rax; \
sbb r9, rdi; \
sbb r10, rdi; \
sbb r11, rdi; \
btr r11, 63; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// A version of multiplication that only guarantees output < 2 * p_25519.
// This basically skips the +1 and final correction in quotient estimation.
#define mul_4(P0,P1,P2) \
xor ecx, ecx; \
mov rdx, [P2]; \
mulx r9, r8, [P1]; \
mulx r10, rax, [P1+0x8]; \
add r9, rax; \
mulx r11, rax, [P1+0x10]; \
adc r10, rax; \
mulx r12, rax, [P1+0x18]; \
adc r11, rax; \
adc r12, rcx; \
xor ecx, ecx; \
mov rdx, [P2+0x8]; \
mulx rbx, rax, [P1]; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r11, rax; \
adox r12, rbx; \
mulx r13, rax, [P1+0x18]; \
adcx r12, rax; \
adox r13, rcx; \
adcx r13, rcx; \
xor ecx, ecx; \
mov rdx, [P2+0x10]; \
mulx rbx, rax, [P1]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r12, rax; \
adox r13, rbx; \
mulx r14, rax, [P1+0x18]; \
adcx r13, rax; \
adox r14, rcx; \
adcx r14, rcx; \
xor ecx, ecx; \
mov rdx, [P2+0x18]; \
mulx rbx, rax, [P1]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r12, rax; \
adox r13, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r13, rax; \
adox r14, rbx; \
mulx r15, rax, [P1+0x18]; \
adcx r14, rax; \
adox r15, rcx; \
adcx r15, rcx; \
mov edx, 0x26; \
xor ecx, ecx; \
mulx rbx, rax, r12; \
adcx r8, rax; \
adox r9, rbx; \
mulx rbx, rax, r13; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, r14; \
adcx r10, rax; \
adox r11, rbx; \
mulx r12, rax, r15; \
adcx r11, rax; \
adox r12, rcx; \
adcx r12, rcx; \
shld r12, r11, 0x1; \
btr r11, 0x3f; \
mov edx, 0x13; \
imul rdx, r12; \
add r8, rdx; \
adc r9, rcx; \
adc r10, rcx; \
adc r11, rcx; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Multiplication just giving a 5-digit result (actually < 39 * p_25519)
// by not doing anything beyond the first stage of reduction
#define mul_5(P0,P1,P2) \
xor edi, edi; \
mov rdx, [P2]; \
mulx r9, r8, [P1]; \
mulx r10, rax, [P1+0x8]; \
add r9, rax; \
mulx r11, rax, [P1+0x10]; \
adc r10, rax; \
mulx r12, rax, [P1+0x18]; \
adc r11, rax; \
adc r12, rdi; \
xor edi, edi; \
mov rdx, [P2+0x8]; \
mulx rbx, rax, [P1]; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r11, rax; \
adox r12, rbx; \
mulx r13, rax, [P1+0x18]; \
adcx r12, rax; \
adox r13, rdi; \
adcx r13, rdi; \
xor edi, edi; \
mov rdx, [P2+0x10]; \
mulx rbx, rax, [P1]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r12, rax; \
adox r13, rbx; \
mulx r14, rax, [P1+0x18]; \
adcx r13, rax; \
adox r14, rdi; \
adcx r14, rdi; \
xor edi, edi; \
mov rdx, [P2+0x18]; \
mulx rbx, rax, [P1]; \
adcx r11, rax; \
adox r12, rbx; \
mulx rbx, rax, [P1+0x8]; \
adcx r12, rax; \
adox r13, rbx; \
mulx rbx, rax, [P1+0x10]; \
adcx r13, rax; \
adox r14, rbx; \
mulx r15, rax, [P1+0x18]; \
adcx r14, rax; \
adox r15, rdi; \
adcx r15, rdi; \
mov edx, 0x26; \
xor edi, edi; \
mulx rbx, rax, r12; \
adcx r8, rax; \
adox r9, rbx; \
mulx rbx, rax, r13; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, r14; \
adcx r10, rax; \
adox r11, rbx; \
mulx r12, rax, r15; \
adcx r11, rax; \
adox r12, rdi; \
adcx r12, rdi; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11; \
mov [P0+0x20], r12
// Squaring just giving a result < 2 * p_25519, which is done by
// basically skipping the +1 in the quotient estimate and the final
// optional correction.
#define sqr_4(P0,P1) \
mov rdx, [P1]; \
mulx r15, r8, rdx; \
mulx r10, r9, [P1+0x8]; \
mulx r12, r11, [P1+0x18]; \
mov rdx, [P1+0x10]; \
mulx r14, r13, [P1+0x18]; \
xor ebx, ebx; \
mulx rcx, rax, [P1]; \
adcx r10, rax; \
adox r11, rcx; \
mulx rcx, rax, [P1+0x8]; \
adcx r11, rax; \
adox r12, rcx; \
mov rdx, [P1+0x18]; \
mulx rcx, rax, [P1+0x8]; \
adcx r12, rax; \
adox r13, rcx; \
adcx r13, rbx; \
adox r14, rbx; \
adc r14, rbx; \
xor ebx, ebx; \
adcx r9, r9; \
adox r9, r15; \
mov rdx, [P1+0x8]; \
mulx rdx, rax, rdx; \
adcx r10, r10; \
adox r10, rax; \
adcx r11, r11; \
adox r11, rdx; \
mov rdx, [P1+0x10]; \
mulx rdx, rax, rdx; \
adcx r12, r12; \
adox r12, rax; \
adcx r13, r13; \
adox r13, rdx; \
mov rdx, [P1+0x18]; \
mulx r15, rax, rdx; \
adcx r14, r14; \
adox r14, rax; \
adcx r15, rbx; \
adox r15, rbx; \
mov edx, 0x26; \
xor ebx, ebx; \
mulx rcx, rax, r12; \
adcx r8, rax; \
adox r9, rcx; \
mulx rcx, rax, r13; \
adcx r9, rax; \
adox r10, rcx; \
mulx rcx, rax, r14; \
adcx r10, rax; \
adox r11, rcx; \
mulx r12, rax, r15; \
adcx r11, rax; \
adox r12, rbx; \
adcx r12, rbx; \
shld r12, r11, 0x1; \
btr r11, 0x3f; \
mov edx, 0x13; \
imul rdx, r12; \
add r8, rdx; \
adc r9, rbx; \
adc r10, rbx; \
adc r11, rbx; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Add 5-digit inputs and normalize to 4 digits
#define add5_4(P0,P1,P2) \
mov r8, [P1]; \
add r8, [P2]; \
mov r9, [P1+8]; \
adc r9, [P2+8]; \
mov r10, [P1+16]; \
adc r10, [P2+16]; \
mov r11, [P1+24]; \
adc r11, [P2+24]; \
mov r12, [P1+32]; \
adc r12, [P2+32]; \
xor ebx, ebx; \
shld r12, r11, 0x1; \
btr r11, 0x3f; \
mov edx, 0x13; \
imul rdx, r12; \
add r8, rdx; \
adc r9, rbx; \
adc r10, rbx; \
adc r11, rbx; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Modular addition with double modulus 2 * p_25519 = 2^256 - 38.
// This only ensures that the result fits in 4 digits, not that it is reduced
// even w.r.t. double modulus. The result is always correct modulo provided
// the sum of the inputs is < 2^256 + 2^256 - 38, so in particular provided
// at least one of them is reduced double modulo.
#define add_twice4(P0,P1,P2) \
mov r8, [P1]; \
xor ecx, ecx; \
add r8, [P2]; \
mov r9, [P1+0x8]; \
adc r9, [P2+0x8]; \
mov r10, [P1+0x10]; \
adc r10, [P2+0x10]; \
mov r11, [P1+0x18]; \
adc r11, [P2+0x18]; \
mov eax, 38; \
cmovnc rax, rcx; \
add r8, rax; \
adc r9, rcx; \
adc r10, rcx; \
adc r11, rcx; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Modular subtraction with double modulus 2 * p_25519 = 2^256 - 38
#define sub_twice4(P0,P1,P2) \
mov r8, [P1]; \
xor ebx, ebx; \
sub r8, [P2]; \
mov r9, [P1+8]; \
sbb r9, [P2+8]; \
mov ecx, 38; \
mov r10, [P1+16]; \
sbb r10, [P2+16]; \
mov rax, [P1+24]; \
sbb rax, [P2+24]; \
cmovnc rcx, rbx; \
sub r8, rcx; \
sbb r9, rbx; \
sbb r10, rbx; \
sbb rax, rbx; \
mov [P0], r8; \
mov [P0+8], r9; \
mov [P0+16], r10; \
mov [P0+24], rax
// 5-digit subtraction with upward bias to make it positive, adding
// 1000 * (2^255 - 19) = 2^256 * 500 - 19000, then normalizing to 4 digits
#define sub5_4(P0,P1,P2) \
mov r8, [P1]; \
sub r8, [P2]; \
mov r9, [P1+8]; \
sbb r9, [P2+8]; \
mov r10, [P1+16]; \
sbb r10, [P2+16]; \
mov r11, [P1+24]; \
sbb r11, [P2+24]; \
mov r12, [P1+32]; \
sbb r12, [P2+32]; \
xor ebx, ebx; \
sub r8, 19000; \
sbb r9, rbx; \
sbb r10, rbx; \
sbb r11, rbx; \
sbb r12, rbx; \
add r12, 500; \
shld r12, r11, 0x1; \
btr r11, 0x3f; \
mov edx, 0x13; \
imul rdx, r12; \
add r8, rdx; \
adc r9, rbx; \
adc r10, rbx; \
adc r11, rbx; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Combined z = c * x + y with reduction only < 2 * p_25519
// It is assumed that 19 * (c * x + y) < 2^60 * 2^256 so we
// don't need a high mul in the final part.
#define cmadd_4(P0,C1,P2,P3) \
mov r8, [P3]; \
mov r9, [P3+8]; \
mov r10, [P3+16]; \
mov r11, [P3+24]; \
xor edi, edi; \
mov rdx, C1; \
mulx rbx, rax, [P2]; \
adcx r8, rax; \
adox r9, rbx; \
mulx rbx, rax, [P2+8]; \
adcx r9, rax; \
adox r10, rbx; \
mulx rbx, rax, [P2+16]; \
adcx r10, rax; \
adox r11, rbx; \
mulx rbx, rax, [P2+24]; \
adcx r11, rax; \
adox rbx, rdi; \
adcx rbx, rdi; \
shld rbx, r11, 0x1; \
btr r11, 63; \
mov edx, 0x13; \
imul rbx, rdx; \
add r8, rbx; \
adc r9, rdi; \
adc r10, rdi; \
adc r11, rdi; \
mov [P0], r8; \
mov [P0+0x8], r9; \
mov [P0+0x10], r10; \
mov [P0+0x18], r11
// Multiplex: z := if NZ then x else y
#define mux_4(P0,P1,P2) \
mov rax, [P1]; \
mov rcx, [P2]; \
cmovz rax, rcx; \
mov [P0], rax; \
mov rax, [P1+8]; \
mov rcx, [P2+8]; \
cmovz rax, rcx; \
mov [P0+8], rax; \
mov rax, [P1+16]; \
mov rcx, [P2+16]; \
cmovz rax, rcx; \
mov [P0+16], rax; \
mov rax, [P1+24]; \
mov rcx, [P2+24]; \
cmovz rax, rcx; \
mov [P0+24], rax
S2N_BN_SYMBOL(curve25519_x25519):
S2N_BN_SYMBOL(curve25519_x25519_byte):
#if WINDOWS_ABI
push rdi
push rsi
mov rdi, rcx
mov rsi, rdx
mov rdx, r8
#endif
// Save registers, make room for temps, preserve input arguments.
push rbx
push rbp
push r12
push r13
push r14
push r15
sub rsp, NSPACE
// Move the output pointer to a stable place
mov res, rdi
// Copy the inputs to the local variables with minimal mangling:
//
// - The scalar is in principle turned into 01xxx...xxx000 but
// in the structure below the special handling of these bits is
// explicit in the main computation; the scalar is just copied.
//
// - The point x coord is reduced mod 2^255 by masking off the
// top bit. In the main loop we only need reduction < 2 * p_25519.
mov rax, [rsi]
mov [rsp], rax
mov rax, [rsi+8]
mov [rsp+8], rax
mov rax, [rsi+16]
mov [rsp+16], rax
mov rax, [rsi+24]
mov [rsp+24], rax
mov r8, [rdx]
mov r9, [rdx+8]
mov r10, [rdx+16]
mov r11, [rdx+24]
btr r11, 63
mov [rsp+32], r8
mov [rsp+40], r9
mov [rsp+48], r10
mov [rsp+56], r11
// Initialize with explicit doubling in order to handle set bit 254.
// Set swap = 1 and (xm,zm) = (x,1) then double as (xn,zn) = 2 * (x,1).
// We use the fact that the point x coordinate is still in registers.
// Since zm = 1 we could do the doubling with an operation count of
// 2 * S + M instead of 2 * S + 2 * M, but it doesn't seem worth
// the slight complication arising from a different linear combination.
mov eax, 1
mov swap, rax
mov [rsp+256], r8
mov [rsp+96], rax
xor eax, eax
mov [rsp+264], r9
mov [rsp+104], rax
mov [rsp+272], r10
mov [rsp+112], rax
mov [rsp+280], r11
mov [rsp+120], rax
sub_twice4(d,xm,zm)
add_twice4(s,xm,zm)
sqr_4(d,d)
sqr_4(s,s)
sub_twice4(p,s,d)
cmadd_4(e,0x1db42,p,d)
mul_4(xn,s,d)
mul_4(zn,p,e)
// The main loop over unmodified bits from i = 253, ..., i = 3 (inclusive).
// This is a classic Montgomery ladder, with the main coordinates only
// reduced mod 2 * p_25519, some intermediate results even more loosely.
mov eax, 253
mov i, rax
curve25519_x25519_scalarloop:
// sm = xm + zm; sn = xn + zn; dm = xm - zm; dn = xn - zn
sub_twice4(dm,xm,zm)
add_twice4(sn,xn,zn)
sub_twice4(dn,xn,zn)
add_twice4(sm,xm,zm)
// DOUBLING: mux d = xt - zt and s = xt + zt for appropriate choice of (xt,zt)
mov rdx, i
mov rcx, rdx
shr rdx, 6
mov rdx, [rsp+8*rdx]
shr rdx, cl
and rdx, 1
cmp rdx, swap
mov swap, rdx
mux_4(d,dm,dn)
mux_4(s,sm,sn)
// ADDING: dmsn = dm * sn; dnsm = sm * dn
mul_5(dnsm,sm,dn)
mul_5(dmsn,sn,dm)
// DOUBLING: d = (xt - zt)^2
sqr_4(d,d)
// ADDING: dpro = (dmsn - dnsm)^2, spro = (dmsn + dnsm)^2
// DOUBLING: s = (xt + zt)^2
sub5_4(dpro,dmsn,dnsm)
add5_4(spro,dmsn,dnsm)
sqr_4(s,s)
sqr_4(dpro,dpro)
// DOUBLING: p = 4 * xt * zt = s - d
sub_twice4(p,s,d)
// ADDING: xm' = (dmsn + dnsm)^2
sqr_4(xm,spro)
// DOUBLING: e = 121666 * p + d
cmadd_4(e,0x1db42,p,d)
// DOUBLING: xn' = (xt + zt)^2 * (xt - zt)^2 = s * d
mul_4(xn,s,d)
// DOUBLING: zn' = (4 * xt * zt) * ((xt - zt)^2 + 121666 * (4 * xt * zt))
// = p * (d + 121666 * p)
mul_4(zn,p,e)
// ADDING: zm' = x * (dmsn - dnsm)^2
mul_4(zm,dpro,pointx)
// Loop down as far as 3 (inclusive)
mov rax, i
sub rax, 1
mov i, rax
cmp rax, 3
jnc curve25519_x25519_scalarloop
// Multiplex directly into (xn,zn) then do three pure doubling steps;
// this accounts for the implicit zeroing of the three lowest bits
// of the scalar.
mov rdx, swap
test rdx, rdx
mux_4(xn,xm,xn)
mux_4(zn,zm,zn)
sub_twice4(d,xn,zn)
add_twice4(s,xn,zn)
sqr_4(d,d)
sqr_4(s,s)
sub_twice4(p,s,d)
cmadd_4(e,0x1db42,p,d)
mul_4(xn,s,d)
mul_4(zn,p,e)
sub_twice4(d,xn,zn)
add_twice4(s,xn,zn)
sqr_4(d,d)
sqr_4(s,s)
sub_twice4(p,s,d)
cmadd_4(e,0x1db42,p,d)
mul_4(xn,s,d)
mul_4(zn,p,e)
sub_twice4(d,xn,zn)
add_twice4(s,xn,zn)
sqr_4(d,d)
sqr_4(s,s)
sub_twice4(p,s,d)
cmadd_4(e,0x1db42,p,d)
mul_4(xn,s,d)
mul_4(zn,p,e)
// The projective result of the scalar multiplication is now (xn,zn).
// Prepare to call the modular inverse function to get zn' = 1/zn
lea rdi, [rsp+224]
lea rsi, [rsp+224]
// Inline copy of bignum_inv_p25519, identical except for stripping out
// the prologue and epilogue saving and restoring registers and making
// and reclaiming room on the stack. For more details and explanations see
// "x86/curve25519/bignum_inv_p25519.S". Note that the stack it uses for
// its own temporaries is 208 bytes, so it has no effect on variables
// that are needed in the rest of our computation here: res, xn and zn.
mov [rsp+0xc0], rdi
xor eax, eax
lea rcx, [rax-0x13]
not rax
mov [rsp], rcx
mov [rsp+0x8], rax
mov [rsp+0x10], rax
btr rax, 0x3f
mov [rsp+0x18], rax
mov rdx, [rsi]
mov rcx, [rsi+0x8]
mov r8, [rsi+0x10]
mov r9, [rsi+0x18]
mov eax, 0x1
xor r10d, r10d
bts r9, 0x3f
adc rax, r10
imul rax, rax, 0x13
add rdx, rax
adc rcx, r10
adc r8, r10
adc r9, r10
mov eax, 0x13
cmovb rax, r10
sub rdx, rax
sbb rcx, r10
sbb r8, r10
sbb r9, r10
btr r9, 0x3f
mov [rsp+0x20], rdx
mov [rsp+0x28], rcx
mov [rsp+0x30], r8
mov [rsp+0x38], r9
xor eax, eax
mov [rsp+0x40], rax
mov [rsp+0x48], rax
mov [rsp+0x50], rax
mov [rsp+0x58], rax
movabs rax, 0xa0f99e2375022099
mov [rsp+0x60], rax
movabs rax, 0xa8c68f3f1d132595
mov [rsp+0x68], rax
movabs rax, 0x6c6c893805ac5242
mov [rsp+0x70], rax
movabs rax, 0x276508b241770615
mov [rsp+0x78], rax
mov QWORD PTR [rsp+0x90], 0xa
mov QWORD PTR [rsp+0x98], 0x1
jmp curve25519_x25519_midloop
curve25519_x25519_inverseloop:
mov r9, r8
sar r9, 0x3f
xor r8, r9
sub r8, r9
mov r11, r10
sar r11, 0x3f
xor r10, r11
sub r10, r11
mov r13, r12
sar r13, 0x3f
xor r12, r13
sub r12, r13
mov r15, r14
sar r15, 0x3f
xor r14, r15
sub r14, r15
mov rax, r8
and rax, r9
mov rdi, r10
and rdi, r11
add rdi, rax
mov [rsp+0x80], rdi
mov rax, r12
and rax, r13
mov rsi, r14
and rsi, r15
add rsi, rax
mov [rsp+0x88], rsi
xor ebx, ebx
mov rax, [rsp]
xor rax, r9
mul r8
add rdi, rax
adc rbx, rdx
mov rax, [rsp+0x20]
xor rax, r11
mul r10
add rdi, rax
adc rbx, rdx
xor ebp, ebp
mov rax, [rsp]
xor rax, r13
mul r12
add rsi, rax
adc rbp, rdx
mov rax, [rsp+0x20]
xor rax, r15
mul r14
add rsi, rax
adc rbp, rdx
xor ecx, ecx
mov rax, [rsp+0x8]
xor rax, r9
mul r8
add rbx, rax
adc rcx, rdx
mov rax, [rsp+0x28]
xor rax, r11
mul r10
add rbx, rax
adc rcx, rdx
shrd rdi, rbx, 0x3b
mov [rsp], rdi
xor edi, edi
mov rax, [rsp+0x8]
xor rax, r13
mul r12
add rbp, rax
adc rdi, rdx
mov rax, [rsp+0x28]
xor rax, r15
mul r14
add rbp, rax
adc rdi, rdx
shrd rsi, rbp, 0x3b
mov [rsp+0x20], rsi
xor esi, esi
mov rax, [rsp+0x10]
xor rax, r9
mul r8
add rcx, rax
adc rsi, rdx
mov rax, [rsp+0x30]
xor rax, r11
mul r10
add rcx, rax
adc rsi, rdx
shrd rbx, rcx, 0x3b
mov [rsp+0x8], rbx
xor ebx, ebx
mov rax, [rsp+0x10]
xor rax, r13
mul r12
add rdi, rax
adc rbx, rdx
mov rax, [rsp+0x30]
xor rax, r15
mul r14
add rdi, rax
adc rbx, rdx
shrd rbp, rdi, 0x3b
mov [rsp+0x28], rbp
mov rax, [rsp+0x18]
xor rax, r9
mov rbp, rax
sar rbp, 0x3f
and rbp, r8
neg rbp
mul r8
add rsi, rax
adc rbp, rdx
mov rax, [rsp+0x38]
xor rax, r11
mov rdx, rax
sar rdx, 0x3f
and rdx, r10
sub rbp, rdx
mul r10
add rsi, rax
adc rbp, rdx
shrd rcx, rsi, 0x3b
mov [rsp+0x10], rcx
shrd rsi, rbp, 0x3b
mov rax, [rsp+0x18]
mov [rsp+0x18], rsi
xor rax, r13
mov rsi, rax
sar rsi, 0x3f
and rsi, r12
neg rsi
mul r12
add rbx, rax
adc rsi, rdx
mov rax, [rsp+0x38]
xor rax, r15
mov rdx, rax
sar rdx, 0x3f
and rdx, r14
sub rsi, rdx
mul r14
add rbx, rax
adc rsi, rdx
shrd rdi, rbx, 0x3b
mov [rsp+0x30], rdi
shrd rbx, rsi, 0x3b
mov [rsp+0x38], rbx