-
Notifications
You must be signed in to change notification settings - Fork 233
/
riak_kv_vnode.erl
1406 lines (1294 loc) · 51.9 KB
/
riak_kv_vnode.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% -------------------------------------------------------------------
%%
%% riak_kv_vnode: VNode Implementation
%%
%% Copyright (c) 2007-2010 Basho Technologies, Inc. All Rights Reserved.
%%
%% This file is provided to you under the Apache License,
%% Version 2.0 (the "License"); you may not use this file
%% except in compliance with the License. You may obtain
%% a copy of the License at
%%
%% http://www.apache.org/licenses/LICENSE-2.0
%%
%% Unless required by applicable law or agreed to in writing,
%% software distributed under the License is distributed on an
%% "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
%% KIND, either express or implied. See the License for the
%% specific language governing permissions and limitations
%% under the License.
%%
%% -------------------------------------------------------------------
-module(riak_kv_vnode).
-author('Kevin Smith <kevin@basho.com>').
-author('John Muellerleile <johnm@basho.com>').
-behaviour(riak_core_vnode).
%% API
-export([test_vnode/1, put/7]).
-export([start_vnode/1,
get/3,
mget/3,
del/3,
put/6,
coord_put/6,
readrepair/6,
list_keys/4,
fold/3,
get_vclocks/2,
vnode_status/1,
ack_keys/1]).
%% riak_core_vnode API
-export([init/1,
terminate/2,
handle_command/3,
handle_coverage/4,
is_empty/1,
delete/1,
handle_handoff_command/3,
handoff_starting/2,
handoff_cancelled/1,
handoff_finished/2,
handle_handoff_data/2,
encode_handoff_item/2,
handle_exit/3,
handle_info/2]).
-include_lib("riak_kv_vnode.hrl").
-include_lib("riak_kv_map_phase.hrl").
-include_lib("riak_core/include/riak_core_pb.hrl").
-ifdef(TEST).
-include_lib("eunit/include/eunit.hrl").
-export([put_merge/6]). %% For fsm_eqc_vnode
-endif.
-record(mrjob, {cachekey :: term(),
bkey :: term(),
reqid :: term(),
target :: pid()}).
-record(state, {idx :: partition(),
index_backend :: boolean(),
mod :: module(),
modstate :: term(),
mrjobs :: term(),
vnodeid :: undefined | binary(),
delete_mode :: keep | immediate | pos_integer(),
bucket_buf_size :: pos_integer(),
index_buf_size :: pos_integer(),
key_buf_size :: pos_integer(),
async_backend :: boolean(),
in_handoff = false :: boolean() }).
-type index_op() :: add | remove.
-type index_value() :: integer() | binary().
-record(putargs, {returnbody :: boolean(),
coord:: boolean(),
lww :: boolean(),
bkey :: {binary(), binary()},
robj :: term(),
index_specs=[] :: [{index_op(), binary(), index_value()}],
reqid :: non_neg_integer(),
bprops :: maybe_improper_list(),
starttime :: non_neg_integer(),
prunetime :: undefined| non_neg_integer()}).
%% TODO: add -specs to all public API funcs, this module seems fragile?
%% API
start_vnode(I) ->
riak_core_vnode_master:get_vnode_pid(I, riak_kv_vnode).
test_vnode(I) ->
riak_core_vnode:start_link(riak_kv_vnode, I, infinity).
get(Preflist, BKey, ReqId) ->
Req = ?KV_GET_REQ{bkey=BKey,
req_id=ReqId},
%% Assuming this function is called from a FSM process
%% so self() == FSM pid
riak_core_vnode_master:command(Preflist,
Req,
{fsm, undefined, self()},
riak_kv_vnode_master).
mget(Preflist, BKeys, ReqId) ->
Req = ?KV_MGET_REQ{bkeys=BKeys,
req_id=ReqId,
from={fsm, self()}},
riak_core_vnode_master:command(Preflist,
Req,
riak_kv_vnode_master).
del(Preflist, BKey, ReqId) ->
riak_core_vnode_master:command(Preflist,
?KV_DELETE_REQ{bkey=BKey,
req_id=ReqId},
riak_kv_vnode_master).
%% Issue a put for the object to the preflist, expecting a reply
%% to an FSM.
put(Preflist, BKey, Obj, ReqId, StartTime, Options) when is_integer(StartTime) ->
put(Preflist, BKey, Obj, ReqId, StartTime, Options, {fsm, undefined, self()}).
put(Preflist, BKey, Obj, ReqId, StartTime, Options, Sender)
when is_integer(StartTime) ->
riak_core_vnode_master:command(Preflist,
?KV_PUT_REQ{
bkey = BKey,
object = Obj,
req_id = ReqId,
start_time = StartTime,
options = Options},
Sender,
riak_kv_vnode_master).
%% Issue a put for the object to the preflist, expecting a reply
%% to an FSM.
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options) when is_integer(StartTime) ->
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options, {fsm, undefined, self()}).
coord_put(IndexNode, BKey, Obj, ReqId, StartTime, Options, Sender)
when is_integer(StartTime) ->
riak_core_vnode_master:command(IndexNode,
?KV_PUT_REQ{
bkey = BKey,
object = Obj,
req_id = ReqId,
start_time = StartTime,
options = [coord | Options]},
Sender,
riak_kv_vnode_master).
%% Do a put without sending any replies
readrepair(Preflist, BKey, Obj, ReqId, StartTime, Options) ->
put(Preflist, BKey, Obj, ReqId, StartTime, [rr | Options], ignore).
list_keys(Preflist, ReqId, Caller, Bucket) ->
riak_core_vnode_master:command(Preflist,
#riak_kv_listkeys_req_v2{
bucket=Bucket,
req_id=ReqId,
caller=Caller},
ignore,
riak_kv_vnode_master).
fold(Preflist, Fun, Acc0) ->
riak_core_vnode_master:sync_spawn_command(Preflist,
?FOLD_REQ{
foldfun=Fun,
acc0=Acc0},
riak_kv_vnode_master).
get_vclocks(Preflist, BKeyList) ->
riak_core_vnode_master:sync_spawn_command(Preflist,
?KV_VCLOCK_REQ{bkeys=BKeyList},
riak_kv_vnode_master).
%% @doc Get status information about the node local vnodes.
-spec vnode_status([{partition(), pid()}]) -> [{atom(), term()}].
vnode_status(PrefLists) ->
ReqId = erlang:phash2(erlang:now()),
%% Get the status of each vnode
riak_core_vnode_master:command(PrefLists,
?KV_VNODE_STATUS_REQ{},
{raw, ReqId, self()},
riak_kv_vnode_master),
wait_for_vnode_status_results(PrefLists, ReqId, []).
%% VNode callbacks
init([Index]) ->
Mod = app_helper:get_env(riak_kv, storage_backend),
Configuration = app_helper:get_env(riak_kv),
BucketBufSize = app_helper:get_env(riak_kv, bucket_buffer_size, 1000),
IndexBufSize = app_helper:get_env(riak_kv, index_buffer_size, 100),
KeyBufSize = app_helper:get_env(riak_kv, key_buffer_size, 100),
{ok, VId} = get_vnodeid(Index),
DeleteMode = app_helper:get_env(riak_kv, delete_mode, 3000),
AsyncFolding = app_helper:get_env(riak_kv, async_folds, true),
case catch Mod:start(Index, [{async_folds, AsyncFolding},
Configuration]) of
{ok, ModState} ->
%% Get the backend capabilities
{_, Capabilities} = Mod:api_version(),
IndexBackend = lists:member(indexes, Capabilities),
AsyncBackend = AsyncFolding andalso
lists:member(async_fold, Capabilities),
State = #state{idx=Index,
async_backend=AsyncBackend,
index_backend=IndexBackend,
mod=Mod,
modstate=ModState,
vnodeid=VId,
delete_mode=DeleteMode,
bucket_buf_size=BucketBufSize,
index_buf_size=IndexBufSize,
key_buf_size=KeyBufSize,
mrjobs=dict:new()},
case AsyncBackend of
true ->
%% Create worker pool initialization tuple
FoldWorkerPool = {pool, riak_kv_worker, 10, []},
{ok, State, [FoldWorkerPool]};
false ->
{ok, State}
end;
{error, Reason} ->
lager:error("Failed to start ~p Reason: ~p",
[Mod, Reason]),
riak:stop("backend module failed to start.");
{'EXIT', Reason1} ->
lager:error("Failed to start ~p Reason: ~p",
[Mod, Reason1]),
riak:stop("backend module failed to start.")
end.
handle_command(?KV_PUT_REQ{bkey=BKey,
object=Object,
req_id=ReqId,
start_time=StartTime,
options=Options},
Sender, State=#state{idx=Idx}) ->
riak_kv_mapred_cache:eject(BKey),
riak_core_vnode:reply(Sender, {w, Idx, ReqId}),
UpdState = do_put(Sender, BKey, Object, ReqId, StartTime, Options, State),
{noreply, UpdState};
handle_command(?KV_GET_REQ{bkey=BKey,req_id=ReqId},Sender,State) ->
do_get(Sender, BKey, ReqId, State);
handle_command(?KV_MGET_REQ{bkeys=BKeys, req_id=ReqId, from=From}, _Sender, State) ->
do_mget(From, BKeys, ReqId, State);
handle_command(#riak_kv_listkeys_req_v1{bucket=Bucket, req_id=ReqId}, _Sender,
State=#state{mod=Mod, modstate=ModState, idx=Idx}) ->
do_legacy_list_bucket(ReqId,Bucket,Mod,ModState,Idx,State);
handle_command(#riak_kv_listkeys_req_v2{bucket=Input, req_id=ReqId, caller=Caller}, _Sender,
State=#state{async_backend=AsyncBackend,
key_buf_size=BufferSize,
mod=Mod,
modstate=ModState,
idx=Idx}) ->
case Input of
{filter, Bucket, Filter} ->
ok;
Bucket ->
Filter = none
end,
BufferMod = riak_kv_fold_buffer,
case Bucket of
'_' ->
case AsyncBackend of
true ->
Opts = [async_fold];
false ->
Opts = []
end,
BufferFun =
fun(Results) ->
UniqueResults = lists:usort(Results),
Caller ! {ReqId, {kl, Idx, UniqueResults}}
end,
FoldFun = fold_fun(buckets, BufferMod, Filter),
ModFun = fold_buckets;
_ ->
case AsyncBackend of
true ->
Opts = [async_fold, {bucket, Bucket}];
false ->
Opts = [{bucket, Bucket}]
end,
BufferFun =
fun(Results) ->
Caller ! {ReqId, {kl, Idx, Results}}
end,
FoldFun = fold_fun(keys, BufferMod, Filter),
ModFun = fold_keys
end,
Buffer = BufferMod:new(BufferSize, BufferFun),
FinishFun =
fun(Buffer1) ->
riak_kv_fold_buffer:flush(Buffer1),
Caller ! {ReqId, Idx, done}
end,
case list(FoldFun, FinishFun, Mod, ModFun, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Caller, State};
_ ->
{noreply, State}
end;
handle_command(?KV_DELETE_REQ{bkey=BKey, req_id=ReqId}, _Sender, State) ->
do_delete(BKey, ReqId, State);
handle_command(?KV_VCLOCK_REQ{bkeys=BKeys}, _Sender, State) ->
{reply, do_get_vclocks(BKeys, State), State};
handle_command(?FOLD_REQ{foldfun=FoldFun, acc0=Acc0}, Sender, State) ->
%% The function in riak_core used for object folding expects the
%% bucket and key pair to be passed as the first parameter, but in
%% riak_kv the bucket and key have been separated. This function
%% wrapper is to address this mismatch.
FoldWrapper = fun(Bucket, Key, Value, Acc) ->
FoldFun({Bucket, Key}, Value, Acc)
end,
do_fold(FoldWrapper, Acc0, Sender, State);
%% Commands originating from inside this vnode
handle_command({backend_callback, Ref, Msg}, _Sender,
State=#state{mod=Mod, modstate=ModState}) ->
Mod:callback(Ref, Msg, ModState),
{noreply, State};
handle_command({mapexec_error_noretry, JobId, Err}, _Sender, #state{mrjobs=Jobs}=State) ->
NewState = case dict:find(JobId, Jobs) of
{ok, Job} ->
Jobs1 = dict:erase(JobId, Jobs),
#mrjob{target=Target} = Job,
gen_fsm:send_event(Target, {mapexec_error_noretry, self(), Err}),
State#state{mrjobs=Jobs1};
error ->
State
end,
{noreply, NewState};
handle_command({mapexec_reply, JobId, Result}, _Sender, #state{mrjobs=Jobs}=State) ->
NewState = case dict:find(JobId, Jobs) of
{ok, Job} ->
Jobs1 = dict:erase(JobId, Jobs),
#mrjob{target=Target} = Job,
gen_fsm:send_event(Target, {mapexec_reply, Result, self()}),
State#state{mrjobs=Jobs1};
error ->
State
end,
{noreply, NewState};
handle_command(?KV_VNODE_STATUS_REQ{},
_Sender,
State=#state{idx=Index,
mod=Mod,
modstate=ModState}) ->
BackendStatus = {backend_status, Mod, Mod:status(ModState)},
VNodeStatus = [BackendStatus],
{reply, {vnode_status, Index, VNodeStatus}, State}.
%% @doc Handle a coverage request.
%% More information about the specification for the ItemFilter
%% parameter can be found in the documentation for the
%% {@link riak_kv_coverage_filter} module.
handle_coverage(?KV_LISTBUCKETS_REQ{item_filter=ItemFilter},
_FilterVNodes,
Sender,
State=#state{async_backend=AsyncBackend,
bucket_buf_size=BufferSize,
mod=Mod,
modstate=ModState}) ->
%% Construct the filter function
Filter = riak_kv_coverage_filter:build_filter(all, ItemFilter, undefined),
BufferMod = riak_kv_fold_buffer,
Buffer = BufferMod:new(BufferSize, result_fun(Sender)),
FoldFun = fold_fun(buckets, BufferMod, Filter),
FinishFun = finish_fun(BufferMod, Sender),
case AsyncBackend of
true ->
Opts = [async_fold];
false ->
Opts = []
end,
case list(FoldFun, FinishFun, Mod, fold_buckets, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end;
handle_coverage(#riak_kv_listkeys_req_v3{bucket=Bucket,
item_filter=ItemFilter},
FilterVNodes, Sender, State) ->
%% v3 == no backpressure
ResultFun = result_fun(Bucket, Sender),
handle_coverage_listkeys(Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, State);
handle_coverage(?KV_LISTKEYS_REQ{bucket=Bucket,
item_filter=ItemFilter},
FilterVNodes, Sender, State) ->
%% v4 == ack-based backpressure
ResultFun = result_fun_ack(Bucket, Sender),
handle_coverage_listkeys(Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender, State);
handle_coverage(?KV_INDEX_REQ{bucket=Bucket,
item_filter=ItemFilter,
qry=Query},
FilterVNodes,
Sender,
State=#state{async_backend=AsyncBackend,
idx=Index,
index_backend=IndexBackend,
index_buf_size=BufferSize,
mod=Mod,
modstate=ModState}) ->
case IndexBackend of
true ->
%% Construct the filter function
FilterVNode = proplists:get_value(Index, FilterVNodes),
Filter = riak_kv_coverage_filter:build_filter(Bucket, ItemFilter, FilterVNode),
BufferMod = riak_kv_fold_buffer,
Buffer = BufferMod:new(BufferSize, result_fun(Bucket, Sender)),
FoldFun = fold_fun(keys, BufferMod, Filter),
FinishFun = finish_fun(BufferMod, Sender),
case AsyncBackend of
true ->
Opts = [async_fold, {index, Bucket, Query}];
false ->
Opts = [{index, Bucket, Query}]
end,
case list(FoldFun, FinishFun, Mod, fold_keys, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end;
false ->
{reply, {error, {indexes_not_supported, Mod}}, State}
end.
%% Convenience for handling both v3 and v4 coverage-based listkeys
handle_coverage_listkeys(Bucket, ItemFilter, ResultFun,
FilterVNodes, Sender,
State=#state{async_backend=AsyncBackend,
idx=Index,
key_buf_size=BufferSize,
mod=Mod,
modstate=ModState}) ->
%% Construct the filter function
FilterVNode = proplists:get_value(Index, FilterVNodes),
Filter = riak_kv_coverage_filter:build_filter(Bucket, ItemFilter, FilterVNode),
BufferMod = riak_kv_fold_buffer,
Buffer = BufferMod:new(BufferSize, ResultFun),
FoldFun = fold_fun(keys, BufferMod, Filter),
FinishFun = finish_fun(BufferMod, Sender),
case AsyncBackend of
true ->
Opts = [async_fold, {bucket, Bucket}];
false ->
Opts = [{bucket, Bucket}]
end,
case list(FoldFun, FinishFun, Mod, fold_keys, ModState, Opts, Buffer) of
{async, AsyncWork} ->
{async, {fold, AsyncWork, FinishFun}, Sender, State};
_ ->
{noreply, State}
end.
%% While in handoff, vnodes have the option of returning {forward, State}
%% which will cause riak_core to forward the request to the handoff target
%% node. For riak_kv, we issue a put locally as well as forward it in case
%% the vnode has already handed off the previous version. All other requests
%% are handled locally and not forwarded since the relevant data may not have
%% yet been handed off to the target node. Since we do not forward deletes it
%% is possible that we do not clear a tombstone that was already handed off.
%% This is benign as the tombstone will eventually be re-deleted.
handle_handoff_command(Req=?KV_PUT_REQ{}, Sender, State) ->
{noreply, NewState} = handle_command(Req, Sender, State),
{forward, NewState};
%% Handle all unspecified cases locally without forwarding
handle_handoff_command(Req, Sender, State) ->
handle_command(Req, Sender, State).
handoff_starting(_TargetNode, State) ->
{true, State#state{in_handoff=true}}.
handoff_cancelled(State) ->
{ok, State#state{in_handoff=false}}.
handoff_finished(_TargetNode, State) ->
{ok, State}.
handle_handoff_data(BinObj, State) ->
PBObj = riak_core_pb:decode_riakobject_pb(zlib:unzip(BinObj)),
BKey = {PBObj#riakobject_pb.bucket,PBObj#riakobject_pb.key},
case do_diffobj_put(BKey, binary_to_term(PBObj#riakobject_pb.val), State) of
{ok, UpdModState} ->
{reply, ok, State#state{modstate=UpdModState}};
{error, Reason, UpdModState} ->
{reply, {error, Reason}, State#state{modstate=UpdModState}};
Err ->
{reply, {error, Err}, State}
end.
encode_handoff_item({B, K}, V) ->
zlib:zip(riak_core_pb:encode_riakobject_pb(
#riakobject_pb{bucket=B, key=K, val=V})).
is_empty(State=#state{mod=Mod, modstate=ModState}) ->
{Mod:is_empty(ModState), State}.
delete(State=#state{idx=Index,mod=Mod, modstate=ModState}) ->
%% clear vnodeid first, if drop removes data but fails
%% want to err on the side of creating a new vnodeid
{ok, cleared} = clear_vnodeid(Index),
case Mod:drop(ModState) of
{ok, UpdModState} ->
ok;
{error, Reason, UpdModState} ->
lager:error("Failed to drop ~p. Reason: ~p~n", [Mod, Reason]),
ok
end,
{ok, State#state{modstate=UpdModState,vnodeid=undefined}}.
terminate(_Reason, #state{mod=Mod, modstate=ModState}) ->
Mod:stop(ModState),
ok.
handle_info({final_delete, BKey, RObjHash}, State = #state{mod=Mod, modstate=ModState}) ->
UpdState = case do_get_term(BKey, Mod, ModState) of
{ok, RObj} ->
case delete_hash(RObj) of
RObjHash ->
do_backend_delete(BKey, RObj, State);
_ ->
State
end;
_ ->
State
end,
{ok, UpdState}.
handle_exit(_Pid, Reason, State) ->
%% A linked processes has died so the vnode
%% process should take appropriate action here.
%% The default behavior is to crash the vnode
%% process so that it can be respawned
%% by riak_core_vnode_master to prevent
%% messages from stacking up on the process message
%% queue and never being processed.
lager:error("Linked process exited. Reason: ~p", [Reason]),
{stop, linked_process_crash, State}.
%% @private
%% upon receipt of a client-initiated put
do_put(Sender, {Bucket,_Key}=BKey, RObj, ReqID, StartTime, Options, State) ->
case proplists:get_value(bucket_props, Options) of
undefined ->
{ok,Ring} = riak_core_ring_manager:get_my_ring(),
BProps = riak_core_bucket:get_bucket(Bucket, Ring);
BProps ->
BProps
end,
case proplists:get_value(rr, Options, false) of
true ->
PruneTime = undefined;
false ->
PruneTime = StartTime
end,
Coord = proplists:get_value(coord, Options, false),
PutArgs = #putargs{returnbody=proplists:get_value(returnbody,Options,false) orelse Coord,
coord=Coord,
lww=proplists:get_value(last_write_wins, BProps, false),
bkey=BKey,
robj=RObj,
reqid=ReqID,
bprops=BProps,
starttime=StartTime,
prunetime=PruneTime},
{PrepPutRes, UpdPutArgs} = prepare_put(State, PutArgs),
{Reply, UpdState} = perform_put(PrepPutRes, State, UpdPutArgs),
riak_core_vnode:reply(Sender, Reply),
riak_kv_stat:update(vnode_put),
UpdState.
do_backend_delete(BKey, RObj, State = #state{mod = Mod, modstate = ModState}) ->
%% object is a tombstone or all siblings are tombstones
riak_kv_mapred_cache:eject(BKey),
%% Calculate the index specs to remove...
%% JDM: This should just be a tombstone by this point, but better
%% safe than sorry.
IndexSpecs = riak_object:diff_index_specs(undefined, RObj),
%% Do the delete...
{Bucket, Key} = BKey,
case Mod:delete(Bucket, Key, IndexSpecs, ModState) of
{ok, UpdModState} ->
State#state{modstate = UpdModState};
{error, _Reason, UpdModState} ->
State#state{modstate = UpdModState}
end.
%% Compute a hash of the deleted object
delete_hash(RObj) ->
erlang:phash2(RObj, 4294967296).
prepare_put(#state{index_backend=false, vnodeid=VId},
PutArgs=#putargs{lww=true, robj=RObj, starttime=StartTime}) ->
{{true, riak_object:increment_vclock(RObj, VId, StartTime)}, PutArgs};
prepare_put(#state{index_backend=IndexBackend,
vnodeid=VId,
mod=Mod,
modstate=ModState},
PutArgs=#putargs{bkey={Bucket, Key},
robj=RObj,
bprops=BProps,
coord=Coord,
lww=LWW,
starttime=StartTime,
prunetime=PruneTime}) ->
case Mod:get(Bucket, Key, ModState) of
{error, not_found, _UpdModState} ->
case IndexBackend of
true ->
IndexSpecs = riak_object:index_specs(RObj);
false ->
IndexSpecs = []
end,
ObjToStore = case Coord of
true ->
riak_object:increment_vclock(RObj, VId, StartTime);
false ->
RObj
end,
{{true, ObjToStore}, PutArgs#putargs{index_specs=IndexSpecs}};
{ok, Val, _UpdModState} ->
OldObj = binary_to_term(Val),
case put_merge(Coord, LWW, OldObj, RObj, VId, StartTime) of
{oldobj, OldObj1} ->
{{false, OldObj1}, PutArgs};
{newobj, NewObj} ->
VC = riak_object:vclock(NewObj),
AMObj = enforce_allow_mult(NewObj, BProps),
case IndexBackend of
true ->
IndexSpecs =
riak_object:diff_index_specs(AMObj,
OldObj);
false ->
IndexSpecs = []
end,
case PruneTime of
undefined ->
ObjToStore = AMObj;
_ ->
ObjToStore =
riak_object:set_vclock(AMObj,
vclock:prune(VC,
PruneTime,
BProps))
end,
{{true, ObjToStore},
PutArgs#putargs{index_specs=IndexSpecs}}
end
end.
perform_put({false, Obj},
#state{idx=Idx}=State,
#putargs{returnbody=true,
reqid=ReqID}) ->
{{dw, Idx, Obj, ReqID}, State};
perform_put({false, _Obj},
#state{idx=Idx}=State,
#putargs{returnbody=false,
reqid=ReqId}) ->
{{dw, Idx, ReqId}, State};
perform_put({true, Obj},
#state{idx=Idx,
mod=Mod,
modstate=ModState}=State,
#putargs{returnbody=RB,
bkey={Bucket, Key},
reqid=ReqID,
index_specs=IndexSpecs}) ->
Val = term_to_binary(Obj),
case Mod:put(Bucket, Key, IndexSpecs, Val, ModState) of
{ok, UpdModState} ->
case RB of
true ->
Reply = {dw, Idx, Obj, ReqID};
false ->
Reply = {dw, Idx, ReqID}
end;
{error, _Reason, UpdModState} ->
Reply = {fail, Idx, ReqID}
end,
{Reply, State#state{modstate=UpdModState}}.
%% @private
%% enforce allow_mult bucket property so that no backend ever stores
%% an object with multiple contents if allow_mult=false for that bucket
enforce_allow_mult(Obj, BProps) ->
case proplists:get_value(allow_mult, BProps) of
true -> Obj;
_ ->
case riak_object:get_contents(Obj) of
[_] -> Obj;
Mult ->
{MD, V} = select_newest_content(Mult),
riak_object:set_contents(Obj, [{MD, V}])
end
end.
%% @private
%% choose the latest content to store for the allow_mult=false case
select_newest_content(Mult) ->
hd(lists:sort(
fun({MD0, _}, {MD1, _}) ->
riak_core_util:compare_dates(
dict:fetch(<<"X-Riak-Last-Modified">>, MD0),
dict:fetch(<<"X-Riak-Last-Modified">>, MD1))
end,
Mult)).
%% @private
put_merge(false, true, _CurObj, UpdObj, _VId, _StartTime) -> % coord=false, LWW=true
{newobj, UpdObj};
put_merge(false, false, CurObj, UpdObj, _VId, _StartTime) -> % coord=false, LWW=false
ResObj = riak_object:syntactic_merge(CurObj, UpdObj),
case ResObj =:= CurObj of
true ->
{oldobj, CurObj};
false ->
{newobj, ResObj}
end;
put_merge(true, true, _CurObj, UpdObj, VId, StartTime) -> % coord=false, LWW=true
{newobj, riak_object:increment_vclock(UpdObj, VId, StartTime)};
put_merge(true, false, CurObj, UpdObj, VId, StartTime) ->
UpdObj1 = riak_object:increment_vclock(UpdObj, VId, StartTime),
UpdVC = riak_object:vclock(UpdObj1),
CurVC = riak_object:vclock(CurObj),
%% Check the coord put will replace the existing object
case vclock:get_counter(VId, UpdVC) > vclock:get_counter(VId, CurVC) andalso
vclock:descends(CurVC, UpdVC) == false andalso
vclock:descends(UpdVC, CurVC) == true of
true ->
{newobj, UpdObj1};
false ->
%% If not, make sure it does
{newobj, riak_object:increment_vclock(
riak_object:merge(CurObj, UpdObj1), VId, StartTime)}
end.
%% @private
do_get(_Sender, BKey, ReqID,
State=#state{idx=Idx,mod=Mod,modstate=ModState}) ->
Retval = do_get_term(BKey, Mod, ModState),
riak_kv_stat:update(vnode_get),
{reply, {r, Retval, Idx, ReqID}, State}.
do_mget({fsm, Sender}, BKeys, ReqId, State=#state{idx=Idx, mod=Mod, modstate=ModState}) ->
F = fun(BKey) ->
R = do_get_term(BKey, Mod, ModState),
case R of
{ok, Obj} ->
gen_fsm:send_event(Sender, {r, Obj, Idx, ReqId});
_ ->
gen_fsm:send_event(Sender, {r, {R, BKey}, Idx, ReqId})
end,
riak_kv_stat:update(vnode_get) end,
[F(BKey) || BKey <- BKeys],
{noreply, State}.
%% @private
do_get_term(BKey, Mod, ModState) ->
case do_get_binary(BKey, Mod, ModState) of
{ok, Bin, _UpdModState} ->
{ok, binary_to_term(Bin)};
%% @TODO Eventually it would be good to
%% make the use of not_found or notfound
%% consistent throughout the code.
{error, not_found, _UpdatedModstate} ->
{error, notfound};
{error, Reason, _UpdatedModstate} ->
{error, Reason};
Err ->
Err
end.
do_get_binary({Bucket, Key}, Mod, ModState) ->
Mod:get(Bucket, Key, ModState).
%% @private
%% @doc This is a generic function for operations that involve
%% listing things from the backend. Examples are listing buckets,
%% listing keys, or doing secondary index queries.
list(FoldFun, FinishFun, Mod, ModFun, ModState, Opts, Buffer) ->
case Mod:ModFun(FoldFun, Buffer, Opts, ModState) of
{ok, Acc} ->
FinishFun(Acc);
{async, AsyncWork} ->
{async, AsyncWork}
end.
%% @private
fold_fun(buckets, BufferMod, none) ->
fun(Bucket, Buffer) ->
BufferMod:add(Bucket, Buffer)
end;
fold_fun(buckets, BufferMod, Filter) ->
fun(Bucket, Buffer) ->
case Filter(Bucket) of
true ->
BufferMod:add(Bucket, Buffer);
false ->
Buffer
end
end;
fold_fun(keys, BufferMod, none) ->
fun(_, Key, Buffer) ->
BufferMod:add(Key, Buffer)
end;
fold_fun(keys, BufferMod, Filter) ->
fun(_, Key, Buffer) ->
case Filter(Key) of
true ->
BufferMod:add(Key, Buffer);
false ->
Buffer
end
end.
%% @private
result_fun(Sender) ->
fun(Items) ->
riak_core_vnode:reply(Sender, Items)
end.
%% @private
result_fun(Bucket, Sender) ->
fun(Items) ->
riak_core_vnode:reply(Sender, {Bucket, Items})
end.
%% wait for acknowledgement that results were received before
%% continuing, as a way of providing backpressure for processes that
%% can't handle results as fast as we can send them
result_fun_ack(Bucket, Sender) ->
fun(Items) ->
Monitor = riak_core_vnode:monitor(Sender),
riak_core_vnode:reply(Sender, {{self(), Monitor}, Bucket, Items}),
receive
{Monitor, ok} ->
erlang:demonitor(Monitor, [flush]);
{'DOWN', Monitor, process, _Pid, _Reason} ->
throw(receiver_down)
end
end.
%% @doc If a listkeys request sends a result of `{From, Bucket,
%% Items}', that means it wants acknowledgement of those items before
%% it will send more. Call this function with that `From' to trigger
%% the next batch.
-spec ack_keys(From::{pid(), reference()}) -> term().
ack_keys({Pid, Ref}) ->
Pid ! {Ref, ok}.
%% @private
finish_fun(BufferMod, Sender) ->
fun(Buffer) ->
finish_fold(BufferMod, Buffer, Sender)
end.
%% @private
finish_fold(BufferMod, Buffer, Sender) ->
BufferMod:flush(Buffer),
riak_core_vnode:reply(Sender, done).
%% @private
%% @deprecated This function is only here to support
%% rolling upgrades and will be removed.
do_legacy_list_bucket(ReqID,'_',Mod,ModState,Idx,State) ->
FoldBucketsFun =
fun(Bucket, Buf) ->
[Bucket | Buf]
end,
RetVal = Mod:fold_buckets(FoldBucketsFun, [], [], ModState),
{reply, {kl, RetVal, Idx, ReqID}, State};
do_legacy_list_bucket(ReqID,Bucket,Mod,ModState,Idx,State) ->
FoldKeysFun =
fun(_, Key, Buf) ->
[Key | Buf]
end,
Opts = [{bucket, Bucket}],
case Mod:fold_keys(FoldKeysFun, [], Opts, ModState) of
{ok, RetVal} ->
{reply, {kl, RetVal, Idx, ReqID}, State};
{error, Reason} ->
{reply, {error, Reason, ReqID}, State}
end.
%% @private
do_delete(BKey, ReqId, State) ->
Mod = State#state.mod,
ModState = State#state.modstate,
Idx = State#state.idx,
DeleteMode = State#state.delete_mode,
%% Get the existing object.
case do_get_term(BKey, Mod, ModState) of
{ok, RObj} ->
%% Object exists, check if it should be deleted.
case riak_kv_util:obj_not_deleted(RObj) of
undefined ->
case DeleteMode of
keep ->
%% keep tombstones indefinitely
{reply, {fail, Idx, ReqId}, State};
immediate ->
UpdState = do_backend_delete(BKey, RObj, State),
{reply, {del, Idx, ReqId}, UpdState};
Delay when is_integer(Delay) ->
erlang:send_after(Delay, self(),
{final_delete, BKey,
delete_hash(RObj)}),
%% Nothing checks these messages - will just reply
%% del for now until we can refactor.
{reply, {del, Idx, ReqId}, State}
end;
_ ->
%% not a tombstone or not all siblings are tombstones
{reply, {fail, Idx, ReqId}, State}
end;
_ ->
%% does not exist in the backend
{reply, {fail, Idx, ReqId}, State}
end.
%% @private
do_fold(Fun, Acc0, Sender, State=#state{async_backend=AsyncBackend,
mod=Mod,
modstate=ModState}) ->
case AsyncBackend of
true ->
Opts = [async_fold];
false ->
Opts = []
end,
case Mod:fold_objects(Fun, Acc0, Opts, ModState) of
{ok, Acc} ->
{reply, Acc, State};
{async, Work} ->
FinishFun =
fun(Acc) ->
riak_core_vnode:reply(Sender, Acc)
end,
{async, {fold, Work, FinishFun}, Sender, State};
ER ->
{reply, ER, State}
end.
%% @private
do_get_vclocks(KeyList,_State=#state{mod=Mod,modstate=ModState}) ->
[{BKey, do_get_vclock(BKey,Mod,ModState)} || BKey <- KeyList].
%% @private
do_get_vclock({Bucket, Key}, Mod, ModState) ->
case Mod:get(Bucket, Key, ModState) of
{error, not_found, _UpdModState} -> vclock:fresh();
{ok, Val, _UpdModState} -> riak_object:vclock(binary_to_term(Val))
end.
%% @private
%% upon receipt of a handoff datum, there is no client FSM
do_diffobj_put({Bucket, Key}, DiffObj,
_StateData=#state{index_backend=IndexBackend,
mod=Mod,
modstate=ModState}) ->
case Mod:get(Bucket, Key, ModState) of
{error, not_found, _UpdModState} ->
case IndexBackend of
true ->
IndexSpecs = riak_object:index_specs(DiffObj);
false ->
IndexSpecs = []