Code actions for isolated constructs

[MaryamZi]

Description:
Few suggestions for potential code actions for isolated constructs,

• A non-final isolated variable can only be accessed within a lock statement.

isolated int i = 1;

function increment() {
    i += 1;
}

This fails with invalid access of an 'isolated' variable outside a 'lock' statement, and can be fixed using a lock statement. Can we provide a code action to do the same?

isolated int i = 1;

function increment() {
    lock {
        i += 1;
    }
}

This is also the case for accessing self in an isolated class.

isolated class Foo {
    private int i = 1;

    function increment() {
        self.i += 1; // error: invalid access of a mutable field of an 'isolated' object outside a 'lock' statement
    }
}

• A field in an isolated class that is not final and/or does not have a type that is a subtype of readonly needs to be private.

isolated class Foo {
    int i = 1; // invalid non-private mutable field in an 'isolated' object
}

can be fixed by making it a private field.

isolated class Foo {
    private int i = 1;
}

• An isolated function can access variables defined outside the function only if it is either an isolated variable or if it is a variable that is both final and has a subtype of readonly.

Can we provide a code action for at least marking a variable as an isolated variable?

int[] arr = [];

isolated function length() returns int {
    return arr.length();
}

Can be fixed either by doing

isolated int[] arr = [];

isolated function length() returns int {
    lock {
        return arr.length();
    }
}

or

final int[] & readonly arr = [];

isolated function length() returns int {
    return arr.length();
}

Affected Versions:
slalpha2

[nipunayf]

The progress of supporting code actions for isolated constructs is tracked with the following issues:

• Implement new code action to enclose a field access expression within a lock statement. #31630
• New code action to add the isolated keyword to a function #34431
• [Improvement]: Provide code actions to fix non-private mutable fields #42314
• [Improvement]: Provide the Add isolated qualifier CA for service functions with concurrent calls #42324
• [Improvement]: Provide code actions to fix invalid access of mutable storage #42331
• [Improvement]: Provide a quick-fix code action for invalid transfer out of a lock statement #42333
• [Improvement]: Provide a quick-fix code action for invalid transfer into of a lock statement #42335