-
Notifications
You must be signed in to change notification settings - Fork 35
/
QML.jl
825 lines (695 loc) · 23.9 KB
/
QML.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
module QML
export QVariant, QString, QUrl
export QQmlContext, root_context, load, qt_prefix_path, set_source, engine, QByteArray, to_string, QQmlComponent, set_data, create, QQuickItem, content_item, QTimer, context_property, emit, JuliaDisplay, JuliaCanvas, init_application, qmlcontext, init_qmlapplicationengine, init_qmlengine, init_qquickview, exec, exec_async, ListModel, addrole, setconstructor, removerole, setrole, roles, QVariantMap
export JuliaPropertyMap
export QStringList, QVariantList
export QPainter, device, width, height, logicalDpiX, logicalDpiY, QQuickWindow, effectiveDevicePixelRatio, window, JuliaPaintedItem
export @emit, @qmlfunction, qmlfunction, load, QQmlPropertyMap
export set_context_property
export QUrlFromLocalFile
export qputenv, qgetenv, qunsetenv
# TODO: Document: init_application, init_qmlapplicationengine
# TODO: Document painter: device, effectiveDevicePixelRatio, height, JuliaCanvas, JuliaPaintedItem, logicalDpiX, logicalDpiY, width, window
using jlqml_jll
using CxxWrap
using Observables
using FileIO
import Libdl
using Requires
using ColorTypes
using MacroTools: @capture
const envfile = joinpath(dirname(dirname(@__FILE__)), "deps", "env.jl")
if isfile(envfile)
include(envfile)
end
@readmodule libjlqml :define_julia_module Libdl.RTLD_GLOBAL
@wraptypes
# Make sure functions accepting a QString argument also accept a Julia string
CxxWrap.argument_overloads(::Type{<:QString}) = [QString,String]
@wrapfunctions
@cxxdereference set_context_property(ctx::QQmlContext, name, value::QObject) = _set_context_property(ctx, QString(name), CxxPtr(value))
@cxxdereference set_context_property(ctx::QQmlContext, name, value) = _set_context_property(ctx, QString(name), QVariant(value))
function load_qml(qmlfilename, engine)
ctx = root_context(CxxRef(engine))
if !load_into_engine(engine, QString(qmlfilename))
error("Failed to load QML file ", qmlfilename)
end
return engine
end
"""
function load(qml_file::String; properties...)
Load a QML file, creating a [`QML.QQmlApplicationEngine`](@ref), and setting the context
`properties` supplied in the keyword arguments. Will create and return a
`QQmlApplicationEngine`. See the example for [`QML.QQmlApplicationEngine`](@ref).
"""
function FileIO.load(f::FileIO.File{format"QML"}; kwargs...)
qml_engine = init_qmlapplicationengine()
ctx = root_context(CxxRef(qml_engine))
for (key,value) in kwargs
set_context_property(ctx, String(key), value)
end
return load_qml(filename(f), qml_engine)
end
@static if Sys.iswindows()
using Mesa_jll
end
function __init__()
@initcxx
FileIO.add_format(format"QML", (), ".qml")
@require Makie="ee78f7c6-11fb-53f2-987a-cfe4a2b5a57a" include(joinpath(@__DIR__, "makie_support.jl"))
# Make sure Qt can find the Mesa dll if it doesn't find a compatible OpenGL implementation
@static if Sys.iswindows()
qputenv("PATH", QByteArray(ENV["PATH"] * ";" * dirname(Mesa_jll.opengl32sw)))
end
end
# QString
function QString(s::String)
char_arr = transcode(UInt16, s)
return fromUtf16(char_arr, length(char_arr))
end
Base.ncodeunits(s::QString)::Int = cppsize(s)
Base.codeunit(s::QString) = UInt16
Base.codeunit(s::QString, i::Integer) = uint16char(s, i-1)
Base.isvalid(s::QString, i::Integer) = isvalidindex(s, i-1)
function Base.iterate(s::QString, i::Integer=1)
if !isvalid(s,i)
return nothing
end
(charcode, nexti) = get_iterate(s,i-1)
if nexti == -1
return nothing
end
return(Char(charcode),nexti+1)
end
Base.convert(::Type{<:QString}, s::String) = QString(s)
QString(u::QUrl) = toString(u)
const QVariantList = QList{QVariant}
# Conversion to the strongly-typed QVariant interface
@inline QVariant(x) = QVariant(Any,x)
@inline QVariant(x::T) where {T<:Union{Number,Ref,CxxWrap.SafeCFunction,QVariantMap,Nothing}} = QVariant(T, x)
@inline QVariant(x::AbstractString) = QVariant(QString,QString(x))
@inline QVariant(x::QString) = QVariant(QString,x)
@inline QVariant(x::QObject) = QVariant(CxxPtr{QObject},CxxPtr(x))
@inline QVariant(x::QVariant) = x
QVariant(::Type{Bool}, b::Bool) = QVariant(CxxBool, CxxBool(b))
@cxxdereference value(::Type{Bool}, qvar::QML.QVariant) = Bool(value(CxxBool, qvar))
function QVariant(arr::AbstractArray)
qvarlist = QVariantList()
for x in arr
push!(qvarlist, x)
end
return QVariant(QVariantList, qvarlist)
end
@inline @cxxdereference setValue(v::QVariant, x::T) where {T} = setValue(T, v, x)
QVariant(::Type{Nothing}, ::Nothing) = QVariant()
@cxxdereference value(::Type{Nothing}, ::QML.QVariant) = nothing
@cxxdereference value(v::QVariant) = CxxWrap.dereference_argument(value(type(v),v))
Base.convert(::Type{QVariant}, x::T) where {T} = QVariant(x)
Base.convert(::Type{T}, x::QVariant) where {T} = convert(T,value(x))
Base.convert(::Type{Any}, x::QVariant) = x
Base.convert(::Type{<:QVariant}, x::QVariant) = x
@cxxdereference Base.show(io::IO, x::QVariant) = write(io, string("QVariant of type ", type(x), " with value ", value(x)))
Base.IndexStyle(::Type{<:QList}) = IndexLinear()
Base.size(v::QList) = (Int(cppsize(v)),)
Base.getindex(v::QList, i::Int) = cppgetindex(v,i-1)[]
Base.setindex!(v::QList{T}, val, i::Int) where {T} = cppsetindex!(v, convert(T,val), i-1)
function Base.push!(v::QList{T}, x) where {T}
push_back(v, convert(T,x))
return v
end
Base.empty!(l::QList) = clear(l)
Base.deleteat!(l::QList, i::Integer) = removeAt(l, i-1)
# Helper to call a julia function
function julia_call(f, argptr::Ptr{Cvoid})
arglist = CxxRef{QVariantList}(argptr)[]
result = QVariant(f((value(x) for x in arglist)...))
return result.cpp_object
end
function get_julia_call()
return @cfunction(julia_call, Ptr{Cvoid}, (Any,Ptr{Cvoid}))
end
# QQmlPropertyMap indexing interface
Base.getindex(propmap::QQmlPropertyMap, key::AbstractString) = value(value(propmap, key))
Base.setindex!(propmap::QQmlPropertyMap, val, key::AbstractString) = insert(propmap, QString(key), QVariant(val))
Base.setindex!(propmap::QQmlPropertyMap, val::QVariant, key::AbstractString) = insert(propmap, key, val)
Base.setindex!(propmap::QQmlPropertyMap, val::Irrational, key::AbstractString) = (propmap[key] = convert(Float64, val))
function on_value_changed end
mutable struct JuliaPropertyMap <: AbstractDict{String,Any}
propertymap::_JuliaPropertyMap
dict::Dict{String, Any}
function JuliaPropertyMap()
result = new(_JuliaPropertyMap(), Dict{String, Any}())
set_julia_value(result.propertymap, result)
connect_value_changed(result.propertymap, result, on_value_changed)
finalizer(result) do jpm
for k in keys(jpm.dict)
delete!(jpm, k) # Call delete on all keys to detach observable updates to QML
end
end
return result
end
end
"""
function JuliaPropertyMap(pairs...)
Store Julia values for access from QML. `Observables` are connected so they change on the
QML side when updated from Julia and vice versa only when passed in a property map. Note
that in the example below, if you run `output[] = new_value` from within Julia, the slider
in QML will move.
```jldoctest
julia> using QML
julia> using Observables: Observable, on
julia> output = Observable(0.0);
julia> on(println, output);
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import QtQuick 2.0
import QtQuick.Controls 1.0
ApplicationWindow {
visible: true
Slider {
onValueChanged: {
observables.output = value;
}
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
\""")
load(path; observables = JuliaPropertyMap("output" => output))
exec()
end
```
"""
function JuliaPropertyMap(pairs::Pair{<:AbstractString,<:Any}...)
result = JuliaPropertyMap()
for (k,v) in pairs
result[k] = v
end
return result
end
JuliaPropertyMap(dict::Dict{<:AbstractString,<:Any}) = JuliaPropertyMap(dict...)
@cxxdereference value(::Type{JuliaPropertyMap}, qvar::QVariant) = getpropertymap(qvar)
# Functor to update a QML property when an Observable is changed in Julia
struct QmlPropertyUpdater
propertymap::QQmlPropertyMap
key::String
end
function (updater::QmlPropertyUpdater)(x)
updater.propertymap[updater.key] = x
end
Base.getindex(jpm::JuliaPropertyMap, k::AbstractString) = jpm.dict[k]
Base.get(jpm::JuliaPropertyMap, k::AbstractString, def) = get(jpm.dict, k, def)
function Base.delete!(jpm::JuliaPropertyMap, k::AbstractString)
storedvalue = jpm.dict[k]
if storedvalue isa Observable
for observer in filter(x -> x isa QmlPropertyUpdater, Observables.listeners(storedvalue))
if observer.propertymap == jpm.propertymap
off(storedvalue, observer)
end
end
end
delete!(jpm.dict, k)
clear(jpm.propertymap, k)
end
function Base.setindex!(jpm::JuliaPropertyMap, val, key::AbstractString)
jpm.propertymap[key] = val
jpm.dict[key] = val
end
# Base.push!(jpm::JuliaPropertyMap, kv::Pair{<:AbstractString}) = setindex!(ENV, kv.second, kv.first)
function Base.setindex!(jpm::JuliaPropertyMap, ob::Observable, key::AbstractString)
val = QVariant(ob[])
jpm.propertymap[key] = val
jpm.dict[key] = ob
on(QmlPropertyUpdater(jpm.propertymap, key), ob)
end
Base.iterate(jpm::JuliaPropertyMap) = iterate(jpm.dict)
Base.iterate(jpm::JuliaPropertyMap, state) = iterate(jpm.dict, state)
Base.length(jpm::JuliaPropertyMap) = length(jpm.dict)
@cxxdereference function set_context_property(ctx::QQmlContext, name, jpm::JuliaPropertyMap)
gc_name = "__jlcxx_gc_protect" * name
set_context_property(ctx, gc_name, QVariant(jpm)) # This is to protect the jpm object from GC
set_context_property(ctx, name, jpm.propertymap) # QML needs the QQmlPropertyMap
end
# Called upon change from QML, so QmlPropertyUpdater is excluded from the handlers
@cxxdereference function on_value_changed(jpm::JuliaPropertyMap, key::QString, variantvalue::QVariant)
storedvalue = jpm[key]
newvalue = value(variantvalue)
if storedvalue isa Observable
Observables.setexcludinghandlers(storedvalue, newvalue, x -> !(x isa QmlPropertyUpdater))
else
jpm.dict[key] = newvalue
end
end
expand_dots(source_expr, func) =
if @capture source_expr object_.field_
Expr(:call, func, expand_dots(object, func), String(field))
else
source_expr
end
"""
QML.@expand_dots object_.field_ func
Expand an expression of the form a.b.c to replace the dot operator by function calls.
```jldoctest
julia> using QML
julia> @macroexpand QML.@expand_dots a.b.c.d f
:(f(f(f(a, "b"), "c"), "d"))
```
"""
macro expand_dots(source_expr, func)
esc(expand_dots(source_expr, func))
end
function emit(name, args...)
arglist = QVariantList()
for arg in args
push!(arglist, QVariant(arg))
end
emit(name, arglist)
end
"""
@emit signal_name(arguments...)
Emit a signal from Julia to QML. Handle signals in QML using a `JuliaSignals` block. See the
example below for syntax.
!!! warning
There must never be more than one JuliaSignals block in QML
```jldoctest
julia> using QML
julia> duplicate(value) = @emit duplicateSignal(value);
julia> @qmlfunction duplicate
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import QtQuick 2.2
import QtQuick.Controls 1.1
import QtQuick.Layouts 1.1
import org.julialang 1.0
ApplicationWindow {
visible: true
Column {
TextField {
id: input
onTextChanged: Julia.duplicate(text)
}
Text {
id: output
}
JuliaSignals {
signal duplicateSignal(var value)
onDuplicateSignal: output.text = value
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
}
\""")
load(path)
exec()
end
```
"""
macro emit(expr)
esc(:(emit($(string(expr.args[1])), $(expr.args[2:end]...))))
end
"""
@qmlfunction function_names...
Register Julia functions for access from QML under their own name. Function names must be
valid in QML, e.g. they can't contain `!`. You can use your newly registered functions in
QML by first importing `org.julialang 1.0`, and then calling them with
`Julia.function_name(arguments...)`. If you would like to register a function under a
different name, use [`qmlfunction`](@ref). This will be necessary for non-exported functions
from a different module or in case the function contains a `!` character.
```jldoctest
julia> using QML
julia> greet() = "Hello, World!";
julia> @qmlfunction greet
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import org.julialang 1.0
import QtQuick 2.0
import QtQuick.Controls 1.0
ApplicationWindow {
visible: true
Text {
text: Julia.greet()
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
\""")
load(path)
exec()
end
```
"""
macro qmlfunction(fnames...)
result = quote end
for fname in fnames
push!(result.args, :(qmlfunction($(esc(string(fname))), $(esc(fname)))))
end
return result
end
function qmlapp(path::AbstractString)
qml_engine = init_qmlapplicationengine()
return load_into_engine(qml_engine, path)
end
function Base.display(d::JuliaDisplay, x)
buf = IOBuffer()
supported_types = (MIME"image/svg+xml"(), MIME"image/png"())
write_methods = (load_svg, load_png)
written = false
for (t,write_method) in zip(supported_types, write_methods)
if showable(t,x)
Base.show(buf, t, x)
write_method(d, take!(buf))
written = true
break
end
end
if !written
throw(MethodError(display, (d,x)))
end
end
function Base.displayable(d::JuliaDisplay, mime::AbstractString)
if mime == "image/png"
return true
end
return false
end
struct ListModelFunctionUndefined <: Exception end
defaultsetter(array, value, index) = throw(ListModelFunctionUndefined())
defaultconstructor(roles...) = throw(ListModelFunctionUndefined())
mutable struct ListModelData
values::AbstractVector
roles::QStringList
getters::Vector{Any}
setters::Vector{Any}
constructor
customroles::Bool
function ListModelData(values::AbstractVector)
roles = QStringList()
return new(values, roles, [], [], defaultconstructor, false)
end
end
rowcount(m::ListModelData) = Int32(length(m.values))
rolenames(m::ListModelData) = m.roles
function data(m::ListModelData, row::Integer, role::Integer)
if row ∉ axes(m.values,1)
@warn "row $row is out of range for listmodel"
return QVariant()
end
@assert length(rolenames(m)) == length(m.getters)
return QVariant(m.getters[role](m.values[row]))
end
@cxxdereference function setdata(m::ListModelData, row::Integer, val::QVariant, role::Integer)
if row ∉ axes(m.values,1)
@warn "row $row is out of range for listmodel"
return false
end
try
m.setters[role](m.values, value(val), row)
return true
catch e
rolename = rolenames(m)[role]
if e isa ListModelFunctionUndefined
@warn "No setter for role $rolename"
else
@warn "Error $e when setting value at row $row for role $rolename"
end
return false
end
end
@cxxdereference function append_list(m::ListModelData, args::QVariantList)
try
push!(m.values, m.constructor((value(x) for x in args)...))
catch e
@error "Error $(typeof(e)) when appending value to listmodel."
end
end
function remove(m::ListModelData, row::Integer)
if row ∉ axes(m.values,1)
@warn "row $row is out of range for listmodel"
return
end
deleteat!(m.values, row)
end
function move(m::ListModelData, from::Integer, to::Integer, nb::Integer)
@assert from < to
# Save elements to mov
removed_elems = m.values[from:from+nb-1]
# Shift elements that remain
m.values[from:to-1] .= m.values[(from:to-1).+nb]
# Place saved elements in to block
m.values[to:to+nb-1] .= removed_elems
return
end
clear(m::ListModelData) = empty!(m.values)
Base.push!(m::ListModelData, val) = push!(m.values, val)
"""
function ListModel(items::AbstractVector, addroles::Bool = true)
Constructor for a ListModel. The `ListModel` type allows using data in QML views such as
`ListView` and `Repeater`, providing a two-way synchronization of the data. A ListModel is
constructed from a 1D Julia array. To use the model from QML, it can be exposed as a context
attribute.
A constructor (the `eltype`) and setter and getter "roles" based on the `fieldnames` of the
`eltype` will be automatically created if `addroles` is `true`.
If new elements need to be constructed from QML, a constructor can also be provided, using
the [`setconstructor`](@ref) method. QML can pass a list of arguments to constructors.
In Qt, each of the elements of a model has a series of roles, available as properties in the
delegate that is used to display each item. The roles can be added using the
[`addrole`](@ref) function.
```jldoctest
julia> using QML
julia> mutable struct Fruit
name::String
cost::Float64
end
julia> fruits = ListModel([Fruit("apple", 1.0), Fruit("orange", 2.0)]);
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import QtQuick 2.0
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0
ApplicationWindow {
visible: true
ListView {
model: fruits
anchors.fill: parent
delegate:
Row {
Text {
text: name
}
Button {
text: "Sale"
onClicked: cost = cost / 2
}
Button {
text: "Duplicate"
onClicked: fruits.append([name, cost])
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
}
}
\""")
load(path; fruits = fruits)
exec()
end
```
"""
function ListModel(a::AbstractVector{T}, addroles=true) where {T}
data = ListModelData(a)
if addroles
empty!(data.roles)
empty!(data.getters)
empty!(data.setters)
if !isabstracttype(T) && !isempty(fieldnames(T))
for fname in fieldnames(T)
push!(data.roles, string(fname))
push!(data.getters, (x) -> getfield(x, fname))
push!(data.setters, (array, value, index) -> setproperty!(array[index], fname, value))
end
data.constructor = T
else
push!(data.roles, "text")
push!(data.getters, string)
push!(data.setters, defaultsetter)
end
end
return ListModel(data)
end
"""
function roles(model::ListModel)
See all roles defined for a [`ListModel`](@ref). See the example for [`addrole`](@ref).
"""
roles(lm::ListModel) = rolenames(get_julia_data(lm))
"""
function addrole(model::ListModel, name::String, getter, [setter])
Add your own `getter` (and optionally, `setter`) functions to a [`ListModel`](@ref) for use
by QML. `setter` is optional, and if it is not provided the role will be read-only. `getter`
will process an item before it is returned. The arguments of `setter` will be
`collection, new_value, index` as in the standard `setindex!` function. If you would like to
see the roles defined for a list, use [`roles`](@ref). To remove a role, use
[`removerole`](@ref).
```jldoctest
julia> using QML
julia> items = ["A", "B"];
julia> array_model = ListModel(items, false);
julia> addrole(array_model, "item", identity, setindex!)
julia> roles(array_model)
1-element QML.QStringListAllocated:
"item"
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import QtQuick 2.0
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0
ApplicationWindow {
visible: true
ListView {
model: array_model
anchors.fill: parent
delegate: TextField {
placeholderText: item
onTextChanged: item = text;
}
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
\""")
load(path; array_model = array_model)
exec()
end
julia> removerole(array_model, "item")
```
"""
function addrole(lm::ListModel, name, getter, setter=defaultsetter)
m = get_julia_data(lm)
if name ∈ rolenames(m)
@error "Role $name exists, aborting add"
return
end
if !m.customroles
empty!(m.roles)
empty!(m.getters)
empty!(m.setters)
m.customroles = true
end
push!(m.roles, name)
push!(m.getters, getter)
push!(m.setters, setter)
emit_roles_changed(lm)
return
end
function setrole(lm::ListModel, idx::Integer, name, getter, setter=defaultsetter)
m = get_julia_data(lm)
if idx ∉ axes(rolenames(m),1)
@error "Listmodel index $idx is out of range, aborting setrole"
end
if name ∈ rolenames(m) && rolenames(m)[idx] != name
@error "Role $name exists, aborting setrole"
return
end
m.getters[idx] = getter
m.setters[idx] = setter
if rolenames(m)[idx] == name
emit_data_changed(lm, 0, length(lm), StdVector(Int32[idx]))
else
m.roles[idx] = name
emit_roles_changed(lm)
end
end
function removerole(lm::ListModel, idx::Integer)
m = get_julia_data(lm)
if idx ∉ axes(rolenames(m),1)
@error "Request to delete non-existing role $idx, aborting"
return
end
deleteat!(m.roles, idx)
deleteat!(m.getters, idx)
deleteat!(m.setters, idx)
@assert length(m.roles) == length(m.getters)
emit_roles_changed(lm)
end
"""
function removerole(model::ListModel, name::AbstractString)
Remove one of the [`roles`](@ref) from a [`ListModel`](@ref). See the example for
[`addrole`](@ref).
"""
function removerole(lm::ListModel, name::AbstractString)
m = get_julia_data(lm)
idx = findfirst(isequal(name), m.roles)
if isnothing(idx)
@error "Request to delete non-existing role $name, aborting"
return
end
removerole(lm,idx)
end
"""
function setconstructor(model::ListModel, constructor)
Add a constructor to a [`ListModel`](@ref). The `constructor` will process `append`ed items
before they are added. Note that you can simply pass a list of arguments from QML,
and they will be interpret in Julia as positional arguments.
```jldoctest
julia> using QML
julia> items = ["A", "B"];
julia> array_model = ListModel(items, false);
julia> setconstructor(array_model, uppercase);
julia> mktempdir() do folder
path = joinpath(folder, "main.qml")
write(path, \"""
import QtQuick 2.0
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0
ApplicationWindow {
visible: true
Button {
text: "Add C"
onClicked: array_model.append(["c"])
}
Timer {
running: true
onTriggered: Qt.quit()
}
}
\""")
load(path; array_model = array_model)
exec()
end
```
"""
function setconstructor(lm::ListModel, constructor)
get_julia_data(lm).constructor = constructor
end
# ListModel Julia interface
Base.getindex(lm::ListModel, idx::Int) = get_julia_data(lm).values[idx]
function Base.setindex!(lm::ListModel, value, idx::Int)
lmdata = get_julia_data(lm)
lmdata.values[idx] = value
emit_data_changed(lm, idx-1, 1, StdVector{Int32}())
end
Base.push!(lm::ListModel, val) = push_back(lm, val)
Base.size(lm::ListModel) = Base.size(get_julia_data(lm).values)
Base.length(lm::ListModel) = length(get_julia_data(lm).values)
Base.delete!(lm::ListModel, i) = remove(lm, i-1)
function force_model_update(lm::ListModel)
lmdata = get_julia_data(lm)
emit_data_changed(lm, 0, length(lm), StdVector{Int32}())
end
include("docs.jl")
end