-
Notifications
You must be signed in to change notification settings - Fork 44
/
Facturacion.CertificadoDeSellos.pas
255 lines (218 loc) · 8.35 KB
/
Facturacion.CertificadoDeSellos.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
{*******************************************************}
{ }
{ TFacturaElectronica }
{ }
{ Copyright (C) 2022 Bambu Code SA de CV }
{ }
{*******************************************************}
unit Facturacion.CertificadoDeSellos;
interface
uses
{$IF CompilerVersion >= 23}
System.SysUtils,
{$ELSE}
SysUtils,
{$IFEND}
OpenSSLUtils;
type
EFECertificadoNoExisteException = class(Exception);
TTipoCertificado = (tcFIEL, tcSellos);
ICertificadoDeSellos = Interface
['{C4F1BC13-8975-4944-AF8F-5FB885C155FF}']
function GetContenidoBase64: string;
function GetContenidoPEM: string;
function GetEmitidoParaNombre: string;
function GetEmitidoParaRFC: String;
function GetEmitidoPor: string;
function GetNoCertificado: string;
function GetTipoCertificado: TTipoCertificado;
function GetVigenciaFin: TDateTime;
function GetVigenciaInicio: TDateTime;
procedure Leer(const aRutaCertificado: TFileName);
property ContenidoPEM: string read GetContenidoPEM;
property ContenidoBase64: string read GetContenidoBase64;
property EmitidoParaNombre: string read GetEmitidoParaNombre;
property EmitidoParaRFC: String read GetEmitidoParaRFC;
property EmitidorPor: string read GetEmitidoPor;
property NoCertificado: string read GetNoCertificado;
property TipoCertificado: TTipoCertificado read GetTipoCertificado;
property VigenciaFin: TDateTime read GetVigenciaFin;
property VigenciaInicio: TDateTime read GetVigenciaInicio;
End;
TCertificadoDeSellos = class(TInterfacedObject, ICertificadoDeSellos)
private
fx509Certificado : TX509Certificate;
fFueLeido: Boolean;
fVigenteDesde: TDateTime;
fVigenteHasta: TDateTime;
fNoCertificado: string;
FContenidoBase64: string;
fSubjectCertificado: String;
fEmitidorPor: String;
fTipoCertificado: TTipoCertificado;
function GetContenidoBase64: string;
function GetContenidoPEM: string;
function GetEmitidoParaNombre: string;
function GetEmitidoParaRFC: String;
function GetEmitidoPor: string;
function GetNoCertificado: string;
function GetTipoCertificado: TTipoCertificado;
function GetVigenciaFin: TDateTime;
function GetVigenciaInicio: TDateTime;
procedure IdentificarTipoDeCertificado(const aContenidoCertificado: String);
property EmitidoPor: string read GetEmitidoPor;
public
destructor Destroy; override;
procedure Leer(const aRutaCertificado: TFileName);
property ContenidoBase64: string read GetContenidoBase64;
property ContenidoPEM: string read GetContenidoPEM;
property EmitidoParaNombre: string read GetEmitidoParaNombre;
property EmitidoParaRFC: String read GetEmitidoParaRFC;
property NoCertificado: string read GetNoCertificado;
property TipoCertificado: TTipoCertificado read GetTipoCertificado;
property VigenciaFin: TDateTime read GetVigenciaFin;
property VigenciaInicio: TDateTime read GetVigenciaInicio;
end;
implementation
{$IFDEF CODESITE}
uses CodeSiteLogging;
{$ENDIF}
{ TCertificadoDeSellos }
procedure TCertificadoDeSellos.Leer(const aRutaCertificado: TFileName);
const
_ERROR_LECTURA_CERTIFICADO = 'Unable to read certificate';
var
rfcDelCertificado: String;
begin
AppStartup;
fx509Certificado := TX509Certificate.Create;
try
if Not FileExists(aRutaCertificado) then
raise EFECertificadoNoExisteException.Create('No existe el archivo del certificado: ' + aRutaCertificado);
try
fx509Certificado.LoadFromFile(aRutaCertificado);
except
On E:Exception do
begin
{$IFDEF CODESITE}
CodeSite.SendException(E);
{$ENDIF}
raise;
end;
end;
FFueLeido := True;
fEmitidorPor := fx509Certificado.Issuer;
{$IFDEF CODESITE}
CodeSite.AddSeparator;
CodeSite.Send('Issuer', fx509Certificado.Issuer);
CodeSite.Send('Subject', fx509Certificado.Subject);
CodeSite.Send('Text', fx509Certificado.Text);
CodeSite.AddSeparator;
{$ENDIF}
// Identificamos el tipo de certificado (FIEL o sellos)
IdentificarTipoDeCertificado(fx509Certificado.Text);
// Leemos las propiedades
fVigenteDesde := fx509Certificado.NotAfter;
fVigenteHasta := fx509Certificado.NotBefore;
fNoCertificado := fx509Certificado.SerialNumber;
fSubjectCertificado := fx509Certificado.Subject;
except
// Pasamos la excepcion tal y como esta
On E: Exception do
begin
FFueLeido := False;
FreeAndNil(fx509Certificado);
raise;
end;
end;
end;
destructor TCertificadoDeSellos.Destroy;
begin
inherited;
if Assigned(fx509Certificado) then
FreeAndNil(fx509Certificado);
end;
function TCertificadoDeSellos.GetContenidoBase64: string;
const
_CADENA_INICIO_CERTIFICADO = '-----BEGIN CERTIFICATE-----';
_CADENA_FIN_CERTIFICADO = '-----END CERTIFICATE-----';
var
sCertificadoBase64: string;
begin
Assert(fx509Certificado <> nil, 'El certificado interno X509 fue nulo');
sCertificadoBase64 := fx509Certificado.AsBase64;
Assert(Pos(_CADENA_INICIO_CERTIFICADO, sCertificadoBase64) > 0, 'No se tuvo cadena de inicio de certificado');
Assert(Pos(_CADENA_FIN_CERTIFICADO, sCertificadoBase64) > 0, 'No se tuvo cadena de fin de certificado');
// Quita los encabezados, pie y retornos de carro del certificado
sCertificadoBase64:=StringReplace(sCertificadoBase64, #13, '', [rfReplaceAll, rfIgnoreCase]);
sCertificadoBase64:=StringReplace(sCertificadoBase64, #10, '', [rfReplaceAll, rfIgnoreCase]);
// Quitamos encabezado del certificado
sCertificadoBase64:=StringReplace(sCertificadoBase64, _CADENA_INICIO_CERTIFICADO, '', [rfReplaceAll, rfIgnoreCase]);
// Quitamos el pie del certificado
Result:=StringReplace(sCertificadoBase64, _CADENA_FIN_CERTIFICADO, '', [rfReplaceAll, rfIgnoreCase]);
end;
function TCertificadoDeSellos.GetContenidoPEM: string;
begin
Assert(fx509Certificado <> nil, 'El certificado interno X509 fue nulo');
result := fx509Certificado.AsBase64;
end;
function TCertificadoDeSellos.GetEmitidoParaNombre: string;
const
_CADENA_INICIO_NOMBRE_EN_CERTIFICADO = '/CN=';
_CADENA_FIN_NOMBRE_EN_CERTIFICADO = '/name=';
begin
{ Ejemplo cadena:
Subject = /CN=RADIOGRAFIAS INDUSTRIALES DEL CENTRO AC/name=RADIOGRAFIAS INDUSTRIALES DEL CENTRO AC/O=RADIOGRAFIAS INDUSTRIALES DEL CENTRO AC
/x500UniqueIdentifier=VOC990129I26 / FUAB770117BXA/serialNumber= / FUAB770117MDFRNN09/OU=Prueba_CFDI
}
Result := Trim(Copy(fSubjectCertificado,
AnsiPos(_CADENA_INICIO_NOMBRE_EN_CERTIFICADO, fSubjectCertificado) + Length(_CADENA_INICIO_NOMBRE_EN_CERTIFICADO),
AnsiPos(_CADENA_FIN_NOMBRE_EN_CERTIFICADO, fSubjectCertificado) - StrLen(_CADENA_INICIO_NOMBRE_EN_CERTIFICADO) - 1));
Result := UpperCase(Result);
end;
function TCertificadoDeSellos.GetEmitidoParaRFC: String;
const
_CADENA_INICIO_RFC_EN_CERTIFICADO = 'UniqueIdentifier=';
_LONGITUD_RFC = 13;
begin
// Obtenemos el RFC al que pertenece el certificado
Result := Trim(Copy(fSubjectCertificado,
Pos(_CADENA_INICIO_RFC_EN_CERTIFICADO, fSubjectCertificado) + Length(_CADENA_INICIO_RFC_EN_CERTIFICADO),
_LONGITUD_RFC));
Result := UpperCase(Result);
end;
function TCertificadoDeSellos.GetEmitidoPor: string;
begin
Result := fEmitidorPor;
end;
procedure TCertificadoDeSellos.IdentificarTipoDeCertificado(const
aContenidoCertificado: String);
const
// Las siguientes cadenas solo se encuentran en un certificado de FIEL
// despues de X509v3 Key Usage
_CADENA_USO_X509V3_CIFRADO = 'Data Encipherment';
_CADENA_USO_X509V3_LLAVE = 'Key Agreement';
begin
if ((AnsiPos(_CADENA_USO_X509V3_CIFRADO, aContenidoCertificado) > 0) And
(AnsiPos(_CADENA_USO_X509V3_LLAVE, aContenidoCertificado) > 0)) then
fTipoCertificado := tcFIEL
else
fTipoCertificado := tcSellos;
end;
function TCertificadoDeSellos.GetNoCertificado: string;
begin
Result := fNoCertificado;
end;
function TCertificadoDeSellos.GetTipoCertificado: TTipoCertificado;
begin
Result := fTipoCertificado;
end;
function TCertificadoDeSellos.GetVigenciaFin: TDateTime;
begin
Result := fVigenteDesde;
end;
function TCertificadoDeSellos.GetVigenciaInicio: TDateTime;
begin
Result := fVigenteHasta;
end;
end.